Remove _all indirection
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mutators / mutator / spawn_near_teammate / sv_spawn_near_teammate.qc
1 #include "sv_spawn_near_teammate.qh"
2
3 float autocvar_g_spawn_near_teammate_distance;
4 int autocvar_g_spawn_near_teammate_ignore_spawnpoint;
5 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
6 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
7 int autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health;
8 bool autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath;
9
10 REGISTER_MUTATOR(spawn_near_teammate, cvar("g_spawn_near_teammate"));
11
12 .entity msnt_lookat;
13
14 .float msnt_timer;
15 .vector msnt_deathloc;
16
17 .float cvar_cl_spawn_near_teammate;
18
19 MUTATOR_HOOKFUNCTION(spawn_near_teammate, Spawn_Score)
20 {
21         entity player = M_ARGV(0, entity);
22         entity spawn_spot = M_ARGV(1, entity);
23         vector spawn_score = M_ARGV(2, vector);
24
25         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && player.cvar_cl_spawn_near_teammate))
26                 return;
27
28         spawn_spot.msnt_lookat = NULL;
29
30         if(!teamplay)
31                 return;
32
33         RandomSelection_Init();
34         FOREACH_CLIENT(IS_PLAYER(it) && it != player && SAME_TEAM(it, player) && !IS_DEAD(it), LAMBDA(
35                 if(vdist(spawn_spot.origin - it.origin, >, autocvar_g_spawn_near_teammate_distance))
36                         continue;
37                 if(vdist(spawn_spot.origin - it.origin, <, 48))
38                         continue;
39                 if(!checkpvs(spawn_spot.origin, it))
40                         continue;
41                 RandomSelection_Add(it, 0, string_null, 1, 1);
42         ));
43
44         if(RandomSelection_chosen_ent)
45         {
46                 spawn_spot.msnt_lookat = RandomSelection_chosen_ent;
47                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_FOUND;
48         }
49         else if(player.team == spawn_spot.team)
50                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_SAMETEAM; // prefer same team, if we can't find a spawn near teammate
51
52         M_ARGV(2, vector) = spawn_score;
53 }
54
55 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerSpawn)
56 {
57         if(!teamplay) { return; }
58         entity player = M_ARGV(0, entity);
59         entity spawn_spot = M_ARGV(1, entity);
60
61         int num_red = 0, num_blue = 0, num_yellow = 0, num_pink = 0;
62         FOREACH_CLIENT(IS_PLAYER(it),
63         {
64                 switch(it.team)
65                 {
66                         case NUM_TEAM_1: ++num_red; break;
67                         case NUM_TEAM_2: ++num_blue; break;
68                         case NUM_TEAM_3: ++num_yellow; break;
69                         case NUM_TEAM_4: ++num_pink; break;
70                 }
71         });
72
73         if(num_red == 1 || num_blue == 1 || num_yellow == 1 || num_pink == 1)
74                 return; // at least 1 team has only 1 player, let's not give the bigger team too much of an advantage!
75
76         // Note: when entering this, fixangle is already set.
77         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && player.cvar_cl_spawn_near_teammate))
78         {
79                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death)
80                         player.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
81
82                 entity best_mate = NULL;
83                 vector best_spot = '0 0 0';
84                 float pc = 0, best_dist = 0, dist = 0;
85                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
86                         if((autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health >= 0 && it.health >= autocvar_g_balance_health_regenstable) || autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health == 0)
87                         if(!IS_DEAD(it))
88                         if(it.msnt_timer < time)
89                         if(SAME_TEAM(player, it))
90                         if(time > it.spawnshieldtime) // spawn shielding
91                         if(STAT(FROZEN, it) == 0)
92                         if(it != player)
93                         {
94                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - '0 0 100', MOVE_NOMONSTERS, it);
95                                 if(trace_fraction != 1.0)
96                                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
97                                 {
98                                         pc = pointcontents(trace_endpos + '0 0 1');
99                                         if(pc == CONTENT_EMPTY)
100                                         {
101                                                 if(vdist(it.velocity, >, 5))
102                                                         fixedmakevectors(vectoangles(it.velocity));
103                                                 else
104                                                         fixedmakevectors(it.angles);
105
106                                                 for(pc = 0; pc < 4; ++pc) // test 4 diffrent spots close to mate
107                                                 {
108                                                         switch(pc)
109                                                         {
110                                                                 case 0:
111                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin + v_right * 128, MOVE_NOMONSTERS, it);
112                                                                         break;
113                                                                 case 1:
114                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_right * 128 , MOVE_NOMONSTERS, it);
115                                                                         break;
116                                                                 case 2:
117                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin + v_right * 128 - v_forward * 64, MOVE_NOMONSTERS, it);
118                                                                         break;
119                                                                 case 3:
120                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_right * 128 - v_forward * 64, MOVE_NOMONSTERS, it);
121                                                                         break;
122                                                                 //case 4:
123                                                                         //tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_forward * 128, MOVE_NOMONSTERS, it);
124                                                                         //break;
125                                                         }
126
127                                                         if(trace_fraction == 1.0)
128                                                         {
129                                                                 traceline(trace_endpos + '0 0 4', trace_endpos - '0 0 100', MOVE_NOMONSTERS, it);
130                                                                 if(trace_fraction != 1.0)
131                                                                 {
132                                                                         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
133                                                                         {
134                                                                                 dist = vlen(trace_endpos - player.msnt_deathloc);
135                                                                                 if(dist < best_dist || best_dist == 0)
136                                                                                 {
137                                                                                         best_dist = dist;
138                                                                                         best_spot = trace_endpos;
139                                                                                         best_mate = it;
140                                                                                 }
141                                                                         }
142                                                                         else
143                                                                         {
144                                                                                 setorigin(player, trace_endpos);
145                                                                                 player.angles = it.angles;
146                                                                                 player.angles_z = 0; // never spawn tilted even if the spot says to
147                                                                                 it.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
148                                                                                 return;
149                                                                         }
150                                                                 }
151                                                         }
152                                                 }
153                                         }
154                                 }
155                         }
156                 ));
157
158                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
159                 if(best_dist)
160                 {
161                         setorigin(player, best_spot);
162                         player.angles = best_mate.angles;
163                         player.angles_z = 0; // never spawn tilted even if the spot says to
164                         best_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
165                 }
166         }
167         else if(spawn_spot.msnt_lookat)
168         {
169                 player.angles = vectoangles(spawn_spot.msnt_lookat.origin - player.origin);
170                 player.angles_x = -player.angles.x;
171                 player.angles_z = 0; // never spawn tilted even if the spot says to
172                 /*
173                 sprint(player, "You should be looking at ", spawn_spot.msnt_lookat.netname, "^7.\n");
174                 sprint(player, "distance: ", vtos(spawn_spot.msnt_lookat.origin - player.origin), "\n");
175                 sprint(player, "angles: ", vtos(player.angles), "\n");
176                 */
177         }
178 }
179
180 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerDies)
181 {
182         entity frag_target = M_ARGV(0, entity);
183
184         frag_target.msnt_deathloc = frag_target.origin;
185 }
186
187 REPLICATE(cvar_cl_spawn_near_teammate, bool, "cl_spawn_near_teammate");