qcsrc/common/mutators/mutator/overkill/hmg.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(HeavyMachineGun, Weapon)
   3 /* ammotype  */ ATTRIB(HeavyMachineGun, ammo_field, .int, ammo_nails)
   4 /* impulse   */ ATTRIB(HeavyMachineGun, impulse, int, 3)
   5 /* flags     */ ATTRIB(HeavyMachineGun, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN | WEP_FLAG_SUPERWEAPON);
   6 /* rating    */ ATTRIB(HeavyMachineGun, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(HeavyMachineGun, wpcolor, vector, '0.5 0.5 0');
   8 /* modelname */ ATTRIB(HeavyMachineGun, mdl, string, "ok_hmg");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(HeavyMachineGun, m_model, Model, MDL_HMG_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(HeavyMachineGun, w_crosshair, string, "gfx/crosshairuzi");
  13 /* crosshair */ ATTRIB(HeavyMachineGun, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(HeavyMachineGun, model2, string, "weaponhmg");
  15 /* refname   */ ATTRIB(HeavyMachineGun, netname, string, "hmg");
  16 /* wepname   */ ATTRIB(HeavyMachineGun, m_name, string, _("Heavy Machine Gun"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, ammo, float, NONE) \
  21                 P(class, prefix, damage, float, NONE) \
  22                 P(class, prefix, force, float, NONE) \
  23                 P(class, prefix, refire, float, NONE) \
  24                 P(class, prefix, reload_ammo, float, NONE) \
  25                 P(class, prefix, reload_time, float, NONE) \
  26                 P(class, prefix, solidpenetration, float, NONE) \
  27                 P(class, prefix, spread_add, float, NONE) \
  28                 P(class, prefix, spread_max, float, NONE) \
  29                 P(class, prefix, spread_min, float, NONE) \
  30                 P(class, prefix, switchdelay_drop, float, NONE) \
  31                 P(class, prefix, switchdelay_raise, float, NONE) \
  32                 P(class, prefix, weaponreplace, string, NONE) \
  33                 P(class, prefix, weaponstartoverride, float, NONE) \
  34                 P(class, prefix, weaponstart, float, NONE) \
  35                 P(class, prefix, weaponthrowable, float, NONE) \
  36     END()
  37     W_PROPS(X, HeavyMachineGun, hmg)
  38 #undef X
  39
  40 ENDCLASS(HeavyMachineGun)
  41 REGISTER_WEAPON(HMG, hmg, NEW(HeavyMachineGun));
  42
  43 #endif
  44 #ifdef IMPLEMENTATION
  45 #ifdef SVQC
  46
  47 REGISTER_MUTATOR(hmg_nadesupport, true);
  48 MUTATOR_HOOKFUNCTION(hmg_nadesupport, Nade_Damage)
  49 {
  50         if (MUTATOR_ARGV(0, entity) != WEP_HMG) return;
  51         return = true;
  52         MUTATOR_ARGV(0, float) /* damage */ = self.max_health * 0.1;
  53 }
  54
  55 spawnfunc(weapon_hmg) { weapon_defaultspawnfunc(this, WEP_HMG); }
  56
  57 void W_HeavyMachineGun_Attack_Auto(Weapon thiswep, entity actor, .entity weaponentity, int fire)
  58 {
  59         if (!actor.BUTTON_ATCK)
  60         {
  61                 w_ready(thiswep, actor, weaponentity, fire);
  62                 return;
  63         }
  64
  65         if(!thiswep.wr_checkammo1(thiswep))
  66         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
  67         {
  68                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
  69                 w_ready(thiswep, actor, weaponentity, fire);
  70                 return;
  71         }
  72
  73         W_DecreaseAmmo(WEP_HMG, self, WEP_CVAR(hmg, ammo));
  74
  75         W_SetupShot (actor, true, 0, SND(UZI_FIRE), CH_WEAPON_A, WEP_CVAR(hmg, damage));
  76
  77         if(!autocvar_g_norecoil)
  78         {
  79                 actor.punchangle_x = random () - 0.5;
  80                 actor.punchangle_y = random () - 0.5;
  81         }
  82
  83         float hmg_spread = bound(WEP_CVAR(hmg, spread_min), WEP_CVAR(hmg, spread_min) + (WEP_CVAR(hmg, spread_add) * actor.misc_bulletcounter), WEP_CVAR(hmg, spread_max));
  84         fireBullet(w_shotorg, w_shotdir, hmg_spread, WEP_CVAR(hmg, solidpenetration), WEP_CVAR(hmg, damage), WEP_CVAR(hmg, force), WEP_HMG.m_id, 0);
  85
  86         actor.misc_bulletcounter = actor.misc_bulletcounter + 1;
  87
  88         Send_Effect(EFFECT_MACHINEGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
  89
  90         W_MachineGun_MuzzleFlash();
  91         W_AttachToShotorg(actor, actor.muzzle_flash, '5 0 0');
  92
  93         if (autocvar_g_casings >= 2) // casing code
  94                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor);
  95
  96         int slot = weaponslot(weaponentity);
  97         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR(hmg, refire) * W_WeaponRateFactor();
  98         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(hmg, refire), W_HeavyMachineGun_Attack_Auto);
  99 }
 100
 101                 METHOD(HeavyMachineGun, wr_aim, void(entity thiswep))
 102                 {
 103                         if(vdist(self.origin - self.enemy.origin, <, 3000 - bound(0, skill, 10) * 200))
 104                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, false);
 105                         else
 106                                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, false);
 107                 }
 108                 METHOD(HeavyMachineGun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 109                 {
 110                         if(WEP_CVAR(hmg, reload_ammo) && actor.clip_load < WEP_CVAR(hmg, ammo)) { // forced reload
 111                                 thiswep.wr_reload(thiswep, actor, weaponentity);
 112                         } else
 113                         {
 114                                 if (fire & 1)
 115                                 if (weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
 116                                 {
 117                                         actor.misc_bulletcounter = 0;
 118                                         W_HeavyMachineGun_Attack_Auto(thiswep, actor, weaponentity, fire);
 119                                 }
 120                         }
 121                 }
 122                 METHOD(HeavyMachineGun, wr_checkammo1, bool(entity thiswep))
 123                 {
 124                         float ammo_amount = self.ammo_nails >= WEP_CVAR(hmg, ammo);
 125
 126                         if(autocvar_g_balance_hmg_reload_ammo)
 127                                 ammo_amount += self.(weapon_load[WEP_HMG.m_id]) >= WEP_CVAR(hmg, ammo);
 128
 129                         return ammo_amount;
 130                 }
 131                 METHOD(HeavyMachineGun, wr_checkammo2, bool(entity thiswep))
 132                 {
 133                         float ammo_amount = self.ammo_nails >= WEP_CVAR(hmg, ammo);
 134
 135                         if(autocvar_g_balance_hmg_reload_ammo)
 136                                 ammo_amount += self.(weapon_load[WEP_HMG.m_id]) >= WEP_CVAR(hmg, ammo);
 137
 138                         return ammo_amount;
 139                 }
 140                 METHOD(HeavyMachineGun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 141                 {
 142                         W_Reload(self, WEP_CVAR(hmg, ammo), SND(RELOAD));
 143                 }
 144                 METHOD(HeavyMachineGun, wr_suicidemessage, int(entity thiswep))
 145                 {
 146                         return WEAPON_THINKING_WITH_PORTALS;
 147                 }
 148                 METHOD(HeavyMachineGun, wr_killmessage, int(entity thiswep))
 149                 {
 150                         if(w_deathtype & HITTYPE_SECONDARY)
 151                                 return WEAPON_HMG_MURDER_SNIPE;
 152                         else
 153                                 return WEAPON_HMG_MURDER_SPRAY;
 154                 }
 155
 156 #endif
 157 #ifdef CSQC
 158
 159                 METHOD(HeavyMachineGun, wr_impacteffect, void(entity thiswep))
 160                 {
 161                         vector org2;
 162                         org2 = w_org + w_backoff * 2;
 163                         pointparticles(EFFECT_MACHINEGUN_IMPACT, org2, w_backoff * 1000, 1);
 164                         if(!w_issilent)
 165                                 sound(self, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 166                 }
 167
 168 #endif
 169 #endif