qcsrc/common/mutators/mutator/overkill/sv_overkill.qc

   1 #include "sv_overkill.qh"
   2
   3 #include "hmg.qh"
   4 #include "rpc.qh"
   5
   6 bool autocvar_g_overkill_powerups_replace;
   7 float autocvar_g_overkill_superguns_respawn_time;
   8 bool autocvar_g_overkill_100h_anyway;
   9 bool autocvar_g_overkill_100a_anyway;
  10 bool autocvar_g_overkill_ammo_charge;
  11 float autocvar_g_overkill_ammo_charge_notice;
  12 float autocvar_g_overkill_ammo_charge_limit;
  13
  14 .vector ok_deathloc;
  15 .float ok_spawnsys_timer;
  16 .float ok_lastwep;
  17 .float ok_item;
  18
  19 .float ok_notice_time;
  20 .float ammo_charge[Weapons_MAX];
  21 .float ok_use_ammocharge = _STAT(OK_AMMO_CHARGE);
  22 .float ok_ammo_charge = _STAT(OK_AMMO_CHARGEPOOL);
  23
  24 .float ok_pauseregen_finished;
  25
  26 void(entity ent, float wep) ok_DecreaseCharge;
  27
  28 void ok_Initialize();
  29
  30 REGISTER_MUTATOR(ok, cvar("g_overkill") && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  31 {
  32         MUTATOR_ONADD
  33         {
  34                 ok_Initialize();
  35         }
  36
  37         MUTATOR_ONREMOVE
  38         {
  39                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  40                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  41         }
  42 }
  43
  44 MUTATOR_HOOKFUNCTION(ok, W_DecreaseAmmo)
  45 {
  46         entity actor = M_ARGV(0, entity);
  47         if (actor.ok_use_ammocharge)
  48         {
  49                 ok_DecreaseCharge(actor, PS(actor).m_weapon.m_id);
  50                 return true;
  51         }
  52 }
  53
  54 MUTATOR_HOOKFUNCTION(ok, W_Reload)
  55 {
  56         entity actor = M_ARGV(0, entity);
  57         return actor.ok_use_ammocharge;
  58 }
  59
  60 void W_Blaster_Attack(entity, .entity, float, float, float, float, float, float, float, float, float, float);
  61 spawnfunc(weapon_hmg);
  62 spawnfunc(weapon_rpc);
  63
  64 void ok_DecreaseCharge(entity ent, int wep)
  65 {
  66         if(!ent.ok_use_ammocharge) return;
  67
  68         entity wepent = Weapons_from(wep);
  69
  70         if (wepent == WEP_Null) return;  // dummy
  71
  72         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  73 }
  74
  75 void ok_IncreaseCharge(entity ent, int wep)
  76 {
  77         entity wepent = Weapons_from(wep);
  78
  79         if (wepent == WEP_Null) return;  // dummy
  80
  81         if(ent.ok_use_ammocharge)
  82         if(!PHYS_INPUT_BUTTON_ATCK(ent)) // not while attacking?
  83                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  84 }
  85
  86 float ok_CheckWeaponCharge(entity ent, int wep)
  87 {
  88         if(!ent.ok_use_ammocharge) return true;
  89
  90         entity wepent = Weapons_from(wep);
  91
  92         if(wepent == WEP_Null) return false;  // dummy
  93
  94         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  95 }
  96
  97 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_Calculate, CBC_ORDER_LAST)
  98 {
  99         entity frag_attacker = M_ARGV(1, entity);
 100         entity frag_target = M_ARGV(2, entity);
 101         float frag_deathtype = M_ARGV(3, float);
 102
 103         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
 104         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
 105         {
 106                 if(frag_attacker != frag_target)
 107                 if(frag_target.health > 0)
 108                 if(STAT(FROZEN, frag_target) == 0)
 109                 if(!IS_DEAD(frag_target))
 110                 {
 111                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
 112                         M_ARGV(6, vector) = '0 0 0';
 113                 }
 114
 115                 M_ARGV(4, float) = 0;
 116         }
 117 }
 118
 119 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_SplitHealthArmor)
 120 {
 121         entity frag_target = M_ARGV(2, entity);
 122         float damage_take = M_ARGV(4, float);
 123
 124         if(damage_take)
 125                 frag_target.ok_pauseregen_finished = max(frag_target.ok_pauseregen_finished, time + 2);
 126 }
 127
 128 void ok_DropItem(entity this, entity targ)
 129 {
 130         entity e = new(droppedweapon); // hax
 131         e.ok_item = true;
 132         e.noalign = true;
 133         e.pickup_anyway = true;
 134         e.spawnfunc_checked = true;
 135         spawnfunc_item_armor_small(e);
 136         if (!wasfreed(e)) { // might have been blocked by a mutator
 137         set_movetype(e, MOVETYPE_TOSS);
 138         e.gravity = 1;
 139         e.reset = SUB_Remove;
 140         setorigin(e, this.origin + '0 0 32');
 141         e.velocity = '0 0 200' + normalize(targ.origin - this.origin) * 500;
 142         SUB_SetFade(e, time + 5, 1);
 143         }
 144 }
 145
 146 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
 147 {
 148         entity frag_attacker = M_ARGV(1, entity);
 149         entity frag_target = M_ARGV(2, entity);
 150
 151         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 152
 153         ok_DropItem(frag_target, targ);
 154
 155         frag_target.ok_lastwep = PS(frag_target).m_switchweapon.m_id;
 156 }
 157
 158 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
 159 {
 160         entity mon = M_ARGV(0, entity);
 161         entity olditem = M_ARGV(1, entity);
 162         entity frag_attacker = M_ARGV(2, entity);
 163
 164         delete(olditem);
 165
 166         M_ARGV(1, entity) = NULL;
 167
 168         ok_DropItem(mon, frag_attacker);
 169 }
 170
 171 MUTATOR_HOOKFUNCTION(ok, PlayerRegen)
 172 {
 173         entity player = M_ARGV(0, entity);
 174
 175         // overkill's values are different, so use custom regen
 176         if(!STAT(FROZEN, player))
 177         {
 178                 player.armorvalue = CalcRotRegen(player.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
 179                         1 * frametime * (time > player.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > player.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 180                 player.health = CalcRotRegen(player.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > player.ok_pauseregen_finished), 200, 0,
 181                         autocvar_g_balance_health_rotlinear, 1 * frametime * (time > player.pauserothealth_finished), autocvar_g_balance_health_limit);
 182
 183                 float minf, maxf, limitf;
 184
 185                 maxf = autocvar_g_balance_fuel_rotstable;
 186                 minf = autocvar_g_balance_fuel_regenstable;
 187                 limitf = autocvar_g_balance_fuel_limit;
 188
 189                 player.ammo_fuel = CalcRotRegen(player.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
 190                         frametime * (time > player.pauseregen_finished) * ((player.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > player.pauserotfuel_finished), limitf);
 191         }
 192         return true; // return true anyway, as frozen uses no regen
 193 }
 194
 195 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 196 {
 197         return true;
 198 }
 199
 200 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 201 {
 202         if(intermission_running || gameover)
 203                 return;
 204
 205         entity player = M_ARGV(0, entity);
 206
 207         if(IS_DEAD(player) || !IS_PLAYER(player) || STAT(FROZEN, player))
 208                 return;
 209
 210         if(player.ok_lastwep)
 211         {
 212                 Weapon newwep = Weapons_from(player.ok_lastwep);
 213                 if(player.ok_lastwep == WEP_HMG.m_id)
 214                         newwep = WEP_MACHINEGUN;
 215                 if(player.ok_lastwep == WEP_RPC.m_id)
 216                         newwep = WEP_VORTEX;
 217                 PS(player).m_switchweapon = newwep;
 218                 player.ok_lastwep = 0;
 219         }
 220
 221         ok_IncreaseCharge(player, PS(player).m_weapon.m_id);
 222
 223         if(PHYS_INPUT_BUTTON_ATCK2(player))
 224         if(!forbidWeaponUse(player) || player.weapon_blocked) // allow if weapon is blocked
 225         if(time >= player.jump_interval)
 226         {
 227                 player.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor(player);
 228                 makevectors(player.v_angle);
 229
 230                 Weapon oldwep = PS(player).m_weapon;
 231                 PS(player).m_weapon = WEP_BLASTER;
 232                 W_Blaster_Attack(
 233                         player,
 234                         weaponentities[0], // TODO: unhardcode
 235                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 236                         WEP_CVAR_SEC(vaporizer, shotangle),
 237                         WEP_CVAR_SEC(vaporizer, damage),
 238                         WEP_CVAR_SEC(vaporizer, edgedamage),
 239                         WEP_CVAR_SEC(vaporizer, radius),
 240                         WEP_CVAR_SEC(vaporizer, force),
 241                         WEP_CVAR_SEC(vaporizer, speed),
 242                         WEP_CVAR_SEC(vaporizer, spread),
 243                         WEP_CVAR_SEC(vaporizer, delay),
 244                         WEP_CVAR_SEC(vaporizer, lifetime)
 245                 );
 246                 PS(player).m_weapon = oldwep;
 247         }
 248
 249         player.weapon_blocked = false;
 250
 251         player.ok_ammo_charge = player.ammo_charge[PS(player).m_weapon.m_id];
 252
 253         if(player.ok_use_ammocharge)
 254         if(!ok_CheckWeaponCharge(player, PS(player).m_weapon.m_id))
 255         {
 256                 if(autocvar_g_overkill_ammo_charge_notice && time > player.ok_notice_time && PHYS_INPUT_BUTTON_ATCK(player) && IS_REAL_CLIENT(player) && PS(player).m_weapon == PS(player).m_switchweapon)
 257                 {
 258                         //Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 259                         player.ok_notice_time = time + 2;
 260                         play2(player, SND(DRYFIRE));
 261                 }
 262                 Weapon wpn = PS(player).m_weapon;
 263                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 264                 if(player.(weaponentity).state != WS_CLEAR)
 265                         w_ready(wpn, player, weaponentity, PHYS_INPUT_BUTTON_ATCK(player) | (PHYS_INPUT_BUTTON_ATCK2(player) << 1));
 266
 267                 player.weapon_blocked = true;
 268         }
 269
 270         PHYS_INPUT_BUTTON_ATCK2(player) = false;
 271 }
 272
 273 MUTATOR_HOOKFUNCTION(ok, PlayerSpawn)
 274 {
 275         entity player = M_ARGV(0, entity);
 276
 277         if(autocvar_g_overkill_ammo_charge)
 278         {
 279                 FOREACH(Weapons, it != WEP_Null, LAMBDA(player.ammo_charge[it.m_id] = autocvar_g_overkill_ammo_charge_limit));
 280
 281                 player.ok_use_ammocharge = 1;
 282                 player.ok_notice_time = time;
 283         }
 284         else
 285                 player.ok_use_ammocharge = 0;
 286
 287         // if player changed their weapon while dead, don't switch to their death weapon
 288         if(player.impulse)
 289                 player.ok_lastwep = 0;
 290
 291         player.ok_pauseregen_finished = time + 2;
 292 }
 293
 294 void self_spawnfunc_weapon_hmg(entity this) { spawnfunc_weapon_hmg(this); }
 295 void self_spawnfunc_weapon_rpc(entity this) { spawnfunc_weapon_rpc(this); }
 296
 297 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 298 {
 299         entity ent = M_ARGV(0, entity);
 300
 301         if(autocvar_g_powerups)
 302         if(autocvar_g_overkill_powerups_replace)
 303         {
 304                 if(ent.classname == "item_strength")
 305                 {
 306                         entity wep = new(weapon_hmg);
 307                         setorigin(wep, ent.origin);
 308                         setmodel(wep, MDL_OK_HMG);
 309                         wep.ok_item = true;
 310                         wep.noalign = ent.noalign;
 311                         wep.cnt = ent.cnt;
 312                         wep.team = ent.team;
 313                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 314                         wep.pickup_anyway = true;
 315                         wep.spawnfunc_checked = true;
 316                         setthink(wep, self_spawnfunc_weapon_hmg);
 317                         wep.nextthink = time + 0.1;
 318                         return true;
 319                 }
 320
 321                 if(ent.classname == "item_invincible")
 322                 {
 323                         entity wep = new(weapon_rpc);
 324                         setorigin(wep, ent.origin);
 325                         setmodel(wep, MDL_OK_RPC);
 326                         wep.ok_item = true;
 327                         wep.noalign = ent.noalign;
 328                         wep.cnt = ent.cnt;
 329                         wep.team = ent.team;
 330                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 331                         wep.pickup_anyway = true;
 332                         wep.spawnfunc_checked = true;
 333                         setthink(wep, self_spawnfunc_weapon_rpc);
 334                         wep.nextthink = time + 0.1;
 335                         return true;
 336                 }
 337         }
 338 }
 339
 340 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 341 {
 342         entity item = M_ARGV(0, entity);
 343
 344         if(item.ok_item)
 345                 return;
 346
 347         switch(item.items)
 348         {
 349                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 350                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 351         }
 352
 353         return true;
 354 }
 355
 356 MUTATOR_HOOKFUNCTION(ok, SpectateCopy)
 357 {
 358         entity spectatee = M_ARGV(0, entity);
 359         entity client = M_ARGV(1, entity);
 360
 361         client.ammo_charge[PS(client).m_weapon.m_id] = spectatee.ammo_charge[PS(spectatee).m_weapon.m_id];
 362         client.ok_use_ammocharge = spectatee.ok_use_ammocharge;
 363 }
 364
 365 MUTATOR_HOOKFUNCTION(ok, SetStartItems, CBC_ORDER_LAST)
 366 {
 367         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 368
 369         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 370         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 371
 372         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 373         start_weapons = warmup_start_weapons = ok_start_items;
 374 }
 375
 376 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 377 {
 378         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
 379 }
 380
 381 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 382 {
 383         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
 384 }
 385
 386 MUTATOR_HOOKFUNCTION(ok, SetModname)
 387 {
 388         M_ARGV(0, string) = "Overkill";
 389         return true;
 390 }
 391
 392 void ok_SetCvars()
 393 {
 394         // hack to force overkill playermodels
 395         cvar_settemp("sv_defaultcharacter", "1");
 396         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 397         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 398         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 399 }
 400
 401 void ok_Initialize()
 402 {
 403         ok_SetCvars();
 404
 405         precache_all_playermodels("models/ok_player/*.dpm");
 406
 407         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 408         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 409
 410         WEP_SHOTGUN.mdl = "ok_shotgun";
 411         WEP_MACHINEGUN.mdl = "ok_mg";
 412         WEP_VORTEX.mdl = "ok_sniper";
 413 }