qcsrc/common/physics/player.qc

   1 #include "player.qh"
   2 #include "../mapobjects/_mod.qh"
   3 #include "../viewloc.qh"
   4
   5 #ifdef SVQC
   6
   7 #include <server/client.qh>
   8 #include <server/miscfunctions.qh>
   9 #include <common/mapobjects/defs.qh>
  10 #include "../mapobjects/trigger/viewloc.qh"
  11 #include <server/main.qh>
  12
  13 // client side physics
  14 bool Physics_Valid(string thecvar)
  15 {
  16         return thecvar != "" && thecvar && thecvar != "default" && strhasword(autocvar_g_physics_clientselect_options, thecvar);
  17 }
  18
  19 float Physics_ClientOption(entity this, string option, float defaultval)
  20 {
  21         if(!autocvar_g_physics_clientselect)
  22                 return defaultval;
  23
  24         if(IS_REAL_CLIENT(this) && Physics_Valid(CS(this).cvar_cl_physics))
  25         {
  26                 string s = strcat("g_physics_", CS(this).cvar_cl_physics, "_", option);
  27                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  28                         return cvar(s);
  29         }
  30         if(autocvar_g_physics_clientselect_default && autocvar_g_physics_clientselect_default != "" && autocvar_g_physics_clientselect_default != "default")
  31         {
  32                 // NOTE: not using Physics_Valid here, so the default can be forced to something normally unavailable
  33                 string s = strcat("g_physics_", autocvar_g_physics_clientselect_default, "_", option);
  34                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  35                         return cvar(s);
  36         }
  37         return defaultval;
  38 }
  39
  40 void Physics_UpdateStats(entity this)
  41 {
  42         // update this first, as it's used on all stats (wouldn't want to update them all manually from a mutator hook now, would we?)
  43         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
  44
  45         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this);
  46         float maxspd_mod = PHYS_HIGHSPEED(this) * ((this.swampslug.active == ACTIVE_ACTIVE) ? this.swampslug.swamp_slowdown : 1);
  47         STAT(MOVEVARS_MAXSPEED, this) = Physics_ClientOption(this, "maxspeed", autocvar_sv_maxspeed) * maxspd_mod; // also slow walking
  48         if (autocvar_g_movement_highspeed_q3_compat) {
  49           STAT(MOVEVARS_AIRACCEL_QW, this) = Physics_ClientOption(this, "airaccel_qw", autocvar_sv_airaccel_qw);
  50           STAT(MOVEVARS_AIRSTRAFEACCEL_QW, this) = Physics_ClientOption(this, "airstrafeaccel_qw", autocvar_sv_airstrafeaccel_qw);
  51           STAT(MOVEVARS_AIRSPEEDLIMIT_NONQW, this) = Physics_ClientOption(this, "airspeedlimit_nonqw", autocvar_sv_airspeedlimit_nonqw);
  52         } else {
  53           STAT(MOVEVARS_AIRACCEL_QW, this) = AdjustAirAccelQW(Physics_ClientOption(this, "airaccel_qw", autocvar_sv_airaccel_qw), maxspd_mod);
  54           STAT(MOVEVARS_AIRSTRAFEACCEL_QW, this) = (Physics_ClientOption(this, "airstrafeaccel_qw", autocvar_sv_airstrafeaccel_qw))
  55             ? AdjustAirAccelQW(Physics_ClientOption(this, "airstrafeaccel_qw", autocvar_sv_airstrafeaccel_qw), maxspd_mod)
  56             : 0;
  57           STAT(MOVEVARS_AIRSPEEDLIMIT_NONQW, this) = Physics_ClientOption(this, "airspeedlimit_nonqw", autocvar_sv_airspeedlimit_nonqw) * maxspd_mod;
  58         }
  59         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox; // NOTE: these hitboxes are off by 1 due to engine differences
  60         STAT(PL_MIN, this) = (q3dfcompat) ? '-15 -15 -20' : autocvar_sv_player_mins;
  61         STAT(PL_MAX, this) = (q3dfcompat) ? '15 15 36' : autocvar_sv_player_maxs;
  62         STAT(PL_VIEW_OFS, this) = (q3dfcompat) ? '0 0 30' : autocvar_sv_player_viewoffset;
  63         STAT(PL_CROUCH_MIN, this) = (q3dfcompat) ? '-15 -15 -20' : autocvar_sv_player_crouch_mins;
  64         STAT(PL_CROUCH_MAX, this) = (q3dfcompat) ? '15 15 20' : autocvar_sv_player_crouch_maxs;
  65         STAT(PL_CROUCH_VIEW_OFS, this) = (q3dfcompat) ? '0 0 16' : autocvar_sv_player_crouch_viewoffset;
  66
  67         // old stats
  68         // fix some new settings
  69         STAT(MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, this) = Physics_ClientOption(this, "airaccel_qw_stretchfactor", autocvar_sv_airaccel_qw_stretchfactor);
  70         STAT(MOVEVARS_MAXAIRSTRAFESPEED, this) = Physics_ClientOption(this, "maxairstrafespeed", autocvar_sv_maxairstrafespeed);
  71         if (autocvar_g_movement_highspeed_q3_compat) {
  72           STAT(MOVEVARS_MAXAIRSPEED, this) = Physics_ClientOption(this, "maxairspeed", autocvar_sv_maxairspeed) * maxspd_mod;
  73         } else {
  74           STAT(MOVEVARS_MAXAIRSPEED, this) = Physics_ClientOption(this, "maxairspeed", autocvar_sv_maxairspeed);
  75         }
  76
  77         STAT(MOVEVARS_AIRSTRAFEACCELERATE, this) = Physics_ClientOption(this, "airstrafeaccelerate", autocvar_sv_airstrafeaccelerate);
  78         STAT(MOVEVARS_WARSOWBUNNY_TURNACCEL, this) = Physics_ClientOption(this, "warsowbunny_turnaccel", autocvar_sv_warsowbunny_turnaccel);
  79         STAT(MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, this) = Physics_ClientOption(this, "airaccel_sideways_friction", autocvar_sv_airaccel_sideways_friction);
  80         STAT(MOVEVARS_AIRCONTROL, this) = Physics_ClientOption(this, "aircontrol", autocvar_sv_aircontrol);
  81         STAT(MOVEVARS_AIRCONTROL_POWER, this) = Physics_ClientOption(this, "aircontrol_power", autocvar_sv_aircontrol_power);
  82         STAT(MOVEVARS_AIRCONTROL_BACKWARDS, this) = Physics_ClientOption(this, "aircontrol_backwards", autocvar_sv_aircontrol_backwards);
  83         STAT(MOVEVARS_AIRCONTROL_SIDEWARDS, this) = Physics_ClientOption(this, "aircontrol_sidewards", autocvar_sv_aircontrol_sidewards);
  84         STAT(MOVEVARS_AIRCONTROL_PENALTY, this) = Physics_ClientOption(this, "aircontrol_penalty", autocvar_sv_aircontrol_penalty);
  85         STAT(MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, this) = Physics_ClientOption(this, "warsowbunny_airforwardaccel", autocvar_sv_warsowbunny_airforwardaccel);
  86         STAT(MOVEVARS_WARSOWBUNNY_TOPSPEED, this) = Physics_ClientOption(this, "warsowbunny_topspeed", autocvar_sv_warsowbunny_topspeed);
  87         STAT(MOVEVARS_WARSOWBUNNY_ACCEL, this) = Physics_ClientOption(this, "warsowbunny_accel", autocvar_sv_warsowbunny_accel);
  88         STAT(MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, this) = Physics_ClientOption(this, "warsowbunny_backtosideratio", autocvar_sv_warsowbunny_backtosideratio);
  89         STAT(MOVEVARS_FRICTION, this) = Physics_ClientOption(this, "friction", autocvar_sv_friction);
  90         STAT(MOVEVARS_ACCELERATE, this) = Physics_ClientOption(this, "accelerate", autocvar_sv_accelerate);
  91         STAT(MOVEVARS_STOPSPEED, this) = Physics_ClientOption(this, "stopspeed", autocvar_sv_stopspeed);
  92         STAT(MOVEVARS_AIRACCELERATE, this) = Physics_ClientOption(this, "airaccelerate", autocvar_sv_airaccelerate);
  93         STAT(MOVEVARS_AIRSTOPACCELERATE, this) = Physics_ClientOption(this, "airstopaccelerate", autocvar_sv_airstopaccelerate);
  94         STAT(MOVEVARS_JUMPVELOCITY, this) = Physics_ClientOption(this, "jumpvelocity", autocvar_sv_jumpvelocity);
  95         STAT(MOVEVARS_JUMPVELOCITY_CROUCH, this) = Physics_ClientOption(this, "jumpvelocity_crouch", autocvar_sv_jumpvelocity_crouch);
  96         STAT(MOVEVARS_TRACK_CANJUMP, this) = Physics_ClientOption(this, "track_canjump", autocvar_sv_track_canjump);
  97
  98         MUTATOR_CALLHOOK(PlayerPhysics_PostUpdateStats, this, maxspd_mod);
  99 }
 100 #endif
 101
 102 float IsMoveInDirection(vector mv, float ang) // key mix factor
 103 {
 104         if (mv_x == 0 && mv_y == 0)
 105                 return 0; // avoid division by zero
 106         ang -= RAD2DEG * atan2(mv_y, mv_x);
 107         ang = remainder(ang, 360) / 45;
 108         return ang > 1 ? 0 : ang < -1 ? 0 : 1 - fabs(ang);
 109 }
 110
 111 float GeomLerp(float a, float _lerp, float b)
 112 {
 113         return a == 0 ? (_lerp < 1 ? 0 : b)
 114                 : b == 0 ? (_lerp > 0 ? 0 : a)
 115                 : a * (fabs(b / a) ** _lerp);
 116 }
 117
 118 void PM_ClientMovement_UpdateStatus(entity this)
 119 {
 120         if(!IS_PLAYER(this))
 121                 return;
 122
 123         bool have_hook = false;
 124         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 125         {
 126         #if defined(CSQC)
 127                 entity wepent = viewmodels[slot];
 128         #elif defined(SVQC)
 129                 .entity weaponentity = weaponentities[slot];
 130                 entity wepent = this.(weaponentity);
 131         #endif
 132                 if(wepent.hook && !wasfreed(wepent.hook))
 133                 {
 134                         have_hook = true;
 135                         break;
 136                 }
 137         }
 138         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
 139         if(this.viewloc && !(this.viewloc.spawnflags & VIEWLOC_FREEMOVE) && PHYS_CS(this).movement.x < 0)
 140                 do_crouch = true;
 141         if (have_hook) {
 142                 do_crouch = false;
 143         //} else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
 144                 //do_crouch = false;
 145         } else if (PHYS_INVEHICLE(this)) {
 146                 do_crouch = false;
 147         } else if (STAT(FROZEN, this) || IS_DEAD(this)) {
 148                 do_crouch = false;
 149     }
 150
 151     MUTATOR_CALLHOOK(PlayerCanCrouch, this, do_crouch);
 152     do_crouch = M_ARGV(1, bool);
 153
 154         if (do_crouch) {
 155                 if (!IS_DUCKED(this)) {
 156                         SET_DUCKED(this);
 157                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
 158                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 159                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
 160                 }
 161         } else if (IS_DUCKED(this)) {
 162         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
 163         if (!trace_startsolid) {
 164             UNSET_DUCKED(this);
 165             this.view_ofs = STAT(PL_VIEW_OFS, this);
 166             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 167         }
 168         }
 169
 170         _Movetype_CheckWater(this); // needs to be run on the client, might as well use the latest on the server too!
 171 }
 172
 173 void CPM_PM_Aircontrol(entity this, float dt, vector wishdir, float wishspeed)
 174 {
 175         float movity = IsMoveInDirection(PHYS_CS(this).movement, 0);
 176         if(PHYS_AIRCONTROL_BACKWARDS(this))
 177                 movity += IsMoveInDirection(PHYS_CS(this).movement, 180);
 178         if(PHYS_AIRCONTROL_SIDEWARDS(this))
 179         {
 180                 movity += IsMoveInDirection(PHYS_CS(this).movement, 90);
 181                 movity += IsMoveInDirection(PHYS_CS(this).movement, -90);
 182         }
 183
 184         float k = 32 * (2 * movity - 1);
 185         if (k <= 0)
 186                 return;
 187
 188         k *= bound(0, wishspeed / PHYS_MAXAIRSPEED(this), 1);
 189
 190         float zspeed = this.velocity_z;
 191         this.velocity_z = 0;
 192         float xyspeed = vlen(this.velocity);
 193         this.velocity = normalize(this.velocity);
 194
 195         float dot = this.velocity * wishdir;
 196
 197         if (dot > 0) // we can't change direction while slowing down
 198         {
 199                 k *= (dot ** PHYS_AIRCONTROL_POWER(this)) * dt;
 200                 xyspeed = max(0, xyspeed - PHYS_AIRCONTROL_PENALTY(this) * sqrt(max(0, 1 - dot*dot)) * k/32);
 201                 k *= PHYS_AIRCONTROL(this);
 202                 this.velocity = normalize(this.velocity * xyspeed + wishdir * k);
 203         }
 204
 205         this.velocity = this.velocity * xyspeed;
 206         this.velocity_z = zspeed;
 207 }
 208
 209 float AdjustAirAccelQW(float accelqw, float factor)
 210 {
 211         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 212 }
 213
 214 // example config for alternate speed clamping:
 215 //   sv_airaccel_qw 0.8
 216 //   sv_airaccel_sideways_friction 0
 217 //   prvm_globalset server speedclamp_mode 1
 218 //     (or 2)
 219 void PM_Accelerate(entity this, float dt, vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 220 {
 221         float speedclamp = stretchfactor > 0 ? stretchfactor
 222         : accelqw < 0 ? 1 // full clamping, no stretch
 223         : -1; // no clamping
 224
 225         accelqw = fabs(accelqw);
 226
 227         if (GAMEPLAYFIX_Q2AIRACCELERATE)
 228                 wishspeed0 = wishspeed; // don't need to emulate this Q1 bug
 229
 230         float vel_straight = this.velocity * wishdir;
 231         float vel_z = this.velocity_z;
 232         vector vel_xy = vec2(this.velocity);
 233         vector vel_perpend = vel_xy - vel_straight * wishdir;
 234
 235         float step = accel * dt * wishspeed0;
 236
 237         float vel_xy_current  = vlen(vel_xy);
 238         if (speedlimit)
 239                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 240         float vel_xy_forward =  vel_xy_current  + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 241         float vel_xy_backward = vel_xy_current  - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 242         vel_xy_backward = max(0, vel_xy_backward); // not that it REALLY occurs that this would cause wrong behaviour afterwards
 243         vel_straight =          vel_straight    + bound(0, wishspeed - vel_straight,   step) * accelqw + step * (1 - accelqw);
 244
 245         if (sidefric < 0 && (vel_perpend*vel_perpend))
 246                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 247         {
 248                 float f = max(0, 1 + dt * wishspeed * sidefric);
 249                 float themin = (vel_xy_backward * vel_xy_backward - vel_straight * vel_straight) / (vel_perpend * vel_perpend);
 250                 // assume: themin > 1
 251                 // vel_xy_backward*vel_xy_backward - vel_straight*vel_straight > vel_perpend*vel_perpend
 252                 // vel_xy_backward*vel_xy_backward > vel_straight*vel_straight + vel_perpend*vel_perpend
 253                 // vel_xy_backward*vel_xy_backward > vel_xy * vel_xy
 254                 // obviously, this cannot be
 255                 if (themin <= 0)
 256                         vel_perpend *= f;
 257                 else
 258                 {
 259                         themin = sqrt(themin);
 260                         vel_perpend *= max(themin, f);
 261                 }
 262         }
 263         else
 264                 vel_perpend *= max(0, 1 - dt * wishspeed * sidefric);
 265
 266         vel_xy = vel_straight * wishdir + vel_perpend;
 267
 268         if (speedclamp >= 0)
 269         {
 270                 float vel_xy_preclamp;
 271                 vel_xy_preclamp = vlen(vel_xy);
 272                 if (vel_xy_preclamp > 0) // prevent division by zero
 273                 {
 274                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 275                         if (vel_xy_current < vel_xy_preclamp)
 276                                 vel_xy *= (vel_xy_current / vel_xy_preclamp);
 277                 }
 278         }
 279
 280         this.velocity = vel_xy + vel_z * '0 0 1';
 281 }
 282
 283 void PM_AirAccelerate(entity this, float dt, vector wishdir, float wishspeed)
 284 {
 285         if (wishspeed == 0)
 286                 return;
 287
 288         vector curvel = this.velocity;
 289         curvel_z = 0;
 290         float curspeed = vlen(curvel);
 291
 292         if (wishspeed > curspeed * 1.01)
 293                 wishspeed = min(wishspeed, curspeed + PHYS_WARSOWBUNNY_AIRFORWARDACCEL(this) * PHYS_MAXSPEED(this) * dt);
 294         else
 295         {
 296                 float f = max(0, (PHYS_WARSOWBUNNY_TOPSPEED(this) - curspeed) / (PHYS_WARSOWBUNNY_TOPSPEED(this) - PHYS_MAXSPEED(this)));
 297                 wishspeed = max(curspeed, PHYS_MAXSPEED(this)) + PHYS_WARSOWBUNNY_ACCEL(this) * f * PHYS_MAXSPEED(this) * dt;
 298         }
 299         vector wishvel = wishdir * wishspeed;
 300         vector acceldir = wishvel - curvel;
 301         float addspeed = vlen(acceldir);
 302         acceldir = normalize(acceldir);
 303
 304         float accelspeed = min(addspeed, PHYS_WARSOWBUNNY_TURNACCEL(this) * PHYS_MAXSPEED(this) * dt);
 305
 306         if (PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this) < 1)
 307         {
 308                 vector curdir = normalize(curvel);
 309                 float dot = acceldir * curdir;
 310                 if (dot < 0)
 311                         acceldir -= (1 - PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this)) * dot * curdir;
 312         }
 313
 314         this.velocity += accelspeed * acceldir;
 315 }
 316
 317
 318 /*
 319 =============
 320 PlayerJump
 321
 322 When you press the jump key
 323 returns true if handled
 324 =============
 325 */
 326 bool PlayerJump(entity this)
 327 {
 328         if (PHYS_FROZEN(this))
 329                 return true; // no jumping in freezetag when frozen
 330
 331         if(PHYS_INPUT_BUTTON_CHAT(this) || PHYS_INPUT_BUTTON_MINIGAME(this))
 332                 return true; // no jumping while typing
 333
 334 #ifdef SVQC
 335         if (this.player_blocked)
 336                 return true; // no jumping while blocked
 337 #endif
 338
 339         bool doublejump = false;
 340         float mjumpheight = ((PHYS_JUMPVELOCITY_CROUCH(this) && IS_DUCKED(this)) ? PHYS_JUMPVELOCITY_CROUCH(this) : PHYS_JUMPVELOCITY(this));
 341         bool track_jump = PHYS_CL_TRACK_CANJUMP(this);
 342
 343         if (MUTATOR_CALLHOOK(PlayerJump, this, mjumpheight, doublejump))
 344                 return true;
 345
 346         mjumpheight = M_ARGV(1, float);
 347         doublejump = M_ARGV(2, bool);
 348
 349         if (this.waterlevel >= WATERLEVEL_SWIMMING)
 350         {
 351                 if(this.viewloc)
 352                 {
 353                         doublejump = true;
 354                         mjumpheight *= 0.7;
 355                         track_jump = true;
 356                 }
 357                 else
 358                 {
 359                         this.velocity_z = PHYS_MAXSPEED(this) * 0.7;
 360                         return true;
 361                 }
 362         }
 363
 364         if (!doublejump)
 365                 if (!IS_ONGROUND(this))
 366                         return IS_JUMP_HELD(this);
 367
 368         if(PHYS_TRACK_CANJUMP(this))
 369                 track_jump = true;
 370
 371         if (track_jump)
 372                 if (IS_JUMP_HELD(this))
 373                         return true;
 374
 375         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 376         // velocity bounds.  Final velocity is bound between (jumpheight *
 377         // min + jumpheight) and (jumpheight * max + jumpheight);
 378
 379         if(PHYS_JUMPSPEEDCAP_MIN != "")
 380         {
 381                 float minjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MIN);
 382
 383                 if (this.velocity_z < minjumpspeed)
 384                         mjumpheight += minjumpspeed - this.velocity_z;
 385         }
 386
 387         if(PHYS_JUMPSPEEDCAP_MAX != "")
 388         {
 389                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 390                 tracebox(this.origin + '0 0 0.01', this.mins, this.maxs, this.origin - '0 0 0.01', MOVE_NORMAL, this);
 391
 392                 if (!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS(this)))
 393                 {
 394                         float maxjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MAX);
 395
 396                         if (this.velocity_z > maxjumpspeed)
 397                                 mjumpheight -= this.velocity_z - maxjumpspeed;
 398                 }
 399         }
 400
 401         if (!WAS_ONGROUND(this) && !WAS_ONSLICK(this))
 402         {
 403 #ifdef SVQC
 404                 if(autocvar_speedmeter)
 405                         LOG_TRACE("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")");
 406 #endif
 407                 if(this.lastground < time - 0.3)
 408                 {
 409                         float f = (1 - PHYS_FRICTION_ONLAND(this));
 410                         this.velocity_x *= f;
 411                         this.velocity_y *= f;
 412                 }
 413 #ifdef SVQC
 414                 if(this.jumppadcount > 1)
 415                         LOG_TRACE(ftos(this.jumppadcount), "x jumppad combo");
 416                 this.jumppadcount = 0;
 417 #endif
 418         }
 419
 420         this.velocity_z += mjumpheight;
 421
 422         UNSET_ONGROUND(this);
 423         UNSET_ONSLICK(this);
 424         SET_JUMP_HELD(this);
 425
 426 #ifdef SVQC
 427         animdecide_setaction(this, ANIMACTION_JUMP, true);
 428
 429         if (autocvar_g_jump_grunt)
 430                 PlayerSound(this, playersound_jump, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 431 #endif
 432         return true;
 433 }
 434
 435 void CheckWaterJump(entity this)
 436 {
 437 // check for a jump-out-of-water
 438         makevectors(this.v_angle);
 439         vector start = this.origin;
 440         start_z += 8;
 441         v_forward_z = 0;
 442         normalize(v_forward);
 443         vector end = start + v_forward*24;
 444         traceline (start, end, true, this);
 445         if (trace_fraction < 1)
 446         {       // solid at waist
 447                 start_z = start_z + this.maxs_z - 8;
 448                 end = start + v_forward*24;
 449                 this.movedir = trace_plane_normal * -50;
 450                 traceline(start, end, true, this);
 451                 if (trace_fraction == 1)
 452                 {       // open at eye level
 453                         this.velocity_z = 225;
 454                         this.flags |= FL_WATERJUMP;
 455                         SET_JUMP_HELD(this);
 456                 }
 457         }
 458 }
 459
 460
 461 #ifdef SVQC
 462         #define JETPACK_JUMP(s) CS(s).cvar_cl_jetpack_jump
 463 #elif defined(CSQC)
 464         float autocvar_cl_jetpack_jump;
 465         #define JETPACK_JUMP(s) autocvar_cl_jetpack_jump
 466 #endif
 467 .float jetpack_stopped;
 468 void CheckPlayerJump(entity this)
 469 {
 470 #ifdef SVQC
 471         bool was_flying = boolean(ITEMS_STAT(this) & IT_USING_JETPACK);
 472 #endif
 473         if (JETPACK_JUMP(this) < 2)
 474                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 475
 476         if(PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this))
 477         {
 478                 bool playerjump = PlayerJump(this); // required
 479
 480                 bool air_jump = !playerjump || M_ARGV(2, bool);
 481                 bool activate = (JETPACK_JUMP(this) && air_jump && PHYS_INPUT_BUTTON_JUMP(this)) || PHYS_INPUT_BUTTON_JETPACK(this);
 482                 bool has_fuel = !PHYS_JETPACK_FUEL(this) || PHYS_AMMO_FUEL(this) || (ITEMS_STAT(this) & IT_UNLIMITED_AMMO);
 483
 484                 if (!(ITEMS_STAT(this) & ITEM_Jetpack.m_itemid)) { }
 485                 else if (this.jetpack_stopped) { }
 486                 else if (!has_fuel)
 487                 {
 488 #ifdef SVQC
 489                         if (was_flying) // TODO: ran out of fuel message
 490                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 491                         else if (activate)
 492                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 493 #endif
 494                         this.jetpack_stopped = true;
 495                         ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 496                 }
 497                 else if (activate && !PHYS_FROZEN(this))
 498                         ITEMS_STAT(this) |= IT_USING_JETPACK;
 499         }
 500         else
 501         {
 502                 this.jetpack_stopped = false;
 503                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 504         }
 505         if (!PHYS_INPUT_BUTTON_JUMP(this))
 506                 UNSET_JUMP_HELD(this);
 507
 508         if (this.waterlevel == WATERLEVEL_SWIMMING)
 509                 CheckWaterJump(this);
 510 }
 511
 512 #ifdef SVQC
 513 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 514 .float specialcommand_pos;
 515 void SpecialCommand(entity this)
 516 {
 517         if(autocvar_sv_cheats || this.maycheat)
 518         {
 519                 if (!CheatImpulse(this, CHIMPULSE_GIVE_ALL.impulse))
 520                         LOG_INFO("A hollow voice says \"Plugh\".");
 521         }
 522         else
 523                 STAT(MOVEVARS_SPECIALCOMMAND, this) = true;
 524 }
 525 #endif
 526
 527 bool PM_check_specialcommand(entity this, int buttons)
 528 {
 529 #ifdef SVQC
 530         string c;
 531         if (!buttons)
 532                 c = "x";
 533         else if (buttons == 1)
 534                 c = "1";
 535         else if (buttons == 2)
 536                 c = " ";
 537         else if (buttons == 128)
 538                 c = "s";
 539         else if (buttons == 256)
 540                 c = "w";
 541         else if (buttons == 512)
 542                 c = "a";
 543         else if (buttons == 1024)
 544                 c = "d";
 545         else
 546                 c = "?";
 547
 548         if (c == substring(specialcommand, CS(this).specialcommand_pos, 1))
 549         {
 550                 CS(this).specialcommand_pos += 1;
 551                 if (CS(this).specialcommand_pos >= strlen(specialcommand))
 552                 {
 553                         CS(this).specialcommand_pos = 0;
 554                         SpecialCommand(this);
 555                         return true;
 556                 }
 557         }
 558         else if (CS(this).specialcommand_pos && (c != substring(specialcommand, CS(this).specialcommand_pos - 1, 1)))
 559                 CS(this).specialcommand_pos = 0;
 560 #endif
 561         return false;
 562 }
 563
 564 void PM_check_nickspam(entity this)
 565 {
 566 #ifdef SVQC
 567         if (time >= this.nickspamtime)
 568                 return;
 569         if (this.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 570         {
 571                 // slight annoyance for nick change scripts
 572                 PHYS_CS(this).movement = -1 * PHYS_CS(this).movement;
 573                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_ZOOM(this) = PHYS_INPUT_BUTTON_CROUCH(this) = PHYS_INPUT_BUTTON_HOOK(this) = PHYS_INPUT_BUTTON_USE(this) = false;
 574
 575                 if (this.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 576                 {
 577                         this.v_angle_x = random() * 360;
 578                         this.v_angle_y = random() * 360;
 579                         // at least I'm not forcing retardedview by also assigning to angles_z
 580                         this.fixangle = true;
 581                 }
 582         }
 583 #endif
 584 }
 585
 586 void PM_check_punch(entity this, float dt)
 587 {
 588 #ifdef SVQC
 589         if (this.punchangle != '0 0 0')
 590         {
 591                 float f = vlen(this.punchangle) - 10 * dt;
 592                 if (f > 0)
 593                         this.punchangle = normalize(this.punchangle) * f;
 594                 else
 595                         this.punchangle = '0 0 0';
 596         }
 597
 598         if (this.punchvector != '0 0 0')
 599         {
 600                 float f = vlen(this.punchvector) - 30 * dt;
 601                 if (f > 0)
 602                         this.punchvector = normalize(this.punchvector) * f;
 603                 else
 604                         this.punchvector = '0 0 0';
 605         }
 606 #endif
 607 }
 608
 609 // predict frozen movement, as frozen players CAN move in some cases
 610 void PM_check_frozen(entity this)
 611 {
 612         if (!PHYS_FROZEN(this))
 613                 return;
 614         if (PHYS_DODGING_FROZEN(this) && IS_CLIENT(this))
 615         {
 616                 // bind movement to a very slow speed so dodging can use .movement for directional calculations
 617                 PHYS_CS(this).movement_x = bound(-2, PHYS_CS(this).movement.x, 2);
 618                 PHYS_CS(this).movement_y = bound(-2, PHYS_CS(this).movement.y, 2);
 619                 PHYS_CS(this).movement_z = bound(-2, PHYS_CS(this).movement.z, 2);
 620         }
 621         else
 622                 PHYS_CS(this).movement = '0 0 0';
 623 }
 624
 625 void PM_check_hitground(entity this)
 626 {
 627 #ifdef SVQC
 628         if (!this.wasFlying) return;
 629     this.wasFlying = false;
 630     if (this.waterlevel >= WATERLEVEL_SWIMMING) return;
 631     if (this.ladder_entity) return;
 632     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 633     {
 634         .entity weaponentity = weaponentities[slot];
 635         if(this.(weaponentity).hook)
 636                 return;
 637     }
 638     this.nextstep = time + 0.3 + random() * 0.1;
 639     trace_dphitq3surfaceflags = 0;
 640     tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 641     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 642     entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 643         ? GS_FALL_METAL
 644         : GS_FALL;
 645     float vol = ((IS_DUCKED(this)) ? VOL_MUFFLED : VOL_BASE);
 646     GlobalSound(this, gs, CH_PLAYER, vol, VOICETYPE_PLAYERSOUND);
 647 #endif
 648 }
 649
 650 void PM_Footsteps(entity this)
 651 {
 652 #ifdef SVQC
 653         if (!g_footsteps) return;
 654         if (IS_DUCKED(this)) return;
 655         if (time >= this.lastground + 0.2) return;
 656         if (vdist(this.velocity, <=, autocvar_sv_maxspeed * 0.6)) return;
 657         if ((time > this.nextstep) || (time < (this.nextstep - 10.0)))
 658         {
 659                 this.nextstep = time + 0.3 + random() * 0.1;
 660                 trace_dphitq3surfaceflags = 0;
 661                 tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 662                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 663                 entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 664                         ? GS_STEP_METAL
 665                         : GS_STEP;
 666                 GlobalSound(this, gs, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 667         }
 668 #endif
 669 }
 670
 671 void PM_check_slick(entity this)
 672 {
 673         if(!IS_ONGROUND(this))
 674                 return;
 675
 676         trace_dphitq3surfaceflags = 0;
 677         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 678         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
 679                 SET_ONSLICK(this);
 680         else
 681                 UNSET_ONSLICK(this);
 682 }
 683
 684 void PM_check_blocked(entity this)
 685 {
 686         if(PHYS_INPUT_BUTTON_CHAT(this) || PHYS_INPUT_BUTTON_MINIGAME(this))
 687                 PHYS_CS(this).movement = '0 0 0';
 688 #ifdef SVQC
 689         if (!this.player_blocked)
 690                 return;
 691         PHYS_CS(this).movement = '0 0 0';
 692         this.disableclientprediction = 1;
 693 #endif
 694 }
 695
 696 void PM_jetpack(entity this, float maxspd_mod, float dt)
 697 {
 698         //makevectors(this.v_angle.y * '0 1 0');
 699         makevectors(this.v_angle);
 700         vector wishvel = v_forward * PHYS_CS(this).movement_x
 701                                         + v_right * PHYS_CS(this).movement_y;
 702         // add remaining speed as Z component
 703         float maxairspd = PHYS_MAXAIRSPEED(this) * max(1, maxspd_mod);
 704         // fix speedhacks :P
 705         wishvel = normalize(wishvel) * min(1, vlen(wishvel) / maxairspd);
 706         // add the unused velocity as up component
 707         wishvel_z = 0;
 708
 709         // if (PHYS_INPUT_BUTTON_JUMP(this))
 710                 wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 711
 712         // it is now normalized, so...
 713         float a_side = PHYS_JETPACK_ACCEL_SIDE(this);
 714         float a_up = PHYS_JETPACK_ACCEL_UP(this);
 715         float a_add = PHYS_JETPACK_ANTIGRAVITY(this) * PHYS_GRAVITY(this);
 716
 717         if(PHYS_JETPACK_REVERSE_THRUST(this) && PHYS_INPUT_BUTTON_CROUCH(this)) { a_up = PHYS_JETPACK_REVERSE_THRUST(this); }
 718
 719         wishvel_x *= a_side;
 720         wishvel_y *= a_side;
 721         wishvel_z *= a_up;
 722         wishvel_z += a_add;
 723
 724         if(PHYS_JETPACK_REVERSE_THRUST(this) && PHYS_INPUT_BUTTON_CROUCH(this)) { wishvel_z *= -1; }
 725
 726         float best = 0;
 727         //////////////////////////////////////////////////////////////////////////////////////
 728         // finding the maximum over all vectors of above form
 729         // with wishvel having an absolute value of 1
 730         //////////////////////////////////////////////////////////////////////////////////////
 731         // we're finding the maximum over
 732         //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 733         // for z in the range from -1 to 1
 734         //////////////////////////////////////////////////////////////////////////////////////
 735         // maximum is EITHER attained at the single extreme point:
 736         float a_diff = a_side * a_side - a_up * a_up;
 737         float f;
 738         if (a_diff != 0)
 739         {
 740                 f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 741                 if (f > -1 && f < 1) // can it be attained?
 742                 {
 743                         best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 744                         //print("middle\n");
 745                 }
 746         }
 747         // OR attained at z = 1:
 748         f = (a_up + a_add) * (a_up + a_add);
 749         if (f > best)
 750         {
 751                 best = f;
 752                 //print("top\n");
 753         }
 754         // OR attained at z = -1:
 755         f = (a_up - a_add) * (a_up - a_add);
 756         if (f > best)
 757         {
 758                 best = f;
 759                 //print("bottom\n");
 760         }
 761         best = sqrt(best);
 762         //////////////////////////////////////////////////////////////////////////////////////
 763
 764         //print("best possible acceleration: ", ftos(best), "\n");
 765
 766         float fxy, fz;
 767         fxy = bound(0, 1 - (this.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / PHYS_JETPACK_MAXSPEED_SIDE(this), 1);
 768         if (wishvel_z - PHYS_GRAVITY(this) > 0)
 769                 fz = bound(0, 1 - this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
 770         else
 771                 fz = bound(0, 1 + this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
 772
 773         float fvel;
 774         fvel = vlen(wishvel);
 775         wishvel_x *= fxy;
 776         wishvel_y *= fxy;
 777         wishvel_z = (wishvel_z - PHYS_GRAVITY(this)) * fz + PHYS_GRAVITY(this);
 778
 779         fvel = min(1, vlen(wishvel) / best);
 780         if (PHYS_JETPACK_FUEL(this) && !(ITEMS_STAT(this) & IT_UNLIMITED_AMMO))
 781                 f = min(1, PHYS_AMMO_FUEL(this) / (PHYS_JETPACK_FUEL(this) * dt * fvel));
 782         else
 783                 f = 1;
 784
 785         //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 786
 787         if (f > 0 && wishvel != '0 0 0')
 788         {
 789                 this.velocity = this.velocity + wishvel * f * dt;
 790                 UNSET_ONGROUND(this);
 791
 792 #ifdef SVQC
 793                 if (!(ITEMS_STAT(this) & IT_UNLIMITED_AMMO))
 794                         TakeResource(this, RES_FUEL, PHYS_JETPACK_FUEL(this) * dt * fvel * f);
 795
 796                 ITEMS_STAT(this) |= IT_USING_JETPACK;
 797
 798                 // jetpack also inhibits health regeneration, but only for 1 second
 799                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 800 #endif
 801         }
 802 }
 803
 804 // used for calculating airshots
 805 bool IsFlying(entity this)
 806 {
 807         if(IS_ONGROUND(this))
 808                 return false;
 809         if(this.waterlevel >= WATERLEVEL_SWIMMING)
 810                 return false;
 811         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 24', MOVE_NORMAL, this);
 812         //traceline(this.origin, this.origin - '0 0 48', MOVE_NORMAL, this);
 813         if(trace_fraction < 1)
 814                 return false;
 815         return true;
 816 }
 817
 818
 819 void sys_phys_update(entity this, float dt);
 820 #if defined(SVQC)
 821 void SV_PlayerPhysics(entity this)
 822 #elif defined(CSQC)
 823 void CSQC_ClientMovement_PlayerMove_Frame(entity this)
 824 #endif
 825 {
 826 #ifdef SVQC
 827         // needs to be called before physics are run!
 828         if(IS_REAL_CLIENT(this))
 829                 PM_UpdateButtons(this, CS(this));
 830 #endif
 831
 832         sys_phys_update(this, PHYS_INPUT_TIMELENGTH);
 833
 834 #ifdef SVQC
 835         CS(this).pm_frametime = frametime;
 836 #elif defined(CSQC)
 837         if((ITEMS_STAT(this) & IT_USING_JETPACK) && !IS_DEAD(this) && !intermission)
 838                 this.csqcmodel_modelflags |= MF_ROCKET;
 839         else
 840                 this.csqcmodel_modelflags &= ~MF_ROCKET;
 841 #endif
 842 }