qcsrc/common/notifications/all.qh

   1 #ifndef NOTIFICATIONS_H
   2 #define NOTIFICATIONS_H
   3
   4 #include <common/command/all.qh>
   5
   6 #include <common/constants.qh>
   7 #include <common/teams.qh>
   8 #include <common/util.qh>
   9
  10 /** main types/groups of notifications */
  11 ENUMCLASS(MSG)
  12         /** "Global" AND "personal" announcer messages */
  13         CASE(MSG, ANNCE)
  14         /** "Global" information messages */
  15         CASE(MSG, INFO)
  16         /** "Personal" centerprint messages */
  17         CASE(MSG, CENTER)
  18         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  19         CASE(MSG, MULTI)
  20         /** Choose which subcall wrapper to activate */
  21         CASE(MSG, CHOICE)
  22         /** Kill centerprint message @deprecated */
  23         CASE(MSG, CENTER_KILL)
  24 ENUMCLASS_END(MSG)
  25
  26 string Get_Notif_TypeName(MSG net_type)
  27 {
  28         switch (net_type)
  29         {
  30                 case MSG_ANNCE: return "MSG_ANNCE";
  31                 case MSG_INFO: return "MSG_INFO";
  32                 case MSG_CENTER: return "MSG_CENTER";
  33                 case MSG_MULTI: return "MSG_MULTI";
  34                 case MSG_CHOICE: return "MSG_CHOICE";
  35         }
  36         LOG_WARNINGF("Get_Notif_TypeName(%d): Improper net type!\n", ORDINAL(net_type));
  37         return "";
  38 }
  39
  40 ENUMCLASS(CPID)
  41         CASE(CPID, ASSAULT_ROLE)
  42         CASE(CPID, ROUND)
  43         CASE(CPID, CAMPCHECK)
  44         CASE(CPID, CTF_CAPSHIELD)
  45         CASE(CPID, CTF_LOWPRIO)
  46         CASE(CPID, CTF_PASS)
  47         CASE(CPID, STALEMATE)
  48         CASE(CPID, NADES)
  49         CASE(CPID, IDLING)
  50         CASE(CPID, ITEM)
  51         CASE(CPID, PREVENT_JOIN)
  52         CASE(CPID, KEEPAWAY)
  53         CASE(CPID, KEEPAWAY_WARN)
  54         CASE(CPID, KEYHUNT)
  55         CASE(CPID, KEYHUNT_OTHER)
  56         CASE(CPID, LMS)
  57         CASE(CPID, MISSING_TEAMS)
  58         CASE(CPID, MISSING_PLAYERS)
  59         CASE(CPID, INSTAGIB_FINDAMMO)
  60         CASE(CPID, MOTD)
  61         CASE(CPID, NIX)
  62         CASE(CPID, ONSLAUGHT)
  63         CASE(CPID, ONS_CAPSHIELD)
  64         CASE(CPID, OVERTIME)
  65         CASE(CPID, POWERUP)
  66         CASE(CPID, RACE_FINISHLAP)
  67         CASE(CPID, TEAMCHANGE)
  68         CASE(CPID, TIMEOUT)
  69         CASE(CPID, VEHICLES)
  70         CASE(CPID, VEHICLES_OTHER)
  71         /** always last */
  72         CASE(CPID, LAST)
  73 ENUMCLASS_END(CPID)
  74
  75 USING(Notification, entity);
  76
  77 // used for notification system multi-team identifiers
  78 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  79 /** @deprecated use APP_TEAM_NUM */
  80 #define APP_TEAM_ENT(ent, prefix) APP_TEAM_NUM(ent.team, prefix)
  81
  82 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  83         VARITEM(1, 0, s1) \
  84         VARITEM(2, 0, XPD(s1, s2)) \
  85         VARITEM(3, 0, XPD(s1, s2, s3)) \
  86         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  87         VARITEM(0, 1, f1) \
  88         VARITEM(1, 1, XPD(s1, f1)) \
  89         VARITEM(2, 1, XPD(s1, s2, f1)) \
  90         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  91         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  92         VARITEM(0, 2, XPD(f1, f2)) \
  93         VARITEM(1, 2, XPD(s1, f1, f2)) \
  94         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  95         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
  96         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
  97         VARITEM(0, 3, XPD(f1, f2, f3)) \
  98         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
  99         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
 100         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 101         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 102         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 103         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 104         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 105         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 106         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 107
 108 void Destroy_All_Notifications();
 109 void Create_Notification_Entity(entity notif,
 110         float var_default,
 111         float var_cvar,
 112         MSG typeId,
 113         string namestring);
 114 void Create_Notification_Entity_Annce(entity notif,
 115                                                                                 float var_cvar,
 116                                                                                 string namestring,
 117                                                                                 /* MSG_ANNCE */
 118                                                                                 float channel,
 119                                                                                 string snd,
 120                                                                                 float vol,
 121                                                                                 float position);
 122
 123 void Create_Notification_Entity_InfoCenter(entity notif,
 124                                                                                         float var_cvar,
 125                                                                                         string namestring,
 126                                                                                         int strnum,
 127                                                                                         int flnum,
 128                                                                                         /* MSG_INFO & MSG_CENTER */
 129                                                                                         string args,
 130                                                                                         string hudargs,
 131                                                                                         string icon,
 132                                                                                         CPID cpid,
 133                                                                                         string durcnt,
 134                                                                                         string normal,
 135                                                                                         string gentle);
 136
 137 void Create_Notification_Entity_Multi(entity notif,
 138                                                                                 float var_cvar,
 139                                                                                 string namestring,
 140                                                                                 /* MSG_MULTI */
 141                                                                                 Notification anncename,
 142                                                                                 Notification infoname,
 143                                                                                 Notification centername);
 144
 145 void Create_Notification_Entity_Choice(entity notif,
 146                                                                                 float var_cvar,
 147                                                                                 string namestring,
 148                                                                                 /* MSG_CHOICE */
 149                                                                                 float challow_def,
 150                                                                                 float challow_var,
 151                                                                                 MSG chtype,
 152                                                                                 Notification optiona,
 153                                                                                 Notification optionb);
 154
 155 void Dump_Notifications(int fh, bool alsoprint);
 156
 157 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
 158 {
 159         switch (request)
 160         {
 161                 case CMD_REQUEST_COMMAND:
 162                 {
 163                         #ifndef MENUQC
 164                         string filename = argv(1);
 165                         bool alsoprint = false;
 166                         if (filename == "")
 167                         {
 168                                 filename = "notifications_dump.cfg";
 169                                 alsoprint = false;
 170                         }
 171                         else if (filename == "-")
 172                         {
 173                                 filename = "notifications_dump.cfg";
 174                                 alsoprint = true;
 175                         }
 176                         int fh = fopen(filename, FILE_WRITE);
 177                         if (fh >= 0)
 178                         {
 179                                 Dump_Notifications(fh, alsoprint);
 180                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.\n", filename);
 181                                 fclose(fh);
 182                         }
 183                         else
 184                         {
 185                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!\n", filename);
 186                         }
 187                         #else
 188                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
 189                         #endif
 190                         return;
 191                 }
 192                 default:
 193                 case CMD_REQUEST_USAGE:
 194                 {
 195                         LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 196                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),\n");
 197                         LOG_INFO("  if supplied with '-' output to console as well as default,\n");
 198                         LOG_INFO("  if left blank, it will only write to default.\n");
 199                         return;
 200                 }
 201         }
 202 }
 203
 204 #ifdef NOTIFICATIONS_DEBUG
 205 void Debug_Notification(string input)
 206 {
 207         switch (autocvar_notification_debug)
 208         {
 209                 case 1: { LOG_TRACE(input); break; }
 210                 case 2: { LOG_INFO(input); break; }
 211         }
 212 }
 213 #endif
 214
 215 void Local_Notification(MSG net_type, Notification net_name, ...count);
 216 /** glue for networking, forwards to `Local_Notification` */
 217 void Local_Notification_WOVA(
 218         MSG net_type, Notification net_name,
 219         float stringcount, float floatcount,
 220         string s1, string s2, string s3, string s4,
 221         float f1, float f2, float f3, float f4);
 222
 223 #ifdef CSQC
 224 string prev_soundfile;
 225 float prev_soundtime;
 226 #endif
 227
 228 #ifdef SVQC
 229 ENUMCLASS(NOTIF)
 230         /** send to one client and their spectators */
 231         CASE(NOTIF, ONE)
 232         /** send ONLY to one client */
 233         CASE(NOTIF, ONE_ONLY)
 234         /** send only to X team and their spectators */
 235         CASE(NOTIF, TEAM)
 236         /** send only to X team and their spectators, except for Y person and their spectators */
 237         CASE(NOTIF, TEAM_EXCEPT)
 238         /** send to everyone */
 239         CASE(NOTIF, ALL)
 240         /** send to everyone except X person and their spectators */
 241         CASE(NOTIF, ALL_EXCEPT)
 242 ENUMCLASS_END(NOTIF)
 243
 244 string Get_Notif_BroadcastName(NOTIF broadcast)
 245 {
 246         switch (broadcast)
 247         {
 248                 case NOTIF_ONE: return "NOTIF_ONE";
 249                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 250                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 251                 case NOTIF_ALL: return "NOTIF_ALL";
 252                 case NOTIF_TEAM: return "NOTIF_TEAM";
 253                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 254         }
 255         LOG_WARNINGF("Get_Notif_BroadcastName(%d): Improper broadcast!\n", broadcast);
 256         return "";
 257 }
 258
 259 void Kill_Notification(
 260         NOTIF broadcast, entity client,
 261         MSG net_type, CPID net_name);
 262 void Send_Notification(
 263         NOTIF broadcast, entity client,
 264         MSG net_type, Notification net_name,
 265         ...count);
 266 void Send_Notification_WOVA(
 267         NOTIF broadcast, entity client,
 268         MSG net_type, Notification net_name,
 269         float stringcount, float floatcount,
 270         string s1, string s2, string s3, string s4,
 271         float f1, float f2, float f3, float f4);
 272 void Send_Notification_WOCOVA(
 273         NOTIF broadcast, entity client,
 274         MSG net_type, Notification net_name,
 275         string s1, string s2, string s3, string s4,
 276         float f1, float f2, float f3, float f4);
 277 #endif
 278
 279 // ===========================
 280 //  Special CVAR Declarations
 281 // ===========================
 282
 283 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 284 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 285
 286 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 287
 288 float autocvar_notification_show_location = false;
 289 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 290 float autocvar_notification_show_sprees = true;
 291 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 292 float autocvar_notification_show_sprees_info_newline = true;
 293 float autocvar_notification_show_sprees_info_specialonly = true;
 294 float autocvar_notification_errors_are_fatal = true;
 295 float autocvar_notification_lifetime_runtime = 0.5;
 296 float autocvar_notification_lifetime_mapload = 10;
 297 float autocvar_notification_debug = false;
 298
 299 #ifdef SVQC
 300 .float FRAG_VERBOSE;
 301 void Notification_GetCvars();
 302 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 303 #else
 304 float autocvar_notification_item_centerprinttime = 1.5;
 305
 306 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 307 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 308 float autocvar_notification_allow_chatboxprint = 0;
 309
 310 float autocvar_notification_show_sprees_center = true;
 311 float autocvar_notification_show_sprees_center_specialonly = true;
 312 #endif
 313
 314
 315 // ============================
 316 //  Notification Argument List
 317 // ============================
 318 /*
 319  These arguments get replaced with the Local_Notification_sprintf
 320  and other such functions found in all.qc to supply data
 321  from networked notifications to their usage in sprintf... It
 322  allows for more dynamic data to be inferred by the local
 323  notification parser, so that the server does not have to network
 324  anything too crazy on a per-client/per-situation basis.
 325
 326  Pay attention to the CSQC/SVQC relations, some of these are redefined
 327  in slightly different ways for different programs, this is because the
 328  server does a more conservative approach to the notifs than the client.
 329
 330  All arguments are swapped into strings, so be sure that your
 331  sprintf usage matches with proper %s placement.
 332
 333  Argument descriptions:
 334         s1-s4: string arguments to be literally swapped into sprintf
 335         s2loc: s2 string of locations of deaths or other events
 336         s3loc: s3 string of locations of deaths or other events
 337         f1-f4: float arguments expanded into strings to be swapped into sprintf
 338         f1p2dec: f1 float to string with 2 decimal places
 339         f2p2dec: f2 float to string with 2 decimal places
 340         f2primsec: f2 float primary or secondary selection for weapons
 341         f3primsec: f3 float primary or secondary selection for weapons
 342         f1secs: count_seconds of f1
 343         f1points: point or points depending on f1
 344         f1ord: count_ordinal of f1
 345         f1time: process_time of f1
 346         f1race_time: mmssss of f1
 347         f2race_time: mmssss of f2
 348         race_col: color of race time/position (i.e. good or bad)
 349         race_diff: show time difference between f2 and f3
 350         missing_teams: show which teams still need players
 351         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 352         frag_ping: show the ping of a player
 353         frag_stats: show health/armor/ping of a player
 354         frag_pos: show score status and position in the match of a player
 355         spree_cen: centerprint notif for kill spree/how many kills they have
 356         spree_inf: info notif for kill spree/how many kills they have
 357         spree_end: placed at the end of murder messages to show ending of sprees
 358         spree_lost: placed at the end of suicide messages to show losing of sprees
 359         item_wepname: return full name of a weapon from weaponid
 360         item_wepammo: ammo display for weapon from string
 361         item_centime: amount of time to display weapon message in centerprint
 362         item_buffname: return full name of a buff from buffid
 363         death_team: show the full name of the team a player is switching from
 364         minigame1_name: return human readable name of a minigame from its id(s1)
 365         minigame1_d: return descriptor name of a minigame from its id(s1)
 366 */
 367
 368 const float NOTIF_MAX_ARGS = 7;
 369 const float NOTIF_MAX_HUDARGS = 2;
 370 const float NOTIF_MAX_DURCNT = 2;
 371
 372 string arg_slot[NOTIF_MAX_ARGS];
 373
 374 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 375 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 376 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 377 const float ARG_CS = 4; // unique result to CSQC
 378 const float ARG_SV = 5; // unique result to SVQC
 379 const float ARG_DC = 6; // unique result to durcnt/centerprint
 380
 381 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 382 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 383
 384 string BUFF_NAME(int i);
 385
 386 #define NOTIF_ARGUMENT_LIST \
 387         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 388         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 389         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 390         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 391         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 392         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 393         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 394         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 395         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 396         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 397         ARG_CASE(ARG_CS_SV,     "f1p2dec",       ftos_decimals(f1/100, 2)) \
 398         ARG_CASE(ARG_CS_SV,     "f2p2dec",       ftos_decimals(f2/100, 2)) \
 399         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 400         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 401         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 402         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 403         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 404         ARG_CASE(ARG_CS,        "f1time",        process_time(2, f1)) \
 405         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 406         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 407         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 408         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 409         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 410         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 411         ARG_CASE(ARG_CS,        "pass_key",      ((((tmp_s = getcommandkey("pass", "+use")) != "pass") && !(strstrofs(tmp_s, "not bound", 0) >= 0)) ? sprintf(CCR(_(" ^F1(Press %s)")), tmp_s) : "")) \
 412         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 413         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 414         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 415         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 416         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 417         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 418         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 419         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 420         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 421         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 422         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (s1 != "" ? sprintf(_(" with %s"), s1) : "")) \
 423         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 424         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 425         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 426         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(world,netname,s1).descriptor.message) \
 427         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(world,netname,s1).descriptor.netname)
 428
 429 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 430         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 431 } MACRO_END
 432 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 433
 434 #define KILL_SPREE_LIST \
 435         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 436         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 437         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 438         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 439         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 440         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 441         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 442
 443 #ifdef CSQC
 444 string notif_arg_frag_ping(bool newline, float fping)
 445 {
 446         string s = newline ? "\n" : " ";
 447         if (fping < 0)
 448                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 449         else
 450                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 451 }
 452
 453 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 454 {
 455         string s = notif_arg_frag_ping(false, fping);
 456         if (fhealth > 1)
 457                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 458         else
 459                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 460 }
 461
 462 string notif_arg_missing_teams(float f1)
 463 {
 464         return sprintf("%s%s%s%s",
 465                 ((f1 & BIT(0)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_1), (f1 & (BIT(1) | BIT(2) | BIT(3)) ? ", " : "")) : ""),
 466                 ((f1 & BIT(1)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_2), (f1 & (         BIT(2) | BIT(3)) ? ", " : "")) : ""),
 467                 ((f1 & BIT(2)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_3), (f1 & (                  BIT(3)) ? ", " : "")) : ""),
 468                 ((f1 & BIT(3)) ?                 Team_ColoredFullName(NUM_TEAM_4)                                                 : "")
 469         );
 470 }
 471
 472 string notif_arg_spree_cen(float spree)
 473 {
 474         // 0 = off, 1 = target (but only for first victim) and attacker
 475         if(autocvar_notification_show_sprees_center)
 476         {
 477                 if(spree > 1)
 478                 {
 479                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 480                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 481
 482                         switch(spree)
 483                         {
 484                                 KILL_SPREE_LIST
 485                                 default:
 486                                 {
 487                                         if (!autocvar_notification_show_sprees_center_specialonly)
 488                                         {
 489                                                 return
 490                                                         sprintf(
 491                                                                 normal_or_gentle(
 492                                                                         _("%d frag spree! "),
 493                                                                         _("%d score spree! ")
 494                                                                 ),
 495                                                                 spree);
 496                                         }
 497                                         else { return ""; } // don't show spree information if it isn't an achievement
 498                                 }
 499                         }
 500
 501                         #undef SPREE_ITEM
 502                 }
 503                 else if(spree == -1) // first blood
 504                 {
 505                         return normal_or_gentle(_("First blood! "), _("First score! "));
 506                 }
 507                 else if(spree == -2) // first victim
 508                 {
 509                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 510                 }
 511         }
 512         return "";
 513 }
 514 #endif
 515
 516 string notif_arg_spree_inf(float type, string input, string player, float spree)
 517 {
 518         switch(type)
 519         {
 520                 case 1: // attacker kill spree
 521                 {
 522                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 523                         // this conditional (& 2) is true for 2 and 3
 524                         if(autocvar_notification_show_sprees_info & 2)
 525                         {
 526                                 #ifdef CSQC
 527                                 string spree_newline =
 528                                         ( autocvar_notification_show_sprees_info_newline ?
 529                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 530                                 #else
 531                                 string spree_newline =
 532                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 533                                 #endif
 534
 535                                 if(spree > 1)
 536                                 {
 537                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 538                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 539
 540                                         switch(spree)
 541                                         {
 542                                                 KILL_SPREE_LIST
 543                                                 default:
 544                                                 {
 545                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 546                                                         {
 547                                                                 return
 548                                                                         sprintf(
 549                                                                                 CCR(normal_or_gentle(
 550                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 551                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 552                                                                                 )),
 553                                                                                 player,
 554                                                                                 spree,
 555                                                                                 spree_newline
 556                                                                         );
 557                                                         }
 558                                                         else { return ""; } // don't show spree information if it isn't an achievement
 559                                                 }
 560                                         }
 561
 562                                         #undef SPREE_ITEM
 563                                 }
 564                                 else if(spree == -1) // firstblood
 565                                 {
 566                                         return
 567                                                 sprintf(
 568                                                         CCR(normal_or_gentle(
 569                                                                 _("%s^K1 drew first blood! %s^BG"),
 570                                                                 _("%s^K1 got the first score! %s^BG")
 571                                                         )),
 572                                                         player,
 573                                                         spree_newline
 574                                                 );
 575                                 }
 576                         }
 577                         break;
 578                 }
 579
 580                 case -1: // kill spree ended
 581                 {
 582                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 583                         {
 584                                 return
 585                                         sprintf(normal_or_gentle(
 586                                                 _(", ending their %d frag spree"),
 587                                                 _(", ending their %d score spree")
 588                                                 ),
 589                                                 spree
 590                                         );
 591                         }
 592                         break;
 593                 }
 594
 595                 case -2: // kill spree lost
 596                 {
 597                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 598                         {
 599                                 return
 600                                         sprintf(normal_or_gentle(
 601                                                 _(", losing their %d frag spree"),
 602                                                 _(", losing their %d score spree")
 603                                                 ),
 604                                                 spree
 605                                         );
 606                         }
 607                         break;
 608                 }
 609         }
 610         return "";
 611 }
 612
 613
 614 // ====================================
 615 //  Initialization/Create Declarations
 616 // ====================================
 617
 618 // common notification entity values
 619 .int nent_default;
 620 .bool nent_enabled;
 621 .MSG nent_type;
 622 .string nent_name;
 623 .int nent_stringcount;
 624 .int nent_floatcount;
 625
 626 // MSG_ANNCE entity values
 627 .int nent_channel;
 628 .string nent_snd;
 629 .float nent_vol;
 630 .float nent_position;
 631
 632 // MSG_INFO and MSG_CENTER entity values
 633 .string nent_args; // used by both
 634 .string nent_hudargs; // used by info
 635 .string nent_icon; // used by info
 636 .CPID nent_cpid; // used by center
 637 .string nent_durcnt; // used by center
 638 .string nent_string; // used by both
 639
 640 // MSG_MULTI entity values
 641 .entity nent_msgannce;
 642 .entity nent_msginfo;
 643 .entity nent_msgcenter;
 644
 645 // MSG_CHOICE entity values
 646 .float nent_challow_def;
 647 .float nent_challow_var;
 648 .entity nent_optiona;
 649 .entity nent_optionb;
 650
 651 // networked notification entity values
 652 #ifdef SVQC
 653 .NOTIF nent_broadcast;
 654 #endif
 655 .entity nent_client;
 656 .MSG nent_net_type;
 657 .float nent_net_name;
 658 .string nent_strings[4];
 659 .float nent_floats[4];
 660
 661 #define ACVNN(name) autocvar_notification_##name
 662
 663 REGISTRY(Notifications, BITS(11))
 664 REGISTER_REGISTRY(Notifications)
 665 REGISTRY_SORT(Notifications); STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 666 REGISTRY_CHECK(Notifications)
 667
 668 const int NOTIF_CHOICE_MAX = 50;
 669 int nent_choice_count = 0;
 670 .int nent_choice_idx;
 671 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 672 // initialization error detection
 673 bool notif_error;
 674 bool notif_global_error;
 675
 676 STATIC_INIT_LATE(Notif_Choices) {
 677         int c = 0;
 678         FOREACH(Notifications, it.nent_type == MSG_CHOICE, { c++; });
 679         if (c > NOTIF_CHOICE_MAX) {
 680                 LOG_FATALF("Too many MSG_CHOICE notifications (%d)", c);
 681         }
 682 }
 683
 684 Notification Get_Notif_Ent(MSG net_type, int net_name)
 685 {
 686         Notification it = _Notifications_from(net_name, NULL);
 687         if (it.nent_type != net_type) {
 688                 LOG_WARNINGF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!\n",
 689                         Get_Notif_TypeName(net_type), net_type,
 690                         it.registered_id, net_name,
 691                         Get_Notif_TypeName(it.nent_type)
 692                 );
 693                 return NULL;
 694         }
 695         return it;
 696 }
 697
 698 #define MSG_ANNCE_NOTIF(name, default, sound, channel, volume, position) \
 699         MSG_ANNCE_NOTIF_(ANNCE_##name, default, sound, channel, volume, position)
 700 #define MSG_ANNCE_NOTIF_(name, default, sound, channel, volume, position) \
 701         NOTIF_ADD_AUTOCVAR(name, default) \
 702         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 703                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_ANNCE, strtoupper(#name)); \
 704                 Create_Notification_Entity_Annce(this, ACVNN(name), strtoupper(#name), \
 705                         channel,   /* channel  */ \
 706                         sound,     /* snd      */ \
 707                         volume,    /* vol      */ \
 708                         position); /* position */ \
 709         }
 710
 711 #define MSG_INFO_NOTIF(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 712         MSG_INFO_NOTIF_(INFO_##name, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 713 #define MSG_INFO_NOTIF_(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 714         NOTIF_ADD_AUTOCVAR(name, default) \
 715         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 716                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name)); \
 717                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 718                         args,     /* args    */ \
 719                         hudargs,  /* hudargs */ \
 720                         icon,     /* icon    */ \
 721                         CPID_Null,/* cpid    */ \
 722                         "",       /* durcnt  */ \
 723                         normal,   /* normal  */ \
 724                         gentle);  /* gentle  */ \
 725         }
 726
 727 .string nent_iconargs;
 728 #define MULTIICON_INFO(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 729         MULTIICON_INFO_(INFO_##name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 730 #define MULTIICON_INFO_(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 731         NOTIF_ADD_AUTOCVAR(name, default) \
 732         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 733                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name)); \
 734                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 735                         args,     /* args    */ \
 736                         hudargs,  /* hudargs */ \
 737                         icon,     /* icon    */ \
 738                         CPID_Null,/* cpid    */ \
 739                         "",       /* durcnt  */ \
 740                         normal,   /* normal  */ \
 741                         gentle);  /* gentle  */ \
 742                 this.nent_iconargs = iconargs; \
 743         }
 744
 745 #define MSG_CENTER_NOTIF(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 746         MSG_CENTER_NOTIF_(CENTER_##name, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 747 #define MSG_CENTER_NOTIF_(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 748         NOTIF_ADD_AUTOCVAR(name, default) \
 749         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 750                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_CENTER, strtoupper(#name)); \
 751                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 752                         args,    /* args    */ \
 753                         "",      /* hudargs */ \
 754                         "",      /* icon    */ \
 755                         cpid,    /* cpid    */ \
 756                         durcnt,  /* durcnt  */ \
 757                         normal,  /* normal  */ \
 758                         gentle); /* gentle  */ \
 759         }
 760
 761 #define MSG_MULTI_NOTIF(name, default, anncename, infoname, centername) \
 762         NOTIF_ADD_AUTOCVAR(name, default) \
 763         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 764                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_MULTI, strtoupper(#name)); \
 765                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 766                         anncename,   /* anncename  */ \
 767                         infoname,    /* infoname   */ \
 768                         centername); /* centername */ \
 769         }
 770
 771 #define MSG_CHOICE_NOTIF(name, default, challow, chtype, optiona, optionb) \
 772         MSG_CHOICE_NOTIF_(CHOICE_##name, default, challow, chtype, optiona, optionb)
 773 #define MSG_CHOICE_NOTIF_(name, default, challow, chtype, optiona, optionb) \
 774         NOTIF_ADD_AUTOCVAR(name, default) \
 775         NOTIF_ADD_AUTOCVAR(name##_ALLOWED, challow) \
 776         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 777                 this.nent_choice_idx = nent_choice_count++; \
 778                 Create_Notification_Entity       (this, default, ACVNN(name), MSG_CHOICE, strtoupper(#name)); \
 779                 Create_Notification_Entity_Choice(this, ACVNN(name), strtoupper(#name), \
 780                         challow,                                 /* challow_def */ \
 781                         autocvar_notification_##name##_ALLOWED,  /* challow_var */ \
 782                         chtype,                                  /* chtype      */ \
 783                         optiona,                                 /* optiona     */ \
 784                         optionb);                                /* optionb     */ \
 785         }
 786
 787 REGISTRY_BEGIN(Notifications)
 788 {
 789         notif_global_error = false;
 790 }
 791
 792 REGISTRY_END(Notifications)
 793 {
 794         if (!notif_global_error) return;
 795         // shit happened... stop the loading of the program now if this is unacceptable
 796         if (autocvar_notification_errors_are_fatal)
 797                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 798         else
 799                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 800 }
 801
 802 #include "all.inc"
 803
 804 #endif