qcsrc/common/mutators/mutator/itemstime/itemstime.qc

   1 #include "itemstime.qh"
   2
   3 REGISTER_MUTATOR(itemstime, true);
   4
   5 REGISTER_NET_TEMP(itemstime)
   6
   7 #ifdef SVQC
   8 void IT_Write(entity e, int i, float f) {
   9     if (!IS_REAL_CLIENT(e)) return;
  10     msg_entity = e;
  11     WriteHeader(MSG_ONE, itemstime);
  12     WriteByte(MSG_ONE, i);
  13     WriteFloat(MSG_ONE, f);
  14 }
  15 #endif
  16
  17 #ifdef CSQC
  18 // reserve one more spot for superweapons time
  19 float ItemsTime_time[REGISTRY_MAX(Items) + 1];
  20 float ItemsTime_availableTime[REGISTRY_MAX(Items) + 1];
  21 NET_HANDLE(itemstime, bool isNew)
  22 {
  23     int i = ReadByte();
  24     float f = ReadFloat();
  25     return = true;
  26     ItemsTime_time[i] = f;
  27 }
  28 #endif
  29
  30 #ifdef CSQC
  31
  32 STATIC_INIT(ItemsTime_Init) {
  33         FOREACH(Items, true, {
  34                 ItemsTime_time[it.m_id] = -1;
  35         });
  36         ItemsTime_time[REGISTRY_MAX(Items)] = -1;
  37 }
  38
  39 int autocvar_hud_panel_itemstime = 2;
  40 float autocvar_hud_panel_itemstime_dynamicsize = 1;
  41 float autocvar_hud_panel_itemstime_ratio = 2;
  42 int autocvar_hud_panel_itemstime_iconalign;
  43 bool autocvar_hud_panel_itemstime_progressbar = 0;
  44 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
  45 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
  46 float autocvar_hud_panel_itemstime_progressbar_reduced;
  47 bool autocvar_hud_panel_itemstime_hidespawned = 1;
  48 bool autocvar_hud_panel_itemstime_hidebig = false;
  49 int autocvar_hud_panel_itemstime_text = 1;
  50 #define hud_panel_itemstime_hidebig autocvar_hud_panel_itemstime_hidebig
  51 #else
  52 #define hud_panel_itemstime_hidebig false
  53 #endif
  54
  55 bool Item_ItemsTime_SpectatorOnly(GameItem it)
  56 {
  57     return (false
  58     || it == ITEM_ArmorMega     || (it == ITEM_ArmorBig && !hud_panel_itemstime_hidebig)
  59     || it == ITEM_HealthMega    || (it == ITEM_HealthBig && !hud_panel_itemstime_hidebig)
  60     );
  61 }
  62
  63 bool Item_ItemsTime_Allow(GameItem it)
  64 {
  65     return (false
  66     || it.instanceOfPowerup
  67     || Item_ItemsTime_SpectatorOnly(it)
  68     );
  69 }
  70
  71 #ifdef SVQC
  72
  73 // reserve one more spot for superweapons time
  74 float it_times[REGISTRY_MAX(Items) + 1];
  75
  76 STATIC_INIT(ItemsTime_Init) {
  77         FOREACH(Items, Item_ItemsTime_Allow(it), {
  78                 it_times[it.m_id] = -1;
  79         });
  80         it_times[REGISTRY_MAX(Items)] = -1;
  81 }
  82
  83 void Item_ItemsTime_ResetTimes()
  84 {
  85     FOREACH(Items, Item_ItemsTime_Allow(it), {
  86         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  87     });
  88     it_times[REGISTRY_MAX(Items)] = (it_times[REGISTRY_MAX(Items)] == -1) ? -1 : 0;
  89 }
  90
  91 void Item_ItemsTime_ResetTimesForPlayer(entity e)
  92 {
  93     FOREACH(Items, Item_ItemsTime_Allow(it), {
  94         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
  95     });
  96     IT_Write(e, REGISTRY_MAX(Items), (it_times[REGISTRY_MAX(Items)] == -1) ? -1 : 0);
  97 }
  98
  99 void Item_ItemsTime_SetTimesForPlayer(entity e)
 100 {
 101     FOREACH(Items, Item_ItemsTime_Allow(it), {
 102         IT_Write(e, it.m_id, it_times[it.m_id]);
 103     });
 104     IT_Write(e, REGISTRY_MAX(Items), it_times[REGISTRY_MAX(Items)]);
 105 }
 106
 107 void Item_ItemsTime_SetTime(entity e, float t)
 108 {
 109     if (!autocvar_sv_itemstime)
 110         return;
 111
 112     GameItem item = e.itemdef;
 113     if (item.instanceOfGameItem)
 114     {
 115                 if (!item.instanceOfWeaponPickup)
 116                         it_times[item.m_id] = t;
 117                 else if (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS)
 118                         it_times[REGISTRY_MAX(Items)] = t;
 119     }
 120 }
 121
 122 void Item_ItemsTime_SetTimesForAllPlayers()
 123 {
 124     FOREACH_CLIENT(IS_REAL_CLIENT(it) && (warmup_stage || !IS_PLAYER(it) || autocvar_sv_itemstime == 2), { Item_ItemsTime_SetTimesForPlayer(it); });
 125 }
 126
 127 float Item_ItemsTime_UpdateTime(entity e, float t)
 128 {
 129     bool isavailable = (t == 0);
 130     IL_EACH(g_items, it != e,
 131     {
 132         if(!(it.itemdef == e.itemdef || ((STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) && (STAT(WEAPONS, it) & WEPSET_SUPERWEAPONS))))
 133             continue;
 134         if (it.scheduledrespawntime <= time)
 135             isavailable = true;
 136         else if (t == 0 || it.scheduledrespawntime < t)
 137             t = it.scheduledrespawntime;
 138     });
 139     if (isavailable)
 140         t = -t; // let know the client there's another available item
 141     return t;
 142 }
 143
 144 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global)
 145 {
 146     Item_ItemsTime_ResetTimes();
 147     // ALL the times need to be reset before .reset()ing each item
 148     // since Item_Reset schedules respawn of superweapons and powerups
 149     IL_EACH(g_items, it.reset,
 150     {
 151         Item_ItemsTime_SetTime(it, 0);
 152     });
 153     Item_ItemsTime_SetTimesForAllPlayers();
 154 }
 155
 156 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver)
 157 {
 158     entity player = M_ARGV(0, entity);
 159
 160     Item_ItemsTime_SetTimesForPlayer(player);
 161 }
 162
 163 MUTATOR_HOOKFUNCTION(itemstime, ClientConnect, CBC_ORDER_LAST)
 164 {
 165     entity player = M_ARGV(0, entity);
 166
 167         if(IS_PLAYER(player))
 168         {
 169                 // client became player on connection skipping putObserverInServer step
 170                 if (IS_REAL_CLIENT(player))
 171                 if (warmup_stage || autocvar_sv_itemstime == 2)
 172                         Item_ItemsTime_SetTimesForPlayer(player);
 173         }
 174 }
 175
 176 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn)
 177 {
 178     if (warmup_stage || autocvar_sv_itemstime == 2) return;
 179     entity player = M_ARGV(0, entity);
 180
 181     Item_ItemsTime_ResetTimesForPlayer(player);
 182 }
 183
 184 #endif
 185
 186 #ifdef CSQC
 187
 188 // ItemsTime (#22)
 189
 190 void HUD_ItemsTime_Export(int fh)
 191 {
 192         // allow saving cvars that aesthetically change the panel into hud skin files
 193         HUD_Write_Cvar("hud_panel_itemstime_iconalign");
 194         HUD_Write_Cvar("hud_panel_itemstime_progressbar");
 195         HUD_Write_Cvar("hud_panel_itemstime_progressbar_name");
 196         HUD_Write_Cvar("hud_panel_itemstime_progressbar_reduced");
 197         HUD_Write_Cvar("hud_panel_itemstime_text");
 198         HUD_Write_Cvar("hud_panel_itemstime_ratio");
 199         HUD_Write_Cvar("hud_panel_itemstime_dynamicsize");
 200 }
 201
 202 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, string item_icon, float item_time, bool item_available, float item_availableTime)
 203 {
 204     float t = 0;
 205     vector color = '0 0 0';
 206     float picalpha;
 207
 208     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 209         picalpha = 1;
 210     else if (item_available)
 211         picalpha = blink(0.85, 0.15, 5);
 212     else
 213         picalpha = 0.5;
 214     t = floor(item_time - time + 0.999);
 215     if (t < 5)
 216         color = '0.7 0 0';
 217     else if (t < 10)
 218         color = '0.7 0.7 0';
 219     else
 220         color = '1 1 1';
 221
 222     vector picpos, numpos;
 223     if (autocvar_hud_panel_itemstime_iconalign)
 224     {
 225         numpos = myPos;
 226         picpos = myPos + eX * (ar - 1) * mySize_y;
 227     }
 228     else
 229     {
 230         numpos = myPos + eX * mySize_y;
 231         picpos = myPos;
 232     }
 233
 234     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 235     {
 236         vector p_pos, p_size;
 237         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 238         {
 239             p_pos = numpos;
 240             p_size = vec2(((ar - 1)/ar) * mySize.x, mySize.y);
 241         }
 242         else
 243         {
 244             p_pos = myPos;
 245             p_size = mySize;
 246         }
 247         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 248     }
 249
 250     if(autocvar_hud_panel_itemstime_text)
 251     {
 252         if(t > 0)
 253             drawstring_aspect(numpos, ftos(t), vec2(((ar - 1)/ar) * mySize.x, mySize.y), color, panel_fg_alpha, DRAWFLAG_NORMAL);
 254         else if(precache_pic("gfx/hud/default/checkmark")) // COMPAT: check if this image exists, as 0.8.1 clients lack it
 255             drawpic_aspect_skin(numpos, "checkmark", vec2((ar - 1) * mySize.y, mySize.y), '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 256         else // legacy code, if the image is missing just center the icon
 257             picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 258     }
 259     if (item_availableTime)
 260         drawpic_aspect_skin_expanding(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 261     drawpic_aspect_skin(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 262 }
 263
 264 float Item_ItemsTime_GetTime(int item)
 265 {
 266     if(autocvar__hud_configure)
 267     {
 268         switch(item)
 269         {
 270             case ITEM_ArmorMega.m_id: return time + 0;
 271             case ITEM_HealthMega.m_id: return time + 8;
 272             case ITEM_Strength.m_id: return time + 0;
 273             case ITEM_Shield.m_id: return time + 4;
 274         }
 275
 276         return -1; // don't show others
 277     }
 278     else
 279         return ItemsTime_time[item];
 280 }
 281
 282 void HUD_ItemsTime()
 283 {
 284     if (!autocvar__hud_configure)
 285     {
 286         if (!(
 287             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 288         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage || STAT(ITEMSTIME) == 2))
 289             )) { return; }
 290     }
 291
 292     int count = 0;
 293     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 294     {
 295         FOREACH(Items, Item_ItemsTime_Allow(it), {
 296             count += (Item_ItemsTime_GetTime(it.m_id) > time || -Item_ItemsTime_GetTime(it.m_id) > time);
 297         });
 298         count += (Item_ItemsTime_GetTime(REGISTRY_MAX(Items)) > time || -Item_ItemsTime_GetTime(REGISTRY_MAX(Items)) > time);
 299     }
 300     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 301     {
 302         FOREACH(Items, Item_ItemsTime_Allow(it), {
 303             count += (Item_ItemsTime_GetTime(it.m_id) > time);
 304         });
 305         count += (Item_ItemsTime_GetTime(REGISTRY_MAX(Items)) > time);
 306     }
 307     else
 308     {
 309         FOREACH(Items, Item_ItemsTime_Allow(it), {
 310             count += (Item_ItemsTime_GetTime(it.m_id) != -1);
 311         });
 312         count += (Item_ItemsTime_GetTime(REGISTRY_MAX(Items)) != -1);
 313     }
 314     if (count == 0)
 315         return;
 316
 317     HUD_Panel_LoadCvars();
 318
 319     vector pos, mySize;
 320     pos = panel_pos;
 321     mySize = panel_size;
 322
 323     if (panel_bg_padding)
 324     {
 325         pos += '1 1 0' * panel_bg_padding;
 326         mySize -= '2 2 0' * panel_bg_padding;
 327     }
 328
 329     float rows, columns;
 330     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 331     rows = HUD_GetRowCount(count, mySize, ar);
 332     columns = ceil(count/rows);
 333
 334     vector itemstime_size = vec2(mySize.x / columns, mySize.y / rows);
 335
 336     vector offset = '0 0 0';
 337     float newSize;
 338     if (autocvar_hud_panel_itemstime_dynamicsize)
 339     {
 340         if (autocvar__hud_configure)
 341         if (hud_configure_menu_open != 2)
 342             HUD_Panel_DrawBg(); // also draw the bg of the entire panel
 343
 344         // reduce panel to avoid spacing items
 345         if (itemstime_size.x / itemstime_size.y < ar)
 346         {
 347             newSize = rows * itemstime_size.x / ar;
 348             pos.y += (mySize.y - newSize) / 2;
 349             mySize.y = newSize;
 350             itemstime_size.y = mySize.y / rows;
 351         }
 352         else
 353         {
 354             newSize = columns * itemstime_size.y * ar;
 355             pos.x += (mySize.x - newSize) / 2;
 356             mySize.x = newSize;
 357             itemstime_size.x = mySize.x / columns;
 358         }
 359         panel_pos = pos - '1 1 0' * panel_bg_padding;
 360         panel_size = mySize + '2 2 0' * panel_bg_padding;
 361     }
 362     else
 363     {
 364         if (itemstime_size.x/itemstime_size.y > ar)
 365         {
 366             newSize = ar * itemstime_size.y;
 367             offset.x = itemstime_size.x - newSize;
 368             pos.x += offset.x/2;
 369             itemstime_size.x = newSize;
 370         }
 371         else
 372         {
 373             newSize = 1/ar * itemstime_size.x;
 374             offset.y = itemstime_size.y - newSize;
 375             pos.y += offset.y/2;
 376             itemstime_size.y = newSize;
 377         }
 378     }
 379
 380     HUD_Scale_Enable();
 381     HUD_Panel_DrawBg();
 382
 383     float row = 0, column = 0;
 384     bool item_available;
 385     int id = 0;
 386     string icon = "";
 387     FOREACH(Items, Item_ItemsTime_Allow(it) && Item_ItemsTime_GetTime(it.m_id) != -1, {
 388         id = it.m_id;
 389         icon = it.m_icon;
 390
 391 LABEL(iteration)
 392         float item_time = Item_ItemsTime_GetTime(id);
 393         if (item_time < -1)
 394         {
 395             item_available = true;
 396             item_time = -item_time;
 397         }
 398         else
 399             item_available = (item_time <= time);
 400
 401         if (Item_ItemsTime_GetTime(id) >= 0)
 402         {
 403             if (time <= Item_ItemsTime_GetTime(id))
 404                 ItemsTime_availableTime[id] = 0;
 405             else if (ItemsTime_availableTime[id] == 0)
 406                 ItemsTime_availableTime[id] = time;
 407         }
 408         else if (ItemsTime_availableTime[id] == 0)
 409             ItemsTime_availableTime[id] = time;
 410
 411         float f = (time - ItemsTime_availableTime[id]) * 2;
 412         f = (f > 1) ? 0 : bound(0, f, 1);
 413
 414         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 415             if (!(Item_ItemsTime_GetTime(id) > time || -Item_ItemsTime_GetTime(id) > time))
 416                 continue;
 417
 418         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 419             if (!(Item_ItemsTime_GetTime(id) > time))
 420                 continue;
 421
 422         DrawItemsTimeItem(pos + vec2(column * (itemstime_size.x + offset.x), row * (itemstime_size.y + offset.y)), itemstime_size, ar, icon, item_time, item_available, f);
 423         ++row;
 424         if (row >= rows)
 425         {
 426             row = 0;
 427             column = column + 1;
 428         }
 429         if(id == REGISTRY_MAX(Items)) // can happen only in the last fake iteration
 430                 break;
 431     });
 432     // add another fake iteration for superweapons time
 433     if(id < REGISTRY_MAX(Items) && Item_ItemsTime_GetTime(REGISTRY_MAX(Items)) != -1)
 434     {
 435                 id = REGISTRY_MAX(Items);
 436                 icon = "superweapons";
 437                 goto iteration;
 438     }
 439 }
 440
 441 #endif