qcsrc/common/mutators/mutator/damagetext/damagetext.qc

   1 #include "damagetext.qh"
   2
   3 #define DAMAGETEXT_PRECISION_MULTIPLIER 128
   4 #define DAMAGETEXT_SHORT_LIMIT 256 // the smallest value that we can't send as short - 2^15 (signed short) / DAMAGETEXT_PRECISION_MULTIPLIER
   5
   6 REGISTER_MUTATOR(damagetext, true);
   7
   8 #if defined(CSQC) || defined(MENUQC)
   9 // no translatable cvar description please
  10 AUTOCVAR_SAVE(cl_damagetext,                        bool,   true,       "Draw damage dealt where you hit the enemy");
  11 AUTOCVAR_SAVE(cl_damagetext_format,             string, "-{total}", "How to format the damage text. {health}, {armor}, {total}, {potential}");
  12 STATIC_INIT(DamageText_LegacyFormat) {
  13     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) autocvar_cl_damagetext_format = "-{total}";
  14 }
  15 AUTOCVAR_SAVE(cl_damagetext_color,                  vector, '1 1 0',    "Damage text color");
  16 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,       bool,   false,      "Damage text uses weapon color");
  17 AUTOCVAR_SAVE(cl_damagetext_size,                   float,  8,          "Damage text font size");
  18 AUTOCVAR_SAVE(cl_damagetext_alpha_start,            float,  1,          "Damage text initial alpha");
  19 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,         float,  3,          "Damage text lifetime in seconds");
  20 AUTOCVAR_SAVE(cl_damagetext_velocity,               vector, '0 0 20',   "Damage text move direction");
  21 AUTOCVAR_SAVE(cl_damagetext_offset,                 vector, '0 -40 0',  "Damage text offset");
  22 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,       float,  30,         "Damage text spawned within this range is accumulated");
  23 AUTOCVAR_SAVE(cl_damagetext_accumulate_alpha_rel,   float,  0.65,       "Only update existing damage text when it's above this much percentage (0 to 1) of the starting alpha");
  24 AUTOCVAR_SAVE(cl_damagetext_friendlyfire,           bool,   true,       "Show damage text for friendlyfire too");
  25 AUTOCVAR_SAVE(cl_damagetext_friendlyfire_color,     vector, '1 0 0',    "Damage text color for friendlyfire");
  26 #endif
  27
  28 #ifdef CSQC
  29 CLASS(DamageText, Object)
  30     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color);
  31     ATTRIB(DamageText, m_color_friendlyfire, vector, autocvar_cl_damagetext_friendlyfire_color);
  32     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size);
  33     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start);
  34     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime);
  35     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity);
  36     ATTRIB(DamageText, m_group, int, 0);
  37     ATTRIB(DamageText, m_friendlyfire, bool, false);
  38     ATTRIB(DamageText, m_damage, int, 0);
  39     ATTRIB(DamageText, m_armordamage, int, 0);
  40     ATTRIB(DamageText, m_potential_damage, int, 0);
  41     ATTRIB(DamageText, m_deathtype, int, 0);
  42     ATTRIB(DamageText, time_prev, float, time);
  43
  44     void DamageText_draw2d(DamageText this) {
  45         float dt = time - this.time_prev;
  46         this.time_prev = time;
  47         setorigin(this, this.origin + dt * this.velocity);
  48         this.alpha -= dt * this.fade_rate;
  49         if (this.alpha < 0) delete(this);
  50         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  51         if (pos.z >= 0 && this.m_size > 0) {
  52             pos.z = 0;
  53             vector rgb;
  54             if (this.m_friendlyfire) {
  55                 rgb = this.m_color_friendlyfire;
  56             }
  57             else {
  58                 rgb = this.m_color;
  59             }
  60             if (autocvar_cl_damagetext_color_per_weapon) {
  61                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  62                 if (w != WEP_Null) rgb = w.wpcolor;
  63             }
  64             string s = autocvar_cl_damagetext_format;
  65             s = strreplace("{health}", sprintf("%d", rint(this.m_damage / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  66             s = strreplace("{armor}",  sprintf("%d", rint(this.m_armordamage / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  67             s = strreplace("{total}",  sprintf("%d", rint((this.m_damage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  68             s = strreplace("{potential}",  sprintf("%d", rint(this.m_potential_damage/DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  69             drawcolorcodedstring2_builtin(pos, s, this.m_size * '1 1 0', rgb, this.alpha, DRAWFLAG_NORMAL);
  70         }
  71     }
  72     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d);
  73
  74     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _potential_damage, int _deathtype) {
  75         this.m_damage = _health;
  76         this.m_armordamage = _armor;
  77         this.m_potential_damage = _potential_damage;
  78         this.m_deathtype = _deathtype;
  79         setorigin(this, _origin);
  80         this.alpha = autocvar_cl_damagetext_alpha_start;
  81     }
  82
  83     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor, int _potential_damage, int _deathtype, bool _friendlyfire) {
  84         CONSTRUCT(DamageText);
  85         this.m_group = _group;
  86         this.m_friendlyfire = _friendlyfire;
  87         DamageText_update(this, _origin, _health, _armor, _potential_damage, _deathtype);
  88                 IL_PUSH(g_drawables_2d, this);
  89     }
  90 ENDCLASS(DamageText)
  91 #endif
  92
  93 REGISTER_NET_TEMP(damagetext)
  94
  95 #ifdef SVQC
  96 AUTOCVAR(sv_damagetext, int, 2, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
  97 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
  98 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
  99 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
 100 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
 101 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
 102     if (SV_DAMAGETEXT_DISABLED()) return;
 103     const entity attacker = M_ARGV(0, entity);
 104     const entity hit = M_ARGV(1, entity); if (hit == attacker) return;
 105     const float health = M_ARGV(2, float);
 106     const float armor = M_ARGV(3, float);
 107     const int deathtype = M_ARGV(5, int);
 108     const float potential_damage = M_ARGV(6, float);
 109     const vector location = hit.origin;
 110     FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 111         if (
 112             (SV_DAMAGETEXT_ALL()) ||
 113             (SV_DAMAGETEXT_PLAYERS() && it == attacker) ||
 114             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(it) && it.enemy == attacker) ||
 115             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(it))
 116         ) {
 117             int flags = SAME_TEAM(hit, attacker); // BIT(0)
 118             if (health >= DAMAGETEXT_SHORT_LIMIT) flags |= BIT(1);
 119             if (armor >= DAMAGETEXT_SHORT_LIMIT) flags |= BIT(2);
 120             if (potential_damage >= DAMAGETEXT_SHORT_LIMIT) flags |= BIT(3);
 121
 122             msg_entity = it;
 123             WriteHeader(MSG_ONE, damagetext);
 124             WriteEntity(MSG_ONE, hit);
 125             WriteCoord(MSG_ONE, location.x);
 126             WriteCoord(MSG_ONE, location.y);
 127             WriteCoord(MSG_ONE, location.z);
 128             WriteInt24_t(MSG_ONE, deathtype);
 129             WriteByte(MSG_ONE, flags);
 130
 131             // we need to send a few decimal places to minimize errors when accumulating damage
 132             // sending them multiplied saves bandwidth compared to using WriteCoord,
 133             // however if the multiplied damage would be too much for (signed) short, we send an int24
 134             if (health >= DAMAGETEXT_SHORT_LIMIT) WriteInt24_t(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
 135             else WriteShort(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
 136             if (armor >= DAMAGETEXT_SHORT_LIMIT) WriteInt24_t(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
 137             else WriteShort(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
 138             if (potential_damage >= DAMAGETEXT_SHORT_LIMIT) WriteInt24_t(MSG_ONE, potential_damage * DAMAGETEXT_PRECISION_MULTIPLIER);
 139             else WriteShort(MSG_ONE, potential_damage * DAMAGETEXT_PRECISION_MULTIPLIER);
 140         }
 141     ));
 142 }
 143 #endif
 144
 145 #ifdef CSQC
 146 NET_HANDLE(damagetext, bool isNew)
 147 {
 148     int group = ReadShort();
 149     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
 150     int deathtype = ReadInt24_t();
 151     int flags = ReadByte();
 152     bool friendlyfire = flags & 1;
 153
 154     int health, armor, potential_damage;
 155     if (flags & BIT(1)) health = ReadInt24_t();
 156     else health = ReadShort();
 157     if (flags & BIT(2)) armor = ReadInt24_t();
 158     else armor = ReadShort();
 159     if (flags & BIT(3)) potential_damage = ReadInt24_t();
 160     else potential_damage = ReadShort();
 161
 162     return = true;
 163     if (autocvar_cl_damagetext) {
 164         if (friendlyfire && !autocvar_cl_damagetext_friendlyfire) {
 165             return;
 166         }
 167         if (autocvar_cl_damagetext_accumulate_range) {
 168             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 169                 if (e.instanceOfDamageText && e.m_group == group && e.alpha > autocvar_cl_damagetext_accumulate_alpha_rel * autocvar_cl_damagetext_alpha_start) {
 170                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor, e.m_potential_damage + potential_damage, deathtype);
 171                     return;
 172                 }
 173             }
 174         }
 175         make_impure(NEW(DamageText, group, location, health, armor, potential_damage, deathtype, friendlyfire));
 176     }
 177 }
 178 #endif
 179
 180 #ifdef MENUQC
 181
 182 #include <menu/gamesettings.qh>
 183
 184 CLASS(XonoticDamageTextSettings, XonoticTab)
 185     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 186     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"));
 187     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9);
 188     ATTRIB(XonoticDamageTextSettings, rows, float, 15.5);
 189     ATTRIB(XonoticDamageTextSettings, columns, float, 5);
 190     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 191     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 192     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 193     {
 194         entity e;
 195         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 196             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 197         this.TR(this);
 198             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Font size:")));
 199                 setDependent(e, "cl_damagetext", 1, 1);
 200             this.TD(this, 1, 2, e = makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 201                 setDependent(e, "cl_damagetext", 1, 1);
 202         this.TR(this);
 203             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Accumulate range:")));
 204                 setDependent(e, "cl_damagetext", 1, 1);
 205             this.TD(this, 1, 2, e = makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 206                 setDependent(e, "cl_damagetext", 1, 1);
 207         this.TR(this);
 208             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Lifetime:")));
 209                 setDependent(e, "cl_damagetext", 1, 1);
 210             this.TD(this, 1, 2, e = makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 211                 setDependent(e, "cl_damagetext", 1, 1);
 212         this.TR(this);
 213             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 214                 setDependent(e, "cl_damagetext", 1, 1);
 215             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 216                 setDependent(e, "cl_damagetext", 1, 1);
 217         this.TR(this);
 218         this.TR(this);
 219         // friendly fire
 220             this.TD(this, 1, 3, e = makeXonoticCheckBox(0, "cl_damagetext_friendlyfire", _("Draw damage numbers for friendly fire")));
 221                 setDependent(e, "cl_damagetext", 1, 1);
 222         this.TR(this);
 223             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 224                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 225             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_friendlyfire_color", "cl_damagetext_friendlyfire_color"));
 226                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 227         this.TR(this);
 228     }
 229 ENDCLASS(XonoticDamageTextSettings)
 230 #endif