qcsrc/common/mutators/mutator/superspec/sv_superspec.qc

   1 #include "sv_superspec.qh"
   2
   3 REGISTER_MUTATOR(superspec, cvar("g_superspectate"));
   4
   5 #define _SSMAGIX "SUPERSPEC_OPTIONSFILE_V1"
   6 #define _ISLOCAL(ent) ((edict_num(1) == (ent)) ? true : false)
   7
   8 const float ASF_STRENGTH                = BIT(0);
   9 const float ASF_SHIELD                  = BIT(1);
  10 const float ASF_MEGA_AR                 = BIT(2);
  11 const float ASF_MEGA_HP                 = BIT(3);
  12 const float ASF_FLAG_GRAB               = BIT(4);
  13 const float ASF_OBSERVER_ONLY   = BIT(5);
  14 const float ASF_SHOWWHAT                = BIT(6);
  15 const float ASF_SSIM                    = BIT(7);
  16 const float ASF_FOLLOWKILLER    = BIT(8);
  17 const float ASF_ALL                     = 0xFFFFFF;
  18 .float autospec_flags;
  19
  20 const float SSF_SILENT = 1;
  21 const float SSF_VERBOSE = 2;
  22 const float SSF_ITEMMSG = 4;
  23 .float superspec_flags;
  24
  25 .string superspec_itemfilter; //"classname1 classname2 ..."
  26
  27 bool superspec_Spectate(entity this, entity targ)
  28 {
  29         if(Spectate(this, targ) == 1)
  30             TRANSMUTE(Spectator, this);
  31
  32         return true;
  33 }
  34
  35 void superspec_save_client_conf(entity this)
  36 {
  37         string fn = "superspec-local.options";
  38         float fh;
  39
  40         if (!_ISLOCAL(this))
  41         {
  42                 if(this.crypto_idfp == "")
  43                         return;
  44
  45                 fn = sprintf("superspec-%s.options", uri_escape(this.crypto_idfp));
  46         }
  47
  48         fh = fopen(fn, FILE_WRITE);
  49         if(fh < 0)
  50         {
  51                 LOG_TRACE("^1ERROR: ^7 superspec can not open ", fn, " for writing.");
  52         }
  53         else
  54         {
  55                 fputs(fh, _SSMAGIX);
  56                 fputs(fh, "\n");
  57                 fputs(fh, ftos(this.autospec_flags));
  58                 fputs(fh, "\n");
  59                 fputs(fh, ftos(this.superspec_flags));
  60                 fputs(fh, "\n");
  61                 fputs(fh, this.superspec_itemfilter);
  62                 fputs(fh, "\n");
  63                 fclose(fh);
  64         }
  65 }
  66
  67 void superspec_msg(string _center_title, string _con_title, entity _to, string _msg, float _spamlevel)
  68 {
  69         sprint(_to, strcat(_con_title, _msg));
  70
  71         if(_to.superspec_flags & SSF_SILENT)
  72                 return;
  73
  74         if(_spamlevel > 1)
  75                 if (!(_to.superspec_flags & SSF_VERBOSE))
  76                         return;
  77
  78         centerprint(_to, strcat(_center_title, _msg));
  79 }
  80
  81 float superspec_filteritem(entity _for, entity _item)
  82 {
  83         float i;
  84
  85         if(_for.superspec_itemfilter == "")
  86                 return true;
  87
  88         if(_for.superspec_itemfilter == "")
  89                 return true;
  90
  91         float l = tokenize_console(_for.superspec_itemfilter);
  92         for(i = 0; i < l; ++i)
  93         {
  94                 if(argv(i) == _item.classname)
  95                         return true;
  96         }
  97
  98         return false;
  99 }
 100
 101 MUTATOR_HOOKFUNCTION(superspec, ItemTouch)
 102 {
 103         entity item = M_ARGV(0, entity);
 104         entity toucher = M_ARGV(1, entity);
 105
 106         FOREACH_CLIENT(true, LAMBDA(
 107                 if(!IS_SPEC(it) && !IS_OBSERVER(it))
 108                         continue;
 109                 if(it.superspec_flags & SSF_ITEMMSG)
 110                         if(superspec_filteritem(it, item))
 111                         {
 112                                 if(it.superspec_flags & SSF_VERBOSE)
 113                                         superspec_msg("", "", it, sprintf("Player %s^7 just picked up ^3%s\n", toucher.netname, item.netname), 1);
 114                                 else
 115                                         superspec_msg("", "", it, sprintf("Player %s^7 just picked up ^3%s\n^8(%s^8)\n", toucher.netname, item.netname, item.classname), 1);
 116                                 if((it.autospec_flags & ASF_SSIM) && it.enemy != toucher)
 117                                 {
 118                                         superspec_Spectate(it, toucher);
 119                                         return MUT_ITEMTOUCH_CONTINUE;
 120                                 }
 121                         }
 122
 123                 if((it.autospec_flags & ASF_SHIELD && item.invincible_finished) ||
 124                         (it.autospec_flags & ASF_STRENGTH && item.strength_finished) ||
 125                         (it.autospec_flags & ASF_MEGA_AR && item.itemdef == ITEM_ArmorMega) ||
 126                         (it.autospec_flags & ASF_MEGA_HP && item.itemdef == ITEM_HealthMega) ||
 127                         (it.autospec_flags & ASF_FLAG_GRAB && item.classname == "item_flag_team"))
 128                 {
 129
 130                         if((it.enemy != toucher) || IS_OBSERVER(it))
 131                         {
 132                                 if(it.autospec_flags & ASF_OBSERVER_ONLY && !IS_OBSERVER(it))
 133                                 {
 134                                         if(it.superspec_flags & SSF_VERBOSE)
 135                                                 superspec_msg("", "", it, sprintf("^8Ignored that ^7%s^8 grabbed %s^8 since the observer_only option is ON\n", toucher.netname, item.netname), 2);
 136                                 }
 137                                 else
 138                                 {
 139                                         if(it.autospec_flags & ASF_SHOWWHAT)
 140                                                 superspec_msg("", "", it, sprintf("^7Following %s^7 due to picking up %s\n", toucher.netname, item.netname), 2);
 141
 142                                         superspec_Spectate(it, toucher);
 143                                 }
 144                         }
 145                 }
 146         ));
 147
 148         return MUT_ITEMTOUCH_CONTINUE;
 149 }
 150
 151 MUTATOR_HOOKFUNCTION(superspec, SV_ParseClientCommand)
 152 {
 153 #define OPTIONINFO(flag,var,test,text,long,short) \
 154     var = strcat(var, ((flag & test) ? "^2[ON]  ^7" : "^1[OFF] ^7")); \
 155     var = strcat(var, text," ^7(^3 ", long, "^7 | ^3", short, " ^7)\n")
 156
 157         if(MUTATOR_RETURNVALUE) // command was already handled?
 158                 return;
 159
 160         entity player = M_ARGV(0, entity);
 161         string cmd_name = M_ARGV(1, string);
 162         int cmd_argc = M_ARGV(2, int);
 163
 164         if(IS_PLAYER(player))
 165                 return;
 166
 167         if(cmd_name == "superspec_itemfilter")
 168         {
 169                 if(argv(1) == "help")
 170                 {
 171                         string _aspeco;
 172                         _aspeco = "^7 superspec_itemfilter ^3\"item_classname1 item_classname2\"^7 only show thise items when ^2superspec ^3item_message^7 is on\n";
 173                         _aspeco = strcat(_aspeco, "^3 clear^7 Remove the filter (show all pickups)\n");
 174                         _aspeco = strcat(_aspeco, "^3 show ^7 Display current filter\n");
 175                         superspec_msg("^3superspec_itemfilter help:\n\n\n", "\n^3superspec_itemfilter help:\n", player, _aspeco, 1);
 176                 }
 177                 else if(argv(1) == "clear")
 178                 {
 179                         if(player.superspec_itemfilter != "")
 180                                 strunzone(player.superspec_itemfilter);
 181
 182                         player.superspec_itemfilter = "";
 183                 }
 184                 else if(argv(1) == "show" || argv(1) == "")
 185                 {
 186                         if(player.superspec_itemfilter == "")
 187                         {
 188                                 superspec_msg("^3superspec_itemfilter^7 is ^1not^7 set", "\n^3superspec_itemfilter^7 is ^1not^7 set\n", player, "", 1);
 189                                 return true;
 190                         }
 191                         float i;
 192                         float l = tokenize_console(player.superspec_itemfilter);
 193                         string _msg = "";
 194                         for(i = 0; i < l; ++i)
 195                                 _msg = strcat(_msg, "^3#", ftos(i), " ^7", argv(i), "\n");
 196                                 //_msg = sprintf("^3#%d^7 %s\n%s", i, _msg, argv(i));
 197
 198                         _msg = strcat(_msg,"\n");
 199
 200                         superspec_msg("^3superspec_itemfilter is:\n\n\n", "\n^3superspec_itemfilter is:\n", player, _msg, 1);
 201                 }
 202                 else
 203                 {
 204                         if(player.superspec_itemfilter != "")
 205                                 strunzone(player.superspec_itemfilter);
 206
 207                         player.superspec_itemfilter = strzone(argv(1));
 208                 }
 209
 210                 return true;
 211         }
 212
 213         if(cmd_name == "superspec")
 214         {
 215                 string _aspeco;
 216
 217                 if(cmd_argc > 1)
 218                 {
 219                         float i, _bits = 0, _start = 1;
 220                         if(argv(1) == "help")
 221                         {
 222                                 _aspeco = "use cmd superspec [option] [on|off] to set options\n\n";
 223                                 _aspeco = strcat(_aspeco, "^3 silent ^7(short^5 si^7) supresses ALL messages from superspectate.\n");
 224                                 _aspeco = strcat(_aspeco, "^3 verbose ^7(short^5 ve^7) makes superspectate print some additional information.\n");
 225                                 _aspeco = strcat(_aspeco, "^3 item_message ^7(short^5 im^7) makes superspectate print items that were picked up.\n");
 226                                 _aspeco = strcat(_aspeco, "^7    Use cmd superspec_itemfilter \"item_class1 item_class2\" to set up a filter of what to show with ^3item_message.\n");
 227                                 superspec_msg("^2Available Super Spectate ^3options:\n\n\n", "\n^2Available Super Spectate ^3options:\n", player, _aspeco, 1);
 228                                 return true;
 229                         }
 230
 231                         if(argv(1) == "clear")
 232                         {
 233                                 player.superspec_flags = 0;
 234                                 _start = 2;
 235                         }
 236
 237                         for(i = _start; i < cmd_argc; ++i)
 238                         {
 239                                 if(argv(i) == "on" || argv(i) == "1")
 240                                 {
 241                                         player.superspec_flags |= _bits;
 242                                         _bits = 0;
 243                                 }
 244                                 else if(argv(i) == "off" || argv(i) == "0")
 245                                 {
 246                                         if(_start == 1)
 247                                                 player.superspec_flags &= ~_bits;
 248
 249                                         _bits = 0;
 250                                 }
 251                                 else
 252                                 {
 253                                         if((argv(i) == "silent") || (argv(i) == "si")) _bits |= SSF_SILENT ;
 254                                         if((argv(i) == "verbose") || (argv(i) == "ve")) _bits |= SSF_VERBOSE;
 255                                         if((argv(i) == "item_message") || (argv(i) == "im")) _bits |= SSF_ITEMMSG;
 256                                 }
 257                         }
 258                 }
 259
 260                 _aspeco = "";
 261                 OPTIONINFO(player.superspec_flags, _aspeco, SSF_SILENT, "Silent", "silent", "si");
 262                 OPTIONINFO(player.superspec_flags, _aspeco, SSF_VERBOSE, "Verbose", "verbose", "ve");
 263                 OPTIONINFO(player.superspec_flags, _aspeco, SSF_ITEMMSG, "Item pickup messages", "item_message", "im");
 264
 265                 superspec_msg("^3Current Super Spectate options are:\n\n\n\n\n", "\n^3Current Super Spectate options are:\n", player, _aspeco, 1);
 266
 267                 return true;
 268         }
 269
 270 /////////////////////
 271
 272         if(cmd_name == "autospec")
 273         {
 274                 string _aspeco;
 275                 if(cmd_argc > 1)
 276                 {
 277                         if(argv(1) == "help")
 278                         {
 279                                 _aspeco = "use cmd autospec [option] [on|off] to set options\n\n";
 280                                 _aspeco = strcat(_aspeco, "^3 strength ^7(short^5 st^7) for automatic spectate on strength powerup\n");
 281                                 _aspeco = strcat(_aspeco, "^3 shield ^7(short^5 sh^7) for automatic spectate on shield powerup\n");
 282                                 _aspeco = strcat(_aspeco, "^3 mega_health ^7(short^5 mh^7) for automatic spectate on mega health\n");
 283                                 _aspeco = strcat(_aspeco, "^3 mega_armor ^7(short^5 ma^7) for automatic spectate on mega armor\n");
 284                                 _aspeco = strcat(_aspeco, "^3 flag_grab ^7(short^5 fg^7) for automatic spectate on CTF flag grab\n");
 285                                 _aspeco = strcat(_aspeco, "^3 observer_only ^7(short^5 oo^7) for automatic spectate only if in observer mode\n");
 286                                 _aspeco = strcat(_aspeco, "^3 show_what ^7(short^5 sw^7) to display what event triggered autospectate\n");
 287                                 _aspeco = strcat(_aspeco, "^3 item_msg ^7(short^5 im^7) to autospec when item_message in superspectate is triggered\n");
 288                                 _aspeco = strcat(_aspeco, "^3 followkiller ^7(short ^5fk^7) to autospec the killer/off\n");
 289                                 _aspeco = strcat(_aspeco, "^3 all ^7(short ^5aa^7) to turn everything on/off\n");
 290                                 superspec_msg("^2Available Auto Spectate ^3options:\n\n\n", "\n^2Available Auto Spectate ^3options:\n", player, _aspeco, 1);
 291                                 return true;
 292                         }
 293
 294                         float i, _bits = 0, _start = 1;
 295                         if(argv(1) == "clear")
 296                         {
 297                                 player.autospec_flags = 0;
 298                                 _start = 2;
 299                         }
 300
 301                         for(i = _start; i < cmd_argc; ++i)
 302                         {
 303                                 if(argv(i) == "on" || argv(i) == "1")
 304                                 {
 305                                         player.autospec_flags |= _bits;
 306                                         _bits = 0;
 307                                 }
 308                                 else if(argv(i) == "off" || argv(i) == "0")
 309                                 {
 310                                         if(_start == 1)
 311                                                 player.autospec_flags &= ~_bits;
 312
 313                                         _bits = 0;
 314                                 }
 315                                 else
 316                                 {
 317                                         if((argv(i) == "strength") || (argv(i) == "st")) _bits |= ASF_STRENGTH;
 318                                         if((argv(i) == "shield") || (argv(i) == "sh")) _bits |= ASF_SHIELD;
 319                                         if((argv(i) == "mega_health") || (argv(i) == "mh")) _bits |= ASF_MEGA_HP;
 320                                         if((argv(i) == "mega_armor") || (argv(i) == "ma")) _bits |= ASF_MEGA_AR;
 321                                         if((argv(i) == "flag_grab") || (argv(i) == "fg")) _bits |= ASF_FLAG_GRAB;
 322                                         if((argv(i) == "observer_only") || (argv(i) == "oo")) _bits |= ASF_OBSERVER_ONLY;
 323                                         if((argv(i) == "show_what") || (argv(i) == "sw")) _bits |= ASF_SHOWWHAT;
 324                                         if((argv(i) == "item_msg") || (argv(i) == "im")) _bits |= ASF_SSIM;
 325                                         if((argv(i) == "followkiller") || (argv(i) == "fk")) _bits |= ASF_FOLLOWKILLER;
 326                                         if((argv(i) == "all") || (argv(i) == "aa")) _bits |= ASF_ALL;
 327                                 }
 328                         }
 329                 }
 330
 331                 _aspeco = "";
 332                 OPTIONINFO(player.autospec_flags, _aspeco, ASF_STRENGTH, "Strength", "strength", "st");
 333                 OPTIONINFO(player.autospec_flags, _aspeco, ASF_SHIELD, "Shield", "shield", "sh");
 334                 OPTIONINFO(player.autospec_flags, _aspeco, ASF_MEGA_HP, "Mega Health", "mega_health", "mh");
 335                 OPTIONINFO(player.autospec_flags, _aspeco, ASF_MEGA_AR, "Mega Armor", "mega_armor", "ma");
 336                 OPTIONINFO(player.autospec_flags, _aspeco, ASF_FLAG_GRAB, "Flag grab", "flag_grab","fg");
 337                 OPTIONINFO(player.autospec_flags, _aspeco, ASF_OBSERVER_ONLY, "Only switch if observer", "observer_only", "oo");
 338                 OPTIONINFO(player.autospec_flags, _aspeco, ASF_SHOWWHAT, "Show what item triggered spectate", "show_what", "sw");
 339                 OPTIONINFO(player.autospec_flags, _aspeco, ASF_SSIM, "Switch on superspec item message", "item_msg", "im");
 340                 OPTIONINFO(player.autospec_flags, _aspeco, ASF_FOLLOWKILLER, "Followkiller", "followkiller", "fk");
 341
 342                 superspec_msg("^3Current auto spectate options are:\n\n\n\n\n", "\n^3Current auto spectate options are:\n", player, _aspeco, 1);
 343                 return true;
 344         }
 345
 346         if(cmd_name == "followpowerup")
 347         {
 348                 FOREACH_CLIENT(IS_PLAYER(it) && (it.strength_finished > time || it.invincible_finished > time), LAMBDA(return superspec_Spectate(player, it)));
 349
 350                 superspec_msg("", "", player, "No active powerup\n", 1);
 351                 return true;
 352         }
 353
 354         if(cmd_name == "followstrength")
 355         {
 356                 FOREACH_CLIENT(IS_PLAYER(it) && it.strength_finished > time, LAMBDA(return superspec_Spectate(player, it)));
 357
 358                 superspec_msg("", "", player, "No active Strength\n", 1);
 359                 return true;
 360         }
 361
 362         if(cmd_name == "followshield")
 363         {
 364                 FOREACH_CLIENT(IS_PLAYER(it) && it.invincible_finished > time, LAMBDA(return superspec_Spectate(player, it)));
 365
 366                 superspec_msg("", "", player, "No active Shield\n", 1);
 367                 return true;
 368         }
 369 #undef OPTIONINFO
 370 }
 371
 372 MUTATOR_HOOKFUNCTION(superspec, BuildMutatorsString)
 373 {
 374         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":SS");
 375 }
 376
 377 MUTATOR_HOOKFUNCTION(superspec, BuildMutatorsPrettyString)
 378 {
 379         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Super Spectators");
 380 }
 381
 382 void superspec_hello(entity this)
 383 {
 384         if(this.enemy.crypto_idfp == "")
 385                 Send_Notification(NOTIF_ONE_ONLY, this.enemy, MSG_INFO, INFO_SUPERSPEC_MISSING_UID);
 386
 387         delete(this);
 388 }
 389
 390 MUTATOR_HOOKFUNCTION(superspec, ClientConnect)
 391 {
 392         entity player = M_ARGV(0, entity);
 393
 394         if(!IS_REAL_CLIENT(player))
 395                 return;
 396
 397         string fn = "superspec-local.options";
 398         float fh;
 399
 400         player.superspec_flags = SSF_VERBOSE;
 401         player.superspec_itemfilter = "";
 402
 403         entity _hello = spawn();
 404         _hello.enemy = player;
 405         setthink(_hello, superspec_hello);
 406         _hello.nextthink = time + 5;
 407
 408         if (!_ISLOCAL(player))
 409         {
 410                 if(player.crypto_idfp == "")
 411                         return;
 412
 413                 fn = sprintf("superspec-%s.options", uri_escape(player.crypto_idfp));
 414         }
 415
 416         fh = fopen(fn, FILE_READ);
 417         if(fh < 0)
 418         {
 419                 LOG_TRACE("^1ERROR: ^7 superspec can not open ", fn, " for reading.");
 420         }
 421         else
 422         {
 423                 string _magic = fgets(fh);
 424                 if(_magic != _SSMAGIX)
 425                 {
 426                         LOG_TRACE("^1ERROR^7 While reading superspec options file: unknown magic");
 427                 }
 428                 else
 429                 {
 430                         player.autospec_flags = stof(fgets(fh));
 431                         player.superspec_flags = stof(fgets(fh));
 432                         player.superspec_itemfilter = strzone(fgets(fh));
 433                 }
 434                 fclose(fh);
 435         }
 436 }
 437
 438 MUTATOR_HOOKFUNCTION(superspec, PlayerDies)
 439 {
 440         entity frag_attacker = M_ARGV(1, entity);
 441         entity frag_target = M_ARGV(2, entity);
 442
 443         FOREACH_CLIENT(IS_SPEC(it), LAMBDA(
 444                 if(it.autospec_flags & ASF_FOLLOWKILLER && IS_PLAYER(frag_attacker) && it.enemy == frag_target)
 445                 {
 446                         if(it.autospec_flags & ASF_SHOWWHAT)
 447                                 superspec_msg("", "", it, sprintf("^7Following %s^7 due to followkiller\n", frag_attacker.netname), 2);
 448
 449                         superspec_Spectate(it, frag_attacker);
 450                 }
 451         ));
 452 }
 453
 454 MUTATOR_HOOKFUNCTION(superspec, ClientDisconnect)
 455 {
 456         entity player = M_ARGV(0, entity);
 457
 458         superspec_save_client_conf(player);
 459 }