qcsrc/common/mutators/mutator/damagetext/damagetext.qc

   1 #include "damagetext.qh"
   2
   3 #define DAMAGETEXT_PRECISION_MULTIPLIER 128
   4 #define DAMAGETEXT_SHORT_LIMIT 256 // the smallest value that we can't send as short - 2^15 (signed short) / DAMAGETEXT_PRECISION_MULTIPLIER
   5
   6 const int DTFLAG_SAMETEAM = BIT(0);
   7 const int DTFLAG_BIG_HEALTH = BIT(1);
   8 const int DTFLAG_BIG_ARMOR = BIT(2);
   9 const int DTFLAG_BIG_POTENTIAL = BIT(3);
  10 const int DTFLAG_NO_ARMOR = BIT(4);
  11 const int DTFLAG_NO_POTENTIAL = BIT(5);
  12
  13 REGISTER_MUTATOR(damagetext, true);
  14
  15 #if defined(CSQC) || defined(MENUQC)
  16 // no translatable cvar description please
  17 AUTOCVAR_SAVE(cl_damagetext,                        bool,   true,       "Draw damage dealt where you hit the enemy");
  18 AUTOCVAR_SAVE(cl_damagetext_format,                 string, "-{total}", "How to format the damage text. {health}, {armor}, {total}, {potential}, {potential_health}");
  19 STATIC_INIT(DamageText_LegacyFormat) {
  20     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) autocvar_cl_damagetext_format = "-{total}";
  21 }
  22 AUTOCVAR_SAVE(cl_damagetext_color,                  vector, '1 1 0',    "Damage text color");
  23 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,       bool,   false,      "Damage text uses weapon color");
  24 AUTOCVAR_SAVE(cl_damagetext_size,                   float,  8,          "Damage text font size");
  25 AUTOCVAR_SAVE(cl_damagetext_alpha_start,            float,  1,          "Damage text initial alpha");
  26 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,         float,  3,          "Damage text lifetime in seconds");
  27 AUTOCVAR_SAVE(cl_damagetext_velocity,               vector, '0 0 20',   "Damage text move direction");
  28 AUTOCVAR_SAVE(cl_damagetext_offset,                 vector, '0 -40 0',  "Damage text offset");
  29 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,       float,  30,         "Damage text spawned within this range is accumulated");
  30 AUTOCVAR_SAVE(cl_damagetext_accumulate_alpha_rel,   float,  0.65,       "Only update existing damage text when it's above this much percentage (0 to 1) of the starting alpha");
  31 AUTOCVAR_SAVE(cl_damagetext_friendlyfire,           bool,   true,       "Show damage text for friendlyfire too");
  32 AUTOCVAR_SAVE(cl_damagetext_friendlyfire_color,     vector, '1 0 0',    "Damage text color for friendlyfire");
  33 #endif
  34
  35 #ifdef CSQC
  36 CLASS(DamageText, Object)
  37     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color);
  38     ATTRIB(DamageText, m_color_friendlyfire, vector, autocvar_cl_damagetext_friendlyfire_color);
  39     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size);
  40     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start);
  41     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime);
  42     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity);
  43     ATTRIB(DamageText, m_group, int, 0);
  44     ATTRIB(DamageText, m_friendlyfire, bool, false);
  45     ATTRIB(DamageText, m_damage, int, 0);
  46     ATTRIB(DamageText, m_armordamage, int, 0);
  47     ATTRIB(DamageText, m_potential_damage, int, 0);
  48     ATTRIB(DamageText, m_deathtype, int, 0);
  49     ATTRIB(DamageText, time_prev, float, time);
  50
  51     void DamageText_draw2d(DamageText this) {
  52         float dt = time - this.time_prev;
  53         this.time_prev = time;
  54         setorigin(this, this.origin + dt * this.velocity);
  55         this.alpha -= dt * this.fade_rate;
  56         if (this.alpha < 0) delete(this);
  57         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  58         if (pos.z >= 0 && this.m_size > 0) {
  59             pos.z = 0;
  60             vector rgb;
  61             if (this.m_friendlyfire) {
  62                 rgb = this.m_color_friendlyfire;
  63             }
  64             else {
  65                 rgb = this.m_color;
  66             }
  67             if (autocvar_cl_damagetext_color_per_weapon) {
  68                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  69                 if (w != WEP_Null) rgb = w.wpcolor;
  70             }
  71             string s = autocvar_cl_damagetext_format;
  72             s = strreplace("{health}", sprintf("%d", rint(this.m_damage / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  73             s = strreplace("{armor}",  sprintf("%d", rint(this.m_armordamage / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  74             s = strreplace("{total}",  sprintf("%d", rint((this.m_damage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  75             s = strreplace("{potential}",  sprintf("%d", rint(this.m_potential_damage/DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  76             s = strreplace("{potential_health}",  sprintf("%d", rint((this.m_potential_damage - this.m_armordamage)/DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  77             drawcolorcodedstring2_builtin(pos, s, this.m_size * '1 1 0', rgb, this.alpha, DRAWFLAG_NORMAL);
  78         }
  79     }
  80     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d);
  81
  82     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _potential_damage, int _deathtype) {
  83         this.m_damage = _health;
  84         this.m_armordamage = _armor;
  85         this.m_potential_damage = _potential_damage;
  86         this.m_deathtype = _deathtype;
  87         setorigin(this, _origin);
  88         this.alpha = autocvar_cl_damagetext_alpha_start;
  89     }
  90
  91     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor, int _potential_damage, int _deathtype, bool _friendlyfire) {
  92         CONSTRUCT(DamageText);
  93         this.m_group = _group;
  94         this.m_friendlyfire = _friendlyfire;
  95         DamageText_update(this, _origin, _health, _armor, _potential_damage, _deathtype);
  96                 IL_PUSH(g_drawables_2d, this);
  97     }
  98 ENDCLASS(DamageText)
  99 #endif
 100
 101 REGISTER_NET_TEMP(damagetext)
 102
 103 #ifdef SVQC
 104 AUTOCVAR(sv_damagetext, int, 2, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
 105 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
 106 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
 107 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
 108 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
 109 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
 110     if (SV_DAMAGETEXT_DISABLED()) return;
 111     const entity attacker = M_ARGV(0, entity);
 112     const entity hit = M_ARGV(1, entity); if (hit == attacker) return;
 113     const float health = M_ARGV(2, float);
 114     const float armor = M_ARGV(3, float);
 115     const int deathtype = M_ARGV(5, int);
 116     const float potential_damage = M_ARGV(6, float);
 117     const vector location = hit.origin;
 118     FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 119         if (
 120             (SV_DAMAGETEXT_ALL()) ||
 121             (SV_DAMAGETEXT_PLAYERS() && it == attacker) ||
 122             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(it) && it.enemy == attacker) ||
 123             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(it))
 124         ) {
 125             int flags = 0;
 126             if (SAME_TEAM(hit, attacker)) flags |= DTFLAG_SAMETEAM;
 127             if (health >= DAMAGETEXT_SHORT_LIMIT) flags |= DTFLAG_BIG_HEALTH;
 128             if (armor >= DAMAGETEXT_SHORT_LIMIT) flags |= DTFLAG_BIG_ARMOR;
 129             if (potential_damage >= DAMAGETEXT_SHORT_LIMIT) flags |= DTFLAG_BIG_POTENTIAL;
 130             if (!armor) flags |= DTFLAG_NO_ARMOR;
 131             if (fabs((armor + health) - potential_damage) < 0.0001) flags |= DTFLAG_NO_POTENTIAL;
 132
 133             msg_entity = it;
 134             WriteHeader(MSG_ONE, damagetext);
 135             WriteEntity(MSG_ONE, hit);
 136             WriteCoord(MSG_ONE, location.x);
 137             WriteCoord(MSG_ONE, location.y);
 138             WriteCoord(MSG_ONE, location.z);
 139             WriteInt24_t(MSG_ONE, deathtype);
 140             WriteByte(MSG_ONE, flags);
 141
 142             // we need to send a few decimal places to minimize errors when accumulating damage
 143             // sending them multiplied saves bandwidth compared to using WriteCoord,
 144             // however if the multiplied damage would be too much for (signed) short, we send an int24
 145             if (flags & DTFLAG_BIG_HEALTH) WriteInt24_t(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
 146             else WriteShort(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
 147             if (!(flags & DTFLAG_NO_ARMOR))
 148             {
 149                 if (flags & DTFLAG_BIG_ARMOR) WriteInt24_t(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
 150                 else WriteShort(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
 151             }
 152             if (!(flags & DTFLAG_NO_POTENTIAL))
 153             {
 154                 if (flags & DTFLAG_BIG_POTENTIAL) WriteInt24_t(MSG_ONE, potential_damage * DAMAGETEXT_PRECISION_MULTIPLIER);
 155                 else WriteShort(MSG_ONE, potential_damage * DAMAGETEXT_PRECISION_MULTIPLIER);
 156                         }
 157         }
 158     ));
 159 }
 160 #endif
 161
 162 #ifdef CSQC
 163 NET_HANDLE(damagetext, bool isNew)
 164 {
 165     int group = ReadShort();
 166     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
 167     int deathtype = ReadInt24_t();
 168     int flags = ReadByte();
 169     bool friendlyfire = flags & DTFLAG_SAMETEAM;
 170
 171     int health, armor, potential_damage;
 172     if (flags & DTFLAG_BIG_HEALTH) health = ReadInt24_t();
 173     else health = ReadShort();
 174     if (flags & DTFLAG_NO_ARMOR) armor = 0;
 175     else if (flags & DTFLAG_BIG_ARMOR) armor = ReadInt24_t();
 176     else armor = ReadShort();
 177     if (flags & DTFLAG_NO_POTENTIAL) potential_damage = health + armor;
 178     else if (flags & DTFLAG_BIG_POTENTIAL) potential_damage = ReadInt24_t();
 179     else potential_damage = ReadShort();
 180
 181     return = true;
 182     if (autocvar_cl_damagetext) {
 183         if (friendlyfire && !autocvar_cl_damagetext_friendlyfire) {
 184             return;
 185         }
 186         if (autocvar_cl_damagetext_accumulate_range) {
 187             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 188                 if (e.instanceOfDamageText && e.m_group == group && e.alpha > autocvar_cl_damagetext_accumulate_alpha_rel * autocvar_cl_damagetext_alpha_start) {
 189                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor, e.m_potential_damage + potential_damage, deathtype);
 190                     return;
 191                 }
 192             }
 193         }
 194         make_impure(NEW(DamageText, group, location, health, armor, potential_damage, deathtype, friendlyfire));
 195     }
 196 }
 197 #endif
 198
 199 #ifdef MENUQC
 200
 201 #include <menu/gamesettings.qh>
 202
 203 CLASS(XonoticDamageTextSettings, XonoticTab)
 204     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 205     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"));
 206     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9);
 207     ATTRIB(XonoticDamageTextSettings, rows, float, 15.5);
 208     ATTRIB(XonoticDamageTextSettings, columns, float, 5);
 209     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 210     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 211     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 212     {
 213         entity e;
 214         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 215             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 216         this.TR(this);
 217             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Font size:")));
 218                 setDependent(e, "cl_damagetext", 1, 1);
 219             this.TD(this, 1, 2, e = makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 220                 setDependent(e, "cl_damagetext", 1, 1);
 221         this.TR(this);
 222             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Accumulate range:")));
 223                 setDependent(e, "cl_damagetext", 1, 1);
 224             this.TD(this, 1, 2, e = makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 225                 setDependent(e, "cl_damagetext", 1, 1);
 226         this.TR(this);
 227             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Lifetime:")));
 228                 setDependent(e, "cl_damagetext", 1, 1);
 229             this.TD(this, 1, 2, e = makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 230                 setDependent(e, "cl_damagetext", 1, 1);
 231         this.TR(this);
 232             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 233                 setDependent(e, "cl_damagetext", 1, 1);
 234             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 235                 setDependent(e, "cl_damagetext", 1, 1);
 236         this.TR(this);
 237         this.TR(this);
 238         // friendly fire
 239             this.TD(this, 1, 3, e = makeXonoticCheckBox(0, "cl_damagetext_friendlyfire", _("Draw damage numbers for friendly fire")));
 240                 setDependent(e, "cl_damagetext", 1, 1);
 241         this.TR(this);
 242             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 243                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 244             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_friendlyfire_color", "cl_damagetext_friendlyfire_color"));
 245                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 246         this.TR(this);
 247     }
 248 ENDCLASS(XonoticDamageTextSettings)
 249 #endif