qcsrc/common/mutators/mutator/instagib/instagib.qc

   1 #ifndef MUTATOR_INSTAGIB_H
   2 #define MUTATOR_INSTAGIB_H
   3
   4 #include "items.qc"
   5
   6 #ifdef SVQC
   7 float autocvar_g_instagib_invis_alpha;
   8 #endif
   9
  10 #endif
  11
  12 #ifdef IMPLEMENTATION
  13 #ifdef SVQC
  14
  15 int autocvar_g_instagib_ammo_drop;
  16 int autocvar_g_instagib_extralives;
  17 float autocvar_g_instagib_speed_highspeed;
  18
  19 #include <server/cl_client.qh>
  20
  21 #include <common/items/all.qc>
  22
  23 REGISTER_MUTATOR(mutator_instagib, cvar("g_instagib") && !g_nexball);
  24
  25 spawnfunc(item_minst_cells)
  26 {
  27         if (!g_instagib) { remove(this); return; }
  28         if (!this.ammo_cells) this.ammo_cells = autocvar_g_instagib_ammo_drop;
  29         StartItem(this, ITEM_VaporizerCells);
  30 }
  31
  32 void instagib_invisibility(entity this)
  33 {
  34         this.strength_finished = autocvar_g_balance_powerup_strength_time;
  35         StartItem(this, ITEM_Invisibility);
  36 }
  37
  38 void instagib_extralife(entity this)
  39 {
  40         StartItem(this, ITEM_ExtraLife);
  41 }
  42
  43 void instagib_speed(entity this)
  44 {
  45         this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
  46         StartItem(this, ITEM_Speed);
  47 }
  48
  49 .float instagib_nextthink;
  50 .float instagib_needammo;
  51 void instagib_stop_countdown(entity e)
  52 {
  53         if (!e.instagib_needammo)
  54                 return;
  55         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER, CPID_INSTAGIB_FINDAMMO);
  56         e.instagib_needammo = false;
  57 }
  58 void instagib_ammocheck(entity this)
  59 {
  60         if(time < this.instagib_nextthink)
  61                 return;
  62         if(!IS_PLAYER(this))
  63                 return; // not a player
  64
  65         if(IS_DEAD(this) || gameover)
  66                 instagib_stop_countdown(this);
  67         else if (this.ammo_cells > 0 || (this.items & IT_UNLIMITED_WEAPON_AMMO) || (this.flags & FL_GODMODE))
  68                 instagib_stop_countdown(this);
  69         else if(autocvar_g_rm && autocvar_g_rm_laser)
  70         {
  71                 if(!this.instagib_needammo)
  72                 {
  73                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_INSTAGIB_DOWNGRADE);
  74                         this.instagib_needammo = true;
  75                 }
  76         }
  77         else
  78         {
  79                 this.instagib_needammo = true;
  80                 if (this.health <= 5)
  81                 {
  82                         Damage(this, this, this, 5, DEATH_NOAMMO.m_id, this.origin, '0 0 0');
  83                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_INSTAGIB_TERMINATED);
  84                 }
  85                 else if (this.health <= 10)
  86                 {
  87                         Damage(this, this, this, 5, DEATH_NOAMMO.m_id, this.origin, '0 0 0');
  88                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_NUM_1);
  89                 }
  90                 else if (this.health <= 20)
  91                 {
  92                         Damage(this, this, this, 10, DEATH_NOAMMO.m_id, this.origin, '0 0 0');
  93                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_NUM_2);
  94                 }
  95                 else if (this.health <= 30)
  96                 {
  97                         Damage(this, this, this, 10, DEATH_NOAMMO.m_id, this.origin, '0 0 0');
  98                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_NUM_3);
  99                 }
 100                 else if (this.health <= 40)
 101                 {
 102                         Damage(this, this, this, 10, DEATH_NOAMMO.m_id, this.origin, '0 0 0');
 103                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_NUM_4);
 104                 }
 105                 else if (this.health <= 50)
 106                 {
 107                         Damage(this, this, this, 10, DEATH_NOAMMO.m_id, this.origin, '0 0 0');
 108                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_NUM_5);
 109                 }
 110                 else if (this.health <= 60)
 111                 {
 112                         Damage(this, this, this, 10, DEATH_NOAMMO.m_id, this.origin, '0 0 0');
 113                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_NUM_6);
 114                 }
 115                 else if (this.health <= 70)
 116                 {
 117                         Damage(this, this, this, 10, DEATH_NOAMMO.m_id, this.origin, '0 0 0');
 118                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_NUM_7);
 119                 }
 120                 else if (this.health <= 80)
 121                 {
 122                         Damage(this, this, this, 10, DEATH_NOAMMO.m_id, this.origin, '0 0 0');
 123                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_NUM_8);
 124                 }
 125                 else if (this.health <= 90)
 126                 {
 127                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_INSTAGIB_FINDAMMO);
 128                         Damage(this, this, this, 10, DEATH_NOAMMO.m_id, this.origin, '0 0 0');
 129                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_NUM_9);
 130                 }
 131                 else
 132                 {
 133                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_MULTI, MULTI_INSTAGIB_FINDAMMO);
 134                         Damage(this, this, this, 10, DEATH_NOAMMO.m_id, this.origin, '0 0 0');
 135                 }
 136         }
 137         this.instagib_nextthink = time + 1;
 138 }
 139
 140 MUTATOR_HOOKFUNCTION(mutator_instagib, MatchEnd)
 141 {
 142         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(instagib_stop_countdown(it)));
 143 }
 144
 145 MUTATOR_HOOKFUNCTION(mutator_instagib, MonsterDropItem)
 146 {
 147         entity item = M_ARGV(1, entity);
 148
 149         item.monster_loot = spawnfunc_item_minst_cells;
 150 }
 151
 152 MUTATOR_HOOKFUNCTION(mutator_instagib, MonsterSpawn)
 153 {
 154         entity mon = M_ARGV(0, entity);
 155
 156         // always refill ammo
 157         if(mon.monsterid == MON_MAGE.monsterid)
 158                 mon.skin = 1;
 159 }
 160
 161 MUTATOR_HOOKFUNCTION(mutator_instagib, BotShouldAttack)
 162 {
 163         entity targ = M_ARGV(1, entity);
 164
 165         if (targ.items & ITEM_Invisibility.m_itemid)
 166                 return true;
 167 }
 168
 169 MUTATOR_HOOKFUNCTION(mutator_instagib, MakePlayerObserver)
 170 {
 171         entity player = M_ARGV(0, entity);
 172
 173         instagib_stop_countdown(player);
 174 }
 175
 176 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerSpawn)
 177 {
 178         entity player = M_ARGV(0, entity);
 179
 180         player.effects |= EF_FULLBRIGHT;
 181 }
 182
 183 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerPreThink)
 184 {
 185         entity player = M_ARGV(0, entity);
 186
 187         instagib_ammocheck(player);
 188 }
 189
 190 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerRegen)
 191 {
 192         // no regeneration in instagib
 193         return true;
 194 }
 195
 196 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerPowerups)
 197 {
 198         entity player = M_ARGV(0, entity);
 199
 200         if (!(player.effects & EF_FULLBRIGHT))
 201                 player.effects |= EF_FULLBRIGHT;
 202
 203         if (player.items & ITEM_Invisibility.m_itemid)
 204         {
 205                 play_countdown(player, player.strength_finished, SND_POWEROFF);
 206                 if (time > player.strength_finished)
 207                 {
 208                         player.alpha = default_player_alpha;
 209                         player.exteriorweaponentity.alpha = default_weapon_alpha;
 210                         player.items &= ~ITEM_Invisibility.m_itemid;
 211                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
 212                 }
 213         }
 214         else
 215         {
 216                 if (time < player.strength_finished)
 217                 {
 218                         player.alpha = autocvar_g_instagib_invis_alpha;
 219                         player.exteriorweaponentity.alpha = autocvar_g_instagib_invis_alpha;
 220                         player.items |= ITEM_Invisibility.m_itemid;
 221                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_INVISIBILITY, player.netname);
 222                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
 223                 }
 224         }
 225
 226         if (player.items & ITEM_Speed.m_itemid)
 227         {
 228                 play_countdown(player, player.invincible_finished, SND_POWEROFF);
 229                 if (time > player.invincible_finished)
 230                 {
 231                         player.items &= ~ITEM_Speed.m_itemid;
 232                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_POWERDOWN_SPEED);
 233                 }
 234         }
 235         else
 236         {
 237                 if (time < player.invincible_finished)
 238                 {
 239                         player.items |= ITEM_Speed.m_itemid;
 240                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SPEED, player.netname);
 241                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_POWERUP_SPEED);
 242                 }
 243         }
 244 }
 245
 246 .float stat_sv_maxspeed;
 247
 248 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerPhysics)
 249 {
 250         entity player = M_ARGV(0, entity);
 251
 252         if(player.items & ITEM_Speed.m_itemid)
 253                 player.stat_sv_maxspeed = player.stat_sv_maxspeed * autocvar_g_instagib_speed_highspeed;
 254 }
 255
 256 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerDamage_SplitHealthArmor)
 257 {
 258         M_ARGV(4, float) = M_ARGV(7, float); // take = damage
 259         M_ARGV(5, float) = 0; // save
 260 }
 261
 262 MUTATOR_HOOKFUNCTION(mutator_instagib, ForbidThrowCurrentWeapon)
 263 {
 264         // weapon dropping on death handled by FilterItem
 265         return true;
 266 }
 267
 268 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerDamage_Calculate)
 269 {
 270         entity frag_attacker = M_ARGV(1, entity);
 271         entity frag_target = M_ARGV(2, entity);
 272         float frag_deathtype = M_ARGV(3, float);
 273         float frag_damage = M_ARGV(4, float);
 274         float frag_mirrordamage = M_ARGV(5, float);
 275         vector frag_force = M_ARGV(6, vector);
 276
 277         if(autocvar_g_friendlyfire == 0 && SAME_TEAM(frag_target, frag_attacker) && IS_PLAYER(frag_target) && IS_PLAYER(frag_attacker))
 278                 frag_damage = 0;
 279
 280         if(IS_PLAYER(frag_target))
 281         {
 282                 if(frag_deathtype == DEATH_FALL.m_id)
 283                         frag_damage = 0; // never count fall damage
 284
 285                 if(!autocvar_g_instagib_damagedbycontents)
 286                 switch(DEATH_ENT(frag_deathtype))
 287                 {
 288                         case DEATH_DROWN:
 289                         case DEATH_SLIME:
 290                         case DEATH_LAVA:
 291                                 frag_damage = 0;
 292                                 break;
 293                 }
 294
 295                 if(IS_PLAYER(frag_attacker))
 296                 if(DEATH_ISWEAPON(frag_deathtype, WEP_VAPORIZER))
 297                 {
 298                         if(!autocvar_g_instagib_friendlypush && SAME_TEAM(frag_target, frag_attacker))
 299                                 frag_force = '0 0 0';
 300
 301                         if(frag_target.armorvalue)
 302                         {
 303                                 frag_target.armorvalue -= 1;
 304                                 frag_damage = 0;
 305                                 frag_target.damage_dealt += 1;
 306                                 frag_attacker.damage_dealt += 1;
 307                                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_INSTAGIB_LIVES_REMAINING, frag_target.armorvalue);
 308                         }
 309                 }
 310
 311                 if(IS_PLAYER(frag_attacker) && DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
 312                 {
 313                         if(frag_deathtype & HITTYPE_SECONDARY)
 314                         {
 315                                 if(!autocvar_g_instagib_blaster_keepdamage || frag_attacker == frag_target)
 316                                 {
 317                                         frag_damage = 0;
 318                                         if(!autocvar_g_instagib_mirrordamage)
 319                                                 frag_mirrordamage = 0; // never do mirror damage on enemies
 320                                 }
 321
 322                                 if(frag_target != frag_attacker)
 323                                 {
 324                                         if(frag_damage <= 0 && frag_target.health > 0) { Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE); }
 325                                         if(!autocvar_g_instagib_blaster_keepforce)
 326                                                 frag_force = '0 0 0';
 327                                 }
 328                         }
 329                 }
 330         }
 331
 332         if(!autocvar_g_instagib_mirrordamage) // only apply the taking lives hack if we don't want to support real damage mirroring
 333         if(IS_PLAYER(frag_attacker))
 334         if(frag_mirrordamage > 0)
 335         {
 336                 // just lose extra LIVES, don't kill the player for mirror damage
 337                 if(frag_attacker.armorvalue > 0)
 338                 {
 339                         frag_attacker.armorvalue -= 1;
 340                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_INSTAGIB_LIVES_REMAINING, frag_attacker.armorvalue);
 341                         frag_attacker.damage_dealt += frag_mirrordamage;
 342                 }
 343                 frag_mirrordamage = 0;
 344         }
 345
 346         if(frag_target.alpha && frag_target.alpha < 1)
 347         if(IS_PLAYER(frag_target))
 348                 yoda = 1;
 349
 350         M_ARGV(4, float) = frag_damage;
 351         M_ARGV(5, float) = frag_mirrordamage;
 352         M_ARGV(6, vector) = frag_force;
 353 }
 354
 355 MUTATOR_HOOKFUNCTION(mutator_instagib, SetStartItems)
 356 {
 357         start_health       = warmup_start_health       = 100;
 358         start_armorvalue   = warmup_start_armorvalue   = 0;
 359
 360         start_ammo_shells  = warmup_start_ammo_shells  = 0;
 361         start_ammo_nails   = warmup_start_ammo_nails   = 0;
 362         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_instagib_ammo_start");
 363         start_ammo_plasma  = warmup_start_ammo_plasma  = 0;
 364         start_ammo_rockets = warmup_start_ammo_rockets = 0;
 365         start_ammo_fuel    = warmup_start_ammo_fuel    = 0;
 366
 367         start_weapons = warmup_start_weapons = WEPSET(VAPORIZER);
 368         start_items |= IT_UNLIMITED_SUPERWEAPONS;
 369 }
 370
 371 MUTATOR_HOOKFUNCTION(mutator_instagib, FilterItem)
 372 {
 373         entity item = M_ARGV(0, entity);
 374
 375         if(item.classname == "item_cells")
 376                 return true; // no normal cells?
 377
 378         if(item.weapon == WEP_VAPORIZER.m_id && item.classname == "droppedweapon")
 379         {
 380                 item.ammo_cells = autocvar_g_instagib_ammo_drop;
 381                 return false;
 382         }
 383
 384         if(item.weapon == WEP_DEVASTATOR.m_id || item.weapon == WEP_VORTEX.m_id)
 385         {
 386                 entity e = spawn();
 387                 setorigin(e, item.origin);
 388                 e.noalign = item.noalign;
 389         e.cnt = item.cnt;
 390         e.team = item.team;
 391         e.spawnfunc_checked = true;
 392                 spawnfunc_item_minst_cells(e);
 393                 return true;
 394         }
 395
 396         if(item.flags & FL_POWERUP)
 397                 return false;
 398
 399         if(item.ammo_cells > autocvar_g_instagib_ammo_drop && item.classname != "item_minst_cells")
 400                 item.ammo_cells = autocvar_g_instagib_ammo_drop;
 401
 402         if(item.ammo_cells && !item.weapon)
 403                 return false;
 404
 405         return true;
 406 }
 407
 408 MUTATOR_HOOKFUNCTION(mutator_instagib, CustomizeWaypoint)
 409 {
 410         entity wp = M_ARGV(0, entity);
 411         entity player = M_ARGV(1, entity);
 412
 413         entity e = WaypointSprite_getviewentity(player);
 414
 415         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 416         // but only apply this to real players, not to spectators
 417         if((wp.owner.flags & FL_CLIENT) && (wp.owner.items & ITEM_Invisibility.m_itemid) && (e == player))
 418         if(DIFF_TEAM(wp.owner, e))
 419                 return true;
 420 }
 421
 422 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerDies)
 423 {
 424         float frag_deathtype = M_ARGV(3, float);
 425
 426         if(DEATH_ISWEAPON(frag_deathtype, WEP_VAPORIZER))
 427                 M_ARGV(4, float) = 1000; // always gib if it was a vaporizer death
 428 }
 429
 430 MUTATOR_HOOKFUNCTION(mutator_instagib, ItemTouch)
 431 {
 432         entity item = M_ARGV(0, entity);
 433         entity toucher = M_ARGV(1, entity);
 434
 435         if(item.ammo_cells)
 436         {
 437                 // play some cool sounds ;)
 438                 if (IS_CLIENT(toucher))
 439                 {
 440                         if(toucher.health <= 5)
 441                                 Send_Notification(NOTIF_ONE, toucher, MSG_ANNCE, ANNCE_INSTAGIB_LASTSECOND);
 442                         else if(toucher.health < 50)
 443                                 Send_Notification(NOTIF_ONE, toucher, MSG_ANNCE, ANNCE_INSTAGIB_NARROWLY);
 444                 }
 445
 446                 if(toucher.health < 100)
 447                         toucher.health = 100;
 448
 449                 return MUT_ITEMTOUCH_CONTINUE;
 450         }
 451
 452         if(item.itemdef == ITEM_ExtraLife)
 453         {
 454                 toucher.armorvalue = bound(toucher.armorvalue, 999, toucher.armorvalue + autocvar_g_instagib_extralives);
 455                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_EXTRALIVES);
 456                 return MUT_ITEMTOUCH_PICKUP;
 457         }
 458
 459         return MUT_ITEMTOUCH_CONTINUE;
 460 }
 461
 462 MUTATOR_HOOKFUNCTION(mutator_instagib, OnEntityPreSpawn)
 463 {
 464         if (!autocvar_g_powerups) { return; }
 465         entity ent = M_ARGV(0, entity);
 466         // Can't use .itemdef here
 467         if (!(ent.classname == "item_strength" || ent.classname == "item_invincible" || ent.classname == "item_health_mega"))
 468                 return;
 469
 470         entity e = spawn();
 471
 472         float r = random();
 473         if (r < 0.3)
 474                 setthink(e, instagib_invisibility);
 475         else if (r < 0.6)
 476                 setthink(e, instagib_extralife);
 477         else
 478                 setthink(e, instagib_speed);
 479
 480         e.nextthink = time + 0.1;
 481         e.spawnflags = ent.spawnflags;
 482         e.noalign = ent.noalign;
 483         setorigin(e, ent.origin);
 484
 485         return true;
 486 }
 487
 488 MUTATOR_HOOKFUNCTION(mutator_instagib, BuildMutatorsString)
 489 {
 490         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":instagib");
 491 }
 492
 493 MUTATOR_HOOKFUNCTION(mutator_instagib, BuildMutatorsPrettyString)
 494 {
 495         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", instagib");
 496 }
 497
 498 MUTATOR_HOOKFUNCTION(mutator_instagib, SetModname)
 499 {
 500         M_ARGV(0, string) = "InstaGib";
 501         return true;
 502 }
 503
 504 #endif
 505 #endif