qcsrc/common/mutators/mutator/overkill/okshotgun.qc

   1 #include "okshotgun.qh"
   2
   3 #ifdef SVQC
   4 METHOD(OverkillShotgun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
   5 {
   6         if (vdist(actor.origin - actor.enemy.origin, >, WEP_CVAR_PRI(okshotgun, bot_range)))
   7         {
   8                 PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
   9         }
  10         else
  11         {
  12                 PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
  13         }
  14 }
  15
  16 METHOD(OverkillShotgun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
  17 {
  18         if ((WEP_CVAR_SEC(okshotgun, refire_type) == 1) && (fire & 2) && (time >= actor.jump_interval))
  19         {
  20                 // Secondary uses it's own refire timer if refire_type is 1.
  21                 actor.jump_interval = time + WEP_CVAR_SEC(okshotgun, refire) * W_WeaponRateFactor(actor);
  22                 BLASTER_SECONDARY_ATTACK(okshotgun, actor, weaponentity);
  23                 if ((actor.(weaponentity).wframe == WFRAME_IDLE) ||
  24                         (actor.(weaponentity).wframe == WFRAME_FIRE2))
  25                 {
  26                         // Set secondary fire animation.
  27                         vector a = '0 0 0';
  28                         actor.(weaponentity).wframe = WFRAME_FIRE2;
  29                         a = actor.(weaponentity).anim_fire2;
  30                         a.z *= g_weaponratefactor;
  31                         FOREACH_CLIENT(true, LAMBDA(
  32                                 if (it == actor || (IS_SPEC(it) && it.enemy == actor))
  33                                 {
  34                                         wframe_send(it, actor.(weaponentity), a, true);
  35                                 }
  36                         ));
  37                         animdecide_setaction(actor, ANIMACTION_SHOOT, true);
  38                 }
  39         }
  40         if (WEP_CVAR(okshotgun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(okshotgun, ammo))
  41         {
  42                 // Forced reload
  43                 thiswep.wr_reload(thiswep, actor, weaponentity);
  44                 return;
  45         }
  46         if (fire & 1) // Primary attack
  47         {
  48                 if (!weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(okshotgun, refire)))
  49                 {
  50                         return;
  51                 }
  52                 W_Shotgun_Attack(thiswep, actor, weaponentity, true,
  53                         WEP_CVAR_PRI(okshotgun, ammo),
  54                         WEP_CVAR_PRI(okshotgun, damage),
  55                         WEP_CVAR_PRI(okshotgun, bullets),
  56                         WEP_CVAR_PRI(okshotgun, spread),
  57                         WEP_CVAR_PRI(okshotgun, solidpenetration),
  58                         WEP_CVAR_PRI(okshotgun, force));
  59                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(okshotgun, animtime), w_ready);
  60                 return;
  61         }
  62         if ((fire & 2) && (WEP_CVAR_SEC(okshotgun, refire_type) == 0)) // Secondary attack
  63         {
  64                 if (!weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(okshotgun, refire)))
  65                 {
  66                         return;
  67                 }
  68                 BLASTER_SECONDARY_ATTACK(okshotgun, actor, weaponentity);
  69                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(okshotgun, animtime), w_ready);
  70         }
  71 }
  72
  73 METHOD(OverkillShotgun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
  74 {
  75         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(okshotgun, ammo);
  76         ammo_amount += actor.(weaponentity).(weapon_load[WEP_OVERKILL_SHOTGUN.m_id]) >= WEP_CVAR_PRI(okshotgun, ammo);
  77         return ammo_amount;
  78 }
  79
  80 METHOD(OverkillShotgun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
  81 {
  82         return true; // Blaster secondary is unlimited.
  83 }
  84
  85 METHOD(OverkillShotgun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
  86 {
  87         W_Reload(actor, weaponentity, WEP_CVAR_PRI(okshotgun, ammo), SND_RELOAD); // WEAPONTODO
  88 }
  89
  90 METHOD(OverkillShotgun, wr_suicidemessage, Notification(entity thiswep))
  91 {
  92         return WEAPON_THINKING_WITH_PORTALS;
  93 }
  94
  95 METHOD(OverkillShotgun, wr_killmessage, Notification(entity thiswep))
  96 {
  97         return WEAPON_OVERKILL_SHOTGUN_MURDER;
  98 }
  99
 100 #endif
 101 #ifdef CSQC
 102 .float prevric;
 103
 104 METHOD(OverkillShotgun, wr_impacteffect, void(entity thiswep, entity actor))
 105 {
 106         vector org2 = w_org + w_backoff * 2;
 107         pointparticles(EFFECT_SHOTGUN_IMPACT, org2, w_backoff * 1000, 1);
 108         if(!w_issilent && time - actor.prevric > 0.25)
 109         {
 110                 if(w_random < 0.05)
 111                         sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 112                 actor.prevric = time;
 113         }
 114 }
 115
 116 #endif