qcsrc/common/notifications/all.qc

   1 #include "all.qh"
   2 #if defined(CSQC)
   3         #include <client/announcer.qh>
   4 #elif defined(MENUQC)
   5 #elif defined(SVQC)
   6         #include <common/constants.qh>
   7         #include <common/net_linked.qh>
   8         #include <common/teams.qh>
   9         #include <server/autocvars.qh>
  10         #include <server/constants.qh>
  11         #include <server/defs.qh>
  12         #include <server/mutators/_mod.qh>
  13 #endif
  14
  15 // ================================================
  16 //  Unified notification system, written by Samual
  17 //  Last updated: August, 2013
  18 // ================================================
  19
  20 #ifdef SVQC
  21 string Notification_CheckArgs(
  22         NOTIF broadcast, entity client)
  23 {
  24         // check supplied broadcast and target for errors
  25         switch (broadcast)
  26         {
  27                 case NOTIF_ONE:
  28                 case NOTIF_ONE_ONLY:
  29                 {
  30                         if (IS_NOT_A_CLIENT(client)) {
  31                                 return "No client provided!";
  32                         }
  33                         break;
  34                 }
  35
  36                 case NOTIF_ALL_EXCEPT:
  37                 {
  38                         if (IS_NOT_A_CLIENT(client)) {
  39                                 return "Exception can't be a non-client!";
  40                         }
  41                         break;
  42                 }
  43
  44                 case NOTIF_ALL:
  45                 {
  46                         if (client) {
  47                                 return "Entity provided when NULL was required!";
  48                         }
  49                         break;
  50                 }
  51
  52                 case NOTIF_TEAM:
  53                 {
  54                         if (!teamplay) {
  55                                 return "Teamplay not active!";
  56                         } else if (!client.team) {
  57                                 // checkargs = sprintf("%sNo team provided!", checkargs);
  58                         }
  59                         break;
  60                 }
  61
  62                 case NOTIF_TEAM_EXCEPT:
  63                 {
  64                         if (!teamplay) {
  65                                 return "Teamplay not active!";
  66                         } else if (IS_NOT_A_CLIENT(client)) {
  67                                 return "Exception can't be a non-client!";
  68                         }
  69                         break;
  70                 }
  71
  72                 default:
  73                 {
  74                         return sprintf("Improper broadcast: %d!", broadcast);
  75                 }
  76         }
  77         return "";
  78 }
  79
  80 bool Notification_ShouldSend(NOTIF broadcast, entity to_client, entity other_client)
  81 {
  82         switch (broadcast)
  83         {
  84                 case NOTIF_ONE:
  85                         return (
  86                                 (to_client == other_client)
  87                                 ||
  88                                 (IS_SPEC(to_client) && (to_client.enemy == other_client))
  89                         );
  90                 case NOTIF_ONE_ONLY:
  91                         return (to_client == other_client);
  92                 case NOTIF_TEAM:
  93                         return (
  94                                 (to_client.team == other_client.team)
  95                                 ||
  96                                 (
  97                                         IS_SPEC(to_client)
  98                                         &&
  99                                         (to_client.enemy.team == other_client.team)
 100                                 )
 101                         );
 102                 case NOTIF_TEAM_EXCEPT:
 103                         return (
 104                                 (to_client != other_client)
 105                                 &&
 106                                 (
 107                                         (to_client.team == other_client.team)
 108                                         ||
 109                                         (
 110                                                 IS_SPEC(to_client)
 111                                                 &&
 112                                                 (
 113                                                         (to_client.enemy != other_client)
 114                                                         &&
 115                                                         (to_client.enemy.team == other_client.team)
 116                                                 )
 117                                         )
 118                                 )
 119                         );
 120                 case NOTIF_ALL:
 121                         return true;
 122                 case NOTIF_ALL_EXCEPT:
 123                         return (
 124                                 (to_client != other_client)
 125                                 &&
 126                                 !(
 127                                         IS_SPEC(to_client)
 128                                         &&
 129                                         (to_client.enemy == other_client)
 130                                 )
 131                         );
 132                 default:
 133                         return false;
 134         }
 135 }
 136
 137 #endif
 138
 139 // ===============================
 140 //  Initialization Core Functions
 141 // ===============================
 142
 143 // used by restartnotifs command to initialize notifications
 144 void Destroy_Notification_Entity(entity notif)
 145 {
 146         if (notif.nent_name != "") strunzone(notif.nent_name);
 147         if (notif.nent_snd != "") strunzone(notif.nent_snd);
 148         if (notif.nent_args != "") strunzone(notif.nent_args);
 149         if (notif.nent_hudargs != "") strunzone(notif.nent_hudargs);
 150         if (notif.nent_icon != "") strunzone(notif.nent_icon);
 151         if (notif.nent_durcnt != "") strunzone(notif.nent_durcnt);
 152         if (notif.nent_string != "") strunzone(notif.nent_string);
 153         delete(notif);
 154 }
 155
 156 void Destroy_All_Notifications()
 157 {
 158         // kill all networked notifications and centerprints
 159         #ifdef SVQC
 160         Kill_Notification(NOTIF_ALL, NULL, MSG_Null, CPID_Null);
 161         #else
 162         reset_centerprint_messages();
 163         #endif
 164
 165         // kill all real notification entities
 166         FOREACH(Notifications, true, { Destroy_Notification_Entity(it); });
 167 }
 168
 169 string Process_Notif_Line(
 170         MSG typeId,
 171         bool chat,
 172         string input,
 173         string notiftype,
 174         string notifname,
 175         string stringtype)
 176 {
 177         #ifdef CSQC
 178         if(typeId == MSG_INFO)
 179         {
 180                 if((chat && autocvar_notification_allow_chatboxprint)
 181                         || (autocvar_notification_allow_chatboxprint == 2))
 182                 {
 183                         // pass 1: add ETX char at beginning of line
 184                         input = strcat("\{3}", input);
 185
 186                         // pass 2: add ETX char at end of each new line (so that
 187                         // messages with multiple lines are put through chatbox too)
 188                         input = strreplace("\n", "\n\{3}", input);
 189
 190                         // pass 3: strip trailing ETX char
 191                         if(substring(input, (strlen(input) - 1), 1) == "\{3}")
 192                                 { input = substring(input, 0, (strlen(input) - 1)); }
 193                 }
 194         }
 195         #endif
 196
 197         // done to both MSG_INFO and MSG_CENTER
 198         if(substring(input, (strlen(input) - 1), 1) == "\n")
 199         {
 200                 LOG_INFOF(
 201                         (
 202                                 "^1TRAILING NEW LINE AT END OF NOTIFICATION: "
 203                                 "^7net_type = %s, net_name = %s, string = %s."
 204                         ),
 205                         notiftype,
 206                         notifname,
 207                         stringtype
 208                 );
 209                 notif_error = true;
 210                 input = substring(input, 1, (strlen(input) - 1));
 211         }
 212
 213         return input;
 214 }
 215
 216 string Process_Notif_Args(
 217         float arg_type,
 218         string args,
 219         string notiftype,
 220         string notifname)
 221 {
 222         string selected, remaining = args;
 223         float sel_num = 0;
 224
 225         for (;(remaining != "");)
 226         {
 227                 selected = car(remaining); remaining = cdr(remaining);
 228
 229                 switch(arg_type)
 230                 {
 231                         case 1: // normal args
 232                         {
 233                                 if(sel_num == NOTIF_MAX_ARGS)
 234                                 {
 235                                         LOG_INFOF(
 236                                                 (
 237                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: "
 238                                                         "^7net_type = %s, net_name = %s, max args = %d."
 239                                                 ),
 240                                                 notiftype,
 241                                                 notifname,
 242                                                 NOTIF_MAX_ARGS
 243                                         );
 244                                         notif_error = true;
 245                                         break;
 246                                 }
 247
 248                                 switch(strtolower(selected))
 249                                 {
 250                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: ++sel_num; break;
 251                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: ++sel_num; break;
 252                                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: ++sel_num; break;
 253                                         #define ARG_CASE_ARG_CS(selected,result)       case selected: ++sel_num; break;
 254                                         #define ARG_CASE_ARG_SV(selected,result)       case selected: ++sel_num; break;
 255                                         #define ARG_CASE_ARG_DC(selected,result)
 256                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 257                                         NOTIF_ARGUMENT_LIST
 258                                         #undef ARG_CASE
 259                                         #undef ARG_CASE_ARG_DC
 260                                         #undef ARG_CASE_ARG_SV
 261                                         #undef ARG_CASE_ARG_CS
 262                                         #undef ARG_CASE_ARG_CS_SV
 263                                         #undef ARG_CASE_ARG_CS_SV_DC
 264                                         #undef ARG_CASE_ARG_CS_SV_HA
 265                                         default:
 266                                         {
 267                                                 LOG_INFOF(
 268                                                         (
 269                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: "
 270                                                                 "^7net_type = %s, net_name = %s, args arg = '%s'."
 271                                                         ),
 272                                                         notiftype,
 273                                                         notifname,
 274                                                         selected
 275                                                 );
 276                                                 notif_error = true;
 277                                                 break;
 278                                         }
 279                                 }
 280                                 break;
 281                         }
 282                         case 2: // hudargs
 283                         {
 284                                 if(sel_num == NOTIF_MAX_HUDARGS)
 285                                 {
 286                                         LOG_INFOF(
 287                                                 (
 288                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: "
 289                                                         "^7net_type = %s, net_name = %s, max hudargs = %d."
 290                                                 ),
 291                                                 notiftype,
 292                                                 notifname,
 293                                                 NOTIF_MAX_HUDARGS
 294                                         );
 295                                         notif_error = true;
 296                                         break;
 297                                 }
 298
 299                                 switch(strtolower(selected))
 300                                 {
 301                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: ++sel_num; break;
 302                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result)
 303                                         #define ARG_CASE_ARG_CS_SV(selected,result)
 304                                         #define ARG_CASE_ARG_CS(selected,result)
 305                                         #define ARG_CASE_ARG_SV(selected,result)
 306                                         #define ARG_CASE_ARG_DC(selected,result)
 307                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 308                                         NOTIF_ARGUMENT_LIST
 309                                         #undef ARG_CASE
 310                                         #undef ARG_CASE_ARG_DC
 311                                         #undef ARG_CASE_ARG_SV
 312                                         #undef ARG_CASE_ARG_CS
 313                                         #undef ARG_CASE_ARG_CS_SV
 314                                         #undef ARG_CASE_ARG_CS_SV_DC
 315                                         #undef ARG_CASE_ARG_CS_SV_HA
 316                                         default:
 317                                         {
 318                                                 LOG_INFOF(
 319                                                         (
 320                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: "
 321                                                                 "^7net_type = %s, net_name = %s, hudargs arg = '%s'."
 322                                                         ),
 323                                                         notiftype,
 324                                                         notifname,
 325                                                         selected
 326                                                 );
 327                                                 notif_error = true;
 328                                                 break;
 329                                         }
 330                                 }
 331                                 break;
 332                         }
 333                         case 3: // durcnt
 334                         {
 335                                 if(sel_num == NOTIF_MAX_DURCNT)
 336                                 {
 337                                         LOG_INFOF(
 338                                                 (
 339                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: "
 340                                                         "^7net_type = %s, net_name = %s, max durcnt = %d."
 341                                                 ),
 342                                                 notiftype,
 343                                                 notifname,
 344                                                 NOTIF_MAX_DURCNT
 345                                         );
 346                                         notif_error = true;
 347                                         break;
 348                                 }
 349
 350                                 switch(strtolower(selected))
 351                                 {
 352                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result)
 353                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: ++sel_num; break;
 354                                         #define ARG_CASE_ARG_CS_SV(selected,result)
 355                                         #define ARG_CASE_ARG_CS(selected,result)
 356                                         #define ARG_CASE_ARG_SV(selected,result)
 357                                         #define ARG_CASE_ARG_DC(selected,result)       case selected: ++sel_num; break;
 358                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 359                                         NOTIF_ARGUMENT_LIST
 360                                         #undef ARG_CASE
 361                                         #undef ARG_CASE_ARG_DC
 362                                         #undef ARG_CASE_ARG_SV
 363                                         #undef ARG_CASE_ARG_CS
 364                                         #undef ARG_CASE_ARG_CS_SV
 365                                         #undef ARG_CASE_ARG_CS_SV_DC
 366                                         #undef ARG_CASE_ARG_CS_SV_HA
 367                                         default:
 368                                         {
 369                                                 if(ftos(stof(selected)) != "") { ++sel_num; }
 370                                                 else
 371                                                 {
 372                                                         LOG_INFOF(
 373                                                                 (
 374                                                                         "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: "
 375                                                                         "^7net_type = %s, net_name = %s, durcnt arg = '%s'."
 376                                                                 ),
 377                                                                 notiftype,
 378                                                                 notifname,
 379                                                                 selected
 380                                                         );
 381                                                         notif_error = true;
 382                                                 }
 383                                                 break;
 384                                         }
 385                                 }
 386                                 break;
 387                         }
 388                 }
 389         }
 390         return args;
 391 }
 392
 393 void Create_Notification_Entity(entity notif,
 394         float var_default,
 395         float var_cvar,
 396         MSG typeId,
 397         string namestring,
 398         int teamnum)
 399 {
 400         // =====================
 401         //  Global Entity Setup
 402         // =====================
 403         notif.nent_default = var_default;
 404         notif.nent_enabled = (var_cvar >= 1);
 405         notif.nent_type = typeId;
 406         notif.nent_name = strzone(namestring);
 407         notif.nent_teamnum = teamnum;
 408
 409         // Other pre-notif-setup requisites
 410         notif_error = false;
 411
 412         switch (typeId)
 413         {
 414                 case MSG_ANNCE:
 415                 case MSG_INFO:
 416                 case MSG_CENTER:
 417                 case MSG_MULTI:
 418                 case MSG_CHOICE:
 419                         break;
 420                 default:
 421                         LOG_INFOF(
 422                                 (
 423                                         "^1NOTIFICATION WITH IMPROPER TYPE: "
 424                                         "^7net_type = %d, net_name = %s."
 425                                 ),
 426                                 typeId,
 427                                 namestring
 428                         );
 429                         notif_error = true;
 430                         break;
 431         }
 432
 433         // now check to see if any errors happened
 434         if (notif_error)
 435         {
 436                 notif.nent_enabled = false; // disable the notification so it can't cause trouble
 437                 notif_global_error = true; // throw the red flag that an error happened on init
 438         }
 439 }
 440
 441 #define AnnouncerFilename(snd) sprintf("announcer/%s/%s.wav", AnnouncerOption(), snd)
 442
 443 void Create_Notification_Entity_Annce(entity notif,
 444                                                                                 float var_cvar,
 445                                                                                 string namestring,
 446                                                                                 /* MSG_ANNCE */
 447                                                                                 float channel,
 448                                                                                 string snd,
 449                                                                                 float vol,
 450                                                                                 float position)
 451                 {
 452                         // Set MSG_ANNCE information and handle precaching
 453                         #ifdef CSQC
 454                         MSG typeId = MSG_ANNCE;
 455                         if (!(GENTLE && (var_cvar == 1)))
 456                         {
 457                                 if(snd != "")
 458                                 {
 459                                         if(notif.nent_enabled)
 460                                         {
 461                                                 precache_sound(AnnouncerFilename(snd));
 462                                                 notif.nent_channel = channel;
 463                                                 notif.nent_snd = strzone(snd);
 464                                                 notif.nent_vol = vol;
 465                                                 notif.nent_position = position;
 466                                         }
 467                                 }
 468                                 else
 469                                 {
 470                                         string typestring = Get_Notif_TypeName(typeId);
 471                                         LOG_INFOF(
 472                                                 (
 473                                                         "^1NOTIFICATION WITH NO SOUND: "
 474                                                         "^7net_type = %s, net_name = %s."
 475                                                 ),
 476                                                 typestring,
 477                                                 namestring
 478                                         );
 479                                         notif_error = true;
 480                                 }
 481                         }
 482                         else { notif.nent_enabled = false; }
 483                         #else
 484                         notif.nent_enabled = false;
 485                         #endif
 486
 487                 }
 488
 489 void Create_Notification_Entity_InfoCenter(entity notif,
 490                                                                                         float var_cvar,
 491                                                                                         string namestring,
 492                                                                                         int strnum,
 493                                                                                         int flnum,
 494                                                                                         /* MSG_INFO & MSG_CENTER */
 495                                                                                         string args,
 496                                                                                         string hudargs,
 497                                                                                         string icon,
 498                                                                                         CPID cpid,
 499                                                                                         string durcnt,
 500                                                                                         string normal,
 501                                                                                         string gentle)
 502                 {
 503                         MSG typeId = notif.nent_type;
 504                         // Set MSG_INFO and MSG_CENTER string/float counts
 505                         notif.nent_stringcount = strnum;
 506                         notif.nent_floatcount = flnum;
 507
 508                         // Only initialize arguments if we're either a client or on a dedicated server
 509                         #ifdef SVQC
 510                         float should_process_args = server_is_dedicated;
 511                         #else
 512                         float should_process_args = true;
 513                         #endif
 514                         string typestring = Get_Notif_TypeName(typeId);
 515                         if(should_process_args)
 516                         {
 517                                 // ========================
 518                                 //  Process Main Arguments
 519                                 // ========================
 520                                 if(strnum + flnum)
 521                                 {
 522                                         if(args != "")
 523                                         {
 524                                                 notif.nent_args = strzone(
 525                                                         Process_Notif_Args(1, args, typestring, namestring));
 526                                         }
 527                                         else if((hudargs == "") && (durcnt ==""))
 528                                         {
 529                                                 LOG_INFOF(
 530                                                         (
 531                                                                 "^1NOTIFICATION HAS ARG COUNTS BUT NO ARGS OR HUDARGS OR DURCNT: "
 532                                                                 "^7net_type = %s, net_name = %s, strnum = %d, flnum = %d"
 533                                                         ),
 534                                                         typestring,
 535                                                         namestring,
 536                                                         strnum,
 537                                                         flnum
 538                                                 );
 539                                                 notif_error = true;
 540                                         }
 541                                 }
 542                                 else if(args != "")
 543                                 {
 544                                         notif.nent_args = strzone(
 545                                                 Process_Notif_Args(1, args, typestring, namestring));
 546                                 }
 547
 548
 549                                 // =======================================
 550                                 //  Process HUD and Centerprint Arguments
 551                                 //    Only processed on CSQC, as these
 552                                 //    args are only for HUD features.
 553                                 // =======================================
 554                                 #ifdef CSQC
 555                                 if(hudargs != "")
 556                                 {
 557                                         notif.nent_hudargs = strzone(
 558                                                 Process_Notif_Args(2, hudargs, typestring, namestring));
 559
 560                                         if(icon != "") { notif.nent_icon = strzone(icon); }
 561                                         else
 562                                         {
 563                                                 LOG_INFOF(
 564                                                         (
 565                                                                 "^1NOTIFICATION HAS HUDARGS BUT NO ICON: "
 566                                                                 "^7net_type = %s, net_name = %s."
 567                                                         ),
 568                                                         typestring,
 569                                                         namestring
 570                                                 );
 571                                                 notif_error = true;
 572                                         }
 573                                 }
 574                                 else if(icon != "")
 575                                 {
 576                                         LOG_WARNF(
 577                                                 (
 578                                                         "^1NOTIFICATION HAS ICON BUT NO HUDARGS: "
 579                                                         "^7net_type = %s, net_name = %s.\n"
 580                                                 ),
 581                                                 typestring,
 582                                                 namestring
 583                                         );
 584                                         notif_error = true;
 585                                 }
 586
 587                                 if (durcnt != "")
 588                                 {
 589                                         notif.nent_durcnt = strzone(Process_Notif_Args(3, durcnt, typestring, namestring));
 590
 591                                         if (cpid == CPID_Null && durcnt != "0 0")
 592                                         {
 593                                                 LOG_WARNF(
 594                                                         (
 595                                                                 "Notification has durcnt but no cpid: "
 596                                                                 "net_type = %s, net_name = %s."
 597                                                         ),
 598                                                         typestring,
 599                                                         namestring
 600                                                 );
 601                                                 notif_error = true;
 602                                         }
 603                                 }
 604                                 notif.nent_cpid = cpid;
 605                                 #endif
 606
 607
 608                                 // ======================
 609                                 //  Process Notif String
 610                                 // ======================
 611                                 #define SET_NOTIF_STRING(string,stringname) MACRO_BEGIN \
 612                                         notif.nent_string = strzone(CCR( \
 613                                                 Process_Notif_Line( \
 614                                                         typeId, \
 615                                                         (var_cvar > 1), \
 616                                                         string, \
 617                                                         typestring, \
 618                                                         namestring, \
 619                                                         stringname \
 620                                                 )) \
 621                                         ); \
 622                                 MACRO_END
 623
 624                                 if(GENTLE)
 625                                 {
 626                                         if(gentle != "") { SET_NOTIF_STRING(gentle, "GENTLE"); }
 627                                         else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
 628                                 }
 629                                 else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
 630                                 #undef SET_NOTIF_STRING
 631
 632                                 // Check to make sure a string was chosen
 633                                 if(notif.nent_string == "")
 634                                 {
 635                                         LOG_INFOF(
 636                                                 (
 637                                                         "^1EMPTY NOTIFICATION: "
 638                                                         "^7net_type = %s, net_name = %s."
 639                                                 ),
 640                                                 typestring,
 641                                                 namestring
 642                                         );
 643                                         notif_error = true;
 644                                 }
 645                         }
 646                 }
 647
 648 void Create_Notification_Entity_Multi(entity notif,
 649                                                                                 float var_cvar,
 650                                                                                 string namestring,
 651                                                                                 /* MSG_MULTI */
 652                                                                                 Notification anncename,
 653                                                                                 Notification infoname,
 654                                                                                 Notification centername)
 655                 {
 656                         MSG typeId = MSG_MULTI;
 657                         // Set MSG_MULTI string/float counts
 658                         if (!anncename && !infoname && !centername)
 659                         {
 660                                 string typestring = Get_Notif_TypeName(typeId);
 661                                 LOG_INFOF(
 662                                         (
 663                                                 "^1NOTIFICATION WITH NO SUBCALLS: "
 664                                                 "^7net_type = %s, net_name = %s."
 665                                         ),
 666                                         typestring,
 667                                         namestring
 668                                 );
 669                                 notif_error = true;
 670                         }
 671                         else
 672                         {
 673                                 // announcements don't actually need any arguments, so lets not even count them.
 674                                 if (anncename) { notif.nent_msgannce = anncename; }
 675
 676                                 float infoname_stringcount = 0, infoname_floatcount = 0;
 677                                 float centername_stringcount = 0, centername_floatcount = 0;
 678
 679                                 if (infoname)
 680                                 {
 681                                         notif.nent_msginfo = infoname;
 682                                         infoname_stringcount = notif.nent_msginfo.nent_stringcount;
 683                                         infoname_floatcount = notif.nent_msginfo.nent_floatcount;
 684                                 }
 685
 686                                 if (centername)
 687                                 {
 688                                         notif.nent_msgcenter = centername;
 689                                         centername_stringcount = notif.nent_msgcenter.nent_stringcount;
 690                                         centername_floatcount = notif.nent_msgcenter.nent_floatcount;
 691                                 }
 692
 693                                 // set the requirements of THIS notification to the totals of its subcalls
 694                                 notif.nent_stringcount = max(infoname_stringcount, centername_stringcount);
 695                                 notif.nent_floatcount = max(infoname_floatcount, centername_floatcount);
 696                         }
 697                 }
 698
 699 void Create_Notification_Entity_Choice(entity notif,
 700                                                                                 float var_cvar,
 701                                                                                 string namestring,
 702                                                                                 /* MSG_CHOICE */
 703                                                                                 float challow_def,
 704                                                                                 float challow_var,
 705                                                                                 MSG chtype,
 706                                                                                 Notification optiona,
 707                                                                                 Notification optionb)
 708                 {
 709                         MSG typeId = MSG_CHOICE;
 710                         if (chtype == MSG_Null || !optiona || !optionb)
 711                         {
 712                                 string typestring = Get_Notif_TypeName(typeId);
 713                                 LOG_INFOF(
 714                                         (
 715                                                 "^1NOTIFICATION IS MISSING CHOICE PARAMS: "
 716                                                 "^7net_type = %s, net_name = %s."
 717                                         ),
 718                                         typestring,
 719                                         namestring
 720                                 );
 721                                 notif_error = true;
 722                         }
 723                         else
 724                         {
 725                                 notif.nent_optiona = optiona;
 726                                 notif.nent_optionb = optionb;
 727                                 notif.nent_challow_def = challow_def; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 728                                 notif.nent_challow_var = challow_var; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 729                                 notif.nent_stringcount = max(notif.nent_optiona.nent_stringcount, notif.nent_optionb.nent_stringcount);
 730                                 notif.nent_floatcount = max(notif.nent_optiona.nent_floatcount, notif.nent_optionb.nent_floatcount);
 731
 732                                 /*#ifdef NOTIFICATIONS_DEBUG
 733                                 Debug_Notification(sprintf(
 734                                         "Create_Notification_Entity(...): MSG_CHOICE: %s\n%s\n%s\n",
 735                                         notif.nent_name,
 736                                         sprintf(
 737                                                 "^ optiona: %s %s : %d %d",
 738                                                 Get_Notif_TypeName(notif.nent_optiona.nent_type),
 739                                                 notif.nent_optiona.nent_name,
 740                                                 notif.nent_optiona.nent_stringcount,
 741                                                 notif.nent_optiona.nent_floatcount
 742                                         ),
 743                                         sprintf(
 744                                                 "^ optionb: %s %s : %d %d",
 745                                                 Get_Notif_TypeName(notif.nent_optionb.nent_type),
 746                                                 notif.nent_optionb.nent_name,
 747                                                 notif.nent_optionb.nent_stringcount,
 748                                                 notif.nent_optionb.nent_floatcount
 749                                         )
 750                                 ));
 751                                 #endif*/
 752                         }
 753                 }
 754
 755
 756 // ===============
 757 //  Cvar Handling
 758 // ===============
 759
 760 // used by MSG_CHOICE to build list of choices
 761 #ifdef SVQC
 762 void Notification_GetCvars(entity this)
 763 {
 764         FOREACH(Notifications, it.nent_type == MSG_CHOICE, {
 765                 GetCvars_handleFloat(
 766                         this,
 767                         CS(this),
 768                         get_cvars_s,
 769                         get_cvars_f,
 770                         msg_choice_choices[it.nent_choice_idx],
 771                         sprintf("notification_%s", Get_Notif_CvarName(it))
 772                 );
 773         });
 774 }
 775 #endif
 776
 777 /** used to output notifications.cfg file */
 778 void Dump_Notifications(int fh, bool alsoprint)
 779 {
 780         #define NOTIF_WRITE(str) write_String_To_File(fh, str, alsoprint)
 781
 782         #define NOTIF_WRITE_ENTITY(e, description) \
 783                 NOTIF_WRITE(sprintf( \
 784                         "seta notification_%s \"%d\" \"%s\"\n", \
 785                         Get_Notif_CvarName(e), e.nent_default, description \
 786                 ))
 787
 788         #define NOTIF_WRITE_ENTITY_CHOICE(e, descriptiona, descriptionb) \
 789                 NOTIF_WRITE(sprintf( \
 790                         "seta notification_%s \"%d\" \"%s\"\n" \
 791                         "seta notification_%s_ALLOWED \"%d\" \"%s\"\n", \
 792                         Get_Notif_CvarName(e), e.nent_default, descriptiona, \
 793                         Get_Notif_CvarName(e), e.nent_challow_def, descriptionb \
 794                 ))
 795
 796         #define NOTIF_WRITE_HARDCODED(cvar, default, description) \
 797                 NOTIF_WRITE("seta notification_" cvar " \"" default "\" \"" description "\"\n")
 798
 799         // Note: This warning only applies to the notifications.cfg file that is output...
 800         // You ARE supposed to manually edit this function to add i.e. hard coded
 801         // notification variables for mutators or game modes or such and then
 802         // regenerate the notifications.cfg file from the new code.
 803
 804         NOTIF_WRITE(
 805                 "// ********************************************** //\n"
 806                 "// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n"
 807                 "// **                                          ** //\n"
 808                 "// **  This file is automatically generated    ** //\n"
 809                 "// **  by code with the command 'dumpnotifs'.  ** //\n"
 810                 "// **                                          ** //\n"
 811                 "// **  If you add a new notification, please   ** //\n"
 812                 "// **  regenerate this file with that command  ** //\n"
 813                 "// **  making sure that the output matches     ** //\n"
 814                 "// **  with the lists and defaults in code.    ** //\n"
 815                 "// **                                          ** //\n"
 816                 "// ********************************************** //\n");
 817
 818         // These notifications will also append their string as a comment...
 819         // This is not necessary, and does not matter if they vary between config versions,
 820         // it is just a semi-helpful tool for those who want to manually change their user settings.
 821
 822         int NOTIF_ANNCE_COUNT = 0; FOREACH(Notifications, it.nent_type == MSG_ANNCE, { ++NOTIF_ANNCE_COUNT; });
 823         NOTIF_WRITE(sprintf("\n// MSG_ANNCE notifications (count = %d):\n", NOTIF_ANNCE_COUNT));
 824         FOREACH(Notifications, it.nent_type == MSG_ANNCE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 825                 NOTIF_WRITE_ENTITY(it,
 826                         "0 = disabled, 1 = enabled if gentle mode is off, 2 = always enabled"
 827                 );
 828         });
 829
 830         int NOTIF_INFO_COUNT = 0; FOREACH(Notifications, it.nent_type == MSG_INFO, { ++NOTIF_INFO_COUNT; });
 831         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
 832         FOREACH(Notifications, it.nent_type == MSG_INFO && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 833                 NOTIF_WRITE_ENTITY(it,
 834                         "0 = off, 1 = print to console, "
 835                         "2 = print to console and chatbox (if notification_allow_chatboxprint is enabled)"
 836                 );
 837         });
 838
 839         int NOTIF_CENTER_COUNT = 0; FOREACH(Notifications, it.nent_type == MSG_CENTER, { ++NOTIF_CENTER_COUNT; });
 840         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
 841         FOREACH(Notifications, it.nent_type == MSG_CENTER && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 842                 NOTIF_WRITE_ENTITY(it,
 843                         "0 = off, 1 = centerprint"
 844                 );
 845         });
 846
 847         int NOTIF_MULTI_COUNT = 0; FOREACH(Notifications, it.nent_type == MSG_MULTI, { ++NOTIF_MULTI_COUNT; });
 848         NOTIF_WRITE(sprintf("\n// MSG_MULTI notifications (count = %d):\n", NOTIF_MULTI_COUNT));
 849         FOREACH(Notifications, it.nent_type == MSG_MULTI && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 850                 NOTIF_WRITE_ENTITY(it,
 851                         "Enable this multiple notification"
 852                 );
 853         });
 854
 855         int NOTIF_CHOICE_COUNT = 0; FOREACH(Notifications, it.nent_type == MSG_CHOICE, { ++NOTIF_CHOICE_COUNT; });
 856         NOTIF_WRITE(sprintf("\n// MSG_CHOICE notifications (count = %d):\n", NOTIF_CHOICE_COUNT));
 857         FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 858                 NOTIF_WRITE_ENTITY_CHOICE(it,
 859                         "Choice for this notification 0 = off, 1 = default message, 2 = verbose message",
 860                         "Allow choice for this notification 0 = off, 1 = only in warmup mode, 2 = always"
 861                 );
 862         });
 863
 864         // edit these to match whichever cvars are used for specific notification options
 865         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
 866
 867         NOTIF_WRITE_HARDCODED(
 868                 "allow_chatboxprint", "1",
 869                 "Allow INFO notifications to be printed to chat box "
 870                 "0 = do not allow, "
 871                 "1 = allow only if allowed by individual notification_INFO* cvars, "
 872                 "2 = force all INFO notifications to be printed to the chatbox"
 873         );
 874
 875         NOTIF_WRITE_HARDCODED(
 876                 "debug", "0",
 877                 "Print extra debug information on all notification function calls "
 878                 "(Requires -DNOTIFICATIONS_DEBUG flag to be enabled on QCSRC compilation)... "
 879                 "0 = disabled, 1 = dprint, 2 = print"
 880         );
 881
 882         NOTIF_WRITE_HARDCODED(
 883                 "errors_are_fatal", "1",
 884                 "If a notification fails upon initialization, cause a Host_Error to stop the program"
 885         );
 886
 887         NOTIF_WRITE_HARDCODED(
 888                 "item_centerprinttime", "1.5",
 889                 "How long to show item information centerprint messages (like 'You got the Electro' or such)"
 890         );
 891
 892         NOTIF_WRITE_HARDCODED(
 893                 "lifetime_mapload", "10",
 894                 "Amount of time that notification entities last immediately at mapload (in seconds) "
 895                 "to help prevent notifications from being lost on early init (like gamestart countdown)"
 896         );
 897
 898         NOTIF_WRITE_HARDCODED(
 899                 "lifetime_runtime", "0.5",
 900                 "Amount of time that notification entities last on the server during runtime (In seconds)"
 901         );
 902
 903         NOTIF_WRITE_HARDCODED(
 904                 "server_allows_location", "1",
 905                 "Server side cvar for allowing death messages to show location information too"
 906         );
 907
 908         NOTIF_WRITE_HARDCODED(
 909                 "show_location", "0",
 910                 "Append location information to MSG_INFO death/kill messages"
 911         );
 912
 913         NOTIF_WRITE_HARDCODED(
 914                 "show_location_string", "",
 915                 "Replacement string piped into sprintf, "
 916                 "so you can do different messages like this: ' at the %s' or ' (near %s)'"
 917         );
 918
 919         NOTIF_WRITE_HARDCODED(
 920                 "show_sprees", "1",
 921                 "Print information about sprees in death/kill messages"
 922         );
 923
 924         NOTIF_WRITE_HARDCODED(
 925                 "show_sprees_center", "1",
 926                 "Show spree information in MSG_CENTER messages... "
 927                 "0 = off, 1 = target (but only for first victim) and attacker"
 928         );
 929
 930         NOTIF_WRITE_HARDCODED(
 931                 "show_sprees_center_specialonly", "1",
 932                 "Don't show spree information in MSG_CENTER messages if it isn't an achievement"
 933         );
 934
 935         NOTIF_WRITE_HARDCODED(
 936                 "show_sprees_info", "3",
 937                 "Show spree information in MSG_INFO messages... "
 938                 "0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker"
 939         );
 940
 941         NOTIF_WRITE_HARDCODED(
 942                 "show_sprees_info_newline", "1",
 943                 "Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself"
 944         );
 945
 946         NOTIF_WRITE_HARDCODED(
 947                 "show_sprees_info_specialonly", "1",
 948                 "Don't show attacker spree information in MSG_INFO messages if it isn't an achievement"
 949         );
 950
 951         NOTIF_WRITE(sprintf(
 952                 (
 953                         "\n// Notification counts (total = %d): "
 954                         "MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n"
 955                 ),
 956                 (
 957                         NOTIF_ANNCE_COUNT +
 958                         NOTIF_INFO_COUNT +
 959                         NOTIF_CENTER_COUNT +
 960                         NOTIF_MULTI_COUNT +
 961                         NOTIF_CHOICE_COUNT
 962                 ),
 963                 NOTIF_ANNCE_COUNT,
 964                 NOTIF_INFO_COUNT,
 965                 NOTIF_CENTER_COUNT,
 966                 NOTIF_MULTI_COUNT,
 967                 NOTIF_CHOICE_COUNT
 968         ));
 969         #undef NOTIF_WRITE_HARDCODED
 970         #undef NOTIF_WRITE_ENTITY
 971         #undef NOTIF_WRITE
 972 }
 973
 974
 975 // ===============================
 976 //  Frontend Notification Pushing
 977 // ===============================
 978
 979 string Local_Notification_sprintf(
 980         string input, string args,
 981         string s1, string s2, string s3, string s4,
 982         int f1, float f2, float f3, float f4)
 983 {
 984         #ifdef NOTIFICATIONS_DEBUG
 985         Debug_Notification(sprintf(
 986                 "Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
 987                 MakeConsoleSafe(input),
 988                 args,
 989                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
 990                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
 991         ));
 992         #endif
 993
 994         for (int sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
 995
 996         for (int sel_num = 0; (args != ""); )
 997         {
 998                 string selected = car(args); args = cdr(args);
 999                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf");
1000                 string tmp_s; // used by NOTIF_ARGUMENT_LIST
1001                 switch (strtolower(selected))
1002                 {
1003                         #define ARG_CASE_ARG_CS_SV_HA(selected, result) case selected: arg_slot[sel_num++] = result; break;
1004                         #define ARG_CASE_ARG_CS_SV_DC(selected, result) case selected: arg_slot[sel_num++] = result; break;
1005                         #define ARG_CASE_ARG_CS_SV(selected, result)    case selected: arg_slot[sel_num++] = result; break;
1006 #ifdef CSQC
1007                         #define ARG_CASE_ARG_CS(selected, result)       case selected: arg_slot[sel_num++] = result; break;
1008                         #define ARG_CASE_ARG_SV(selected, result)
1009 #else
1010                         #define ARG_CASE_ARG_CS(selected, result)
1011                         #define ARG_CASE_ARG_SV(selected, result)       case selected: arg_slot[sel_num++] = result; break;
1012 #endif
1013                         #define ARG_CASE_ARG_DC(selected, result)
1014                         #define ARG_CASE(prog, selected, result)        ARG_CASE_##prog(selected, result)
1015                         NOTIF_ARGUMENT_LIST
1016                         #undef ARG_CASE
1017                         #undef ARG_CASE_ARG_DC
1018                         #undef ARG_CASE_ARG_SV
1019                         #undef ARG_CASE_ARG_CS
1020                         #undef ARG_CASE_ARG_CS_SV
1021                         #undef ARG_CASE_ARG_CS_SV_DC
1022                         #undef ARG_CASE_ARG_CS_SV_HA
1023                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1024                 }
1025         }
1026         return sprintf(
1027                 strcat(input, "\n"),
1028                 arg_slot[0],
1029                 arg_slot[1],
1030                 arg_slot[2],
1031                 arg_slot[3],
1032                 arg_slot[4],
1033                 arg_slot[5],
1034                 arg_slot[6]
1035         );
1036 }
1037
1038 #ifdef CSQC
1039 void Local_Notification_sound(int soundchannel, string soundfile, float soundvolume, float soundposition)
1040 {
1041         if ((soundfile != prev_soundfile) || (time >= (prev_soundtime + autocvar_cl_announcer_antispam)))
1042         {
1043                 #ifdef NOTIFICATIONS_DEBUG
1044                 Debug_Notification(sprintf(
1045                         "Local_Notification_sound(%f, '%s', %f, %f);\n",
1046                         soundchannel,
1047                         AnnouncerFilename(soundfile),
1048                         soundvolume,
1049                         soundposition
1050                 ));
1051                 #endif
1052
1053                 _sound(NULL, soundchannel, AnnouncerFilename(soundfile), soundvolume, soundposition);
1054
1055                 strcpy(prev_soundfile, soundfile);
1056                 prev_soundtime = time;
1057         }
1058         else
1059         {
1060                 #ifdef NOTIFICATIONS_DEBUG
1061                 Debug_Notification(sprintf(
1062                         (
1063                                 "Local_Notification_sound(%f, '%s', %f, %f) "
1064                                 "^1BLOCKED BY ANTISPAM:^7 prevsnd: '%s', timediff: %f, limit: %f\n"
1065                         ),
1066                         soundchannel,
1067                         AnnouncerFilename(soundfile),
1068                         soundvolume,
1069                         soundposition,
1070                         prev_soundfile,
1071                         (time - prev_soundtime),
1072                         autocvar_cl_announcer_antispam
1073                 ));
1074                 #endif
1075         }
1076 }
1077
1078 void Local_Notification_HUD_Notify_Push(
1079         string icon, string hudargs,
1080         string s1, string s2, string s3, string s4,
1081         float f1, float f2, float f3, float f4)
1082 {
1083         arg_slot[0] = ""; arg_slot[1] = "";
1084
1085         for (int sel_num = 0; (hudargs != ""); )
1086         {
1087                 string selected = car(hudargs); hudargs = cdr(hudargs);
1088                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push");
1089                 switch (strtolower(selected))
1090                 {
1091                         #define ARG_CASE_ARG_CS_SV_HA(selected, result) case selected: arg_slot[sel_num++] = result; break;
1092                         #define ARG_CASE_ARG_CS_SV_DC(selected, result)
1093                         #define ARG_CASE_ARG_CS_SV(selected, result)
1094                         #define ARG_CASE_ARG_CS(selected, result)
1095                         #define ARG_CASE_ARG_SV(selected, result)
1096                         #define ARG_CASE_ARG_DC(selected, result)
1097                         #define ARG_CASE(prog, selected, result)        ARG_CASE_##prog(selected, result)
1098                         NOTIF_ARGUMENT_LIST
1099                         #undef ARG_CASE
1100                         #undef ARG_CASE_ARG_DC
1101                         #undef ARG_CASE_ARG_SV
1102                         #undef ARG_CASE_ARG_CS
1103                         #undef ARG_CASE_ARG_CS_SV
1104                         #undef ARG_CASE_ARG_CS_SV_DC
1105                         #undef ARG_CASE_ARG_CS_SV_HA
1106                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1107                 }
1108         }
1109         #ifdef NOTIFICATIONS_DEBUG
1110         Debug_Notification(sprintf(
1111                 "Local_Notification_HUD_Notify_Push('%s^7', '%s', %s, %s, %s);\n",
1112                 icon,
1113                 hudargs,
1114                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1115                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4),
1116                 MakeConsoleSafe(sprintf("'%s^7', '%s^7'", stof(arg_slot[0]), stof(arg_slot[1])))
1117         ));
1118         #endif
1119         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
1120 }
1121
1122 void Local_Notification_centerprint_generic(
1123         string input, string durcnt,
1124         CPID cpid, float f1, float f2)
1125 {
1126         arg_slot[0] = ""; arg_slot[1] = "";
1127
1128         for (int sel_num = 0; (durcnt != ""); )
1129         {
1130                 string selected = car(durcnt); durcnt = cdr(durcnt);
1131                 NOTIF_HIT_MAX(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic");
1132                 switch (strtolower(selected))
1133                 {
1134                         #define ARG_CASE_ARG_CS_SV_HA(selected, result)
1135                         #define ARG_CASE_ARG_CS_SV_DC(selected, result) case selected: arg_slot[sel_num++] = result; break;
1136                         #define ARG_CASE_ARG_CS_SV(selected, result)
1137                         #define ARG_CASE_ARG_CS(selected, result)
1138                         #define ARG_CASE_ARG_SV(selected, result)
1139                         #define ARG_CASE_ARG_DC(selected, result)       case selected: arg_slot[sel_num++] = result; break;
1140                         #define ARG_CASE(prog, selected, result)        ARG_CASE_##prog(selected,result)
1141                         NOTIF_ARGUMENT_LIST
1142                         #undef ARG_CASE
1143                         #undef ARG_CASE_ARG_DC
1144                         #undef ARG_CASE_ARG_SV
1145                         #undef ARG_CASE_ARG_CS
1146                         #undef ARG_CASE_ARG_CS_SV
1147                         #undef ARG_CASE_ARG_CS_SV_DC
1148                         #undef ARG_CASE_ARG_CS_SV_HA
1149                         default:
1150                         {
1151                                 if (/* wtf */ ftos(stof(selected)) != "") { arg_slot[sel_num++] = selected; }
1152                                 else { NOTIF_HIT_UNKNOWN(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic") }
1153                                 break;
1154                         }
1155                 }
1156         }
1157         #ifdef NOTIFICATIONS_DEBUG
1158         Debug_Notification(sprintf(
1159                 "Local_Notification_centerprint_generic('%s^7', '%s', %d, %d, %d, %d);\n",
1160                 MakeConsoleSafe(input),
1161                 durcnt,
1162                 f1, f2,
1163                 stof(arg_slot[0]),
1164                 stof(arg_slot[1])
1165         ));
1166         #endif
1167         centerprint_generic(ORDINAL(cpid), input, stof(arg_slot[0]), stof(arg_slot[1]));
1168 }
1169 #endif
1170
1171 void Local_Notification(MSG net_type, Notification net_name, ...count)
1172 {
1173         // retreive entity of this notification
1174         entity notif = net_name;
1175         if (!notif)
1176         {
1177                 #ifdef NOTIFICATIONS_DEBUG
1178                 Debug_Notification(sprintf(
1179                         "Local_Notification(%s, NULL, ...);\n",
1180                         Get_Notif_TypeName(net_type)
1181                 ));
1182                 #endif
1183                 LOG_WARNF("Incorrect usage of Local_Notification: %s", "Null notification");
1184                 return;
1185         }
1186
1187         // check if the notification is enabled
1188         if (!notif.nent_enabled)
1189         {
1190                 #ifdef NOTIFICATIONS_DEBUG
1191                 Debug_Notification(sprintf(
1192                         "Local_Notification(%s, %s, ...): Entity was disabled...\n",
1193                         Get_Notif_TypeName(net_type),
1194                         notif.nent_name
1195                 ));
1196                 #endif
1197                 return;
1198         }
1199
1200         string s1 = CCR((notif.nent_stringcount > 0) ? ...(0, string) : "");
1201         string s2 = CCR((notif.nent_stringcount > 1) ? ...(1, string) : "");
1202         string s3 = CCR((notif.nent_stringcount > 2) ? ...(2, string) : "");
1203         string s4 = CCR((notif.nent_stringcount > 3) ? ...(3, string) : "");
1204         float f1 =  ((notif.nent_floatcount  > 0) ? ...((notif.nent_stringcount + 0), float) : 0);
1205         float f2 =  ((notif.nent_floatcount  > 1) ? ...((notif.nent_stringcount + 1), float) : 0);
1206         float f3 =  ((notif.nent_floatcount  > 2) ? ...((notif.nent_stringcount + 2), float) : 0);
1207         float f4 =  ((notif.nent_floatcount  > 3) ? ...((notif.nent_stringcount + 3), float) : 0);
1208
1209         #ifdef NOTIFICATIONS_DEBUG
1210         Debug_Notification(sprintf(
1211                 "Local_Notification(%s, %s, %s, %s);\n",
1212                 Get_Notif_TypeName(net_type),
1213                 notif.nent_name,
1214                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1215                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1216         ));
1217         #endif
1218
1219         if ((notif.nent_stringcount + notif.nent_floatcount) != count)
1220         {
1221                 backtrace(sprintf(
1222                         (
1223                                 "Arguments mismatch for Local_Notification(%s, %s, ...)! "
1224                                 "stringcount(%d) + floatcount(%d) != count(%d)\n"
1225                                 "Check the definition and function call for accuracy...?\n"
1226                         ),
1227                         Get_Notif_TypeName(net_type),
1228                         notif.nent_name,
1229                         notif.nent_stringcount,
1230                         notif.nent_floatcount,
1231                         count
1232                 ));
1233                 return;
1234         }
1235
1236         switch (net_type)
1237         {
1238                 case MSG_ANNCE:
1239                 {
1240                         #ifdef CSQC
1241                         Local_Notification_sound(notif.nent_channel, notif.nent_snd, notif.nent_vol, notif.nent_position);
1242                         #else
1243                         backtrace("MSG_ANNCE on server?... Please notify Samual immediately!\n");
1244                         #endif
1245                         break;
1246                 }
1247
1248                 case MSG_INFO:
1249                 {
1250                         print(
1251                                 Local_Notification_sprintf(
1252                                         notif.nent_string,
1253                                         notif.nent_args,
1254                                         s1, s2, s3, s4,
1255                                         f1, f2, f3, f4)
1256                         );
1257                         #ifdef CSQC
1258                         if (notif.nent_icon != "")
1259                         {
1260                                 if (notif.nent_iconargs != "")
1261                                 {
1262                                         string s = Local_Notification_sprintf(
1263                                                 notif.nent_icon,notif.nent_iconargs,
1264                                                 s1, s2, s3, s4, f1, f2, f3, f4);
1265                                         // remove the trailing newline
1266                                         notif.nent_icon = strzone(substring(s, 0, -1));
1267                                 }
1268                                 Local_Notification_HUD_Notify_Push(
1269                                         notif.nent_icon,
1270                                         notif.nent_hudargs,
1271                                         s1, s2, s3, s4,
1272                                         f1, f2, f3, f4);
1273                         }
1274                         #endif
1275                         break;
1276                 }
1277
1278                 #ifdef CSQC
1279                 case MSG_CENTER:
1280                 {
1281                         Local_Notification_centerprint_generic(
1282                                 Local_Notification_sprintf(
1283                                         notif.nent_string,
1284                                         notif.nent_args,
1285                                         s1, s2, s3, s4,
1286                                         f1, f2, f3, f4),
1287                                 notif.nent_durcnt,
1288                                 notif.nent_cpid,
1289                                 f1, f2);
1290                         break;
1291                 }
1292                 #endif
1293
1294                 case MSG_MULTI:
1295                 {
1296                         if (notif.nent_msginfo && notif.nent_msginfo.nent_enabled)
1297                         {
1298                                 Local_Notification_WOVA(
1299                                         MSG_INFO,
1300                                         notif.nent_msginfo,
1301                                         notif.nent_msginfo.nent_stringcount,
1302                                         notif.nent_msginfo.nent_floatcount,
1303                                         s1, s2, s3, s4,
1304                                         f1, f2, f3, f4);
1305                         }
1306                         #ifdef CSQC
1307                         if (notif.nent_msgannce && notif.nent_msgannce.nent_enabled)
1308                         {
1309                                 Local_Notification_WOVA(
1310                                         MSG_ANNCE,
1311                                         notif.nent_msgannce,
1312                                         0, 0,
1313                                         "", "", "", "",
1314                                         0, 0, 0, 0);
1315                         }
1316                         if (notif.nent_msgcenter && notif.nent_msgcenter.nent_enabled)
1317                         {
1318                                 Local_Notification_WOVA(
1319                                         MSG_CENTER,
1320                                         notif.nent_msgcenter,
1321                                         notif.nent_msgcenter.nent_stringcount,
1322                                         notif.nent_msgcenter.nent_floatcount,
1323                                         s1, s2, s3, s4,
1324                                         f1, f2, f3, f4);
1325                         }
1326                         #endif
1327                         break;
1328                 }
1329
1330                 case MSG_CHOICE:
1331                 {
1332                         entity found_choice = notif.nent_optiona;
1333                         if (notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) {
1334                                 switch (cvar(sprintf("notification_%s", Get_Notif_CvarName(notif))))
1335                                 {
1336                                         case 1: break;
1337                                         case 2: found_choice = notif.nent_optionb; break;
1338                                         default: return; // not enabled anyway
1339                                 }
1340                         }
1341
1342                         Local_Notification_WOVA(
1343                                 found_choice.nent_type,
1344                                 found_choice,
1345                                 found_choice.nent_stringcount,
1346                                 found_choice.nent_floatcount,
1347                                 s1, s2, s3, s4,
1348                                 f1, f2, f3, f4);
1349                 }
1350         }
1351 }
1352
1353 // WOVA = Without Variable Arguments
1354 void Local_Notification_WOVA(
1355         MSG net_type, Notification net_name,
1356         float stringcount, float floatcount,
1357         string s1, string s2, string s3, string s4,
1358         float f1, float f2, float f3, float f4)
1359 {
1360         #define VARITEM(stringc, floatc, args) \
1361                 if ((stringcount == stringc) && (floatcount == floatc)) \
1362                 { Local_Notification(net_type, net_name, args); return; }
1363         EIGHT_VARS_TO_VARARGS_VARLIST
1364         #undef VARITEM
1365         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
1366 }
1367
1368
1369 // =========================
1370 //  Notification Networking
1371 // =========================
1372
1373 /** networked as a linked entity to give newly connecting clients some notification context */
1374 REGISTER_NET_LINKED(ENT_CLIENT_NOTIFICATION)
1375
1376 #ifdef CSQC
1377 NET_HANDLE(ENT_CLIENT_NOTIFICATION, bool is_new)
1378 {
1379         make_pure(this);
1380         MSG net_type = ENUMCAST(MSG, ReadByte());
1381         int net_name = ReadShort();
1382     return = true;
1383
1384         if (net_type == MSG_CENTER_KILL)
1385     {
1386         if (!is_new) return;
1387         // killing
1388         #ifdef NOTIFICATIONS_DEBUG
1389         Debug_Notification(sprintf(
1390             "Read_Notification(%d) at %f: net_type = %s, cpid = %d\n",
1391             is_new,
1392             time,
1393             Get_Notif_TypeName(net_type),
1394             net_name
1395         ));
1396         #endif
1397         int _net_name = net_name;
1398         CPID net_name = ENUMCAST(CPID, _net_name);
1399         if (net_name == CPID_Null) {
1400             // kill all
1401             reset_centerprint_messages();
1402         } else {
1403             // kill group
1404             centerprint_generic(ORDINAL(net_name), "", 0, 0);
1405         }
1406         return;
1407     }
1408
1409         Notification notif = Get_Notif_Ent(net_type, net_name);
1410
1411         #ifdef NOTIFICATIONS_DEBUG
1412         Debug_Notification(sprintf(
1413                 "Read_Notification(%d) at %f: net_type = %s, net_name = %s (%d)\n",
1414                 is_new,
1415                 time,
1416                 Get_Notif_TypeName(net_type),
1417                 notif.registered_id,
1418                 net_name
1419         ));
1420         #endif
1421
1422     if (!notif) {
1423         backtrace("Read_Notification: Could not find notification entity!\n");
1424         return false;
1425     }
1426
1427     string s1 = ((notif.nent_stringcount > 0) ? ReadString() : "");
1428     string s2 = ((notif.nent_stringcount > 1) ? ReadString() : "");
1429     string s3 = ((notif.nent_stringcount > 2) ? ReadString() : "");
1430     string s4 = ((notif.nent_stringcount > 3) ? ReadString() : "");
1431     float f1 = ((notif.nent_floatcount > 0) ? ReadLong() : 0);
1432     float f2 = ((notif.nent_floatcount > 1) ? ReadLong() : 0);
1433     float f3 = ((notif.nent_floatcount > 2) ? ReadLong() : 0);
1434     float f4 = ((notif.nent_floatcount > 3) ? ReadLong() : 0);
1435
1436     if (!is_new) return;
1437     Local_Notification_WOVA(
1438         net_type, notif,
1439         notif.nent_stringcount,
1440         notif.nent_floatcount,
1441         s1, s2, s3, s4,
1442         f1, f2, f3, f4);
1443 }
1444 #endif
1445
1446 #ifdef SVQC
1447 void Net_Notification_Remove(entity this)
1448 {
1449         #ifdef NOTIFICATIONS_DEBUG
1450         Debug_Notification(sprintf(
1451                 "Net_Notification_Remove() at %f: %s '%s - %s' notification\n",
1452                 time,
1453                 ((this.nent_net_name == -1) ? "Killed" : "Removed"),
1454                 Get_Notif_TypeName(this.nent_net_type),
1455                 this.owner.nent_name
1456         ));
1457         #endif
1458         for (int i = 0; i < this.nent_stringcount; ++i) { strfree(this.nent_strings[i]); }
1459         delete(this);
1460 }
1461
1462 bool Net_Write_Notification(entity this, entity client, int sf)
1463 {
1464         if (!Notification_ShouldSend(this.nent_broadcast, client, this.nent_client)) return false;
1465         WriteHeader(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
1466         WriteByte(MSG_ENTITY, ORDINAL(this.nent_net_type));
1467         WriteShort(MSG_ENTITY, this.nent_net_name);
1468         for (int i = 0; i < this.nent_stringcount; ++i) { WriteString(MSG_ENTITY, this.nent_strings[i]); }
1469         for (int i = 0; i < this.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, this.nent_floats[i]); }
1470         return true;
1471 }
1472
1473 void Kill_Notification(
1474         NOTIF broadcast, entity client,
1475         /** message group, MSG_Null for all */
1476         MSG net_type,
1477         /** cpid group, CPID_Null for all */
1478         CPID net_cpid)
1479 {
1480         #ifdef NOTIFICATIONS_DEBUG
1481         Debug_Notification(sprintf(
1482                 "Kill_Notification(%s, '%s', %s, %d);\n",
1483                 Get_Notif_BroadcastName(broadcast),
1484                 client.netname,
1485                 (net_type ? Get_Notif_TypeName(net_type) : "0"),
1486                 net_cpid
1487         ));
1488         #endif
1489
1490         string checkargs = Notification_CheckArgs(broadcast, client);
1491         if (checkargs != "") { LOG_WARNF("Incorrect usage of Kill_Notification: %s", checkargs); return; }
1492
1493         entity net_notif = new_pure(net_kill_notification);
1494         net_notif.nent_broadcast = broadcast;
1495         net_notif.nent_client = client;
1496         net_notif.nent_net_type = MSG_CENTER_KILL;
1497         net_notif.nent_net_name = ORDINAL(net_cpid);
1498         Net_LinkEntity(net_notif, false, autocvar_notification_lifetime_runtime, Net_Write_Notification);
1499
1500         IL_EACH(g_notifications,
1501                 (it.owner.nent_type == net_type || net_type == MSG_Null) && (it.owner.nent_cpid == net_cpid || net_cpid == CPID_Null),
1502                 {
1503                         it.nent_net_name = -1;
1504                         it.nextthink = time;
1505                 }
1506         );
1507 }
1508
1509 void Send_Notification(
1510         NOTIF broadcast, entity client,
1511         MSG net_type, Notification net_name,
1512         ...count)
1513 {
1514     if (broadcast != NOTIF_ALL && broadcast != NOTIF_ALL_EXCEPT && !IS_REAL_CLIENT(client)) return;
1515         entity notif = net_name;
1516         string parms = sprintf("%s, '%s', %s, %s",
1517                 Get_Notif_BroadcastName(broadcast),
1518                 client.classname,
1519                 Get_Notif_TypeName(net_type),
1520                 net_name.registered_id
1521         );
1522         #ifdef NOTIFICATIONS_DEBUG
1523         Debug_Notification(sprintf("Send_Notification(%s, ...%d);\n", parms, count));
1524         #endif
1525
1526         if (!notif)
1527         {
1528                 LOG_WARN("Send_Notification: Could not find notification entity!");
1529                 return;
1530         }
1531
1532         // check supplied broadcast, target, type, and name for errors
1533         string checkargs = Notification_CheckArgs(broadcast, client);
1534     if (!net_name) { checkargs = sprintf("No notification provided! %s", checkargs); }
1535         if (checkargs != "")
1536         {
1537                 LOG_WARNF("Incorrect usage of Send_Notification: %s", checkargs);
1538                 return;
1539         }
1540
1541         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1542         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1543         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1544         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1545         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1546         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1547         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1548         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1549
1550         #ifdef NOTIFICATIONS_DEBUG
1551         Debug_Notification(sprintf(
1552                 "Send_Notification(%s, %s, %s);\n",
1553                 parms,
1554                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1555                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1556         ));
1557         #endif
1558
1559         if ((notif.nent_stringcount + notif.nent_floatcount) != count)
1560         {
1561                 LOG_WARNF(
1562                         "Argument mismatch for Send_Notification(%s, ...)! "
1563                         "stringcount(%d) + floatcount(%d) != count(%d)\n"
1564                         "Check the definition and function call for accuracy...?\n",
1565                         parms,
1566                         notif.nent_stringcount,
1567                         notif.nent_floatcount,
1568                         count
1569                 );
1570                 return;
1571         }
1572
1573         if (server_is_dedicated
1574                 && (broadcast == NOTIF_ALL || broadcast == NOTIF_ALL_EXCEPT)
1575                 && !(net_type == MSG_ANNCE || net_type == MSG_CENTER)
1576         )
1577         {
1578                 Local_Notification_WOVA(
1579                         net_type, net_name,
1580                         notif.nent_stringcount,
1581                         notif.nent_floatcount,
1582                         s1, s2, s3, s4,
1583                         f1, f2, f3, f4);
1584         }
1585
1586         if (net_type == MSG_CHOICE)
1587         {
1588                 // THIS GETS TRICKY... now we have to cycle through each possible player (checking broadcast)
1589                 // and then do an individual NOTIF_ONE_ONLY recursive call for each one depending on their option...
1590                 // It's slow, but it's better than the alternatives:
1591                 //   1. Constantly networking all info and letting client decide
1592                 //   2. Manually handling each separate call on per-usage basis (See old CTF usage of verbose)
1593                 entity found_choice;
1594
1595                 #define RECURSE_FROM_CHOICE(ent,action) MACRO_BEGIN \
1596                         if (notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) { \
1597                                 switch (CS(ent).msg_choice_choices[net_name.nent_choice_idx]) \
1598                                 { \
1599                                         case 1: found_choice = notif.nent_optiona; break; \
1600                                         case 2: found_choice = notif.nent_optionb; break; \
1601                                         default: action; \
1602                                 } \
1603                         } else { \
1604                                 found_choice = notif.nent_optiona; \
1605                         } \
1606                         Send_Notification_WOVA( \
1607                                 NOTIF_ONE_ONLY, \
1608                                 ent, \
1609                                 found_choice.nent_type, \
1610                                 found_choice, \
1611                                 found_choice.nent_stringcount, \
1612                                 found_choice.nent_floatcount, \
1613                                 s1, s2, s3, s4, \
1614                                 f1, f2, f3, f4); \
1615                 MACRO_END
1616
1617                 switch (broadcast)
1618                 {
1619                         case NOTIF_ONE_ONLY: // we can potentially save processing power with this broadcast method
1620                         {
1621                                 if (IS_REAL_CLIENT(client)) {
1622                                         RECURSE_FROM_CHOICE(client, return);
1623                                 }
1624                                 break;
1625                         }
1626                         default:
1627                         {
1628                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && Notification_ShouldSend(broadcast, it, client), {
1629                                         RECURSE_FROM_CHOICE(it, continue);
1630                                 });
1631                                 break;
1632                         }
1633                 }
1634         }
1635         else
1636         {
1637                 entity net_notif = new_pure(net_notification);
1638                 IL_PUSH(g_notifications, net_notif);
1639                 net_notif.owner = notif;
1640                 net_notif.nent_broadcast = broadcast;
1641                 net_notif.nent_client = client;
1642                 net_notif.nent_net_type = net_type;
1643                 net_notif.nent_net_name = notif.m_id;
1644                 net_notif.nent_stringcount = notif.nent_stringcount;
1645                 net_notif.nent_floatcount = notif.nent_floatcount;
1646
1647                 for (int i = 0; i < net_notif.nent_stringcount; ++i) {
1648                         net_notif.nent_strings[i] = strzone(...(i, string));
1649                 }
1650                 for (int i = 0; i < net_notif.nent_floatcount; ++i) {
1651                         net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float);
1652                 }
1653
1654                 setthink(net_notif, Net_Notification_Remove);
1655                 net_notif.nextthink = (time > autocvar_notification_lifetime_mapload)
1656                         ? (time + autocvar_notification_lifetime_runtime)
1657                         : autocvar_notification_lifetime_mapload;
1658
1659                 Net_LinkEntity(net_notif, false, 0, Net_Write_Notification);
1660         }
1661 }
1662
1663 // WOVA = Without Variable Arguments
1664 void Send_Notification_WOVA(
1665         NOTIF broadcast, entity client,
1666         MSG net_type, Notification net_name,
1667         float stringcount, float floatcount,
1668         string s1, string s2, string s3, string s4,
1669         float f1, float f2, float f3, float f4)
1670 {
1671         #ifdef NOTIFICATIONS_DEBUG
1672         entity notif = net_name;
1673         Debug_Notification(sprintf(
1674                 "Send_Notification_WOVA(%s, %d, %d, %s, %s);\n",
1675                 sprintf(
1676                         "%s, '%s', %s, %s",
1677                         Get_Notif_BroadcastName(broadcast),
1678                         client.classname,
1679                         Get_Notif_TypeName(net_type),
1680                         notif.nent_name
1681                 ),
1682                 stringcount,
1683                 floatcount,
1684                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1685                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1686         ));
1687         #endif
1688
1689         #define VARITEM(stringc, floatc, args) \
1690                 if ((stringcount == stringc) && (floatcount == floatc)) \
1691                 { Send_Notification(broadcast, client, net_type, net_name, args); return; }
1692         EIGHT_VARS_TO_VARARGS_VARLIST
1693         #undef VARITEM
1694         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
1695 }
1696
1697 // WOCOVA = Without Counts Or Variable Arguments
1698 void Send_Notification_WOCOVA(
1699         NOTIF broadcast, entity client,
1700         MSG net_type, Notification net_name,
1701         string s1, string s2, string s3, string s4,
1702         float f1, float f2, float f3, float f4)
1703 {
1704         entity notif = net_name;
1705
1706         #ifdef NOTIFICATIONS_DEBUG
1707         Debug_Notification(sprintf(
1708                 "Send_Notification_WOCOVA(%s, %s, %s);\n",
1709                 sprintf(
1710                         "%s, '%s', %s, %s",
1711                         Get_Notif_BroadcastName(broadcast),
1712                         client.classname,
1713                         Get_Notif_TypeName(net_type),
1714                         notif.nent_name
1715                 ),
1716                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1717                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1718         ));
1719         #endif
1720
1721         #define VARITEM(stringc, floatc, args) \
1722                 if ((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
1723                 { Send_Notification(broadcast, client, net_type, net_name, args); return; }
1724         EIGHT_VARS_TO_VARARGS_VARLIST
1725         #undef VARITEM
1726         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
1727 }
1728 #endif // ifdef SVQC