qcsrc/common/mutators/mutator/damagetext/damagetext.qc

   1 #ifndef MUTATOR_DAMAGETEXT_H
   2 #define MUTATOR_DAMAGETEXT_H
   3
   4 #ifdef MENUQC
   5 #include <menu/xonotic/tab.qh>
   6 #endif
   7
   8 #endif
   9
  10 #ifdef IMPLEMENTATION
  11 REGISTER_MUTATOR(damagetext, true);
  12
  13 #if defined(CSQC) || defined(MENUQC)
  14 // no translatable cvar description please
  15 AUTOCVAR_SAVE(cl_damagetext,                    bool,   false,      "Draw damage dealt where you hit the enemy");
  16 AUTOCVAR_SAVE(cl_damagetext_format,             string, "-{total}", "How to format the damage text. {health}, {armor}, {total}");
  17 STATIC_INIT(DamageText_LegacyFormat) {
  18     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) autocvar_cl_damagetext_format = "-{total}";
  19 }
  20 AUTOCVAR_SAVE(cl_damagetext_color,              vector, '1 1 0',    "Damage text color");
  21 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,   bool,   false,      "Damage text uses weapon color");
  22 AUTOCVAR_SAVE(cl_damagetext_size,               float,  8,          "Damage text font size");
  23 AUTOCVAR_SAVE(cl_damagetext_alpha_start,        float,  1,          "Damage text initial alpha");
  24 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,     float,  3,          "Damage text lifetime in seconds");
  25 AUTOCVAR_SAVE(cl_damagetext_velocity,           vector, '0 0 20',   "Damage text move direction");
  26 AUTOCVAR_SAVE(cl_damagetext_offset,             vector, '0 -40 0',  "Damage text offset");
  27 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,   float,  30,         "Damage text spawned within this range is accumulated");
  28 #endif
  29
  30 #ifdef CSQC
  31 CLASS(DamageText, Object)
  32     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color)
  33     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size)
  34     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start)
  35     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime)
  36     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity)
  37     ATTRIB(DamageText, m_group, int, 0)
  38     ATTRIB(DamageText, m_damage, int, 0)
  39     ATTRIB(DamageText, m_armordamage, int, 0)
  40     ATTRIB(DamageText, m_deathtype, int, 0)
  41     ATTRIB(DamageText, time_prev, float, time)
  42
  43     void DamageText_draw2d(DamageText this) {
  44         float dt = time - this.time_prev;
  45         this.time_prev = time;
  46         setorigin(this, this.origin + dt * this.velocity);
  47         this.alpha -= dt * this.fade_rate;
  48         if (this.alpha < 0) remove(this);
  49         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  50         if (pos.z >= 0 && this.m_size > 0) {
  51             pos.z = 0;
  52             vector rgb = this.m_color;
  53             if (autocvar_cl_damagetext_color_per_weapon) {
  54                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  55                 if (w != WEP_Null) rgb = w.wpcolor;
  56             }
  57             string s = autocvar_cl_damagetext_format;
  58             s = strreplace("{health}", sprintf("%d", this.m_damage), s);
  59             s = strreplace("{armor}",  sprintf("%d", this.m_armordamage), s);
  60             s = strreplace("{total}",  sprintf("%d", this.m_damage + this.m_armordamage), s);
  61             drawcolorcodedstring2_builtin(pos, s, this.m_size * '1 1 0', rgb, this.alpha, DRAWFLAG_NORMAL);
  62         }
  63     }
  64     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d)
  65
  66     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _deathtype) {
  67         this.m_damage = _health;
  68         this.m_armordamage = _armor;
  69         this.m_deathtype = _deathtype;
  70         setorigin(this, _origin);
  71         this.alpha = 1;
  72     }
  73
  74     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor, int _deathtype) {
  75         CONSTRUCT(DamageText);
  76         this.m_group = _group;
  77         DamageText_update(this, _origin, _health, _armor, _deathtype);
  78     }
  79 ENDCLASS(DamageText)
  80 #endif
  81
  82 REGISTER_NET_TEMP(damagetext)
  83
  84 #ifdef SVQC
  85 AUTOCVAR(sv_damagetext, int, 2, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
  86 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
  87 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
  88 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
  89 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
  90 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
  91     if (SV_DAMAGETEXT_DISABLED()) return;
  92     const entity attacker = M_ARGV(0, entity);
  93     const entity hit = M_ARGV(1, entity); if (hit == attacker) return;
  94     const int health = M_ARGV(2, int);
  95     const int armor = M_ARGV(3, int);
  96     const int deathtype = M_ARGV(5, int);
  97     const vector location = hit.origin;
  98     FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
  99         if (
 100             (SV_DAMAGETEXT_ALL()) ||
 101             (SV_DAMAGETEXT_PLAYERS() && it == attacker) ||
 102             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(it) && it.enemy == attacker) ||
 103             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(it))
 104         ) {
 105             msg_entity = it;
 106             WriteHeader(MSG_ONE, damagetext);
 107             WriteShort(MSG_ONE, rint(health));
 108             WriteShort(MSG_ONE, rint(armor));
 109             WriteEntity(MSG_ONE, hit);
 110             WriteCoord(MSG_ONE, location.x);
 111             WriteCoord(MSG_ONE, location.y);
 112             WriteCoord(MSG_ONE, location.z);
 113             WriteInt24_t(MSG_ONE, deathtype);
 114         }
 115     ));
 116 }
 117 #endif
 118
 119 #ifdef CSQC
 120 NET_HANDLE(damagetext, bool isNew)
 121 {
 122     int health = ReadShort();
 123     int armor = ReadShort();
 124     int group = ReadShort();
 125     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
 126     int deathtype = ReadInt24_t();
 127     return = true;
 128     if (autocvar_cl_damagetext) {
 129         if (autocvar_cl_damagetext_accumulate_range) {
 130             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 131                 if (e.instanceOfDamageText && e.m_group == group) {
 132                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor, deathtype);
 133                     return;
 134                 }
 135             }
 136         }
 137         NEW(DamageText, group, location, health, armor, deathtype);
 138     }
 139 }
 140 #endif
 141
 142 #ifdef MENUQC
 143 CLASS(XonoticDamageTextSettings, XonoticTab)
 144     #include <menu/gamesettings.qh>
 145     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 146     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"))
 147     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9)
 148     ATTRIB(XonoticDamageTextSettings, rows, float, 15.5)
 149     ATTRIB(XonoticDamageTextSettings, columns, float, 5)
 150     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 151     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 152     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 153     {
 154         entity e;
 155         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 156             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 157         this.TR(this);
 158             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Font size:")));
 159                 setDependent(e, "cl_damagetext", 1, 1);
 160             this.TD(this, 1, 2, e = makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 161                 setDependent(e, "cl_damagetext", 1, 1);
 162         this.TR(this);
 163             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Accumulate range:")));
 164                 setDependent(e, "cl_damagetext", 1, 1);
 165             this.TD(this, 1, 2, e = makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 166                 setDependent(e, "cl_damagetext", 1, 1);
 167         this.TR(this);
 168             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Lifetime:")));
 169                 setDependent(e, "cl_damagetext", 1, 1);
 170             this.TD(this, 1, 2, e = makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 171                 setDependent(e, "cl_damagetext", 1, 1);
 172         this.TR(this);
 173             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 174                 setDependent(e, "cl_damagetext", 1, 1);
 175             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 176                 setDependent(e, "cl_damagetext", 1, 1);
 177     }
 178 ENDCLASS(XonoticDamageTextSettings)
 179 #endif
 180 #endif