qcsrc/common/mutators/mutator/multijump/multijump.qc

   1 #include "multijump.qh"
   2
   3 #ifdef GAMEQC
   4
   5 #ifdef SVQC
   6         #include <server/antilag.qh>
   7 #endif
   8 #include <common/physics/player.qh>
   9
  10
  11 #if defined(SVQC)
  12 REGISTER_MUTATOR(multijump, autocvar_g_multijump);
  13 #elif defined(CSQC)
  14 REGISTER_MUTATOR(multijump, true);
  15 #endif
  16
  17 #define PHYS_MULTIJUMP(s)                               STAT(MULTIJUMP, s)
  18 #define PHYS_MULTIJUMP_SPEED(s)                 STAT(MULTIJUMP_SPEED, s)
  19 #define PHYS_MULTIJUMP_ADD(s)                   STAT(MULTIJUMP_ADD, s)
  20 #define PHYS_MULTIJUMP_MAXSPEED(s)              STAT(MULTIJUMP_MAXSPEED, s)
  21 #define PHYS_MULTIJUMP_DODGING(s)               STAT(MULTIJUMP_DODGING, s)
  22 #define PHYS_MULTIJUMP_COUNT(s)                 STAT(MULTIJUMP_COUNT, s)
  23
  24 .bool multijump_ready;
  25
  26 #ifdef CSQC
  27 bool cvar_cl_multijump;
  28 bool autocvar_cl_multijump = true;
  29
  30         #define PHYS_MULTIJUMP_CLIENT(s)        autocvar_cl_multijump
  31 #elif defined(SVQC)
  32 .bool cvar_cl_multijump;
  33
  34         #define PHYS_MULTIJUMP_CLIENT(s)        CS(s).cvar_cl_multijump
  35 #endif
  36
  37 MUTATOR_HOOKFUNCTION(multijump, PlayerPhysics)
  38 {
  39     entity player = M_ARGV(0, entity);
  40
  41 #ifdef CSQC
  42         player.multijump_count = PHYS_MULTIJUMP_COUNT(player);
  43 #endif
  44         if(!PHYS_MULTIJUMP(player)) { return; }
  45
  46         if(IS_ONGROUND(player))
  47                 player.multijump_count = 0;
  48 }
  49
  50 MUTATOR_HOOKFUNCTION(multijump, PlayerJump)
  51 {
  52         entity player = M_ARGV(0, entity);
  53
  54         if(!PHYS_MULTIJUMP(player)) { return; }
  55
  56         int client_multijump = PHYS_MULTIJUMP_CLIENT(player);
  57         if(client_multijump > 1)
  58                 return; // nope
  59
  60         if (!IS_JUMP_HELD(player) && !IS_ONGROUND(player) && client_multijump) // jump button pressed this frame and we are in midair
  61                 player.multijump_ready = true;  // this is necessary to check that we released the jump button and pressed it again
  62         else
  63                 player.multijump_ready = false;
  64
  65         int phys_multijump = PHYS_MULTIJUMP(player);
  66
  67         if(!M_ARGV(2, bool) && player.multijump_ready && (PHYS_MULTIJUMP_COUNT(player) < phys_multijump || phys_multijump == -1) && player.velocity_z > PHYS_MULTIJUMP_SPEED(player) &&
  68                 (!PHYS_MULTIJUMP_MAXSPEED(player) || vdist(player.velocity, <=, PHYS_MULTIJUMP_MAXSPEED(player))))
  69         {
  70                 if (PHYS_MULTIJUMP(player))
  71                 {
  72                         if (!PHYS_MULTIJUMP_ADD(player)) // in this case we make the z velocity == jumpvelocity
  73                         {
  74                                 if (player.velocity_z < PHYS_JUMPVELOCITY(player))
  75                                 {
  76                                         M_ARGV(2, bool) = true;
  77                                         player.velocity_z = 0;
  78                                 }
  79                         }
  80                         else
  81                                 M_ARGV(2, bool) = true;
  82
  83                         if(M_ARGV(2, bool))
  84                         {
  85                                 if(PHYS_MULTIJUMP_DODGING(player))
  86                                 if(PHYS_CS(player).movement_x != 0 || PHYS_CS(player).movement_y != 0) // don't remove all speed if player isnt pressing any movement keys
  87                                 {
  88                                         float curspeed;
  89                                         vector wishvel, wishdir;
  90
  91 /*#ifdef SVQC
  92                                         curspeed = max(
  93                                                 vlen(vec2(player.velocity)), // current xy speed
  94                                                 vlen(vec2(antilag_takebackavgvelocity(player, max(player.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
  95                                         );
  96 #elif defined(CSQC)*/
  97                                         curspeed = vlen(vec2(player.velocity));
  98 //#endif
  99
 100                                         makevectors(player.v_angle_y * '0 1 0');
 101                                         wishvel = v_forward * PHYS_CS(player).movement_x + v_right * PHYS_CS(player).movement_y;
 102                                         wishdir = normalize(wishvel);
 103
 104                                         player.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
 105                                         player.velocity_y = wishdir_y * curspeed;
 106                                         // keep velocity_z unchanged!
 107                                 }
 108                                 if (PHYS_MULTIJUMP(player) > 0)
 109                                 {
 110                                         player.multijump_count += 1;
 111                                 }
 112                         }
 113                 }
 114                 player.multijump_ready = false; // require releasing and pressing the jump button again for the next jump
 115         }
 116 }
 117
 118 REPLICATE(cvar_cl_multijump, bool, "cl_multijump");
 119
 120 #ifdef SVQC
 121
 122 MUTATOR_HOOKFUNCTION(multijump, BuildMutatorsString)
 123 {
 124         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":multijump");
 125 }
 126
 127 MUTATOR_HOOKFUNCTION(multijump, BuildMutatorsPrettyString)
 128 {
 129         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Multi jump");
 130 }
 131
 132 #endif
 133
 134 #endif