qcsrc/common/mutators/mutator/overkill/okmachinegun.qc

   1 #include "okmachinegun.qh"
   2
   3 #ifdef SVQC
   4
   5 void W_OverkillMachineGun_Attack_Auto(Weapon thiswep, entity actor, .entity weaponentity, int fire)
   6 {
   7         float okmachinegun_spread;
   8
   9         if(!(fire & 1))
  10         {
  11                 w_ready(thiswep, actor, weaponentity, fire);
  12                 return;
  13         }
  14
  15         if(!thiswep.wr_checkammo1(thiswep, actor, weaponentity))
  16         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
  17         {
  18                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
  19                 w_ready(thiswep, actor, weaponentity, fire);
  20                 return;
  21         }
  22
  23         W_DecreaseAmmo(WEP_OVERKILL_MACHINEGUN, actor, WEP_CVAR_PRI(okmachinegun, ammo), weaponentity);
  24
  25         W_SetupShot(actor, weaponentity, true, 0, SND_UZI_FIRE, CH_WEAPON_A, WEP_CVAR_PRI(okmachinegun, damage), WEP_OVERKILL_MACHINEGUN.m_id);
  26         if(!autocvar_g_norecoil)
  27         {
  28                 actor.punchangle_x = random() - 0.5;
  29                 actor.punchangle_y = random() - 0.5;
  30         }
  31
  32         okmachinegun_spread = bound(WEP_CVAR_PRI(okmachinegun, spread_min), WEP_CVAR_PRI(okmachinegun, spread_min) + (WEP_CVAR_PRI(okmachinegun, spread_add) * actor.(weaponentity).misc_bulletcounter), WEP_CVAR_PRI(okmachinegun, spread_max));
  33         fireBullet(actor, weaponentity, w_shotorg, w_shotdir, okmachinegun_spread, WEP_CVAR_PRI(okmachinegun, solidpenetration), WEP_CVAR_PRI(okmachinegun, damage), WEP_CVAR_PRI(okmachinegun, force), WEP_OVERKILL_MACHINEGUN.m_id, 0);
  34
  35         actor.(weaponentity).misc_bulletcounter = actor.(weaponentity).misc_bulletcounter + 1;
  36
  37         Send_Effect(EFFECT_MACHINEGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
  38
  39         W_MachineGun_MuzzleFlash(actor, weaponentity);
  40         W_AttachToShotorg(actor, weaponentity, actor.(weaponentity).muzzle_flash, '5 0 0');
  41
  42         if(autocvar_g_casings >= 2) // casing code
  43         {
  44                 makevectors(actor.v_angle); // for some reason, this is lost
  45                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor, weaponentity);
  46         }
  47
  48         int slot = weaponslot(weaponentity);
  49         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR_PRI(okmachinegun, refire) * W_WeaponRateFactor(actor);
  50         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(okmachinegun, refire), W_OverkillMachineGun_Attack_Auto);
  51 }
  52
  53 METHOD(OverkillMachineGun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
  54 {
  55         if(vdist(actor.origin - actor.enemy.origin, <, 3000 - bound(0, skill, 10) * 200))
  56                 PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
  57         else
  58                 PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
  59 }
  60
  61 METHOD(OverkillMachineGun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
  62 {
  63         if ((WEP_CVAR_SEC(okmachinegun, refire_type) == 1) && (fire & 2) && (time >= actor.jump_interval))
  64         {
  65                 // Secondary uses it's own refire timer if refire_type is 1.
  66                 actor.jump_interval = time + WEP_CVAR_SEC(okmachinegun, refire) * W_WeaponRateFactor(actor);
  67                 // Ugly hack to reuse the fire mode of the blaster.
  68                 makevectors(actor.v_angle);
  69                 W_Blaster_Attack(
  70                         actor,
  71                         weaponentity,
  72                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
  73                         WEP_CVAR_SEC(okmachinegun, shotangle),
  74                         WEP_CVAR_SEC(okmachinegun, damage),
  75                         WEP_CVAR_SEC(okmachinegun, edgedamage),
  76                         WEP_CVAR_SEC(okmachinegun, radius),
  77                         WEP_CVAR_SEC(okmachinegun, force),
  78                         WEP_CVAR_SEC(okmachinegun, speed),
  79                         WEP_CVAR_SEC(okmachinegun, spread),
  80                         WEP_CVAR_SEC(okmachinegun, delay),
  81                         WEP_CVAR_SEC(okmachinegun, lifetime)
  82                 );
  83                 if ((actor.(weaponentity).wframe == WFRAME_IDLE) ||
  84                         (actor.(weaponentity).wframe == WFRAME_FIRE2))
  85                 {
  86                         // Set secondary fire animation.
  87                         vector a = '0 0 0';
  88                         actor.(weaponentity).wframe = WFRAME_FIRE2;
  89                         a = actor.(weaponentity).anim_fire2;
  90                         a.z *= g_weaponratefactor;
  91                         FOREACH_CLIENT(true, LAMBDA(
  92                                 if (it == actor || (IS_SPEC(it) && it.enemy == actor))
  93                                 {
  94                                         wframe_send(it, actor.(weaponentity), a, true);
  95                                 }
  96                         ));
  97                         animdecide_setaction(actor, ANIMACTION_SHOOT, true);
  98                 }
  99         }
 100         if (WEP_CVAR(okmachinegun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(okmachinegun, ammo))
 101         {
 102                 // Forced reload
 103                 thiswep.wr_reload(thiswep, actor, weaponentity);
 104                 return;
 105         }
 106         if (fire & 1) // Primary attack
 107         {
 108                 if (!weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
 109                 {
 110                         return;
 111                 }
 112                 actor.(weaponentity).misc_bulletcounter = 0;
 113                 W_OverkillMachineGun_Attack_Auto(thiswep, actor, weaponentity, fire);
 114                 return;
 115         }
 116         if ((fire & 2) && (WEP_CVAR_SEC(okmachinegun, refire_type) == 0)) // Secondary attack
 117         {
 118                 if (!weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(okmachinegun, refire)))
 119                 {
 120                         return;
 121                 }
 122                 // Ugly hack to reuse the fire mode of the blaster.
 123                 makevectors(actor.v_angle);
 124                 W_Blaster_Attack(
 125                         actor,
 126                         weaponentity,
 127                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 128                         WEP_CVAR_SEC(okmachinegun, shotangle),
 129                         WEP_CVAR_SEC(okmachinegun, damage),
 130                         WEP_CVAR_SEC(okmachinegun, edgedamage),
 131                         WEP_CVAR_SEC(okmachinegun, radius),
 132                         WEP_CVAR_SEC(okmachinegun, force),
 133                         WEP_CVAR_SEC(okmachinegun, speed),
 134                         WEP_CVAR_SEC(okmachinegun, spread),
 135                         WEP_CVAR_SEC(okmachinegun, delay),
 136                         WEP_CVAR_SEC(okmachinegun, lifetime)
 137                 );
 138                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(okmachinegun, animtime), w_ready);
 139         }
 140 }
 141
 142 METHOD(OverkillMachineGun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 143 {
 144         float ammo_amount;
 145         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(okmachinegun, ammo);
 146         if (WEP_CVAR(okmachinegun, reload_ammo))
 147         {
 148                 ammo_amount += actor.(weaponentity).(weapon_load[WEP_OVERKILL_MACHINEGUN.m_id]) >= WEP_CVAR_PRI(okmachinegun, ammo);
 149         }
 150         return ammo_amount;
 151 }
 152
 153 METHOD(OverkillMachineGun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 154 {
 155         return true; // Blaster secondary is unlimited.
 156 }
 157
 158 METHOD(OverkillMachineGun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 159 {
 160         W_Reload(actor, weaponentity, WEP_CVAR_PRI(okmachinegun, ammo), SND_RELOAD);
 161 }
 162
 163 METHOD(OverkillMachineGun, wr_suicidemessage, Notification(entity thiswep))
 164 {
 165         return WEAPON_THINKING_WITH_PORTALS;
 166 }
 167
 168 METHOD(OverkillMachineGun, wr_killmessage, Notification(entity thiswep))
 169 {
 170         return WEAPON_OVERKILL_MACHINEGUN_MURDER;
 171 }
 172
 173 #endif
 174 #ifdef CSQC
 175
 176 METHOD(OverkillMachineGun, wr_impacteffect, void(entity thiswep, entity actor))
 177 {
 178         vector org2;
 179         org2 = w_org + w_backoff * 2;
 180         pointparticles(EFFECT_MACHINEGUN_IMPACT, org2, w_backoff * 1000, 1);
 181         if(!w_issilent)
 182                 sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
 183 }
 184
 185 #endif
 186