qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_all.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8
   9 /** main types/groups of notifications */
  10 ENUMCLASS(MSG)
  11         /** "Global" AND "personal" announcer messages */
  12         CASE(MSG, ANNCE)
  13         /** "Global" information messages */
  14         CASE(MSG, INFO)
  15         /** "Personal" centerprint messages */
  16         CASE(MSG, CENTER)
  17         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  18         CASE(MSG, MULTI)
  19         /** Choose which subcall wrapper to activate */
  20         CASE(MSG, CHOICE)
  21         /** Kill centerprint message @deprecated */
  22         CASE(MSG, CENTER_KILL)
  23 ENUMCLASS_END(MSG)
  24
  25 string Get_Notif_TypeName(MSG net_type)
  26 {
  27         switch (net_type)
  28         {
  29                 case MSG_ANNCE: return "MSG_ANNCE";
  30                 case MSG_INFO: return "MSG_INFO";
  31                 case MSG_CENTER: return "MSG_CENTER";
  32                 case MSG_MULTI: return "MSG_MULTI";
  33                 case MSG_CHOICE: return "MSG_CHOICE";
  34         }
  35         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  36         return "";
  37 }
  38
  39 ENUMCLASS(CPID)
  40         CASE(CPID, ASSAULT_ROLE)
  41         CASE(CPID, ROUND)
  42         CASE(CPID, CAMPCHECK)
  43         CASE(CPID, CTF_CAPSHIELD)
  44         CASE(CPID, CTF_LOWPRIO)
  45         CASE(CPID, CTF_PASS)
  46         CASE(CPID, STALEMATE)
  47         CASE(CPID, NADES)
  48         CASE(CPID, IDLING)
  49         CASE(CPID, ITEM)
  50         CASE(CPID, PREVENT_JOIN)
  51         CASE(CPID, KEEPAWAY)
  52         CASE(CPID, KEEPAWAY_WARN)
  53         CASE(CPID, KEYHUNT)
  54         CASE(CPID, KEYHUNT_OTHER)
  55         CASE(CPID, LMS)
  56         CASE(CPID, MISSING_TEAMS)
  57         CASE(CPID, MISSING_PLAYERS)
  58         CASE(CPID, INSTAGIB_FINDAMMO)
  59         CASE(CPID, MOTD)
  60         CASE(CPID, NIX)
  61         CASE(CPID, ONSLAUGHT)
  62         CASE(CPID, ONS_CAPSHIELD)
  63         CASE(CPID, OVERTIME)
  64         CASE(CPID, POWERUP)
  65         CASE(CPID, RACE_FINISHLAP)
  66         CASE(CPID, TEAMCHANGE)
  67         CASE(CPID, TIMEOUT)
  68         CASE(CPID, VEHICLES)
  69         CASE(CPID, VEHICLES_OTHER)
  70         /** always last */
  71         CASE(CPID, LAST)
  72 ENUMCLASS_END(CPID)
  73
  74 USING(Notification, entity);
  75
  76 // used for notification system multi-team identifiers
  77 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  78 /** @deprecated use APP_TEAM_NUM */
  79 #define APP_TEAM_ENT(ent, prefix) APP_TEAM_NUM(ent.team, prefix)
  80
  81 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  82         VARITEM(1, 0, s1) \
  83         VARITEM(2, 0, XPD(s1, s2)) \
  84         VARITEM(3, 0, XPD(s1, s2, s3)) \
  85         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  86         VARITEM(0, 1, f1) \
  87         VARITEM(1, 1, XPD(s1, f1)) \
  88         VARITEM(2, 1, XPD(s1, s2, f1)) \
  89         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  90         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  91         VARITEM(0, 2, XPD(f1, f2)) \
  92         VARITEM(1, 2, XPD(s1, f1, f2)) \
  93         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  94         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
  95         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
  96         VARITEM(0, 3, XPD(f1, f2, f3)) \
  97         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
  98         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
  99         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 100         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 101         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 102         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 103         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 104         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 105         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 106
 107 void Destroy_All_Notifications();
 108 void Create_Notification_Entity(entity notif,
 109         float var_default,
 110         float var_cvar,
 111         MSG typeId,
 112         string namestring);
 113 void Create_Notification_Entity_Annce(entity notif,
 114                                                                                 float var_cvar,
 115                                                                                 string namestring,
 116                                                                                 /* MSG_ANNCE */
 117                                                                                 float channel,
 118                                                                                 string snd,
 119                                                                                 float vol,
 120                                                                                 float position);
 121
 122 void Create_Notification_Entity_InfoCenter(entity notif,
 123                                                                                         float var_cvar,
 124                                                                                         string namestring,
 125                                                                                         int strnum,
 126                                                                                         int flnum,
 127                                                                                         /* MSG_INFO & MSG_CENTER */
 128                                                                                         string args,
 129                                                                                         string hudargs,
 130                                                                                         string icon,
 131                                                                                         CPID cpid,
 132                                                                                         string durcnt,
 133                                                                                         string normal,
 134                                                                                         string gentle);
 135
 136 void Create_Notification_Entity_Multi(entity notif,
 137                                                                                 float var_cvar,
 138                                                                                 string namestring,
 139                                                                                 /* MSG_MULTI */
 140                                                                                 Notification anncename,
 141                                                                                 Notification infoname,
 142                                                                                 Notification centername);
 143
 144 void Create_Notification_Entity_Choice(entity notif,
 145                                                                                 float var_cvar,
 146                                                                                 string namestring,
 147                                                                                 /* MSG_CHOICE */
 148                                                                                 float challow_def,
 149                                                                                 float challow_var,
 150                                                                                 MSG chtype,
 151                                                                                 Notification optiona,
 152                                                                                 Notification optionb);
 153
 154 void Dump_Notifications(int fh, bool alsoprint);
 155
 156 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
 157 {
 158         switch (request)
 159         {
 160                 case CMD_REQUEST_COMMAND:
 161                 {
 162                         #ifndef MENUQC
 163                         string filename = argv(1);
 164                         bool alsoprint = false;
 165                         if (filename == "")
 166                         {
 167                                 filename = "notifications_dump.cfg";
 168                                 alsoprint = false;
 169                         }
 170                         else if (filename == "-")
 171                         {
 172                                 filename = "notifications_dump.cfg";
 173                                 alsoprint = true;
 174                         }
 175                         int fh = fopen(filename, FILE_WRITE);
 176                         if (fh >= 0)
 177                         {
 178                                 Dump_Notifications(fh, alsoprint);
 179                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.\n", filename);
 180                                 fclose(fh);
 181                         }
 182                         else
 183                         {
 184                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!\n", filename);
 185                         }
 186                         #else
 187                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
 188                         #endif
 189                         return;
 190                 }
 191                 default:
 192                 case CMD_REQUEST_USAGE:
 193                 {
 194                         LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 195                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),\n");
 196                         LOG_INFO("  if supplied with '-' output to console as well as default,\n");
 197                         LOG_INFO("  if left blank, it will only write to default.\n");
 198                         return;
 199                 }
 200         }
 201 }
 202
 203 float autocvar_notification_debug = false;
 204 #ifdef NOTIFICATIONS_DEBUG
 205 void Debug_Notification(string input)
 206 {
 207         switch (autocvar_notification_debug)
 208         {
 209                 case 1: { LOG_TRACE(input); break; }
 210                 case 2: { LOG_INFO(input); break; }
 211         }
 212 }
 213 #endif
 214
 215 void Local_Notification(MSG net_type, Notification net_name, ...count);
 216 /** glue for networking, forwards to `Local_Notification` */
 217 void Local_Notification_WOVA(
 218         MSG net_type, Notification net_name,
 219         float stringcount, float floatcount,
 220         string s1, string s2, string s3, string s4,
 221         float f1, float f2, float f3, float f4);
 222
 223 #ifdef CSQC
 224 string prev_soundfile;
 225 float prev_soundtime;
 226 #endif
 227
 228 #ifdef SVQC
 229 ENUMCLASS(NOTIF)
 230         /** send to one client and their spectators */
 231         CASE(NOTIF, ONE)
 232         /** send ONLY to one client */
 233         CASE(NOTIF, ONE_ONLY)
 234         /** send only to X team and their spectators */
 235         CASE(NOTIF, TEAM)
 236         /** send only to X team and their spectators, except for Y person and their spectators */
 237         CASE(NOTIF, TEAM_EXCEPT)
 238         /** send to everyone */
 239         CASE(NOTIF, ALL)
 240         /** send to everyone except X person and their spectators */
 241         CASE(NOTIF, ALL_EXCEPT)
 242 ENUMCLASS_END(NOTIF)
 243
 244 string Get_Notif_BroadcastName(NOTIF broadcast)
 245 {
 246         switch (broadcast)
 247         {
 248                 case NOTIF_ONE: return "NOTIF_ONE";
 249                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 250                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 251                 case NOTIF_ALL: return "NOTIF_ALL";
 252                 case NOTIF_TEAM: return "NOTIF_TEAM";
 253                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 254         }
 255         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 256         return "";
 257 }
 258
 259 void Kill_Notification(
 260         NOTIF broadcast, entity client,
 261         MSG net_type, CPID net_name);
 262 void Send_Notification(
 263         NOTIF broadcast, entity client,
 264         MSG net_type, Notification net_name,
 265         ...count);
 266 void Send_Notification_WOVA(
 267         NOTIF broadcast, entity client,
 268         MSG net_type, Notification net_name,
 269         float stringcount, float floatcount,
 270         string s1, string s2, string s3, string s4,
 271         float f1, float f2, float f3, float f4);
 272 void Send_Notification_WOCOVA(
 273         NOTIF broadcast, entity client,
 274         MSG net_type, Notification net_name,
 275         string s1, string s2, string s3, string s4,
 276         float f1, float f2, float f3, float f4);
 277 #endif
 278
 279 // ===========================
 280 //  Special CVAR Declarations
 281 // ===========================
 282
 283 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 284 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 285
 286 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 287
 288 float autocvar_notification_show_location = false;
 289 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 290 float autocvar_notification_show_sprees = true;
 291 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 292 float autocvar_notification_show_sprees_info_newline = true;
 293 float autocvar_notification_show_sprees_info_specialonly = true;
 294 float autocvar_notification_errors_are_fatal = true;
 295 float autocvar_notification_lifetime_runtime = 0.5;
 296 float autocvar_notification_lifetime_mapload = 10;
 297
 298 #ifdef SVQC
 299 .float FRAG_VERBOSE;
 300 void Notification_GetCvars(entity this);
 301 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 302 #else
 303 float autocvar_notification_item_centerprinttime = 1.5;
 304
 305 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 306 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 307 float autocvar_notification_allow_chatboxprint = 0;
 308
 309 float autocvar_notification_show_sprees_center = true;
 310 float autocvar_notification_show_sprees_center_specialonly = true;
 311 #endif
 312
 313
 314 // ============================
 315 //  Notification Argument List
 316 // ============================
 317 /*
 318  These arguments get replaced with the Local_Notification_sprintf
 319  and other such functions found in all.qc to supply data
 320  from networked notifications to their usage in sprintf... It
 321  allows for more dynamic data to be inferred by the local
 322  notification parser, so that the server does not have to network
 323  anything too crazy on a per-client/per-situation basis.
 324
 325  Pay attention to the CSQC/SVQC relations, some of these are redefined
 326  in slightly different ways for different programs, this is because the
 327  server does a more conservative approach to the notifs than the client.
 328
 329  All arguments are swapped into strings, so be sure that your
 330  sprintf usage matches with proper %s placement.
 331
 332  Argument descriptions:
 333         s1-s4: string arguments to be literally swapped into sprintf
 334         s2loc: s2 string of locations of deaths or other events
 335         s3loc: s3 string of locations of deaths or other events
 336         f1-f4: float arguments expanded into strings to be swapped into sprintf
 337         f1p2dec: f1 float to string with 2 decimal places
 338         f2p2dec: f2 float to string with 2 decimal places
 339         f2primsec: f2 float primary or secondary selection for weapons
 340         f3primsec: f3 float primary or secondary selection for weapons
 341         f1secs: count_seconds of f1
 342         f1points: point or points depending on f1
 343         f1ord: count_ordinal of f1
 344         f1time: process_time of f1
 345         f1race_time: mmssss of f1
 346         f2race_time: mmssss of f2
 347         race_col: color of race time/position (i.e. good or bad)
 348         race_diff: show time difference between f2 and f3
 349         missing_teams: show which teams still need players
 350         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 351         frag_ping: show the ping of a player
 352         frag_stats: show health/armor/ping of a player
 353         frag_pos: show score status and position in the match of a player
 354         spree_cen: centerprint notif for kill spree/how many kills they have
 355         spree_inf: info notif for kill spree/how many kills they have
 356         spree_end: placed at the end of murder messages to show ending of sprees
 357         spree_lost: placed at the end of suicide messages to show losing of sprees
 358         item_wepname: return full name of a weapon from weaponid
 359         item_wepammo: ammo display for weapon from string
 360         item_centime: amount of time to display weapon message in centerprint
 361         item_buffname: return full name of a buff from buffid
 362         death_team: show the full name of the team a player is switching from
 363         minigame1_name: return human readable name of a minigame from its id(s1)
 364         minigame1_d: return descriptor name of a minigame from its id(s1)
 365 */
 366
 367 const float NOTIF_MAX_ARGS = 7;
 368 const float NOTIF_MAX_HUDARGS = 2;
 369 const float NOTIF_MAX_DURCNT = 2;
 370
 371 string arg_slot[NOTIF_MAX_ARGS];
 372
 373 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 374 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 375 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 376 const float ARG_CS = 4; // unique result to CSQC
 377 const float ARG_SV = 5; // unique result to SVQC
 378 const float ARG_DC = 6; // unique result to durcnt/centerprint
 379
 380 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 381 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 382
 383 string BUFF_NAME(int i);
 384
 385 #define NOTIF_ARGUMENT_LIST \
 386         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 387         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 388         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 389         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 390         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 391         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 392         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 393         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 394         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 395         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 396         ARG_CASE(ARG_CS_SV,     "f1p2dec",       ftos_decimals(f1/100, 2)) \
 397         ARG_CASE(ARG_CS_SV,     "f2p2dec",       ftos_decimals(f2/100, 2)) \
 398         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 399         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 400         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 401         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 402         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 403         ARG_CASE(ARG_CS,        "f1time",        process_time(2, f1)) \
 404         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 405         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 406         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 407         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 408         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 409         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 410         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 411         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 412         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 413         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 414         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 415         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 416         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 417         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 418         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 419         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 420         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 421         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (s1 != "" ? sprintf(_(" with %s"), s1) : "")) \
 422         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 423         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 424         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 425         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 426         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 427
 428 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 429         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 430 } MACRO_END
 431 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 432
 433 #define KILL_SPREE_LIST \
 434         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 435         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 436         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 437         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 438         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 439         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 440         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 441
 442 #ifdef CSQC
 443 string notif_arg_frag_ping(bool newline, float fping)
 444 {
 445         string s = newline ? "\n" : " ";
 446         if (fping < 0)
 447                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 448         else
 449                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 450 }
 451
 452 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 453 {
 454         string s = notif_arg_frag_ping(false, fping);
 455         if (fhealth > 1)
 456                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 457         else
 458                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 459 }
 460
 461 string notif_arg_missing_teams(float f1)
 462 {
 463         return sprintf("%s%s%s%s",
 464                 ((f1 & BIT(0)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_1), (f1 & (BIT(1) | BIT(2) | BIT(3)) ? ", " : "")) : ""),
 465                 ((f1 & BIT(1)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_2), (f1 & (         BIT(2) | BIT(3)) ? ", " : "")) : ""),
 466                 ((f1 & BIT(2)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_3), (f1 & (                  BIT(3)) ? ", " : "")) : ""),
 467                 ((f1 & BIT(3)) ?                 Team_ColoredFullName(NUM_TEAM_4)                                                 : "")
 468         );
 469 }
 470
 471 string notif_arg_spree_cen(float spree)
 472 {
 473         // 0 = off, 1 = target (but only for first victim) and attacker
 474         if(autocvar_notification_show_sprees_center)
 475         {
 476                 if(spree > 1)
 477                 {
 478                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 479                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 480
 481                         switch(spree)
 482                         {
 483                                 KILL_SPREE_LIST
 484                                 default:
 485                                 {
 486                                         if (!autocvar_notification_show_sprees_center_specialonly)
 487                                         {
 488                                                 return
 489                                                         sprintf(
 490                                                                 normal_or_gentle(
 491                                                                         _("%d frag spree! "),
 492                                                                         _("%d score spree! ")
 493                                                                 ),
 494                                                                 spree);
 495                                         }
 496                                         else { return ""; } // don't show spree information if it isn't an achievement
 497                                 }
 498                         }
 499
 500                         #undef SPREE_ITEM
 501                 }
 502                 else if(spree == -1) // first blood
 503                 {
 504                         return normal_or_gentle(_("First blood! "), _("First score! "));
 505                 }
 506                 else if(spree == -2) // first victim
 507                 {
 508                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 509                 }
 510         }
 511         return "";
 512 }
 513 #endif
 514
 515 string notif_arg_spree_inf(float type, string input, string player, float spree)
 516 {
 517         switch(type)
 518         {
 519                 case 1: // attacker kill spree
 520                 {
 521                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 522                         // this conditional (& 2) is true for 2 and 3
 523                         if(autocvar_notification_show_sprees_info & 2)
 524                         {
 525                                 #ifdef CSQC
 526                                 string spree_newline =
 527                                         ( autocvar_notification_show_sprees_info_newline ?
 528                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 529                                 #else
 530                                 string spree_newline =
 531                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 532                                 #endif
 533
 534                                 if(spree > 1)
 535                                 {
 536                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 537                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 538
 539                                         switch(spree)
 540                                         {
 541                                                 KILL_SPREE_LIST
 542                                                 default:
 543                                                 {
 544                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 545                                                         {
 546                                                                 return
 547                                                                         sprintf(
 548                                                                                 CCR(normal_or_gentle(
 549                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 550                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 551                                                                                 )),
 552                                                                                 player,
 553                                                                                 spree,
 554                                                                                 spree_newline
 555                                                                         );
 556                                                         }
 557                                                         else { return ""; } // don't show spree information if it isn't an achievement
 558                                                 }
 559                                         }
 560
 561                                         #undef SPREE_ITEM
 562                                 }
 563                                 else if(spree == -1) // firstblood
 564                                 {
 565                                         return
 566                                                 sprintf(
 567                                                         CCR(normal_or_gentle(
 568                                                                 _("%s^K1 drew first blood! %s^BG"),
 569                                                                 _("%s^K1 got the first score! %s^BG")
 570                                                         )),
 571                                                         player,
 572                                                         spree_newline
 573                                                 );
 574                                 }
 575                         }
 576                         break;
 577                 }
 578
 579                 case -1: // kill spree ended
 580                 {
 581                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 582                         {
 583                                 return
 584                                         sprintf(normal_or_gentle(
 585                                                 _(", ending their %d frag spree"),
 586                                                 _(", ending their %d score spree")
 587                                                 ),
 588                                                 spree
 589                                         );
 590                         }
 591                         break;
 592                 }
 593
 594                 case -2: // kill spree lost
 595                 {
 596                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 597                         {
 598                                 return
 599                                         sprintf(normal_or_gentle(
 600                                                 _(", losing their %d frag spree"),
 601                                                 _(", losing their %d score spree")
 602                                                 ),
 603                                                 spree
 604                                         );
 605                         }
 606                         break;
 607                 }
 608         }
 609         return "";
 610 }
 611
 612
 613 // ====================================
 614 //  Initialization/Create Declarations
 615 // ====================================
 616
 617 // common notification entity values
 618 .int nent_default;
 619 .bool nent_enabled;
 620 .MSG nent_type;
 621 .string nent_name;
 622 .int nent_stringcount;
 623 .int nent_floatcount;
 624
 625 // MSG_ANNCE entity values
 626 .int nent_channel;
 627 .string nent_snd;
 628 .float nent_vol;
 629 .float nent_position;
 630
 631 // MSG_INFO and MSG_CENTER entity values
 632 .string nent_args; // used by both
 633 .string nent_hudargs; // used by info
 634 .string nent_icon; // used by info
 635 .CPID nent_cpid; // used by center
 636 .string nent_durcnt; // used by center
 637 .string nent_string; // used by both
 638
 639 // MSG_MULTI entity values
 640 .entity nent_msgannce;
 641 .entity nent_msginfo;
 642 .entity nent_msgcenter;
 643
 644 // MSG_CHOICE entity values
 645 .float nent_challow_def;
 646 .float nent_challow_var;
 647 .entity nent_optiona;
 648 .entity nent_optionb;
 649
 650 // networked notification entity values
 651 #ifdef SVQC
 652 .NOTIF nent_broadcast;
 653 #endif
 654 .entity nent_client;
 655 .MSG nent_net_type;
 656 .float nent_net_name;
 657 .string nent_strings[4];
 658 .float nent_floats[4];
 659
 660 #define ACVNN(name) autocvar_notification_##name
 661
 662 REGISTRY(Notifications, BITS(11))
 663 REGISTER_REGISTRY(Notifications)
 664 REGISTRY_SORT(Notifications); STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 665 REGISTRY_CHECK(Notifications)
 666
 667 const int NOTIF_CHOICE_MAX = 50;
 668 int nent_choice_count = 0;
 669 .int nent_choice_idx;
 670 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 671 // initialization error detection
 672 bool notif_error;
 673 bool notif_global_error;
 674
 675 STATIC_INIT_LATE(Notif_Choices) {
 676         int c = 0;
 677         FOREACH(Notifications, it.nent_type == MSG_CHOICE, { c++; });
 678         if (c > NOTIF_CHOICE_MAX) {
 679                 LOG_FATALF("Too many MSG_CHOICE notifications (%d)", c);
 680         }
 681 }
 682
 683 Notification Get_Notif_Ent(MSG net_type, int net_name)
 684 {
 685         Notification it = _Notifications_from(net_name, NULL);
 686         if (it.nent_type != net_type) {
 687                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 688                         Get_Notif_TypeName(net_type), net_type,
 689                         it.registered_id, net_name,
 690                         Get_Notif_TypeName(it.nent_type)
 691                 );
 692                 return NULL;
 693         }
 694         return it;
 695 }
 696
 697 #define MSG_ANNCE_NOTIF(name, default, sound, channel, volume, position) \
 698         MSG_ANNCE_NOTIF_(ANNCE_##name, default, sound, channel, volume, position)
 699 #define MSG_ANNCE_NOTIF_(name, default, sound, channel, volume, position) \
 700         NOTIF_ADD_AUTOCVAR(name, default) \
 701         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 702                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_ANNCE, strtoupper(#name)); \
 703                 Create_Notification_Entity_Annce(this, ACVNN(name), strtoupper(#name), \
 704                         channel,   /* channel  */ \
 705                         sound,     /* snd      */ \
 706                         volume,    /* vol      */ \
 707                         position); /* position */ \
 708         }
 709
 710 #define MSG_INFO_NOTIF(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 711         MSG_INFO_NOTIF_(INFO_##name, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 712 #define MSG_INFO_NOTIF_(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 713         NOTIF_ADD_AUTOCVAR(name, default) \
 714         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 715                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name)); \
 716                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 717                         args,     /* args    */ \
 718                         hudargs,  /* hudargs */ \
 719                         icon,     /* icon    */ \
 720                         CPID_Null,/* cpid    */ \
 721                         "",       /* durcnt  */ \
 722                         normal,   /* normal  */ \
 723                         gentle);  /* gentle  */ \
 724         }
 725
 726 .string nent_iconargs;
 727 #define MULTIICON_INFO(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 728         MULTIICON_INFO_(INFO_##name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 729 #define MULTIICON_INFO_(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 730         NOTIF_ADD_AUTOCVAR(name, default) \
 731         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 732                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, strtoupper(#name)); \
 733                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 734                         args,     /* args    */ \
 735                         hudargs,  /* hudargs */ \
 736                         icon,     /* icon    */ \
 737                         CPID_Null,/* cpid    */ \
 738                         "",       /* durcnt  */ \
 739                         normal,   /* normal  */ \
 740                         gentle);  /* gentle  */ \
 741                 this.nent_iconargs = iconargs; \
 742         }
 743
 744 #define MSG_CENTER_NOTIF(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 745         MSG_CENTER_NOTIF_(CENTER_##name, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 746 #define MSG_CENTER_NOTIF_(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 747         NOTIF_ADD_AUTOCVAR(name, default) \
 748         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 749                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_CENTER, strtoupper(#name)); \
 750                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 751                         args,    /* args    */ \
 752                         "",      /* hudargs */ \
 753                         "",      /* icon    */ \
 754                         cpid,    /* cpid    */ \
 755                         durcnt,  /* durcnt  */ \
 756                         normal,  /* normal  */ \
 757                         gentle); /* gentle  */ \
 758         }
 759
 760 #define MSG_MULTI_NOTIF(name, default, anncename, infoname, centername) \
 761         NOTIF_ADD_AUTOCVAR(name, default) \
 762         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 763                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_MULTI, strtoupper(#name)); \
 764                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 765                         anncename,   /* anncename  */ \
 766                         infoname,    /* infoname   */ \
 767                         centername); /* centername */ \
 768         }
 769
 770 #define MSG_CHOICE_NOTIF(name, default, challow, chtype, optiona, optionb) \
 771         MSG_CHOICE_NOTIF_(CHOICE_##name, default, challow, chtype, optiona, optionb)
 772 #define MSG_CHOICE_NOTIF_(name, default, challow, chtype, optiona, optionb) \
 773         NOTIF_ADD_AUTOCVAR(name, default) \
 774         NOTIF_ADD_AUTOCVAR(name##_ALLOWED, challow) \
 775         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 776                 this.nent_choice_idx = nent_choice_count++; \
 777                 Create_Notification_Entity       (this, default, ACVNN(name), MSG_CHOICE, strtoupper(#name)); \
 778                 Create_Notification_Entity_Choice(this, ACVNN(name), strtoupper(#name), \
 779                         challow,                                 /* challow_def */ \
 780                         autocvar_notification_##name##_ALLOWED,  /* challow_var */ \
 781                         chtype,                                  /* chtype      */ \
 782                         optiona,                                 /* optiona     */ \
 783                         optionb);                                /* optionb     */ \
 784         }
 785
 786 REGISTRY_BEGIN(Notifications)
 787 {
 788         notif_global_error = false;
 789 }
 790
 791 REGISTRY_END(Notifications)
 792 {
 793         if (!notif_global_error) return;
 794         // shit happened... stop the loading of the program now if this is unacceptable
 795         if (autocvar_notification_errors_are_fatal)
 796                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 797         else
 798                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 799 }
 800
 801 #include "all.inc"