qcsrc/common/mutators/mutator/itemstime.qc

   1 #ifdef IMPLEMENTATION
   2 REGISTER_MUTATOR(itemstime, true);
   3
   4 REGISTER_NET_TEMP(itemstime)
   5
   6 #ifdef SVQC
   7 void IT_Write(entity e, int i, float f) {
   8     if (!IS_REAL_CLIENT(e)) return;
   9     msg_entity = e;
  10     WriteHeader(MSG_ONE, itemstime);
  11     WriteByte(MSG_ONE, i);
  12     WriteFloat(MSG_ONE, f);
  13 }
  14 #endif
  15
  16 #ifdef CSQC
  17 // reserve one more spot for superweapons time
  18 float ItemsTime_time[Items_MAX + 1];
  19 float ItemsTime_availableTime[Items_MAX + 1];
  20 NET_HANDLE(itemstime, bool isNew)
  21 {
  22     int i = ReadByte();
  23     float f = ReadFloat();
  24     return = true;
  25     ItemsTime_time[i] = f;
  26 }
  27 #endif
  28
  29 #ifdef CSQC
  30 void Item_ItemsTime_Init()
  31 {
  32     FOREACH(Items, true, LAMBDA(
  33         ItemsTime_time[it.m_id] = -1;
  34     ));
  35     ItemsTime_time[Items_MAX] = -1;
  36 }
  37
  38 STATIC_INIT(ItemsTime_Init) {
  39     Item_ItemsTime_Init();
  40 }
  41
  42 int autocvar_hud_panel_itemstime = 2;
  43 float autocvar_hud_panel_itemstime_dynamicsize = 1;
  44 float autocvar_hud_panel_itemstime_ratio = 2;
  45 int autocvar_hud_panel_itemstime_iconalign;
  46 bool autocvar_hud_panel_itemstime_progressbar = 0;
  47 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
  48 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
  49 float autocvar_hud_panel_itemstime_progressbar_reduced;
  50 bool autocvar_hud_panel_itemstime_hidespawned = 1;
  51 bool autocvar_hud_panel_itemstime_hidelarge = false;
  52 int autocvar_hud_panel_itemstime_text = 1;
  53 #define hud_panel_itemstime_hidelarge autocvar_hud_panel_itemstime_hidelarge
  54 #else
  55 #define hud_panel_itemstime_hidelarge false
  56 #endif
  57
  58 bool Item_ItemsTime_SpectatorOnly(GameItem it)
  59 {
  60     return (false
  61     || it == ITEM_ArmorMega     || (it == ITEM_ArmorLarge && !hud_panel_itemstime_hidelarge)
  62     || it == ITEM_HealthMega    || (it == ITEM_HealthLarge && !hud_panel_itemstime_hidelarge)
  63     );
  64 }
  65
  66 bool Item_ItemsTime_Allow(GameItem it)
  67 {
  68     return (false
  69     || it.instanceOfPowerup
  70     || Item_ItemsTime_SpectatorOnly(it)
  71     );
  72 }
  73
  74 #ifdef SVQC
  75
  76 // reserve one more spot for superweapons time
  77 float it_times[Items_MAX + 1];
  78
  79 void Item_ItemsTime_Init()
  80 {
  81     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  82         it_times[it.m_id] = -1;
  83     ));
  84     it_times[Items_MAX] = -1;
  85 }
  86
  87 STATIC_INIT(ItemsTime_Init) {
  88     // items time
  89     Item_ItemsTime_Init();
  90 }
  91
  92 void Item_ItemsTime_ResetTimes()
  93 {
  94     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  95         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  96     ));
  97     it_times[Items_MAX] = (it_times[Items_MAX] == -1) ? -1 : 0;
  98 }
  99
 100 void Item_ItemsTime_ResetTimesForPlayer(entity e)
 101 {
 102     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 103         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
 104     ));
 105     IT_Write(e, Items_MAX, (it_times[Items_MAX] == -1) ? -1 : 0);
 106 }
 107
 108 void Item_ItemsTime_SetTimesForPlayer(entity e)
 109 {
 110     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 111         IT_Write(e, it.m_id, it_times[it.m_id]);
 112     ));
 113     IT_Write(e, Items_MAX, it_times[Items_MAX]);
 114 }
 115
 116 void Item_ItemsTime_SetTime(entity e, float t)
 117 {
 118     if (!autocvar_sv_itemstime)
 119         return;
 120
 121     GameItem item = e.itemdef;
 122     if (item.instanceOfGameItem)
 123     {
 124                 if (!item.instanceOfWeaponPickup)
 125                         it_times[item.m_id] = t;
 126                 else if (e.weapons & WEPSET_SUPERWEAPONS)
 127                         it_times[Items_MAX] = t;
 128     }
 129 }
 130
 131 void Item_ItemsTime_SetTimesForAllPlayers()
 132 {
 133     FOREACH_CLIENT(IS_REAL_CLIENT(it) && (warmup_stage || !IS_PLAYER(it) || autocvar_sv_itemstime == 2), LAMBDA(Item_ItemsTime_SetTimesForPlayer(it)));
 134 }
 135
 136 float Item_ItemsTime_UpdateTime(entity e, float t)
 137 {
 138     bool isavailable = (t == 0);
 139     FOREACH_ENTITY_FLOAT(pure_data, false,
 140     {
 141         if(!(it.itemdef == e.itemdef || ((e.weapons & WEPSET_SUPERWEAPONS) && (it.weapons & WEPSET_SUPERWEAPONS) && clienttype(it) == CLIENTTYPE_NOTACLIENT)))
 142             continue;
 143         if (e == it) continue;
 144         if (it.scheduledrespawntime <= time)
 145             isavailable = true;
 146         else if (t == 0 || it.scheduledrespawntime < t)
 147             t = it.scheduledrespawntime;
 148     });
 149     if (isavailable)
 150         t = -t; // let know the client there's another available item
 151     return t;
 152 }
 153
 154 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global)
 155 {
 156     Item_ItemsTime_ResetTimes();
 157     // ALL the times need to be reset before .reset()ing each item
 158     // since Item_Reset schedules respawn of superweapons and powerups
 159     FOREACH_ENTITY_FLOAT(pure_data, false,
 160     {
 161         if(IS_CLIENT(it))
 162             continue;
 163         if (it.reset) Item_ItemsTime_SetTime(it, 0);
 164     });
 165     Item_ItemsTime_SetTimesForAllPlayers();
 166 }
 167
 168 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver)
 169 {
 170     entity player = M_ARGV(0, entity);
 171
 172     Item_ItemsTime_SetTimesForPlayer(player);
 173 }
 174
 175 MUTATOR_HOOKFUNCTION(itemstime, ClientConnect, CBC_ORDER_LAST)
 176 {
 177     entity player = M_ARGV(0, entity);
 178
 179         if(IS_PLAYER(player))
 180         {
 181                 // client became player on connection skipping putObserverInServer step
 182                 if (IS_REAL_CLIENT(player))
 183                 if (warmup_stage || autocvar_sv_itemstime == 2)
 184                         Item_ItemsTime_SetTimesForPlayer(player);
 185         }
 186 }
 187
 188 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn)
 189 {
 190     if (warmup_stage || autocvar_sv_itemstime == 2) return;
 191     entity player = M_ARGV(0, entity);
 192
 193     Item_ItemsTime_ResetTimesForPlayer(player);
 194 }
 195
 196 #endif
 197
 198 #ifdef CSQC
 199
 200 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, string item_icon, float item_time, bool item_available, float item_availableTime)
 201 {
 202     float t = 0;
 203     vector color = '0 0 0';
 204     float picalpha;
 205
 206     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 207         picalpha = 1;
 208     else if (item_available)
 209     {
 210         float BLINK_FACTOR = 0.15;
 211         float BLINK_BASE = 0.85;
 212         float BLINK_FREQ = 5;
 213         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 214     }
 215     else
 216         picalpha = 0.5;
 217     t = floor(item_time - time + 0.999);
 218     if (t < 5)
 219         color = '0.7 0 0';
 220     else if (t < 10)
 221         color = '0.7 0.7 0';
 222     else
 223         color = '1 1 1';
 224
 225     vector picpos, numpos;
 226     if (autocvar_hud_panel_itemstime_iconalign)
 227     {
 228         numpos = myPos;
 229         picpos = myPos + eX * (ar - 1) * mySize_y;
 230     }
 231     else
 232     {
 233         numpos = myPos + eX * mySize_y;
 234         picpos = myPos;
 235     }
 236
 237     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 238     {
 239         vector p_pos, p_size;
 240         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 241         {
 242             p_pos = numpos;
 243             p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
 244         }
 245         else
 246         {
 247             p_pos = myPos;
 248             p_size = mySize;
 249         }
 250         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 251     }
 252
 253     if(autocvar_hud_panel_itemstime_text)
 254     {
 255         if(t > 0)
 256             drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 257         else if(precache_pic("gfx/hud/default/checkmark")) // COMPAT: check if this image exists, as 0.8.1 clients lack it
 258             drawpic_aspect_skin(numpos, "checkmark", eX * (ar - 1) * mySize_y + eY * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 259         else // legacy code, if the image is missing just center the icon
 260             picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 261     }
 262     if (item_availableTime)
 263         drawpic_aspect_skin_expanding(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 264     drawpic_aspect_skin(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 265 }
 266
 267 void HUD_ItemsTime()
 268 {
 269     if (!autocvar__hud_configure)
 270     {
 271         if (!(
 272             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 273         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage || STAT(ITEMSTIME) == 2))
 274             )) { return; }
 275     }
 276     else
 277     {
 278         ItemsTime_time[ITEM_ArmorMega.m_id] = time + 0;
 279         ItemsTime_time[ITEM_HealthMega.m_id] = time + 8;
 280         ItemsTime_time[ITEM_Strength.m_id] = time + 0;
 281         ItemsTime_time[ITEM_Shield.m_id] = time + 4;
 282     }
 283
 284     int count = 0;
 285     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 286     {
 287         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 288             count += (ItemsTime_time[it.m_id] > time || -ItemsTime_time[it.m_id] > time);
 289         ));
 290         count += (ItemsTime_time[Items_MAX] > time || -ItemsTime_time[Items_MAX] > time);
 291     }
 292     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 293     {
 294         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 295             count += (ItemsTime_time[it.m_id] > time);
 296         ));
 297         count += (ItemsTime_time[Items_MAX] > time);
 298     }
 299     else
 300     {
 301         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 302             count += (ItemsTime_time[it.m_id] != -1);
 303         ));
 304         count += (ItemsTime_time[Items_MAX] != -1);
 305     }
 306     if (count == 0)
 307         return;
 308
 309     HUD_Panel_LoadCvars();
 310
 311     vector pos, mySize;
 312     pos = panel_pos;
 313     mySize = panel_size;
 314
 315     if (panel_bg_padding)
 316     {
 317         pos += '1 1 0' * panel_bg_padding;
 318         mySize -= '2 2 0' * panel_bg_padding;
 319     }
 320
 321     float rows, columns;
 322     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 323     rows = HUD_GetRowCount(count, mySize, ar);
 324     columns = ceil(count/rows);
 325
 326     vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 327
 328     vector offset = '0 0 0';
 329     float newSize;
 330     if (autocvar_hud_panel_itemstime_dynamicsize)
 331     {
 332         if (autocvar__hud_configure)
 333         if (hud_configure_menu_open != 2)
 334             HUD_Panel_DrawBg(); // also draw the bg of the entire panel
 335
 336         // reduce panel to avoid spacing items
 337         if (itemstime_size.x / itemstime_size.y < ar)
 338         {
 339             newSize = rows * itemstime_size.x / ar;
 340             pos.y += (mySize.y - newSize) / 2;
 341             mySize.y = newSize;
 342             itemstime_size.y = mySize.y / rows;
 343         }
 344         else
 345         {
 346             newSize = columns * itemstime_size.y * ar;
 347             pos.x += (mySize.x - newSize) / 2;
 348             mySize.x = newSize;
 349             itemstime_size.x = mySize.x / columns;
 350         }
 351         panel_pos = pos - '1 1 0' * panel_bg_padding;
 352         panel_size = mySize + '2 2 0' * panel_bg_padding;
 353     }
 354     else
 355     {
 356         if (itemstime_size.x/itemstime_size.y > ar)
 357         {
 358             newSize = ar * itemstime_size.y;
 359             offset.x = itemstime_size.x - newSize;
 360             pos.x += offset.x/2;
 361             itemstime_size.x = newSize;
 362         }
 363         else
 364         {
 365             newSize = 1/ar * itemstime_size.x;
 366             offset.y = itemstime_size.y - newSize;
 367             pos.y += offset.y/2;
 368             itemstime_size.y = newSize;
 369         }
 370     }
 371
 372     HUD_Scale_Enable();
 373     HUD_Panel_DrawBg();
 374
 375     float row = 0, column = 0;
 376     bool item_available;
 377     int id = 0;
 378     string icon = "";
 379     FOREACH(Items, Item_ItemsTime_Allow(it) && ItemsTime_time[it.m_id] != -1, LAMBDA(
 380         id = it.m_id;
 381         icon = it.m_icon;
 382
 383 LABEL(iteration)
 384         float item_time = ItemsTime_time[id];
 385         if (item_time < -1)
 386         {
 387             item_available = true;
 388             item_time = -item_time;
 389         }
 390         else
 391             item_available = (item_time <= time);
 392
 393         if (ItemsTime_time[id] >= 0)
 394         {
 395             if (time <= ItemsTime_time[id])
 396                 ItemsTime_availableTime[id] = 0;
 397             else if (ItemsTime_availableTime[id] == 0)
 398                 ItemsTime_availableTime[id] = time;
 399         }
 400         else if (ItemsTime_availableTime[id] == 0)
 401             ItemsTime_availableTime[id] = time;
 402
 403         float f = (time - ItemsTime_availableTime[id]) * 2;
 404         f = (f > 1) ? 0 : bound(0, f, 1);
 405
 406         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 407             if (!(ItemsTime_time[id] > time || -ItemsTime_time[id] > time))
 408                 continue;
 409
 410         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 411             if (!(ItemsTime_time[id] > time))
 412                 continue;
 413
 414         DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, icon, item_time, item_available, f);
 415         ++row;
 416         if (row >= rows)
 417         {
 418             row = 0;
 419             column = column + 1;
 420         }
 421         if(id == Items_MAX) // can happen only in the last fake iteration
 422                 break;
 423     ));
 424     // add another fake iteration for superweapons time
 425     if(id < Items_MAX && ItemsTime_time[Items_MAX] != -1)
 426     {
 427                 id = Items_MAX;
 428                 icon = "superweapons";
 429                 goto iteration;
 430     }
 431 }
 432
 433 #endif
 434 #endif