49097aa814b0917f92e7a29a25fb0b5abd823aa4
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mutators / mutator / damagetext / damagetext.qc
1 #include "damagetext.qh"
2
3 #define DAMAGETEXT_PRECISION_MULTIPLIER 128
4 #define DAMAGETEXT_SHORT_LIMIT 256 // the smallest value that we can't send as short - 2^15 (signed short) / DAMAGETEXT_PRECISION_MULTIPLIER
5
6 const int DTFLAG_SAMETEAM = BIT(0);
7 const int DTFLAG_BIG_HEALTH = BIT(1);
8 const int DTFLAG_BIG_ARMOR = BIT(2);
9 const int DTFLAG_BIG_POTENTIAL = BIT(3);
10 const int DTFLAG_NO_ARMOR = BIT(4);
11 const int DTFLAG_NO_POTENTIAL = BIT(5);
12
13 REGISTER_MUTATOR(damagetext, true);
14
15 // || defined(MENUQC)
16 #if defined(CSQC)
17 // no translatable cvar description please
18 AUTOCVAR_SAVE(cl_damagetext,                        bool,   true,       "Draw damage dealt where you hit the enemy");
19 AUTOCVAR_SAVE(cl_damagetext_format,                 string, "-{total}", "How to format the damage text. {health}, {armor}, {total}, {potential}: full damage not capped to target's health, {potential_health}: health damage not capped to target's health");
20 AUTOCVAR_SAVE(cl_damagetext_format_verbose,         bool,   false,      "{health} shows {potential_health} too when they differ; {total} shows {potential} too when they differ");
21 STATIC_INIT(DamageText_LegacyFormat) {
22     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) autocvar_cl_damagetext_format = "-{total}";
23 }
24 AUTOCVAR_SAVE(cl_damagetext_color,                  vector, '1 1 0',    "Damage text color");
25 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,       bool,   false,      "Damage text uses weapon color");
26 AUTOCVAR_SAVE(cl_damagetext_size,                   float,  8,          "Damage text font size");
27 AUTOCVAR_SAVE(cl_damagetext_alpha_start,            float,  1,          "Damage text initial alpha");
28 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,         float,  3,          "Damage text lifetime in seconds");
29 AUTOCVAR_SAVE(cl_damagetext_velocity,               vector, '0 0 20',   "Damage text move direction");
30 AUTOCVAR_SAVE(cl_damagetext_offset,                 vector, '0 -40 0',  "Damage text offset");
31 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,       float,  30,         "Damage text spawned within this range is accumulated");
32 AUTOCVAR_SAVE(cl_damagetext_accumulate_alpha_rel,   float,  0.65,       "Only update existing damage text when it's above this much percentage (0 to 1) of the starting alpha");
33 AUTOCVAR_SAVE(cl_damagetext_friendlyfire,           bool,   true,       "Show damage text for friendlyfire too");
34 AUTOCVAR_SAVE(cl_damagetext_friendlyfire_color,     vector, '1 0 0',    "Damage text color for friendlyfire");
35 #endif
36
37 #ifdef CSQC
38 CLASS(DamageText, Object)
39     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color);
40     ATTRIB(DamageText, m_color_friendlyfire, vector, autocvar_cl_damagetext_friendlyfire_color);
41     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size);
42     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start);
43     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime);
44     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity);
45     ATTRIB(DamageText, m_group, int, 0);
46     ATTRIB(DamageText, m_friendlyfire, bool, false);
47     ATTRIB(DamageText, m_damage, int, 0);
48     ATTRIB(DamageText, m_armordamage, int, 0);
49     ATTRIB(DamageText, m_potential_damage, int, 0);
50     ATTRIB(DamageText, m_deathtype, int, 0);
51     ATTRIB(DamageText, time_prev, float, time);
52
53     void DamageText_draw2d(DamageText this) {
54         float dt = time - this.time_prev;
55         this.time_prev = time;
56         setorigin(this, this.origin + dt * this.velocity);
57         this.alpha -= dt * this.fade_rate;
58         if (this.alpha < 0) delete(this);
59         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
60         if (pos.z >= 0 && this.m_size > 0) {
61             pos.z = 0;
62             vector rgb;
63             if (this.m_friendlyfire) {
64                 rgb = this.m_color_friendlyfire;
65             }
66             else {
67                 rgb = this.m_color;
68             }
69             if (autocvar_cl_damagetext_color_per_weapon) {
70                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
71                 if (w != WEP_Null) rgb = w.wpcolor;
72             }
73             int health = rint(this.m_damage / DAMAGETEXT_PRECISION_MULTIPLIER);
74             int total = rint((this.m_damage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER);
75             int potential = rint(this.m_potential_damage / DAMAGETEXT_PRECISION_MULTIPLIER);
76             int potential_health = rint((this.m_potential_damage - this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER);
77
78             string s = autocvar_cl_damagetext_format;
79             s = strreplace("{armor}",  sprintf("%d", rint(this.m_armordamage / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
80             s = strreplace("{potential}",  sprintf("%d", potential), s);
81             s = strreplace("{potential_health}",  sprintf("%d", potential_health), s);
82
83             s = strreplace("{health}", (
84                                 (health == potential_health || !autocvar_cl_damagetext_format_verbose)
85                                 ? sprintf("%d",      health)
86                                 : sprintf("%d (%d)", health, potential_health)
87                 ), s);
88             s = strreplace("{total}", (
89                                 (total == potential || !autocvar_cl_damagetext_format_verbose)
90                                 ? sprintf("%d",      total)
91                                 : sprintf("%d (%d)", total, potential)
92                 ), s);
93             drawcolorcodedstring2_builtin(pos, s, this.m_size * '1 1 0', rgb, this.alpha, DRAWFLAG_NORMAL);
94         }
95     }
96     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d);
97
98     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _potential_damage, int _deathtype) {
99         this.m_damage = _health;
100         this.m_armordamage = _armor;
101         this.m_potential_damage = _potential_damage;
102         this.m_deathtype = _deathtype;
103         setorigin(this, _origin);
104         this.alpha = autocvar_cl_damagetext_alpha_start;
105     }
106
107     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor, int _potential_damage, int _deathtype, bool _friendlyfire) {
108         CONSTRUCT(DamageText);
109         this.m_group = _group;
110         this.m_friendlyfire = _friendlyfire;
111         DamageText_update(this, _origin, _health, _armor, _potential_damage, _deathtype);
112                 IL_PUSH(g_drawables_2d, this);
113     }
114 ENDCLASS(DamageText)
115 #endif
116
117 REGISTER_NET_TEMP(damagetext)
118
119 #ifdef SVQC
120 AUTOCVAR(sv_damagetext, int, 2, "<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players");
121 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
122 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
123 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
124 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
125 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
126     if (SV_DAMAGETEXT_DISABLED()) return;
127     const entity attacker = M_ARGV(0, entity);
128     const entity hit = M_ARGV(1, entity); if (hit == attacker) return;
129     const float health = M_ARGV(2, float);
130     const float armor = M_ARGV(3, float);
131     const int deathtype = M_ARGV(5, int);
132     const float potential_damage = M_ARGV(6, float);
133     const vector location = hit.origin;
134     FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
135         if (
136             (SV_DAMAGETEXT_ALL()) ||
137             (SV_DAMAGETEXT_PLAYERS() && it == attacker) ||
138             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(it) && it.enemy == attacker) ||
139             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(it))
140         ) {
141             int flags = 0;
142             if (SAME_TEAM(hit, attacker)) flags |= DTFLAG_SAMETEAM;
143             if (health >= DAMAGETEXT_SHORT_LIMIT) flags |= DTFLAG_BIG_HEALTH;
144             if (armor >= DAMAGETEXT_SHORT_LIMIT) flags |= DTFLAG_BIG_ARMOR;
145             if (potential_damage >= DAMAGETEXT_SHORT_LIMIT) flags |= DTFLAG_BIG_POTENTIAL;
146             if (!armor) flags |= DTFLAG_NO_ARMOR;
147             if (fabs((armor + health) - potential_damage) < 0.0001) flags |= DTFLAG_NO_POTENTIAL;
148
149             msg_entity = it;
150             WriteHeader(MSG_ONE, damagetext);
151             WriteEntity(MSG_ONE, hit);
152             WriteCoord(MSG_ONE, location.x);
153             WriteCoord(MSG_ONE, location.y);
154             WriteCoord(MSG_ONE, location.z);
155             WriteInt24_t(MSG_ONE, deathtype);
156             WriteByte(MSG_ONE, flags);
157
158             // we need to send a few decimal places to minimize errors when accumulating damage
159             // sending them multiplied saves bandwidth compared to using WriteCoord,
160             // however if the multiplied damage would be too much for (signed) short, we send an int24
161             if (flags & DTFLAG_BIG_HEALTH) WriteInt24_t(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
162             else WriteShort(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
163             if (!(flags & DTFLAG_NO_ARMOR))
164             {
165                 if (flags & DTFLAG_BIG_ARMOR) WriteInt24_t(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
166                 else WriteShort(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
167             }
168             if (!(flags & DTFLAG_NO_POTENTIAL))
169             {
170                 if (flags & DTFLAG_BIG_POTENTIAL) WriteInt24_t(MSG_ONE, potential_damage * DAMAGETEXT_PRECISION_MULTIPLIER);
171                 else WriteShort(MSG_ONE, potential_damage * DAMAGETEXT_PRECISION_MULTIPLIER);
172                         }
173         }
174     ));
175 }
176 #endif
177
178 #ifdef CSQC
179 NET_HANDLE(damagetext, bool isNew)
180 {
181     int group = ReadShort();
182     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
183     int deathtype = ReadInt24_t();
184     int flags = ReadByte();
185     bool friendlyfire = flags & DTFLAG_SAMETEAM;
186
187     int health, armor, potential_damage;
188     if (flags & DTFLAG_BIG_HEALTH) health = ReadInt24_t();
189     else health = ReadShort();
190     if (flags & DTFLAG_NO_ARMOR) armor = 0;
191     else if (flags & DTFLAG_BIG_ARMOR) armor = ReadInt24_t();
192     else armor = ReadShort();
193     if (flags & DTFLAG_NO_POTENTIAL) potential_damage = health + armor;
194     else if (flags & DTFLAG_BIG_POTENTIAL) potential_damage = ReadInt24_t();
195     else potential_damage = ReadShort();
196
197     return = true;
198     if (autocvar_cl_damagetext) {
199         if (friendlyfire && !autocvar_cl_damagetext_friendlyfire) {
200             return;
201         }
202         if (autocvar_cl_damagetext_accumulate_range) {
203             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
204                 if (e.instanceOfDamageText && e.m_group == group && e.alpha > autocvar_cl_damagetext_accumulate_alpha_rel * autocvar_cl_damagetext_alpha_start) {
205                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor, e.m_potential_damage + potential_damage, deathtype);
206                     return;
207                 }
208             }
209         }
210         make_impure(NEW(DamageText, group, location, health, armor, potential_damage, deathtype, friendlyfire));
211     }
212 }
213 #endif
214
215 #ifdef MENUQC
216
217 #include <menu/gamesettings.qh>
218
219 CLASS(XonoticDamageTextSettings, XonoticTab)
220     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
221     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"));
222     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9);
223     ATTRIB(XonoticDamageTextSettings, rows, float, 15.5);
224     ATTRIB(XonoticDamageTextSettings, columns, float, 5);
225     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
226     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
227     METHOD(XonoticDamageTextSettings, fill, void(entity this))
228     {
229         entity e;
230         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
231             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
232         this.TR(this);
233             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Font size:")));
234                 setDependent(e, "cl_damagetext", 1, 1);
235             this.TD(this, 1, 2, e = makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
236                 setDependent(e, "cl_damagetext", 1, 1);
237         this.TR(this);
238             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Accumulate range:")));
239                 setDependent(e, "cl_damagetext", 1, 1);
240             this.TD(this, 1, 2, e = makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
241                 setDependent(e, "cl_damagetext", 1, 1);
242         this.TR(this);
243             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Lifetime:")));
244                 setDependent(e, "cl_damagetext", 1, 1);
245             this.TD(this, 1, 2, e = makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
246                 setDependent(e, "cl_damagetext", 1, 1);
247         this.TR(this);
248             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
249                 setDependent(e, "cl_damagetext", 1, 1);
250             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
251                 setDependent(e, "cl_damagetext", 1, 1);
252         this.TR(this);
253         this.TR(this);
254         // friendly fire
255             this.TD(this, 1, 3, e = makeXonoticCheckBox(0, "cl_damagetext_friendlyfire", _("Draw damage numbers for friendly fire")));
256                 setDependent(e, "cl_damagetext", 1, 1);
257         this.TR(this);
258             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
259                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
260             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_friendlyfire_color", "cl_damagetext_friendlyfire_color"));
261                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
262         this.TR(this);
263     }
264 ENDCLASS(XonoticDamageTextSettings)
265 #endif