qcsrc/common/mutators/mutator/damagetext/cl_damagetext.qc

   1 #include "cl_damagetext.qh"
   2
   3 // no translatable cvar description please
   4 AUTOCVAR_SAVE(cl_damagetext,                        bool,   true,       "Draw damage dealt where you hit the enemy");
   5 AUTOCVAR_SAVE(cl_damagetext_format,                 string, "-{total}", "How to format the damage text. {health}, {armor}, {total}, {potential}: full damage not capped to target's health, {potential_health}: health damage not capped to target's health");
   6 AUTOCVAR_SAVE(cl_damagetext_format_verbose,         bool,   false,      "{health} shows {potential_health} too when they differ; {total} shows {potential} too when they differ");
   7 AUTOCVAR_SAVE(cl_damagetext_format_hide_redundant,  bool,   false,      "hide {armor} if 0; hide {potential} and {potential_health} when same as actual");
   8 STATIC_INIT(DamageText_LegacyFormat) {
   9     // damagetext used to be off by default and the cvar got saved in people's configs along with the old format
  10     // enable damagetext while updating the format for a one time effect
  11     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) {
  12         localcmd("\nseta cl_damagetext 1\n");
  13         localcmd("\nseta cl_damagetext_format -{total}\n");
  14     };
  15 }
  16 AUTOCVAR_SAVE(cl_damagetext_color,                  vector, '1 1 0',    "Damage text color");
  17 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,       bool,   false,      "Damage text uses weapon color");
  18 AUTOCVAR_SAVE(cl_damagetext_size_min,               float,  10,          "Damage text font size for small damage");
  19 AUTOCVAR_SAVE(cl_damagetext_size_min_damage,        float,  25,          "How much damage is considered small");
  20 AUTOCVAR_SAVE(cl_damagetext_size_max,               float,  16,         "Damage text font size for large damage");
  21 AUTOCVAR_SAVE(cl_damagetext_size_max_damage,        float,  140,        "How much damage is considered large");
  22 AUTOCVAR_SAVE(cl_damagetext_alpha_start,            float,  1,          "Damage text initial alpha");
  23 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,         float,  3,          "Damage text lifetime in seconds");
  24 AUTOCVAR_SAVE(cl_damagetext_velocity,               vector, '0 0 20',   "Damage text move direction (world coordinates)");
  25 AUTOCVAR_SAVE(cl_damagetext_offset,                 vector, '0 -40 0',  "Damage text offset (screen coordinates)");
  26 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,       float,  30,         "Damage text spawned within this range is accumulated");
  27 AUTOCVAR_SAVE(cl_damagetext_accumulate_alpha_rel,   float,  0.65,       "Only update existing damage text when it's above this much percentage (0 to 1) of the starting alpha");
  28 AUTOCVAR_SAVE(cl_damagetext_friendlyfire,           bool,   true,       "Show damage text for friendlyfire too");
  29 AUTOCVAR_SAVE(cl_damagetext_friendlyfire_color,     vector, '1 0 0',    "Damage text color for friendlyfire");
  30
  31 AUTOCVAR_SAVE(cl_damagetext_2d,                     bool,   true,       "Show damagetext in 2D coordinated if the enemy's location is not known");
  32 AUTOCVAR_SAVE(cl_damagetext_2d_pos,                 vector, '0.47 0.53 0',     "2D damage text initial position (X and Y between 0 and 1)");
  33 AUTOCVAR_SAVE(cl_damagetext_2d_alpha_start,         float,  1,          "2D damage text initial alpha");
  34 AUTOCVAR_SAVE(cl_damagetext_2d_alpha_lifetime,      float,  1.3,        "2D damage text lifetime (alpha fading) in seconds");
  35 AUTOCVAR_SAVE(cl_damagetext_2d_size_lifetime,       float,  3,          "2D damage text lifetime (size shrinking) in seconds");
  36 AUTOCVAR_SAVE(cl_damagetext_2d_velocity,            vector, '-25 0 0',  "2D damage text move direction (screen coordinates)");
  37 AUTOCVAR_SAVE(cl_damagetext_2d_overlap_offset,      vector, '0 -15 0',  "Offset 2D damage text by this much to prevent overlapping (screen coordinates)");
  38 AUTOCVAR_SAVE(cl_damagetext_2d_close_range,         float,  125,        "Always use 2D damagetext for hits closer that this");
  39 AUTOCVAR_SAVE(cl_damagetext_2d_out_of_view,         bool,   true,       "Always use 2D damagetext for hits that occured off-screen");
  40
  41 CLASS(DamageText, Object)
  42     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color);
  43     ATTRIB(DamageText, m_color_friendlyfire, vector, autocvar_cl_damagetext_friendlyfire_color);
  44     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size_min);
  45     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start);
  46     ATTRIB(DamageText, fade_rate, float, 0);
  47     ATTRIB(DamageText, m_shrink_rate, float, 0);
  48     ATTRIB(DamageText, m_group, int, 0);
  49     ATTRIB(DamageText, m_friendlyfire, bool, false);
  50     ATTRIB(DamageText, m_healthdamage, int, 0);
  51     ATTRIB(DamageText, m_armordamage, int, 0);
  52     ATTRIB(DamageText, m_potential_damage, int, 0);
  53     ATTRIB(DamageText, m_deathtype, int, 0);
  54     ATTRIB(DamageText, hit_time, float, 0);
  55     ATTRIB(DamageText, text, string, string_null);
  56     ATTRIB(DamageText, m_screen_coords, bool, false);
  57
  58     STATIC_ATTRIB(DamageText, screen_first, DamageText, NULL);
  59     STATIC_ATTRIB(DamageText, screen_count, int, 0);
  60
  61     void DamageText_draw2d(DamageText this) {
  62         float since_hit = time - this.hit_time;
  63         float size = this.m_size - since_hit * this.m_shrink_rate * this.m_size;
  64         float alpha_ = this.alpha - since_hit * this.fade_rate;
  65         if (alpha_ <= 0 || size <= 0) {
  66             delete(this);
  67             return;
  68         }
  69         vector screen_pos;
  70         if (this.m_screen_coords) {
  71             screen_pos = this.origin + since_hit * autocvar_cl_damagetext_2d_velocity;
  72         } else {
  73             screen_pos = project_3d_to_2d(this.origin + since_hit * autocvar_cl_damagetext_velocity) + autocvar_cl_damagetext_offset;
  74         }
  75         if (screen_pos.z >= 0) {
  76             screen_pos.z = 0;
  77             vector rgb;
  78             if (this.m_friendlyfire) {
  79                 rgb = this.m_color_friendlyfire;
  80             } else {
  81                 rgb = this.m_color;
  82             }
  83             if (autocvar_cl_damagetext_color_per_weapon) {
  84                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  85                 if (w != WEP_Null) rgb = w.wpcolor;
  86             }
  87
  88             vector drawfontscale_save = drawfontscale;
  89             drawfontscale = (size / autocvar_cl_damagetext_size_max) * '1 1 0';
  90             drawcolorcodedstring2_builtin(screen_pos, this.text, autocvar_cl_damagetext_size_max * '1 1 0', rgb, alpha_, DRAWFLAG_NORMAL);
  91             drawfontscale = drawfontscale_save;
  92         }
  93     }
  94     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d);
  95
  96     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _potential_damage, int _deathtype) {
  97         this.m_healthdamage = _health;
  98         this.m_armordamage = _armor;
  99         this.m_potential_damage = _potential_damage;
 100         this.m_deathtype = _deathtype;
 101         setorigin(this, _origin);
 102         if (this.m_screen_coords) {
 103             this.alpha = autocvar_cl_damagetext_2d_alpha_start;
 104         } else {
 105             this.alpha = autocvar_cl_damagetext_alpha_start;
 106         }
 107         this.hit_time = time;
 108
 109         int health = rint(this.m_healthdamage / DAMAGETEXT_PRECISION_MULTIPLIER);
 110         int armor = rint(this.m_armordamage / DAMAGETEXT_PRECISION_MULTIPLIER);
 111         int total = rint((this.m_healthdamage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER);
 112         int potential = rint(this.m_potential_damage / DAMAGETEXT_PRECISION_MULTIPLIER);
 113         int potential_health = rint((this.m_potential_damage - this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER);
 114
 115         bool redundant = almost_equals_eps(this.m_healthdamage + this.m_armordamage, this.m_potential_damage, 5);
 116
 117         string s = autocvar_cl_damagetext_format;
 118         s = strreplace("{armor}", (
 119             (this.m_armordamage == 0 && autocvar_cl_damagetext_format_hide_redundant)
 120                 ? ""
 121                 : sprintf("%d", armor)
 122             ), s);
 123         s = strreplace("{potential}", (
 124             (redundant && autocvar_cl_damagetext_format_hide_redundant)
 125                 ? ""
 126                 : sprintf("%d", potential)
 127             ), s);
 128         s = strreplace("{potential_health}", (
 129             (redundant && autocvar_cl_damagetext_format_hide_redundant)
 130                 ? ""
 131                 : sprintf("%d", potential_health)
 132             ), s);
 133
 134         s = strreplace("{health}", (
 135             (health == potential_health || !autocvar_cl_damagetext_format_verbose)
 136                 ? sprintf("%d",      health)
 137                 : sprintf("%d (%d)", health, potential_health)
 138             ), s);
 139         s = strreplace("{total}", (
 140             (total == potential || !autocvar_cl_damagetext_format_verbose)
 141                 ? sprintf("%d",      total)
 142                 : sprintf("%d (%d)", total, potential)
 143             ), s);
 144
 145         // futureproofing: remove any remaining (unknown) format strings in case we add new ones in the future
 146         // so players can use them on new servers and still have working damagetext on old ones
 147         while (true) {
 148             int opening_pos = strstrofs(s, "{", 0);
 149             if (opening_pos == -1) break;
 150             int closing_pos = strstrofs(s, "}", opening_pos);
 151             if (closing_pos == -1 || closing_pos <= opening_pos) break;
 152             s = strcat(
 153                 substring(s, 0, opening_pos),
 154                 substring_range(s, closing_pos + 1, strlen(s))
 155             );
 156         }
 157
 158         strcpy(this.text, s);
 159
 160         this.m_size = map_bound_ranges(potential,
 161             autocvar_cl_damagetext_size_min_damage, autocvar_cl_damagetext_size_max_damage,
 162             autocvar_cl_damagetext_size_min, autocvar_cl_damagetext_size_max);
 163     }
 164
 165     CONSTRUCTOR(DamageText, int _group, vector _origin, bool _screen_coords, int _health, int _armor, int _potential_damage, int _deathtype, bool _friendlyfire) {
 166         CONSTRUCT(DamageText);
 167         this.m_group = _group;
 168         this.m_friendlyfire = _friendlyfire;
 169         this.m_screen_coords = _screen_coords;
 170         if (_screen_coords) {
 171             this.fade_rate = 1 / autocvar_cl_damagetext_2d_alpha_lifetime;
 172             this.m_shrink_rate = 1 / autocvar_cl_damagetext_2d_size_lifetime;
 173         } else {
 174             this.fade_rate = 1 / autocvar_cl_damagetext_alpha_lifetime;
 175             this.m_shrink_rate = 0;
 176         }
 177         DamageText_update(this, _origin, _health, _armor, _potential_damage, _deathtype);
 178         IL_PUSH(g_drawables_2d, this);
 179     }
 180
 181     DESTRUCTOR(DamageText) {
 182         strfree(this.text);
 183         if (this == DamageText_screen_first) {
 184             // start from 0 offset again, hopefully, others (if any) will have faded away by now
 185             DamageText_screen_first = NULL;
 186             DamageText_screen_count = 0;
 187         }
 188     }
 189 ENDCLASS(DamageText)
 190
 191 NET_HANDLE(damagetext, bool isNew)
 192 {
 193     int server_entity_index = ReadByte();
 194     int deathtype = ReadInt24_t();
 195     int flags = ReadByte();
 196     bool friendlyfire = flags & DTFLAG_SAMETEAM;
 197
 198     int health, armor, potential_damage;
 199     if (flags & DTFLAG_BIG_HEALTH) health = ReadInt24_t();
 200     else health = ReadShort();
 201     if (flags & DTFLAG_NO_ARMOR) armor = 0;
 202     else if (flags & DTFLAG_BIG_ARMOR) armor = ReadInt24_t();
 203     else armor = ReadShort();
 204     if (flags & DTFLAG_NO_POTENTIAL) potential_damage = health + armor;
 205     else if (flags & DTFLAG_BIG_POTENTIAL) potential_damage = ReadInt24_t();
 206     else potential_damage = ReadShort();
 207
 208     return = true;
 209     if (!autocvar_cl_damagetext) return;
 210     if (friendlyfire && !autocvar_cl_damagetext_friendlyfire) return;
 211
 212     int client_entity_index = server_entity_index - 1;
 213     entity entcs = entcs_receiver(client_entity_index);
 214
 215     bool can_use_3d = entcs && entcs.has_origin;
 216     bool too_close = vdist(entcs.origin - view_origin, <, autocvar_cl_damagetext_2d_close_range);
 217     bool prefer_in_view = autocvar_cl_damagetext_2d_out_of_view && !projected_on_screen(project_3d_to_2d(entcs.origin));
 218     bool prefer_2d = spectatee_status != -1 && autocvar_cl_damagetext_2d && (too_close || prefer_in_view);
 219
 220     if (can_use_3d && !prefer_2d) {
 221         // world coords
 222         if (autocvar_cl_damagetext_accumulate_range) {
 223             for (entity e = findradius(entcs.origin, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 224                 if (e.instanceOfDamageText
 225                     && !e.m_screen_coords // we're using origin for both world coords and screen coords so avoid mismatches
 226                     && e.m_group == server_entity_index
 227                     && e.alpha > autocvar_cl_damagetext_accumulate_alpha_rel * autocvar_cl_damagetext_alpha_start) {
 228                     DamageText_update(e, entcs.origin, e.m_healthdamage + health, e.m_armordamage + armor, e.m_potential_damage + potential_damage, deathtype);
 229                     return;
 230                 }
 231             }
 232         }
 233         make_impure(NEW(DamageText, server_entity_index, entcs.origin, false, health, armor, potential_damage, deathtype, friendlyfire));
 234     } else if (autocvar_cl_damagetext_2d && spectatee_status != -1) {
 235         // never show 2d damagetext when observing - might be a bug in .has_origin
 236
 237         // screen coords only
 238         vector screen_pos = vec2(vid_conwidth * autocvar_cl_damagetext_2d_pos.x, vid_conheight * autocvar_cl_damagetext_2d_pos.y);
 239         IL_EACH(g_drawables_2d, it.instanceOfDamageText && it.m_screen_coords && it.m_group == server_entity_index, {
 240             DamageText_update(it, screen_pos, it.m_healthdamage + health, it.m_armordamage + armor, it.m_potential_damage + potential_damage, deathtype);
 241             return;
 242         });
 243
 244         // when hitting multiple enemies, dmgtext would overlap
 245         if (DamageText_screen_first == NULL) {
 246             DamageText dt = NEW(DamageText, server_entity_index, screen_pos, true, health, armor, potential_damage, deathtype, friendlyfire);
 247             make_impure(dt);
 248             DamageText_screen_first = dt;
 249             DamageText_screen_count = 1;
 250         } else {
 251             screen_pos += autocvar_cl_damagetext_2d_overlap_offset * DamageText_screen_count;
 252             DamageText_screen_count++;
 253             make_impure(NEW(DamageText, server_entity_index, screen_pos, true, health, armor, potential_damage, deathtype, friendlyfire));
 254         }
 255     }
 256 }