qcsrc/common/mutators/mutator/casings.qc

   1 #include "../../util.qh"
   2
   3 #ifdef CSQC
   4 #include "../../movetypes/movetypes.qh"
   5 #include "../../../client/rubble.qh"
   6 #endif
   7
   8 REGISTER_MUTATOR(casings, true);
   9
  10 #ifdef SVQC
  11 void SpawnCasing(vector vel, float randomvel, vector ang, vector avel, float randomavel, int casingtype, entity casingowner)
  12 {SELFPARAM();
  13     vector org = self.origin + self.view_ofs + self.weaponentity.spawnorigin.x * v_forward - self.weaponentity.spawnorigin.y * v_right + self.weaponentity.spawnorigin.z * v_up;
  14
  15     if (!sound_allowed(MSG_BROADCAST, casingowner))
  16         casingtype |= 0x80;
  17
  18     WriteByte(MSG_ALL, SVC_TEMPENTITY);
  19     WriteMutator(MSG_ALL, casings);
  20     WriteByte(MSG_ALL, casingtype);
  21     WriteCoord(MSG_ALL, org.x);
  22     WriteCoord(MSG_ALL, org.y);
  23     WriteCoord(MSG_ALL, org.z);
  24     WriteShort(MSG_ALL, compressShortVector(vel)); // actually compressed velocity
  25     WriteByte(MSG_ALL, ang.x * 256 / 360);
  26     WriteByte(MSG_ALL, ang.y * 256 / 360);
  27     WriteByte(MSG_ALL, ang.z * 256 / 360);
  28 }
  29 #endif
  30
  31 #ifdef CSQC
  32 entityclass(Casing);
  33 class(Casing) .float alpha;
  34 class(Casing) .bool silent;
  35 class(Casing) .int state;
  36 class(Casing) .float cnt;
  37
  38 void Casing_Delete()
  39 {SELFPARAM();
  40     remove(self);
  41 }
  42
  43 void Casing_Draw()
  44 {SELFPARAM();
  45     if (self.move_flags & FL_ONGROUND)
  46     {
  47         self.move_angles_x = 0;
  48         self.move_angles_z = 0;
  49         self.flags &= ~FL_ONGROUND;
  50     }
  51
  52     Movetype_Physics_MatchTicrate(autocvar_cl_casings_ticrate, autocvar_cl_casings_sloppy);
  53     if (wasfreed(self))
  54         return; // deleted by touch function
  55
  56     self.renderflags = 0;
  57     self.alpha = bound(0, self.cnt - time, 1);
  58
  59     if (self.alpha < ALPHA_MIN_VISIBLE)
  60     {
  61         Casing_Delete();
  62         self.drawmask = 0;
  63     }
  64 }
  65
  66 void Casing_Touch()
  67 {SELFPARAM();
  68     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  69     {
  70         Casing_Delete();
  71         return;
  72     }
  73
  74     if (!self.silent)
  75     if (!trace_ent || trace_ent.solid == SOLID_BSP)
  76     {
  77         if (vlen(self.velocity) > 50)
  78         {
  79             if (time >= self.nextthink)
  80             {
  81                 string s;
  82                 int f = floor(prandom() * 3) + 1;
  83
  84                 switch (self.state)
  85                 {
  86                     case 1:
  87                         s = W_Sound(strcat("casings", itos(f)));
  88                         break;
  89                     default:
  90                         s = W_Sound(strcat("brass", itos(f)));
  91                         break;
  92                 }
  93
  94                 sound (self, CH_SHOTS, s, VOL_BASE, ATTEN_LARGE);
  95             }
  96         }
  97     }
  98
  99     self.nextthink = time + 0.2;
 100 }
 101
 102 void Casing_Damage(float thisdmg, int hittype, vector org, vector thisforce)
 103 {SELFPARAM();
 104     if (thisforce.z < 0)
 105         thisforce.z = 0;
 106     self.move_velocity = self.move_velocity + thisforce + '0 0 100';
 107     self.move_flags &= ~FL_ONGROUND;
 108 }
 109
 110 MUTATOR_HOOKFUNCTION(casings, CSQC_Parse_TempEntity)
 111 {
 112     if (MUTATOR_RETURNVALUE) return;
 113     if (!ReadMutatorEquals(mutator_argv_int_0, casings)) return;
 114     return = true;
 115
 116     int _state = ReadByte();
 117     vector org;
 118     org_x = ReadCoord();
 119     org_y = ReadCoord();
 120     org_z = ReadCoord();
 121     vector vel = decompressShortVector(ReadShort());
 122     vector ang;
 123     ang_x = ReadByte() * 360 / 256;
 124     ang_y = ReadByte() * 360 / 256;
 125     ang_z = ReadByte() * 360 / 256;
 126
 127     if (!autocvar_cl_casings) return;
 128
 129     Casing casing = RubbleNew("casing");
 130     casing.silent = (_state & 0x80);
 131     casing.state = (_state & 0x7F);
 132     casing.origin = org;
 133     setorigin(casing, casing.origin);
 134     casing.velocity = vel;
 135     casing.angles = ang;
 136     casing.drawmask = MASK_NORMAL;
 137
 138     casing.draw = Casing_Draw;
 139     casing.move_origin = casing.origin;
 140     casing.move_velocity = casing.velocity + 2 * prandomvec();
 141     casing.move_angles = casing.angles;
 142     casing.move_avelocity = '0 250 0' + 100 * prandomvec();
 143     casing.move_movetype = MOVETYPE_BOUNCE;
 144     casing.move_touch = Casing_Touch;
 145     casing.move_time = time;
 146     casing.event_damage = Casing_Damage;
 147     casing.solid = SOLID_TRIGGER;
 148
 149     switch (casing.state)
 150     {
 151         case 1:
 152             setmodel(casing, "models/casing_shell.mdl");
 153             casing.cnt = time + autocvar_cl_casings_shell_time;
 154             break;
 155         default:
 156             setmodel(casing, "models/casing_bronze.iqm");
 157             casing.cnt = time + autocvar_cl_casings_bronze_time;
 158             break;
 159     }
 160
 161     setsize(casing, '0 0 -1', '0 0 -1');
 162
 163     RubbleLimit("casing", autocvar_cl_casings_maxcount, Casing_Delete);
 164 }
 165
 166 STATIC_INIT(Casings)
 167 {
 168     precache_model("models/casing_shell.mdl");
 169     precache_model("models/casing_bronze.iqm");
 170     precache_sound(W_Sound("brass1"));
 171     precache_sound(W_Sound("brass2"));
 172     precache_sound(W_Sound("brass3"));
 173     precache_sound(W_Sound("casings1"));
 174     precache_sound(W_Sound("casings2"));
 175     precache_sound(W_Sound("casings3"));
 176 }
 177 #endif