qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8 #include <common/sounds/sound.qh>
   9 #include <common/weapons/all.qh>
  10
  11 #ifdef CSQC
  12 #include <client/autocvars.qh>
  13 #endif
  14
  15 /** main types/groups of notifications */
  16 ENUMCLASS(MSG)
  17         /** "Global" AND "personal" announcer messages */
  18         CASE(MSG, ANNCE)
  19         /** "Global" information messages */
  20         CASE(MSG, INFO)
  21         /** "Personal" centerprint messages */
  22         CASE(MSG, CENTER)
  23         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  24         CASE(MSG, MULTI)
  25         /** Choose which subcall wrapper to activate */
  26         CASE(MSG, CHOICE)
  27         /** Kill centerprint message @deprecated */
  28         CASE(MSG, CENTER_KILL)
  29 ENUMCLASS_END(MSG)
  30
  31 string Get_Notif_TypeName(MSG net_type)
  32 {
  33         switch (net_type)
  34         {
  35                 case MSG_ANNCE: return "MSG_ANNCE";
  36                 case MSG_INFO: return "MSG_INFO";
  37                 case MSG_CENTER: return "MSG_CENTER";
  38                 case MSG_MULTI: return "MSG_MULTI";
  39                 case MSG_CHOICE: return "MSG_CHOICE";
  40         }
  41         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  42         return "";
  43 }
  44
  45 ENUMCLASS(CPID)
  46         CASE(CPID, ASSAULT_ROLE)
  47         CASE(CPID, ROUND)
  48         CASE(CPID, CAMPCHECK)
  49         CASE(CPID, CTF_CAPSHIELD)
  50         CASE(CPID, CTF_LOWPRIO)
  51         CASE(CPID, CTF_PASS)
  52         CASE(CPID, STALEMATE)
  53         CASE(CPID, NADES)
  54         CASE(CPID, IDLING)
  55         CASE(CPID, ITEM)
  56         CASE(CPID, PREVENT_JOIN)
  57         CASE(CPID, KEEPAWAY)
  58         CASE(CPID, KEEPAWAY_WARN)
  59         CASE(CPID, KEYHUNT)
  60         CASE(CPID, KEYHUNT_OTHER)
  61         CASE(CPID, LMS)
  62         CASE(CPID, MISSING_TEAMS)
  63         CASE(CPID, MISSING_PLAYERS)
  64         CASE(CPID, INSTAGIB_FINDAMMO)
  65         CASE(CPID, MOTD)
  66         CASE(CPID, NIX)
  67         CASE(CPID, ONSLAUGHT)
  68         CASE(CPID, ONS_CAPSHIELD)
  69         CASE(CPID, OVERTIME)
  70         CASE(CPID, POWERUP)
  71         CASE(CPID, RACE_FINISHLAP)
  72         CASE(CPID, TEAMCHANGE)
  73         CASE(CPID, TIMEOUT)
  74         CASE(CPID, TIMEIN)
  75         CASE(CPID, VEHICLES)
  76         CASE(CPID, VEHICLES_OTHER)
  77         /** always last */
  78         CASE(CPID, LAST)
  79 ENUMCLASS_END(CPID)
  80
  81 USING(Notification, entity);
  82
  83 // used for notification system multi-team identifiers
  84 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  85 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  86
  87 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  88         VARITEM(1, 0, s1) \
  89         VARITEM(2, 0, XPD(s1, s2)) \
  90         VARITEM(3, 0, XPD(s1, s2, s3)) \
  91         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  92         VARITEM(0, 1, f1) \
  93         VARITEM(1, 1, XPD(s1, f1)) \
  94         VARITEM(2, 1, XPD(s1, s2, f1)) \
  95         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  96         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  97         VARITEM(0, 2, XPD(f1, f2)) \
  98         VARITEM(1, 2, XPD(s1, f1, f2)) \
  99         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
 100         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
 101         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
 102         VARITEM(0, 3, XPD(f1, f2, f3)) \
 103         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
 104         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
 105         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 106         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 107         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 108         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 109         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 110         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 111         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 112
 113 void Destroy_All_Notifications();
 114 void Create_Notification_Entity(entity notif,
 115         float var_default,
 116         float var_cvar,
 117         MSG typeId,
 118         string namestring,
 119         int teamnum);
 120 void Create_Notification_Entity_Annce(entity notif,
 121                                                                                 float var_cvar,
 122                                                                                 string namestring,
 123                                                                                 /* MSG_ANNCE */
 124                                                                                 float channel,
 125                                                                                 string snd,
 126                                                                                 float vol,
 127                                                                                 float position);
 128
 129 void Create_Notification_Entity_InfoCenter(entity notif,
 130                                                                                         float var_cvar,
 131                                                                                         string namestring,
 132                                                                                         int strnum,
 133                                                                                         int flnum,
 134                                                                                         /* MSG_INFO & MSG_CENTER */
 135                                                                                         string args,
 136                                                                                         string hudargs,
 137                                                                                         string icon,
 138                                                                                         CPID cpid,
 139                                                                                         string durcnt,
 140                                                                                         string normal,
 141                                                                                         string gentle);
 142
 143 void Create_Notification_Entity_Multi(entity notif,
 144                                                                                 float var_cvar,
 145                                                                                 string namestring,
 146                                                                                 /* MSG_MULTI */
 147                                                                                 Notification anncename,
 148                                                                                 Notification infoname,
 149                                                                                 Notification centername);
 150
 151 void Create_Notification_Entity_Choice(entity notif,
 152                                                                                 float var_cvar,
 153                                                                                 string namestring,
 154                                                                                 /* MSG_CHOICE */
 155                                                                                 float challow_def,
 156                                                                                 float challow_var,
 157                                                                                 MSG chtype,
 158                                                                                 Notification optiona,
 159                                                                                 Notification optionb);
 160
 161 void Dump_Notifications(int fh, bool alsoprint);
 162
 163 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
 164 {
 165         switch (request)
 166         {
 167                 case CMD_REQUEST_COMMAND:
 168                 {
 169                         #ifdef GAMEQC
 170                         string filename = argv(1);
 171                         bool alsoprint = false;
 172                         if (filename == "")
 173                         {
 174                                 filename = "notifications_dump.cfg";
 175                                 alsoprint = false;
 176                         }
 177                         else if (filename == "-")
 178                         {
 179                                 filename = "notifications_dump.cfg";
 180                                 alsoprint = true;
 181                         }
 182                         int fh = fopen(filename, FILE_WRITE);
 183                         if (fh >= 0)
 184                         {
 185                                 Dump_Notifications(fh, alsoprint);
 186                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.", filename);
 187                                 fclose(fh);
 188                         }
 189                         else
 190                         {
 191                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!", filename);
 192                         }
 193                         #else
 194                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd."));
 195                         #endif
 196                         return;
 197                 }
 198                 default:
 199                 case CMD_REQUEST_USAGE:
 200                 {
 201                         LOG_INFO("Usage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]");
 202                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),");
 203                         LOG_INFO("  if supplied with '-' output to console as well as default,");
 204                         LOG_INFO("  if left blank, it will only write to default.");
 205                         return;
 206                 }
 207         }
 208 }
 209
 210 #ifdef NOTIFICATIONS_DEBUG
 211 bool autocvar_notification_debug = false;
 212 void Debug_Notification(string input)
 213 {
 214         switch (autocvar_notification_debug)
 215         {
 216                 case 1: { LOG_TRACE(input); break; }
 217                 case 2: { LOG_INFO(input); break; }
 218         }
 219 }
 220 #endif
 221
 222 void Local_Notification(MSG net_type, Notification net_name, ...count);
 223 /** glue for networking, forwards to `Local_Notification` */
 224 void Local_Notification_WOVA(
 225         MSG net_type, Notification net_name,
 226         float stringcount, float floatcount,
 227         string s1, string s2, string s3, string s4,
 228         float f1, float f2, float f3, float f4);
 229
 230 #ifdef CSQC
 231 string prev_soundfile;
 232 float prev_soundtime;
 233 #endif
 234
 235 #ifdef SVQC
 236 IntrusiveList g_notifications;
 237 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 238 #endif
 239
 240 #ifdef SVQC
 241 ENUMCLASS(NOTIF)
 242         /** send to one client and their spectators */
 243         CASE(NOTIF, ONE)
 244         /** send ONLY to one client */
 245         CASE(NOTIF, ONE_ONLY)
 246         /** send only to X team and their spectators */
 247         CASE(NOTIF, TEAM)
 248         /** send only to X team and their spectators, except for Y person and their spectators */
 249         CASE(NOTIF, TEAM_EXCEPT)
 250         /** send to everyone */
 251         CASE(NOTIF, ALL)
 252         /** send to everyone except X person and their spectators */
 253         CASE(NOTIF, ALL_EXCEPT)
 254 ENUMCLASS_END(NOTIF)
 255
 256 string Get_Notif_BroadcastName(NOTIF broadcast)
 257 {
 258         switch (broadcast)
 259         {
 260                 case NOTIF_ONE: return "NOTIF_ONE";
 261                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 262                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 263                 case NOTIF_ALL: return "NOTIF_ALL";
 264                 case NOTIF_TEAM: return "NOTIF_TEAM";
 265                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 266         }
 267         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 268         return "";
 269 }
 270
 271 void Kill_Notification(
 272         NOTIF broadcast, entity client,
 273         MSG net_type, CPID net_name);
 274 void Send_Notification(
 275         NOTIF broadcast, entity client,
 276         MSG net_type, Notification net_name,
 277         ...count);
 278 void Send_Notification_WOVA(
 279         NOTIF broadcast, entity client,
 280         MSG net_type, Notification net_name,
 281         float stringcount, float floatcount,
 282         string s1, string s2, string s3, string s4,
 283         float f1, float f2, float f3, float f4);
 284 void Send_Notification_WOCOVA(
 285         NOTIF broadcast, entity client,
 286         MSG net_type, Notification net_name,
 287         string s1, string s2, string s3, string s4,
 288         float f1, float f2, float f3, float f4);
 289 #endif
 290
 291 // ===========================
 292 //  Special CVAR Declarations
 293 // ===========================
 294
 295 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 296 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 297
 298 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 299
 300 float autocvar_notification_show_location = false;
 301 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 302 float autocvar_notification_show_sprees = true;
 303 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 304 float autocvar_notification_show_sprees_info_newline = true;
 305 float autocvar_notification_show_sprees_info_specialonly = true;
 306 float autocvar_notification_errors_are_fatal = true;
 307 #ifdef SVQC
 308 float autocvar_notification_lifetime_runtime = 0.5;
 309 float autocvar_notification_lifetime_mapload = 10;
 310 #endif
 311
 312 #ifdef SVQC
 313 .float FRAG_VERBOSE;
 314 void Notification_GetCvars(entity this);
 315 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 316 #else
 317 float autocvar_notification_item_centerprinttime = 1.5;
 318
 319 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 320 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 321 float autocvar_notification_allow_chatboxprint = 0;
 322
 323 float autocvar_notification_show_sprees_center = true;
 324 float autocvar_notification_show_sprees_center_specialonly = true;
 325 #endif
 326
 327
 328 // ============================
 329 //  Notification Argument List
 330 // ============================
 331 /*
 332  These arguments get replaced with the Local_Notification_sprintf
 333  and other such functions found in all.qc to supply data
 334  from networked notifications to their usage in sprintf... It
 335  allows for more dynamic data to be inferred by the local
 336  notification parser, so that the server does not have to network
 337  anything too crazy on a per-client/per-situation basis.
 338
 339  Pay attention to the CSQC/SVQC relations, some of these are redefined
 340  in slightly different ways for different programs, this is because the
 341  server does a more conservative approach to the notifs than the client.
 342
 343  All arguments are swapped into strings, so be sure that your
 344  sprintf usage matches with proper %s placement.
 345
 346  Argument descriptions:
 347         s1-s4: string arguments to be literally swapped into sprintf
 348         s2loc: s2 string of locations of deaths or other events
 349         s3loc: s3 string of locations of deaths or other events
 350         f1-f4: float arguments expanded into strings to be swapped into sprintf
 351         f1p2dec: f1 float to string with 2 decimal places
 352         f2p2dec: f2 float to string with 2 decimal places
 353         f2primsec: f2 float primary or secondary selection for weapons
 354         f3primsec: f3 float primary or secondary selection for weapons
 355         f1secs: count_seconds of f1
 356         f1points: point or points depending on f1
 357         f1ord: count_ordinal of f1
 358         f1time: process_time of f1
 359         f1race_time: mmssss of f1
 360         f2race_time: mmssss of f2
 361         race_col: color of race time/position (i.e. good or bad)
 362         race_diff: show time difference between f2 and f3
 363         missing_teams: show which teams still need players
 364         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 365         nade_key: find the keybind for nade throwing
 366         frag_ping: show the ping of a player
 367         frag_stats: show health/armor/ping of a player
 368         frag_pos: show score status and position in the match of a player
 369         spree_cen: centerprint notif for kill spree/how many kills they have
 370         spree_inf: info notif for kill spree/how many kills they have
 371         spree_end: placed at the end of murder messages to show ending of sprees
 372         spree_lost: placed at the end of suicide messages to show losing of sprees
 373         item_wepname: return full name of a weapon from weaponid
 374         item_wepammo: ammo display for weapon from f1 and f2
 375         item_centime: amount of time to display weapon message in centerprint
 376         item_buffname: return full name of a buff from buffid
 377         death_team: show the full name of the team a player is switching from
 378         minigame1_name: return human readable name of a minigame from its id(s1)
 379         minigame1_d: return descriptor name of a minigame from its id(s1)
 380 */
 381
 382 const float NOTIF_MAX_ARGS = 7;
 383 const float NOTIF_MAX_HUDARGS = 2;
 384 const float NOTIF_MAX_DURCNT = 2;
 385
 386 string arg_slot[NOTIF_MAX_ARGS];
 387
 388 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 389 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 390 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 391 const float ARG_CS = 4; // unique result to CSQC
 392 const float ARG_SV = 5; // unique result to SVQC
 393 const float ARG_DC = 6; // unique result to durcnt/centerprint
 394
 395 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 396 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 397
 398 string BUFF_NAME(int i);
 399
 400 #define NOTIF_ARGUMENT_LIST \
 401         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 402         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 403         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 404         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 405         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 406         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 407         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 408         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 409         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 410         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 411         ARG_CASE(ARG_CS_SV,     "f1dtime",       ftos_decimals(TIME_DECODE(f1), 2)) \
 412         ARG_CASE(ARG_CS_SV,     "f2dtime",       ftos_decimals(TIME_DECODE(f2), 2)) \
 413         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 414         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 415         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 416         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 417         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 418         ARG_CASE(ARG_CS_SV,     "f1time",        process_time(2, f1)) \
 419         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 420         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 421         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 422         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 423         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 424         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 425         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 426         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 427         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 428         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 429         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 430         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 431         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 432         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 433         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 434         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 435         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 436         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 437         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (f2 > 0 ? notif_arg_item_wepammo(f1, f2) : "")) \
 438         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 439         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 440         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 441         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 442         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 443
 444 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 445         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 446 } MACRO_END
 447 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 448
 449 #define KILL_SPREE_LIST \
 450         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 451         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 452         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 453         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 454         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 455         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 456         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 457
 458 #ifdef CSQC
 459 string notif_arg_frag_ping(bool newline, float fping)
 460 {
 461         string s = newline ? "\n" : " ";
 462         if (fping < 0)
 463                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 464         else
 465                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 466 }
 467
 468 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 469 {
 470         string s = notif_arg_frag_ping(false, fping);
 471         if (fhealth > 1)
 472                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 473         else
 474                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 475 }
 476
 477 string notif_arg_missing_teams(float f1)
 478 {
 479         return strcat(
 480                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
 481                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
 482                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
 483                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
 484         );
 485 }
 486
 487 string notif_arg_spree_cen(float spree)
 488 {
 489         // 0 = off, 1 = target (but only for first victim) and attacker
 490         if(autocvar_notification_show_sprees_center)
 491         {
 492                 if(spree > 1)
 493                 {
 494                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 495                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 496
 497                         switch(spree)
 498                         {
 499                                 KILL_SPREE_LIST
 500                                 default:
 501                                 {
 502                                         if (!autocvar_notification_show_sprees_center_specialonly)
 503                                         {
 504                                                 return
 505                                                         sprintf(
 506                                                                 normal_or_gentle(
 507                                                                         _("%d frag spree! "),
 508                                                                         _("%d score spree! ")
 509                                                                 ),
 510                                                                 spree);
 511                                         }
 512                                         else { return ""; } // don't show spree information if it isn't an achievement
 513                                 }
 514                         }
 515
 516                         #undef SPREE_ITEM
 517                 }
 518                 else if(spree == -1) // first blood
 519                 {
 520                         return normal_or_gentle(_("First blood! "), _("First score! "));
 521                 }
 522                 else if(spree == -2) // first victim
 523                 {
 524                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 525                 }
 526         }
 527         return "";
 528 }
 529 #endif
 530
 531 string notif_arg_spree_inf(float type, string input, string player, float spree)
 532 {
 533         switch(type)
 534         {
 535                 case 1: // attacker kill spree
 536                 {
 537                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 538                         // this conditional (& 2) is true for 2 and 3
 539                         if(autocvar_notification_show_sprees_info & 2)
 540                         {
 541                                 #ifdef CSQC
 542                                 string spree_newline =
 543                                         ( autocvar_notification_show_sprees_info_newline ?
 544                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 545                                 #else
 546                                 string spree_newline =
 547                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 548                                 #endif
 549
 550                                 if(spree > 1)
 551                                 {
 552                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 553                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 554
 555                                         switch(spree)
 556                                         {
 557                                                 KILL_SPREE_LIST
 558                                                 default:
 559                                                 {
 560                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 561                                                         {
 562                                                                 return
 563                                                                         sprintf(
 564                                                                                 CCR(normal_or_gentle(
 565                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 566                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 567                                                                                 )),
 568                                                                                 player,
 569                                                                                 spree,
 570                                                                                 spree_newline
 571                                                                         );
 572                                                         }
 573                                                         else { return ""; } // don't show spree information if it isn't an achievement
 574                                                 }
 575                                         }
 576
 577                                         #undef SPREE_ITEM
 578                                 }
 579                                 else if(spree == -1) // firstblood
 580                                 {
 581                                         return
 582                                                 sprintf(
 583                                                         CCR(normal_or_gentle(
 584                                                                 _("%s^K1 drew first blood! %s^BG"),
 585                                                                 _("%s^K1 got the first score! %s^BG")
 586                                                         )),
 587                                                         player,
 588                                                         spree_newline
 589                                                 );
 590                                 }
 591                         }
 592                         break;
 593                 }
 594
 595                 case -1: // kill spree ended
 596                 {
 597                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 598                         {
 599                                 return
 600                                         sprintf(normal_or_gentle(
 601                                                 _(", ending their %d frag spree"),
 602                                                 _(", ending their %d score spree")
 603                                                 ),
 604                                                 spree
 605                                         );
 606                         }
 607                         break;
 608                 }
 609
 610                 case -2: // kill spree lost
 611                 {
 612                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 613                         {
 614                                 return
 615                                         sprintf(normal_or_gentle(
 616                                                 _(", losing their %d frag spree"),
 617                                                 _(", losing their %d score spree")
 618                                                 ),
 619                                                 spree
 620                                         );
 621                         }
 622                         break;
 623                 }
 624         }
 625         return "";
 626 }
 627
 628 string notif_arg_item_wepammo(float f1, float f2)
 629 {
 630         string ammoitems = "";
 631         Weapon wep = Weapons_from(f1);
 632         switch (wep.ammo_type)
 633         {
 634                 case RESOURCE_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 635                 case RESOURCE_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 636                 case RESOURCE_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 637                 case RESOURCE_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 638                 case RESOURCE_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 639                 case RESOURCE_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 640                 default: return ""; // doesn't use ammo
 641         }
 642         return sprintf(_(" with %d %s"), f2, ammoitems);
 643 }
 644
 645
 646 // ====================================
 647 //  Initialization/Create Declarations
 648 // ====================================
 649
 650 // common notification entity values
 651 .int nent_default;
 652 .bool nent_enabled;
 653 .MSG nent_type;
 654 .string nent_name;
 655 .int nent_stringcount;
 656 .int nent_floatcount;
 657 .int nent_teamnum;
 658
 659 // MSG_ANNCE entity values
 660 .int nent_channel;
 661 .string nent_snd;
 662 .float nent_vol;
 663 .float nent_position;
 664
 665 // MSG_INFO and MSG_CENTER entity values
 666 .string nent_args; // used by both
 667 .string nent_hudargs; // used by info
 668 .string nent_icon; // used by info
 669 .CPID nent_cpid; // used by center
 670 .string nent_durcnt; // used by center
 671 .string nent_string; // used by both
 672
 673 // MSG_MULTI entity values
 674 .entity nent_msgannce;
 675 .entity nent_msginfo;
 676 .entity nent_msgcenter;
 677
 678 // MSG_CHOICE entity values
 679 .float nent_challow_def;
 680 .float nent_challow_var;
 681 .entity nent_optiona;
 682 .entity nent_optionb;
 683
 684 // networked notification entity values
 685 #ifdef SVQC
 686 .NOTIF nent_broadcast;
 687 #endif
 688 .entity nent_client;
 689 .MSG nent_net_type;
 690 .float nent_net_name;
 691 .string nent_strings[4];
 692 .float nent_floats[4];
 693
 694 #define ACVNN(name) autocvar_notification_##name
 695
 696 REGISTRY(Notifications, BITS(11))
 697 REGISTER_REGISTRY(Notifications)
 698 REGISTRY_SORT(Notifications);
 699 STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 700 REGISTRY_CHECK(Notifications)
 701
 702 const int NOTIF_CHOICE_MAX = 50;
 703 int nent_choice_count = 0;
 704 .int nent_choice_idx;
 705 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 706 // initialization error detection
 707 bool notif_error;
 708 bool notif_global_error;
 709
 710 STATIC_INIT_LATE(Notif_Choices) {
 711         int c = 0;
 712         FOREACH(Notifications, it.nent_type == MSG_CHOICE, { c++; });
 713         if (c > NOTIF_CHOICE_MAX) {
 714                 LOG_FATALF("Too many MSG_CHOICE notifications (%d)", c);
 715         }
 716 }
 717
 718 string Get_Notif_CvarName(Notification notif)
 719 {
 720         if(!notif.nent_teamnum)
 721                 return notif.nent_name;
 722         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
 723 }
 724
 725 Notification Get_Notif_Ent(MSG net_type, int net_name)
 726 {
 727         Notification it = _Notifications_from(net_name, NULL);
 728         if (it.nent_type != net_type) {
 729                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 730                         Get_Notif_TypeName(net_type), net_type,
 731                         it.registered_id, net_name,
 732                         Get_Notif_TypeName(it.nent_type)
 733                 );
 734                 return NULL;
 735         }
 736         return it;
 737 }
 738
 739 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, default, sound, channel, volume, position) \
 740         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, default, sound, channel, volume, position)
 741
 742 #define MSG_ANNCE_NOTIF(name, default, sound, channel, volume, position) \
 743         NOTIF_ADD_AUTOCVAR(ANNCE_##name, default) \
 744         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, default, sound, channel, volume, position)
 745
 746 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, default, sound, channel, volume, position) \
 747         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 748                 Create_Notification_Entity      (this, default, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
 749                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 750                         channel,   /* channel  */ \
 751                         sound,     /* snd      */ \
 752                         volume,    /* vol      */ \
 753                         position); /* position */ \
 754         }
 755
 756 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 757         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 758
 759 #define MSG_INFO_NOTIF(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 760         NOTIF_ADD_AUTOCVAR(INFO_##name, default) \
 761         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 762
 763 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 764         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 765                 Create_Notification_Entity           (this, default, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
 766                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 767                         args,     /* args    */ \
 768                         hudargs,  /* hudargs */ \
 769                         icon,     /* icon    */ \
 770                         CPID_Null,/* cpid    */ \
 771                         "",       /* durcnt  */ \
 772                         normal,   /* normal  */ \
 773                         gentle);  /* gentle  */ \
 774         }
 775
 776 .string nent_iconargs;
 777 #define MULTIICON_INFO(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 778         MULTIICON_INFO_(INFO_##name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 779 #define MULTIICON_INFO_(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 780         NOTIF_ADD_AUTOCVAR(name, default) \
 781         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 782                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
 783                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 784                         args,     /* args    */ \
 785                         hudargs,  /* hudargs */ \
 786                         icon,     /* icon    */ \
 787                         CPID_Null,/* cpid    */ \
 788                         "",       /* durcnt  */ \
 789                         normal,   /* normal  */ \
 790                         gentle);  /* gentle  */ \
 791                 this.nent_iconargs = iconargs; \
 792         }
 793
 794 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 795         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 796
 797 #define MSG_CENTER_NOTIF(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 798         NOTIF_ADD_AUTOCVAR(CENTER_##name, default) \
 799         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 800
 801 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 802         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 803                 Create_Notification_Entity           (this, default, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
 804                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 805                         args,    /* args    */ \
 806                         "",      /* hudargs */ \
 807                         "",      /* icon    */ \
 808                         cpid,    /* cpid    */ \
 809                         durcnt,  /* durcnt  */ \
 810                         normal,  /* normal  */ \
 811                         gentle); /* gentle  */ \
 812         }
 813
 814 #define MSG_MULTI_NOTIF(name, default, anncename, infoname, centername) \
 815         NOTIF_ADD_AUTOCVAR(name, default) \
 816         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 817                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
 818                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 819                         anncename,   /* anncename  */ \
 820                         infoname,    /* infoname   */ \
 821                         centername); /* centername */ \
 822         }
 823
 824 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, default, challow, chtype, optiona, optionb) \
 825         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, default, challow, chtype, optiona, optionb)
 826
 827 #define MSG_CHOICE_NOTIF(name, default, challow, chtype, optiona, optionb) \
 828         NOTIF_ADD_AUTOCVAR(CHOICE_##name, default) \
 829         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 830         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, default, challow, chtype, optiona, optionb)
 831
 832 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, default, challow, chtype, optiona, optionb) \
 833         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 834                 this.nent_choice_idx = nent_choice_count++; \
 835                 Create_Notification_Entity       (this, default, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
 836                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 837                         challow,                                 /* challow_def */ \
 838                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 839                         chtype,                                  /* chtype      */ \
 840                         optiona,                                 /* optiona     */ \
 841                         optionb);                                /* optionb     */ \
 842         }
 843
 844 REGISTRY_BEGIN(Notifications)
 845 {
 846         notif_global_error = false;
 847 }
 848
 849 REGISTRY_END(Notifications)
 850 {
 851         if (!notif_global_error) return;
 852         // shit happened... stop the loading of the program now if this is unacceptable
 853         if (autocvar_notification_errors_are_fatal)
 854                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 855         else
 856                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 857 }
 858
 859 #include "all.inc"