qcsrc/common/mutators/mutator/overkill/okmachinegun.qc

   1 #include "okmachinegun.qh"
   2
   3 #ifdef SVQC
   4
   5 void W_OverkillMachineGun_Attack_Auto(Weapon thiswep, entity actor, .entity weaponentity, int fire)
   6 {
   7         float okmachinegun_spread;
   8
   9         if(!(fire & 1))
  10         {
  11                 w_ready(thiswep, actor, weaponentity, fire);
  12                 return;
  13         }
  14
  15         if(!thiswep.wr_checkammo1(thiswep, actor, weaponentity))
  16         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
  17         {
  18                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
  19                 w_ready(thiswep, actor, weaponentity, fire);
  20                 return;
  21         }
  22
  23         W_DecreaseAmmo(WEP_OVERKILL_MACHINEGUN, actor, WEP_CVAR_PRI(okmachinegun, ammo), weaponentity);
  24
  25         W_SetupShot(actor, weaponentity, true, 0, SND_UZI_FIRE, CH_WEAPON_A, WEP_CVAR_PRI(okmachinegun, damage), WEP_OVERKILL_MACHINEGUN.m_id);
  26         if(!autocvar_g_norecoil)
  27         {
  28                 actor.punchangle_x = random() - 0.5;
  29                 actor.punchangle_y = random() - 0.5;
  30         }
  31
  32         okmachinegun_spread = bound(WEP_CVAR_PRI(okmachinegun, spread_min), WEP_CVAR_PRI(okmachinegun, spread_min) + (WEP_CVAR_PRI(okmachinegun, spread_add) * actor.(weaponentity).misc_bulletcounter), WEP_CVAR_PRI(okmachinegun, spread_max));
  33         fireBullet(actor, weaponentity, w_shotorg, w_shotdir, okmachinegun_spread, WEP_CVAR_PRI(okmachinegun, solidpenetration), WEP_CVAR_PRI(okmachinegun, damage), WEP_CVAR_PRI(okmachinegun, force), WEP_OVERKILL_MACHINEGUN.m_id, EFFECT_RIFLE);
  34
  35         actor.(weaponentity).misc_bulletcounter = actor.(weaponentity).misc_bulletcounter + 1;
  36
  37         Send_Effect(EFFECT_MACHINEGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
  38
  39         W_MachineGun_MuzzleFlash(actor, weaponentity);
  40         W_AttachToShotorg(actor, weaponentity, actor.(weaponentity).muzzle_flash, '5 0 0');
  41
  42         if(autocvar_g_casings >= 2) // casing code
  43         {
  44                 makevectors(actor.v_angle); // for some reason, this is lost
  45                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor, weaponentity);
  46         }
  47
  48         int slot = weaponslot(weaponentity);
  49         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR_PRI(okmachinegun, refire) * W_WeaponRateFactor(actor);
  50         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(okmachinegun, refire), W_OverkillMachineGun_Attack_Auto);
  51 }
  52
  53 METHOD(OverkillMachineGun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
  54 {
  55         if(vdist(actor.origin - actor.enemy.origin, <, 3000 - bound(0, skill, 10) * 200))
  56                 PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
  57         else
  58                 PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
  59 }
  60
  61 METHOD(OverkillMachineGun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
  62 {
  63         if ((WEP_CVAR_SEC(okmachinegun, refire_type) == 1) && (fire & 2) && (time >= actor.jump_interval))
  64         {
  65                 // Secondary uses it's own refire timer if refire_type is 1.
  66                 actor.jump_interval = time + WEP_CVAR_SEC(okmachinegun, refire) * W_WeaponRateFactor(actor);
  67                 BLASTER_SECONDARY_ATTACK(okmachinegun, actor, weaponentity);
  68                 if ((actor.(weaponentity).wframe == WFRAME_IDLE) ||
  69                         (actor.(weaponentity).wframe == WFRAME_FIRE2))
  70                 {
  71                         // Set secondary fire animation.
  72                         vector a = '0 0 0';
  73                         actor.(weaponentity).wframe = WFRAME_FIRE2;
  74                         a = actor.(weaponentity).anim_fire2;
  75                         a.z *= g_weaponratefactor;
  76                         FOREACH_CLIENT(true, LAMBDA(
  77                                 if (it == actor || (IS_SPEC(it) && it.enemy == actor))
  78                                 {
  79                                         wframe_send(it, actor.(weaponentity), a, true);
  80                                 }
  81                         ));
  82                         animdecide_setaction(actor, ANIMACTION_SHOOT, true);
  83                 }
  84         }
  85         if (WEP_CVAR(okmachinegun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(okmachinegun, ammo))
  86         {
  87                 // Forced reload
  88                 thiswep.wr_reload(thiswep, actor, weaponentity);
  89                 return;
  90         }
  91         if (fire & 1) // Primary attack
  92         {
  93                 if (!weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
  94                 {
  95                         return;
  96                 }
  97                 actor.(weaponentity).misc_bulletcounter = 0;
  98                 W_OverkillMachineGun_Attack_Auto(thiswep, actor, weaponentity, fire);
  99                 return;
 100         }
 101         if ((fire & 2) && (WEP_CVAR_SEC(okmachinegun, refire_type) == 0)) // Secondary attack
 102         {
 103                 if (!weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(okmachinegun, refire)))
 104                 {
 105                         return;
 106                 }
 107                 BLASTER_SECONDARY_ATTACK(okmachinegun, actor, weaponentity);
 108                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(okmachinegun, animtime), w_ready);
 109         }
 110 }
 111
 112 METHOD(OverkillMachineGun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 113 {
 114         float ammo_amount;
 115         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(okmachinegun, ammo);
 116         if (WEP_CVAR(okmachinegun, reload_ammo))
 117         {
 118                 ammo_amount += actor.(weaponentity).(weapon_load[WEP_OVERKILL_MACHINEGUN.m_id]) >= WEP_CVAR_PRI(okmachinegun, ammo);
 119         }
 120         return ammo_amount;
 121 }
 122
 123 METHOD(OverkillMachineGun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 124 {
 125         return true; // Blaster secondary is unlimited.
 126 }
 127
 128 METHOD(OverkillMachineGun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 129 {
 130         W_Reload(actor, weaponentity, WEP_CVAR_PRI(okmachinegun, ammo), SND_RELOAD);
 131 }
 132
 133 METHOD(OverkillMachineGun, wr_suicidemessage, Notification(entity thiswep))
 134 {
 135         return WEAPON_THINKING_WITH_PORTALS;
 136 }
 137
 138 METHOD(OverkillMachineGun, wr_killmessage, Notification(entity thiswep))
 139 {
 140         return WEAPON_OVERKILL_MACHINEGUN_MURDER;
 141 }
 142
 143 #endif
 144 #ifdef CSQC
 145
 146 METHOD(OverkillMachineGun, wr_impacteffect, void(entity thiswep, entity actor))
 147 {
 148         vector org2;
 149         org2 = w_org + w_backoff * 2;
 150         pointparticles(EFFECT_MACHINEGUN_IMPACT, org2, w_backoff * 1000, 1);
 151         if(!w_issilent)
 152                 sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
 153 }
 154
 155 #endif