qcsrc/common/mutators/mutator/overkill/overkill.qc

   1 #ifdef IMPLEMENTATION
   2 bool autocvar_g_overkill_powerups_replace;
   3 float autocvar_g_overkill_superguns_respawn_time;
   4 bool autocvar_g_overkill_100h_anyway;
   5 bool autocvar_g_overkill_100a_anyway;
   6 bool autocvar_g_overkill_ammo_charge;
   7 float autocvar_g_overkill_ammo_charge_notice;
   8 float autocvar_g_overkill_ammo_charge_limit;
   9
  10 .vector ok_deathloc;
  11 .float ok_spawnsys_timer;
  12 .float ok_lastwep;
  13 .float ok_item;
  14
  15 .float ok_notice_time;
  16 .float ammo_charge[Weapons_MAX];
  17 .float ok_use_ammocharge = _STAT(OK_AMMO_CHARGE);
  18 .float ok_ammo_charge = _STAT(OK_AMMO_CHARGEPOOL);
  19
  20 .float ok_pauseregen_finished;
  21
  22 void(entity ent, float wep) ok_DecreaseCharge;
  23
  24 void ok_Initialize();
  25
  26 REGISTER_MUTATOR(ok, cvar("g_overkill") && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  27 {
  28         MUTATOR_ONADD
  29         {
  30                 ok_Initialize();
  31         }
  32
  33         MUTATOR_ONREMOVE
  34         {
  35                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  36                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  37         }
  38 }
  39
  40 MUTATOR_HOOKFUNCTION(ok, W_DecreaseAmmo)
  41 {
  42         entity actor = M_ARGV(0, entity);
  43         if (actor.ok_use_ammocharge)
  44         {
  45                 ok_DecreaseCharge(actor, PS(actor).m_weapon.m_id);
  46                 return true;
  47         }
  48 }
  49
  50 MUTATOR_HOOKFUNCTION(ok, W_Reload)
  51 {
  52         entity actor = M_ARGV(0, entity);
  53         return actor.ok_use_ammocharge;
  54 }
  55
  56 void W_Blaster_Attack(entity, float, float, float, float, float, float, float, float, float, float);
  57 spawnfunc(weapon_hmg);
  58 spawnfunc(weapon_rpc);
  59
  60 void ok_DecreaseCharge(entity ent, int wep)
  61 {
  62         if(!ent.ok_use_ammocharge) return;
  63
  64         entity wepent = Weapons_from(wep);
  65
  66         if (wepent == WEP_Null) return;  // dummy
  67
  68         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  69 }
  70
  71 void ok_IncreaseCharge(entity ent, int wep)
  72 {
  73         entity wepent = Weapons_from(wep);
  74
  75         if (wepent == WEP_Null) return;  // dummy
  76
  77         if(ent.ok_use_ammocharge)
  78         if(!PHYS_INPUT_BUTTON_ATCK(ent)) // not while attacking?
  79                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  80 }
  81
  82 float ok_CheckWeaponCharge(entity ent, int wep)
  83 {
  84         if(!ent.ok_use_ammocharge) return true;
  85
  86         entity wepent = Weapons_from(wep);
  87
  88         if(wepent == WEP_Null) return false;  // dummy
  89
  90         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  91 }
  92
  93 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_Calculate, CBC_ORDER_LAST)
  94 {
  95         entity frag_attacker = M_ARGV(1, entity);
  96         entity frag_target = M_ARGV(2, entity);
  97         float frag_deathtype = M_ARGV(3, float);
  98
  99         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
 100         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
 101         {
 102                 if(frag_attacker != frag_target)
 103                 if(frag_target.health > 0)
 104                 if(STAT(FROZEN, frag_target) == 0)
 105                 if(!IS_DEAD(frag_target))
 106                 {
 107                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
 108                         M_ARGV(6, vector) = '0 0 0';
 109                 }
 110
 111                 M_ARGV(4, float) = 0;
 112         }
 113 }
 114
 115 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_SplitHealthArmor)
 116 {
 117         entity frag_target = M_ARGV(2, entity);
 118         float damage_take = M_ARGV(4, float);
 119
 120         if(damage_take)
 121                 frag_target.ok_pauseregen_finished = max(frag_target.ok_pauseregen_finished, time + 2);
 122 }
 123
 124 void ok_DropItem(entity this, entity targ)
 125 {
 126         entity e = new(droppedweapon); // hax
 127         e.ok_item = true;
 128         e.noalign = true;
 129         e.pickup_anyway = true;
 130         e.spawnfunc_checked = true;
 131         spawnfunc_item_armor_small(e);
 132         if (!wasfreed(e)) { // might have been blocked by a mutator
 133         set_movetype(e, MOVETYPE_TOSS);
 134         e.gravity = 1;
 135         e.reset = SUB_Remove;
 136         setorigin(e, this.origin + '0 0 32');
 137         e.velocity = '0 0 200' + normalize(targ.origin - this.origin) * 500;
 138         SUB_SetFade(e, time + 5, 1);
 139         }
 140 }
 141
 142 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
 143 {
 144         entity frag_attacker = M_ARGV(1, entity);
 145         entity frag_target = M_ARGV(2, entity);
 146
 147         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 148
 149         ok_DropItem(frag_target, targ);
 150
 151         frag_target.ok_lastwep = PS(frag_target).m_switchweapon.m_id;
 152 }
 153
 154 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
 155 {
 156         entity mon = M_ARGV(0, entity);
 157         entity olditem = M_ARGV(1, entity);
 158         entity frag_attacker = M_ARGV(2, entity);
 159
 160         delete(olditem);
 161
 162         M_ARGV(1, entity) = NULL;
 163
 164         ok_DropItem(mon, frag_attacker);
 165 }
 166
 167 MUTATOR_HOOKFUNCTION(ok, PlayerRegen)
 168 {
 169         entity player = M_ARGV(0, entity);
 170
 171         // overkill's values are different, so use custom regen
 172         if(!STAT(FROZEN, player))
 173         {
 174                 player.armorvalue = CalcRotRegen(player.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
 175                         1 * frametime * (time > player.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > player.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 176                 player.health = CalcRotRegen(player.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > player.ok_pauseregen_finished), 200, 0,
 177                         autocvar_g_balance_health_rotlinear, 1 * frametime * (time > player.pauserothealth_finished), autocvar_g_balance_health_limit);
 178
 179                 float minf, maxf, limitf;
 180
 181                 maxf = autocvar_g_balance_fuel_rotstable;
 182                 minf = autocvar_g_balance_fuel_regenstable;
 183                 limitf = autocvar_g_balance_fuel_limit;
 184
 185                 player.ammo_fuel = CalcRotRegen(player.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
 186                         frametime * (time > player.pauseregen_finished) * ((player.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > player.pauserotfuel_finished), limitf);
 187         }
 188         return true; // return true anyway, as frozen uses no regen
 189 }
 190
 191 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 192 {
 193         return true;
 194 }
 195
 196 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 197 {
 198         if(intermission_running || gameover)
 199                 return;
 200
 201         entity player = M_ARGV(0, entity);
 202
 203         if(IS_DEAD(player) || !IS_PLAYER(player) || STAT(FROZEN, player))
 204                 return;
 205
 206         if(player.ok_lastwep)
 207         {
 208                 Weapon newwep = Weapons_from(player.ok_lastwep);
 209                 if(player.ok_lastwep == WEP_HMG.m_id)
 210                         newwep = WEP_MACHINEGUN;
 211                 if(player.ok_lastwep == WEP_RPC.m_id)
 212                         newwep = WEP_VORTEX;
 213                 PS(player).m_switchweapon = newwep;
 214                 player.ok_lastwep = 0;
 215         }
 216
 217         ok_IncreaseCharge(player, PS(player).m_weapon.m_id);
 218
 219         if(PHYS_INPUT_BUTTON_ATCK2(player))
 220         if(!forbidWeaponUse(player) || player.weapon_blocked) // allow if weapon is blocked
 221         if(time >= player.jump_interval)
 222         {
 223                 player.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor(player);
 224                 makevectors(player.v_angle);
 225
 226                 Weapon oldwep = PS(player).m_weapon;
 227                 PS(player).m_weapon = WEP_BLASTER;
 228                 W_Blaster_Attack(
 229                         player,
 230                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 231                         WEP_CVAR_SEC(vaporizer, shotangle),
 232                         WEP_CVAR_SEC(vaporizer, damage),
 233                         WEP_CVAR_SEC(vaporizer, edgedamage),
 234                         WEP_CVAR_SEC(vaporizer, radius),
 235                         WEP_CVAR_SEC(vaporizer, force),
 236                         WEP_CVAR_SEC(vaporizer, speed),
 237                         WEP_CVAR_SEC(vaporizer, spread),
 238                         WEP_CVAR_SEC(vaporizer, delay),
 239                         WEP_CVAR_SEC(vaporizer, lifetime)
 240                 );
 241                 PS(player).m_weapon = oldwep;
 242         }
 243
 244         player.weapon_blocked = false;
 245
 246         player.ok_ammo_charge = player.ammo_charge[PS(player).m_weapon.m_id];
 247
 248         if(player.ok_use_ammocharge)
 249         if(!ok_CheckWeaponCharge(player, PS(player).m_weapon.m_id))
 250         {
 251                 if(autocvar_g_overkill_ammo_charge_notice && time > player.ok_notice_time && PHYS_INPUT_BUTTON_ATCK(player) && IS_REAL_CLIENT(player) && PS(player).m_weapon == PS(player).m_switchweapon)
 252                 {
 253                         //Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 254                         player.ok_notice_time = time + 2;
 255                         play2(player, SND(DRYFIRE));
 256                 }
 257                 Weapon wpn = PS(player).m_weapon;
 258                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 259                 if(player.(weaponentity).state != WS_CLEAR)
 260                         w_ready(wpn, player, weaponentity, PHYS_INPUT_BUTTON_ATCK(player) | (PHYS_INPUT_BUTTON_ATCK2(player) << 1));
 261
 262                 player.weapon_blocked = true;
 263         }
 264
 265         PHYS_INPUT_BUTTON_ATCK2(player) = false;
 266 }
 267
 268 MUTATOR_HOOKFUNCTION(ok, PlayerSpawn)
 269 {
 270         entity player = M_ARGV(0, entity);
 271
 272         if(autocvar_g_overkill_ammo_charge)
 273         {
 274                 FOREACH(Weapons, it != WEP_Null, LAMBDA(player.ammo_charge[it.m_id] = autocvar_g_overkill_ammo_charge_limit));
 275
 276                 player.ok_use_ammocharge = 1;
 277                 player.ok_notice_time = time;
 278         }
 279         else
 280                 player.ok_use_ammocharge = 0;
 281
 282         // if player changed their weapon while dead, don't switch to their death weapon
 283         if(player.impulse)
 284                 player.ok_lastwep = 0;
 285
 286         player.ok_pauseregen_finished = time + 2;
 287 }
 288
 289 void self_spawnfunc_weapon_hmg(entity this) { spawnfunc_weapon_hmg(this); }
 290 void self_spawnfunc_weapon_rpc(entity this) { spawnfunc_weapon_rpc(this); }
 291
 292 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 293 {
 294         entity ent = M_ARGV(0, entity);
 295
 296         if(autocvar_g_powerups)
 297         if(autocvar_g_overkill_powerups_replace)
 298         {
 299                 if(ent.classname == "item_strength")
 300                 {
 301                         entity wep = new(weapon_hmg);
 302                         setorigin(wep, ent.origin);
 303                         setmodel(wep, MDL_OK_HMG);
 304                         wep.ok_item = true;
 305                         wep.noalign = ent.noalign;
 306                         wep.cnt = ent.cnt;
 307                         wep.team = ent.team;
 308                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 309                         wep.pickup_anyway = true;
 310                         wep.spawnfunc_checked = true;
 311                         setthink(wep, self_spawnfunc_weapon_hmg);
 312                         wep.nextthink = time + 0.1;
 313                         return true;
 314                 }
 315
 316                 if(ent.classname == "item_invincible")
 317                 {
 318                         entity wep = new(weapon_rpc);
 319                         setorigin(wep, ent.origin);
 320                         setmodel(wep, MDL_OK_RPC);
 321                         wep.ok_item = true;
 322                         wep.noalign = ent.noalign;
 323                         wep.cnt = ent.cnt;
 324                         wep.team = ent.team;
 325                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 326                         wep.pickup_anyway = true;
 327                         wep.spawnfunc_checked = true;
 328                         setthink(wep, self_spawnfunc_weapon_rpc);
 329                         wep.nextthink = time + 0.1;
 330                         return true;
 331                 }
 332         }
 333 }
 334
 335 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 336 {
 337         entity item = M_ARGV(0, entity);
 338
 339         if(item.ok_item)
 340                 return;
 341
 342         switch(item.items)
 343         {
 344                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 345                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 346         }
 347
 348         return true;
 349 }
 350
 351 MUTATOR_HOOKFUNCTION(ok, SpectateCopy)
 352 {
 353         entity spectatee = M_ARGV(0, entity);
 354         entity client = M_ARGV(1, entity);
 355
 356         client.ammo_charge[PS(client).m_weapon.m_id] = spectatee.ammo_charge[PS(spectatee).m_weapon.m_id];
 357         client.ok_use_ammocharge = spectatee.ok_use_ammocharge;
 358 }
 359
 360 MUTATOR_HOOKFUNCTION(ok, SetStartItems)
 361 {
 362         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 363
 364         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 365         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 366
 367         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 368         start_weapons = warmup_start_weapons = ok_start_items;
 369 }
 370
 371 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 372 {
 373         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
 374 }
 375
 376 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 377 {
 378         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
 379 }
 380
 381 MUTATOR_HOOKFUNCTION(ok, SetModname)
 382 {
 383         M_ARGV(0, string) = "Overkill";
 384         return true;
 385 }
 386
 387 void ok_SetCvars()
 388 {
 389         // hack to force overkill playermodels
 390         cvar_settemp("sv_defaultcharacter", "1");
 391         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 392         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 393         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 394 }
 395
 396 void ok_Initialize()
 397 {
 398         ok_SetCvars();
 399
 400         precache_all_playermodels("models/ok_player/*.dpm");
 401
 402         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 403         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 404
 405         WEP_SHOTGUN.mdl = "ok_shotgun";
 406         WEP_MACHINEGUN.mdl = "ok_mg";
 407         WEP_VORTEX.mdl = "ok_sniper";
 408 }
 409 #endif