qcsrc/common/mutators/mutator/overkill/rpc.qc

   1 #include "rpc.qh"
   2
   3 #ifdef SVQC
   4 spawnfunc(weapon_rpc) { weapon_defaultspawnfunc(this, WEP_RPC); }
   5
   6 void W_RocketPropelledChainsaw_Explode(entity this, entity directhitentity)
   7 {
   8         this.event_damage = func_null;
   9         this.takedamage = DAMAGE_NO;
  10
  11         RadiusDamage (this, this.realowner, WEP_CVAR(rpc, damage), WEP_CVAR(rpc, edgedamage), WEP_CVAR(rpc, radius), NULL, NULL, WEP_CVAR(rpc, force), this.projectiledeathtype, directhitentity);
  12
  13         delete (this);
  14 }
  15
  16 void W_RocketPropelledChainsaw_Explode_think(entity this)
  17 {
  18         W_RocketPropelledChainsaw_Explode(this, NULL);
  19 }
  20
  21 void W_RocketPropelledChainsaw_Touch (entity this, entity toucher)
  22 {
  23         if(WarpZone_Projectile_Touch(this, toucher))
  24                 if(wasfreed(this))
  25                         return;
  26
  27         W_RocketPropelledChainsaw_Explode(this, toucher);
  28 }
  29
  30 void W_RocketPropelledChainsaw_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
  31 {
  32         if (this.health <= 0)
  33                 return;
  34
  35         if (!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
  36                 return; // g_projectiles_damage says to halt
  37
  38         this.health = this.health - damage;
  39
  40         if (this.health <= 0)
  41                 W_PrepareExplosionByDamage(this, attacker, W_RocketPropelledChainsaw_Explode_think);
  42 }
  43
  44 void W_RocketPropelledChainsaw_Think(entity this)
  45 {
  46         if(this.cnt <= time)
  47         {
  48                 delete(this);
  49                 return;
  50         }
  51
  52         this.cnt = vlen(this.velocity);
  53         this.wait = this.cnt * sys_frametime;
  54         this.pos1 = normalize(this.velocity);
  55
  56         tracebox(this.origin, this.mins, this.maxs, this.origin + this.pos1 * (2 * this.wait), MOVE_NORMAL, this);
  57         if(IS_PLAYER(trace_ent))
  58                 Damage (trace_ent, this, this.realowner, WEP_CVAR(rpc, damage2), this.projectiledeathtype, this.origin, normalize(this.origin - other.origin) * WEP_CVAR(rpc, force));
  59
  60         this.velocity = this.pos1 * (this.cnt + (WEP_CVAR(rpc, speedaccel) * sys_frametime));
  61
  62         UpdateCSQCProjectile(this);
  63         this.nextthink = time;
  64 }
  65
  66 void W_RocketPropelledChainsaw_Attack (Weapon thiswep, entity actor, .entity weaponentity)
  67 {
  68         entity missile = spawn(); //WarpZone_RefSys_SpawnSameRefSys(actor);
  69         entity flash = spawn ();
  70
  71         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(rpc, ammo), weaponentity);
  72         W_SetupShot_ProjectileSize (actor, weaponentity, '-3 -3 -3', '3 3 3', false, 5, SND_ROCKET_FIRE, CH_WEAPON_A, WEP_CVAR(rpc, damage));
  73         Send_Effect(EFFECT_ROCKET_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
  74         PROJECTILE_MAKETRIGGER(missile);
  75
  76         missile.owner = missile.realowner = actor;
  77         missile.bot_dodge = true;
  78         missile.bot_dodgerating = WEP_CVAR(rpc, damage) * 2;
  79
  80         missile.takedamage = DAMAGE_YES;
  81         missile.damageforcescale = WEP_CVAR(rpc, damageforcescale);
  82         missile.health = WEP_CVAR(rpc, health);
  83         missile.event_damage = W_RocketPropelledChainsaw_Damage;
  84         missile.damagedbycontents = true;
  85         IL_PUSH(g_damagedbycontents, missile);
  86         set_movetype(missile, MOVETYPE_FLY);
  87
  88         missile.projectiledeathtype = WEP_RPC.m_id;
  89         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
  90
  91         setorigin(missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
  92         W_SetupProjVelocity_Basic(missile, WEP_CVAR(rpc, speed), 0);
  93
  94         settouch(missile, W_RocketPropelledChainsaw_Touch);
  95
  96         setthink(missile, W_RocketPropelledChainsaw_Think);
  97         missile.cnt = time + WEP_CVAR(rpc, lifetime);
  98         missile.nextthink = time;
  99         missile.flags = FL_PROJECTILE;
 100         IL_PUSH(g_projectiles, missile);
 101         IL_PUSH(g_bot_dodge, missile);
 102
 103         CSQCProjectile(missile, true, PROJECTILE_RPC, false);
 104
 105         setmodel(flash, MDL_RPC_MUZZLEFLASH); // precision set below
 106         SUB_SetFade (flash, time, 0.1);
 107         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 108         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
 109         missile.pos1 = missile.velocity;
 110
 111         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 112 }
 113
 114 METHOD(RocketPropelledChainsaw, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 115 {
 116     PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, WEP_CVAR(rpc, speed), 0, WEP_CVAR(rpc, lifetime), false);
 117 }
 118
 119 METHOD(RocketPropelledChainsaw, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 120 {
 121     if(WEP_CVAR(rpc, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR(rpc, ammo)) {
 122         thiswep.wr_reload(thiswep, actor, weaponentity);
 123     } else
 124     {
 125         if (fire & 1)
 126         {
 127             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(rpc, refire)))
 128             {
 129                 W_RocketPropelledChainsaw_Attack(thiswep, actor, weaponentity);
 130                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(rpc, animtime), w_ready);
 131             }
 132         }
 133
 134         if (fire & 2)
 135         {
 136             // to-do
 137         }
 138     }
 139 }
 140
 141 METHOD(RocketPropelledChainsaw, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 142 {
 143     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(rpc, ammo);
 144     ammo_amount += actor.(weaponentity).(weapon_load[WEP_RPC.m_id]) >= WEP_CVAR(rpc, ammo);
 145     return ammo_amount;
 146 }
 147
 148 METHOD(RocketPropelledChainsaw, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 149 {
 150     return false;
 151 }
 152
 153 METHOD(RocketPropelledChainsaw, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 154 {
 155     W_Reload(actor, weaponentity, WEP_CVAR(rpc, ammo), SND_RELOAD);
 156 }
 157
 158 METHOD(RocketPropelledChainsaw, wr_suicidemessage, Notification(entity thiswep))
 159 {
 160     if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 161         return WEAPON_RPC_SUICIDE_SPLASH;
 162     else
 163         return WEAPON_RPC_SUICIDE_DIRECT;
 164 }
 165
 166 METHOD(RocketPropelledChainsaw, wr_killmessage, Notification(entity thiswep))
 167 {
 168     if(w_deathtype & HITTYPE_SECONDARY)
 169         return WEAPON_BLASTER_MURDER;
 170     else if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 171         return WEAPON_RPC_MURDER_SPLASH;
 172     else
 173         return WEAPON_RPC_MURDER_DIRECT;
 174 }
 175
 176 #endif
 177
 178 #ifdef CSQC
 179
 180 METHOD(RocketPropelledChainsaw, wr_impacteffect, void(entity thiswep, entity actor))
 181 {
 182     vector org2;
 183     org2 = w_org + w_backoff * 12;
 184     pointparticles(EFFECT_ROCKET_EXPLODE, org2, '0 0 0', 1);
 185     if(!w_issilent)
 186         sound(actor, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 187 }
 188
 189 #endif