qcsrc/common/mutators/mutator/damagetext/damagetext.qc

   1 #include "damagetext.qh"
   2
   3 #define DAMAGETEXT_PRECISION_MULTIPLIER 128
   4 #define DAMAGETEXT_SHORT_LIMIT 256 // the smallest value that we can't send as short - 2^15 (signed short) / DAMAGETEXT_PRECISION_MULTIPLIER
   5
   6 REGISTER_MUTATOR(damagetext, true);
   7
   8 #if defined(CSQC) || defined(MENUQC)
   9 // no translatable cvar description please
  10 AUTOCVAR_SAVE(cl_damagetext,                    bool,   true,      "Draw damage dealt where you hit the enemy");
  11 AUTOCVAR_SAVE(cl_damagetext_format,             string, "-{total}", "How to format the damage text. {health}, {armor}, {total}");
  12 STATIC_INIT(DamageText_LegacyFormat) {
  13     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) autocvar_cl_damagetext_format = "-{total}";
  14 }
  15 AUTOCVAR_SAVE(cl_damagetext_color,              vector, '1 1 0',    "Damage text color");
  16 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,   bool,   false,      "Damage text uses weapon color");
  17 AUTOCVAR_SAVE(cl_damagetext_size,               float,  8,          "Damage text font size");
  18 AUTOCVAR_SAVE(cl_damagetext_alpha_start,        float,  1,          "Damage text initial alpha");
  19 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,     float,  3,          "Damage text lifetime in seconds");
  20 AUTOCVAR_SAVE(cl_damagetext_velocity,           vector, '0 0 20',   "Damage text move direction");
  21 AUTOCVAR_SAVE(cl_damagetext_offset,             vector, '0 -40 0',  "Damage text offset");
  22 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,   float,  30,         "Damage text spawned within this range is accumulated");
  23 AUTOCVAR_SAVE(cl_damagetext_accumulate_visibility,   float,  0.65,       "Only update existing damage text when it's above this much percentage (0 to 1) of the starting alpha");
  24 AUTOCVAR_SAVE(cl_damagetext_friendlyfire,       bool,   true,       "Show damage text for friendlyfire too");
  25 AUTOCVAR_SAVE(cl_damagetext_friendlyfire_color, vector, '1 0 0',    "Damage text color for friendlyfire");
  26 #endif
  27
  28 #ifdef CSQC
  29 CLASS(DamageText, Object)
  30     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color);
  31     ATTRIB(DamageText, m_color_friendlyfire, vector, autocvar_cl_damagetext_friendlyfire_color);
  32     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size);
  33     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start);
  34     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime);
  35     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity);
  36     ATTRIB(DamageText, m_group, int, 0);
  37     ATTRIB(DamageText, m_friendlyfire, bool, false);
  38     ATTRIB(DamageText, m_damage, int, 0);
  39     ATTRIB(DamageText, m_armordamage, int, 0);
  40     ATTRIB(DamageText, m_deathtype, int, 0);
  41     ATTRIB(DamageText, time_prev, float, time);
  42
  43     void DamageText_draw2d(DamageText this) {
  44         float dt = time - this.time_prev;
  45         this.time_prev = time;
  46         setorigin(this, this.origin + dt * this.velocity);
  47         this.alpha -= dt * this.fade_rate;
  48         if (this.alpha < 0) delete(this);
  49         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  50         if (pos.z >= 0 && this.m_size > 0) {
  51             pos.z = 0;
  52             vector rgb;
  53             if (this.m_friendlyfire) {
  54                 rgb = this.m_color_friendlyfire;
  55             }
  56             else {
  57                 rgb = this.m_color;
  58             }
  59             if (autocvar_cl_damagetext_color_per_weapon) {
  60                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  61                 if (w != WEP_Null) rgb = w.wpcolor;
  62             }
  63             string s = autocvar_cl_damagetext_format;
  64             s = strreplace("{health}", sprintf("%d", rint(this.m_damage / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  65             s = strreplace("{armor}",  sprintf("%d", rint(this.m_armordamage / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  66             s = strreplace("{total}",  sprintf("%d", rint((this.m_damage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  67             drawcolorcodedstring2_builtin(pos, s, this.m_size * '1 1 0', rgb, this.alpha, DRAWFLAG_NORMAL);
  68         }
  69     }
  70     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d);
  71
  72     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _deathtype) {
  73         this.m_damage = _health;
  74         this.m_armordamage = _armor;
  75         this.m_deathtype = _deathtype;
  76         setorigin(this, _origin);
  77         this.alpha = autocvar_cl_damagetext_alpha_start;
  78     }
  79
  80     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor, int _deathtype, bool _friendlyfire) {
  81         CONSTRUCT(DamageText);
  82         this.m_group = _group;
  83         this.m_friendlyfire = _friendlyfire;
  84         DamageText_update(this, _origin, _health, _armor, _deathtype);
  85                 IL_PUSH(g_drawables_2d, this);
  86     }
  87 ENDCLASS(DamageText)
  88 #endif
  89
  90 REGISTER_NET_TEMP(damagetext)
  91
  92 #ifdef SVQC
  93 AUTOCVAR(sv_damagetext, int, 2, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
  94 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
  95 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
  96 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
  97 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
  98 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
  99     if (SV_DAMAGETEXT_DISABLED()) return;
 100     const entity attacker = M_ARGV(0, entity);
 101     const entity hit = M_ARGV(1, entity); if (hit == attacker) return;
 102     const float health = M_ARGV(2, float);
 103     const float armor = M_ARGV(3, float);
 104     const int deathtype = M_ARGV(5, int);
 105     const vector location = hit.origin;
 106     FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 107         if (
 108             (SV_DAMAGETEXT_ALL()) ||
 109             (SV_DAMAGETEXT_PLAYERS() && it == attacker) ||
 110             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(it) && it.enemy == attacker) ||
 111             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(it))
 112         ) {
 113             int flags = SAME_TEAM(hit, attacker); // BIT(0)
 114             if (health >= DAMAGETEXT_SHORT_LIMIT) flags |= BIT(1);
 115             if (armor >= DAMAGETEXT_SHORT_LIMIT) flags |= BIT(2);
 116
 117             msg_entity = it;
 118             WriteHeader(MSG_ONE, damagetext);
 119             WriteEntity(MSG_ONE, hit);
 120             WriteCoord(MSG_ONE, location.x);
 121             WriteCoord(MSG_ONE, location.y);
 122             WriteCoord(MSG_ONE, location.z);
 123             WriteInt24_t(MSG_ONE, deathtype);
 124             WriteByte(MSG_ONE, flags);
 125
 126             // we need to send a few decimal places to minimize errors when accumulating damage
 127             // sending them multiplied saves bandwidth compared to using WriteCoord,
 128             // however if the multiplied damage would be too much for (signed) short, we send an int24
 129             if (health >= DAMAGETEXT_SHORT_LIMIT) WriteInt24_t(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
 130             else WriteShort(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
 131             if (armor >= DAMAGETEXT_SHORT_LIMIT) WriteInt24_t(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
 132             else WriteShort(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
 133         }
 134     ));
 135 }
 136 #endif
 137
 138 #ifdef CSQC
 139 NET_HANDLE(damagetext, bool isNew)
 140 {
 141     int group = ReadShort();
 142     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
 143     int deathtype = ReadInt24_t();
 144     int flags = ReadByte();
 145     bool friendlyfire = flags & 1;
 146
 147     int health, armor;
 148     if (flags & BIT(1)) health = ReadInt24_t();
 149     else health = ReadShort();
 150     if (flags & BIT(2)) armor = ReadInt24_t();
 151     else armor = ReadShort();
 152
 153     return = true;
 154     if (autocvar_cl_damagetext) {
 155         if (friendlyfire && !autocvar_cl_damagetext_friendlyfire) {
 156             return;
 157         }
 158         if (autocvar_cl_damagetext_accumulate_range) {
 159             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 160                 if (e.instanceOfDamageText && e.m_group == group && e.alpha > autocvar_cl_damagetext_accumulate_visibility * autocvar_cl_damagetext_alpha_start) {
 161                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor, deathtype);
 162                     return;
 163                 }
 164             }
 165         }
 166         make_impure(NEW(DamageText, group, location, health, armor, deathtype, friendlyfire));
 167     }
 168 }
 169 #endif
 170
 171 #ifdef MENUQC
 172
 173 #include <menu/gamesettings.qh>
 174
 175 CLASS(XonoticDamageTextSettings, XonoticTab)
 176     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 177     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"));
 178     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9);
 179     ATTRIB(XonoticDamageTextSettings, rows, float, 15.5);
 180     ATTRIB(XonoticDamageTextSettings, columns, float, 5);
 181     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 182     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 183     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 184     {
 185         entity e;
 186         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 187             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 188         this.TR(this);
 189             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Font size:")));
 190                 setDependent(e, "cl_damagetext", 1, 1);
 191             this.TD(this, 1, 2, e = makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 192                 setDependent(e, "cl_damagetext", 1, 1);
 193         this.TR(this);
 194             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Accumulate range:")));
 195                 setDependent(e, "cl_damagetext", 1, 1);
 196             this.TD(this, 1, 2, e = makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 197                 setDependent(e, "cl_damagetext", 1, 1);
 198         this.TR(this);
 199             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Lifetime:")));
 200                 setDependent(e, "cl_damagetext", 1, 1);
 201             this.TD(this, 1, 2, e = makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 202                 setDependent(e, "cl_damagetext", 1, 1);
 203         this.TR(this);
 204             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 205                 setDependent(e, "cl_damagetext", 1, 1);
 206             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 207                 setDependent(e, "cl_damagetext", 1, 1);
 208         this.TR(this);
 209         this.TR(this);
 210             this.TD(this, 1, 3, e = makeXonoticCheckBox(0, "cl_damagetext_friendlyfire", _("Draw damage numbers for friendly fire")));
 211                 setDependent(e, "cl_damagetext", 1, 1);
 212         this.TR(this);
 213             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 214                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 215             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_friendlyfire_color", "cl_damagetext_friendlyfire_color"));
 216                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 217         this.TR(this);
 218     }
 219 ENDCLASS(XonoticDamageTextSettings)
 220 #endif