qcsrc/common/physics/player.qc

   1 #include "player.qh"
   2 #include "../triggers/include.qh"
   3 #include "../viewloc.qh"
   4
   5 #ifdef SVQC
   6
   7 #include <server/miscfunctions.qh>
   8 #include "../triggers/trigger/viewloc.qh"
   9
  10 // client side physics
  11 bool Physics_Valid(string thecvar)
  12 {
  13         return autocvar_g_physics_clientselect && strhasword(autocvar_g_physics_clientselect_options, thecvar);
  14 }
  15
  16 float Physics_ClientOption(entity this, string option, float defaultval)
  17 {
  18         if(Physics_Valid(this.cvar_cl_physics))
  19         {
  20                 string s = sprintf("g_physics_%s_%s", this.cvar_cl_physics, option);
  21                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  22                         return cvar(s);
  23         }
  24         if(autocvar_g_physics_clientselect && autocvar_g_physics_clientselect_default)
  25         {
  26                 string s = sprintf("g_physics_%s_%s", autocvar_g_physics_clientselect_default, option);
  27                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  28                         return cvar(s);
  29         }
  30         return defaultval;
  31 }
  32
  33 void Physics_UpdateStats(entity this, float maxspd_mod)
  34 {
  35         STAT(MOVEVARS_AIRACCEL_QW, this) = AdjustAirAccelQW(Physics_ClientOption(this, "airaccel_qw", autocvar_sv_airaccel_qw), maxspd_mod);
  36         STAT(MOVEVARS_AIRSTRAFEACCEL_QW, this) = (Physics_ClientOption(this, "airstrafeaccel_qw", autocvar_sv_airstrafeaccel_qw))
  37                 ? AdjustAirAccelQW(Physics_ClientOption(this, "airstrafeaccel_qw", autocvar_sv_airstrafeaccel_qw), maxspd_mod)
  38                 : 0;
  39         STAT(MOVEVARS_AIRSPEEDLIMIT_NONQW, this) = Physics_ClientOption(this, "airspeedlimit_nonqw", autocvar_sv_airspeedlimit_nonqw) * maxspd_mod;
  40         STAT(MOVEVARS_MAXSPEED, this) = Physics_ClientOption(this, "maxspeed", autocvar_sv_maxspeed) * maxspd_mod; // also slow walking
  41
  42         STAT(PL_MIN, this) = autocvar_sv_player_mins;
  43         STAT(PL_MAX, this) = autocvar_sv_player_maxs;
  44         STAT(PL_VIEW_OFS, this) = autocvar_sv_player_viewoffset;
  45         STAT(PL_CROUCH_MIN, this) = autocvar_sv_player_crouch_mins;
  46         STAT(PL_CROUCH_MAX, this) = autocvar_sv_player_crouch_maxs;
  47         STAT(PL_CROUCH_VIEW_OFS, this) = autocvar_sv_player_crouch_viewoffset;
  48
  49         // old stats
  50         // fix some new settings
  51         STAT(MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, this) = Physics_ClientOption(this, "airaccel_qw_stretchfactor", autocvar_sv_airaccel_qw_stretchfactor);
  52         STAT(MOVEVARS_MAXAIRSTRAFESPEED, this) = Physics_ClientOption(this, "maxairstrafespeed", autocvar_sv_maxairstrafespeed);
  53         STAT(MOVEVARS_MAXAIRSPEED, this) = Physics_ClientOption(this, "maxairspeed", autocvar_sv_maxairspeed);
  54         STAT(MOVEVARS_AIRSTRAFEACCELERATE, this) = Physics_ClientOption(this, "airstrafeaccelerate", autocvar_sv_airstrafeaccelerate);
  55         STAT(MOVEVARS_WARSOWBUNNY_TURNACCEL, this) = Physics_ClientOption(this, "warsowbunny_turnaccel", autocvar_sv_warsowbunny_turnaccel);
  56         STAT(MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, this) = Physics_ClientOption(this, "airaccel_sideways_friction", autocvar_sv_airaccel_sideways_friction);
  57         STAT(MOVEVARS_AIRCONTROL, this) = Physics_ClientOption(this, "aircontrol", autocvar_sv_aircontrol);
  58         STAT(MOVEVARS_AIRCONTROL_POWER, this) = Physics_ClientOption(this, "aircontrol_power", autocvar_sv_aircontrol_power);
  59         STAT(MOVEVARS_AIRCONTROL_BACKWARDS, this) = Physics_ClientOption(this, "aircontrol_backwards", autocvar_sv_aircontrol_backwards);
  60         STAT(MOVEVARS_AIRCONTROL_PENALTY, this) = Physics_ClientOption(this, "aircontrol_penalty", autocvar_sv_aircontrol_penalty);
  61         STAT(MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, this) = Physics_ClientOption(this, "warsowbunny_airforwardaccel", autocvar_sv_warsowbunny_airforwardaccel);
  62         STAT(MOVEVARS_WARSOWBUNNY_TOPSPEED, this) = Physics_ClientOption(this, "warsowbunny_topspeed", autocvar_sv_warsowbunny_topspeed);
  63         STAT(MOVEVARS_WARSOWBUNNY_ACCEL, this) = Physics_ClientOption(this, "warsowbunny_accel", autocvar_sv_warsowbunny_accel);
  64         STAT(MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, this) = Physics_ClientOption(this, "warsowbunny_backtosideratio", autocvar_sv_warsowbunny_backtosideratio);
  65         STAT(MOVEVARS_FRICTION, this) = Physics_ClientOption(this, "friction", autocvar_sv_friction);
  66         STAT(MOVEVARS_ACCELERATE, this) = Physics_ClientOption(this, "accelerate", autocvar_sv_accelerate);
  67         STAT(MOVEVARS_STOPSPEED, this) = Physics_ClientOption(this, "stopspeed", autocvar_sv_stopspeed);
  68         STAT(MOVEVARS_AIRACCELERATE, this) = Physics_ClientOption(this, "airaccelerate", autocvar_sv_airaccelerate);
  69         STAT(MOVEVARS_AIRSTOPACCELERATE, this) = Physics_ClientOption(this, "airstopaccelerate", autocvar_sv_airstopaccelerate);
  70         STAT(MOVEVARS_JUMPVELOCITY, this) = Physics_ClientOption(this, "jumpvelocity", autocvar_sv_jumpvelocity);
  71         STAT(MOVEVARS_TRACK_CANJUMP, this) = Physics_ClientOption(this, "track_canjump", autocvar_sv_track_canjump);
  72 }
  73 #endif
  74
  75 float IsMoveInDirection(vector mv, float ang) // key mix factor
  76 {
  77         if (mv_x == 0 && mv_y == 0)
  78                 return 0; // avoid division by zero
  79         ang -= RAD2DEG * atan2(mv_y, mv_x);
  80         ang = remainder(ang, 360) / 45;
  81         return ang > 1 ? 0 : ang < -1 ? 0 : 1 - fabs(ang);
  82 }
  83
  84 float GeomLerp(float a, float _lerp, float b)
  85 {
  86         return a == 0 ? (_lerp < 1 ? 0 : b)
  87                 : b == 0 ? (_lerp > 0 ? 0 : a)
  88                 : a * pow(fabs(b / a), _lerp);
  89 }
  90
  91 void PM_ClientMovement_UpdateStatus(entity this)
  92 {
  93 #ifdef CSQC
  94         if(!IS_PLAYER(this))
  95                 return;
  96
  97         // set crouched
  98         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
  99         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 100         {
 101                 entity wep = viewmodels[slot];
 102                 if(wep.hook && !wasfreed(wep.hook))
 103                 {
 104                         do_crouch = false;
 105                         break; // don't bother checking the others
 106                 }
 107         }
 108         if(this.waterlevel >= WATERLEVEL_SWIMMING)
 109                 do_crouch = false;
 110         if(hud != HUD_NORMAL)
 111                 do_crouch = false;
 112         if(STAT(FROZEN, this))
 113                 do_crouch = false;
 114
 115         if (do_crouch)
 116         {
 117                 // wants to crouch, this always works
 118                 if (!IS_DUCKED(this)) SET_DUCKED(this);
 119         }
 120         else
 121         {
 122                 // wants to stand, if currently crouching we need to check for a low ceiling first
 123                 if (IS_DUCKED(this))
 124                 {
 125                         tracebox(this.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), this.origin, MOVE_NORMAL, this);
 126                         if (!trace_startsolid) UNSET_DUCKED(this);
 127                 }
 128         }
 129
 130         if (IS_ONGROUND(this) || this.velocity.z <= 0 || PHYS_WATERJUMP_TIME(this) <= 0)
 131                 PHYS_WATERJUMP_TIME(this) = 0;
 132 #endif
 133 }
 134
 135 void CPM_PM_Aircontrol(entity this, float dt, vector wishdir, float wishspeed)
 136 {
 137         float movity = IsMoveInDirection(this.movement, 0);
 138         if(PHYS_AIRCONTROL_BACKWARDS(this))
 139                 movity += IsMoveInDirection(this.movement, 180);
 140
 141         float k = 32 * (2 * movity - 1);
 142         if (k <= 0)
 143                 return;
 144
 145         k *= bound(0, wishspeed / PHYS_MAXAIRSPEED(this), 1);
 146
 147         float zspeed = this.velocity_z;
 148         this.velocity_z = 0;
 149         float xyspeed = vlen(this.velocity);
 150         this.velocity = normalize(this.velocity);
 151
 152         float dot = this.velocity * wishdir;
 153
 154         if (dot > 0) // we can't change direction while slowing down
 155         {
 156                 k *= pow(dot, PHYS_AIRCONTROL_POWER(this)) * dt;
 157                 xyspeed = max(0, xyspeed - PHYS_AIRCONTROL_PENALTY(this) * sqrt(max(0, 1 - dot*dot)) * k/32);
 158                 k *= PHYS_AIRCONTROL(this);
 159                 this.velocity = normalize(this.velocity * xyspeed + wishdir * k);
 160         }
 161
 162         this.velocity = this.velocity * xyspeed;
 163         this.velocity_z = zspeed;
 164 }
 165
 166 float AdjustAirAccelQW(float accelqw, float factor)
 167 {
 168         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 169 }
 170
 171 // example config for alternate speed clamping:
 172 //   sv_airaccel_qw 0.8
 173 //   sv_airaccel_sideways_friction 0
 174 //   prvm_globalset server speedclamp_mode 1
 175 //     (or 2)
 176 void PM_Accelerate(entity this, float dt, vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 177 {
 178         float speedclamp = stretchfactor > 0 ? stretchfactor
 179         : accelqw < 0 ? 1 // full clamping, no stretch
 180         : -1; // no clamping
 181
 182         accelqw = fabs(accelqw);
 183
 184         if (GAMEPLAYFIX_Q2AIRACCELERATE)
 185                 wishspeed0 = wishspeed; // don't need to emulate this Q1 bug
 186
 187         float vel_straight = this.velocity * wishdir;
 188         float vel_z = this.velocity_z;
 189         vector vel_xy = vec2(this.velocity);
 190         vector vel_perpend = vel_xy - vel_straight * wishdir;
 191
 192         float step = accel * dt * wishspeed0;
 193
 194         float vel_xy_current  = vlen(vel_xy);
 195         if (speedlimit)
 196                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 197         float vel_xy_forward =  vel_xy_current  + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 198         float vel_xy_backward = vel_xy_current  - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 199         vel_xy_backward = max(0, vel_xy_backward); // not that it REALLY occurs that this would cause wrong behaviour afterwards
 200         vel_straight =          vel_straight    + bound(0, wishspeed - vel_straight,   step) * accelqw + step * (1 - accelqw);
 201
 202         if (sidefric < 0 && (vel_perpend*vel_perpend))
 203                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 204         {
 205                 float f = max(0, 1 + dt * wishspeed * sidefric);
 206                 float themin = (vel_xy_backward * vel_xy_backward - vel_straight * vel_straight) / (vel_perpend * vel_perpend);
 207                 // assume: themin > 1
 208                 // vel_xy_backward*vel_xy_backward - vel_straight*vel_straight > vel_perpend*vel_perpend
 209                 // vel_xy_backward*vel_xy_backward > vel_straight*vel_straight + vel_perpend*vel_perpend
 210                 // vel_xy_backward*vel_xy_backward > vel_xy * vel_xy
 211                 // obviously, this cannot be
 212                 if (themin <= 0)
 213                         vel_perpend *= f;
 214                 else
 215                 {
 216                         themin = sqrt(themin);
 217                         vel_perpend *= max(themin, f);
 218                 }
 219         }
 220         else
 221                 vel_perpend *= max(0, 1 - dt * wishspeed * sidefric);
 222
 223         vel_xy = vel_straight * wishdir + vel_perpend;
 224
 225         if (speedclamp >= 0)
 226         {
 227                 float vel_xy_preclamp;
 228                 vel_xy_preclamp = vlen(vel_xy);
 229                 if (vel_xy_preclamp > 0) // prevent division by zero
 230                 {
 231                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 232                         if (vel_xy_current < vel_xy_preclamp)
 233                                 vel_xy *= (vel_xy_current / vel_xy_preclamp);
 234                 }
 235         }
 236
 237         this.velocity = vel_xy + vel_z * '0 0 1';
 238 }
 239
 240 void PM_AirAccelerate(entity this, float dt, vector wishdir, float wishspeed)
 241 {
 242         if (wishspeed == 0)
 243                 return;
 244
 245         vector curvel = this.velocity;
 246         curvel_z = 0;
 247         float curspeed = vlen(curvel);
 248
 249         if (wishspeed > curspeed * 1.01)
 250                 wishspeed = min(wishspeed, curspeed + PHYS_WARSOWBUNNY_AIRFORWARDACCEL(this) * PHYS_MAXSPEED(this) * dt);
 251         else
 252         {
 253                 float f = max(0, (PHYS_WARSOWBUNNY_TOPSPEED(this) - curspeed) / (PHYS_WARSOWBUNNY_TOPSPEED(this) - PHYS_MAXSPEED(this)));
 254                 wishspeed = max(curspeed, PHYS_MAXSPEED(this)) + PHYS_WARSOWBUNNY_ACCEL(this) * f * PHYS_MAXSPEED(this) * dt;
 255         }
 256         vector wishvel = wishdir * wishspeed;
 257         vector acceldir = wishvel - curvel;
 258         float addspeed = vlen(acceldir);
 259         acceldir = normalize(acceldir);
 260
 261         float accelspeed = min(addspeed, PHYS_WARSOWBUNNY_TURNACCEL(this) * PHYS_MAXSPEED(this) * dt);
 262
 263         if (PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this) < 1)
 264         {
 265                 vector curdir = normalize(curvel);
 266                 float dot = acceldir * curdir;
 267                 if (dot < 0)
 268                         acceldir -= (1 - PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this)) * dot * curdir;
 269         }
 270
 271         this.velocity += accelspeed * acceldir;
 272 }
 273
 274
 275 /*
 276 =============
 277 PlayerJump
 278
 279 When you press the jump key
 280 returns true if handled
 281 =============
 282 */
 283 bool PlayerJump(entity this)
 284 {
 285         if (PHYS_FROZEN(this))
 286                 return true; // no jumping in freezetag when frozen
 287
 288 #ifdef SVQC
 289         if (this.player_blocked)
 290                 return true; // no jumping while blocked
 291 #endif
 292
 293         bool doublejump = false;
 294         float mjumpheight = PHYS_JUMPVELOCITY(this);
 295
 296         if (MUTATOR_CALLHOOK(PlayerJump, this, mjumpheight, doublejump))
 297                 return true;
 298
 299         mjumpheight = M_ARGV(1, float);
 300         doublejump = M_ARGV(2, bool);
 301
 302         if (this.waterlevel >= WATERLEVEL_SWIMMING)
 303         {
 304                 if(this.viewloc)
 305                 {
 306                         doublejump = true;
 307                         mjumpheight *= 0.7;
 308                 }
 309                 else
 310                 {
 311                         this.velocity_z = PHYS_MAXSPEED(this) * 0.7;
 312                         return true;
 313                 }
 314         }
 315
 316         if (!doublejump)
 317                 if (!IS_ONGROUND(this))
 318                         return IS_JUMP_HELD(this);
 319
 320         bool track_jump = PHYS_CL_TRACK_CANJUMP(this);
 321         if(PHYS_TRACK_CANJUMP(this))
 322                 track_jump = true;
 323
 324         if (track_jump)
 325                 if (IS_JUMP_HELD(this))
 326                         return true;
 327
 328         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 329         // velocity bounds.  Final velocity is bound between (jumpheight *
 330         // min + jumpheight) and (jumpheight * max + jumpheight);
 331
 332         if(PHYS_JUMPSPEEDCAP_MIN != "")
 333         {
 334                 float minjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MIN);
 335
 336                 if (this.velocity_z < minjumpspeed)
 337                         mjumpheight += minjumpspeed - this.velocity_z;
 338         }
 339
 340         if(PHYS_JUMPSPEEDCAP_MAX != "")
 341         {
 342                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 343                 tracebox(this.origin + '0 0 0.01', this.mins, this.maxs, this.origin - '0 0 0.01', MOVE_NORMAL, this);
 344
 345                 if (!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS(this)))
 346                 {
 347                         float maxjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MAX);
 348
 349                         if (this.velocity_z > maxjumpspeed)
 350                                 mjumpheight -= this.velocity_z - maxjumpspeed;
 351                 }
 352         }
 353
 354         if (!WAS_ONGROUND(this))
 355         {
 356 #ifdef SVQC
 357                 if(autocvar_speedmeter)
 358                         LOG_TRACE("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")");
 359 #endif
 360                 if(this.lastground < time - 0.3)
 361                 {
 362                         float f = (1 - PHYS_FRICTION_ONLAND(this));
 363                         this.velocity_x *= f;
 364                         this.velocity_y *= f;
 365                 }
 366 #ifdef SVQC
 367                 if(this.jumppadcount > 1)
 368                         LOG_TRACE(ftos(this.jumppadcount), "x jumppad combo");
 369                 this.jumppadcount = 0;
 370 #endif
 371         }
 372
 373         this.velocity_z += mjumpheight;
 374
 375         UNSET_ONGROUND(this);
 376         SET_JUMP_HELD(this);
 377
 378 #ifdef SVQC
 379
 380         this.oldvelocity_z = this.velocity_z;
 381
 382         animdecide_setaction(this, ANIMACTION_JUMP, true);
 383
 384         if (autocvar_g_jump_grunt)
 385                 PlayerSound(this, playersound_jump, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 386 #endif
 387         return true;
 388 }
 389
 390 void CheckWaterJump(entity this)
 391 {
 392 // check for a jump-out-of-water
 393         makevectors(this.v_angle);
 394         vector start = this.origin;
 395         start_z += 8;
 396         v_forward_z = 0;
 397         normalize(v_forward);
 398         vector end = start + v_forward*24;
 399         traceline (start, end, true, this);
 400         if (trace_fraction < 1)
 401         {       // solid at waist
 402                 start_z = start_z + this.maxs_z - 8;
 403                 end = start + v_forward*24;
 404                 this.movedir = trace_plane_normal * -50;
 405                 traceline(start, end, true, this);
 406                 if (trace_fraction == 1)
 407                 {       // open at eye level
 408                         this.velocity_z = 225;
 409                         this.flags |= FL_WATERJUMP;
 410                         SET_JUMP_HELD(this);
 411                 #ifdef SVQC
 412                         PHYS_TELEPORT_TIME(this) = time + 2;    // safety net
 413                 #elif defined(CSQC)
 414                         PHYS_WATERJUMP_TIME(this) = 2;
 415                 #endif
 416                 }
 417         }
 418 }
 419
 420
 421 #ifdef SVQC
 422         #define JETPACK_JUMP(s) s.cvar_cl_jetpack_jump
 423 #elif defined(CSQC)
 424         float autocvar_cl_jetpack_jump;
 425         #define JETPACK_JUMP(s) autocvar_cl_jetpack_jump
 426 #endif
 427 .float jetpack_stopped;
 428 void CheckPlayerJump(entity this)
 429 {
 430 #ifdef SVQC
 431         bool was_flying = boolean(ITEMS_STAT(this) & IT_USING_JETPACK);
 432 #endif
 433         if (JETPACK_JUMP(this) < 2)
 434                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 435
 436         if(PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this))
 437         {
 438                 bool playerjump = PlayerJump(this); // required
 439
 440                 bool air_jump = !playerjump || M_ARGV(2, bool);
 441                 bool activate = JETPACK_JUMP(this) && air_jump && PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this);
 442                 bool has_fuel = !PHYS_JETPACK_FUEL(this) || PHYS_AMMO_FUEL(this) || (ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO);
 443
 444                 if (!(ITEMS_STAT(this) & ITEM_Jetpack.m_itemid)) { }
 445                 else if (this.jetpack_stopped) { }
 446                 else if (!has_fuel)
 447                 {
 448 #ifdef SVQC
 449                         if (was_flying) // TODO: ran out of fuel message
 450                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 451                         else if (activate)
 452                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 453 #endif
 454                         this.jetpack_stopped = true;
 455                         ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 456                 }
 457                 else if (activate && !PHYS_FROZEN(this))
 458                         ITEMS_STAT(this) |= IT_USING_JETPACK;
 459         }
 460         else
 461         {
 462                 this.jetpack_stopped = false;
 463                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 464         }
 465         if (!PHYS_INPUT_BUTTON_JUMP(this))
 466                 UNSET_JUMP_HELD(this);
 467
 468         if (this.waterlevel == WATERLEVEL_SWIMMING)
 469                 CheckWaterJump(this);
 470 }
 471
 472 float racecar_angle(float forward, float down)
 473 {
 474         if (forward < 0)
 475         {
 476                 forward = -forward;
 477                 down = -down;
 478         }
 479
 480         float ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 481
 482         float angle_mult = forward / (800 + forward);
 483
 484         if (ret > 180)
 485                 return ret * angle_mult + 360 * (1 - angle_mult);
 486         else
 487                 return ret * angle_mult;
 488 }
 489
 490 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 491 .float specialcommand_pos;
 492 void SpecialCommand(entity this)
 493 {
 494 #ifdef SVQC
 495         if (!CheatImpulse(this, CHIMPULSE_GIVE_ALL.impulse))
 496                 LOG_INFO("A hollow voice says \"Plugh\".\n");
 497 #endif
 498 }
 499
 500 bool PM_check_specialcommand(entity this, int buttons)
 501 {
 502 #ifdef SVQC
 503         string c;
 504         if (!buttons)
 505                 c = "x";
 506         else if (buttons == 1)
 507                 c = "1";
 508         else if (buttons == 2)
 509                 c = " ";
 510         else if (buttons == 128)
 511                 c = "s";
 512         else if (buttons == 256)
 513                 c = "w";
 514         else if (buttons == 512)
 515                 c = "a";
 516         else if (buttons == 1024)
 517                 c = "d";
 518         else
 519                 c = "?";
 520
 521         if (c == substring(specialcommand, this.specialcommand_pos, 1))
 522         {
 523                 this.specialcommand_pos += 1;
 524                 if (this.specialcommand_pos >= strlen(specialcommand))
 525                 {
 526                         this.specialcommand_pos = 0;
 527                         SpecialCommand(this);
 528                         return true;
 529                 }
 530         }
 531         else if (this.specialcommand_pos && (c != substring(specialcommand, this.specialcommand_pos - 1, 1)))
 532                 this.specialcommand_pos = 0;
 533 #endif
 534         return false;
 535 }
 536
 537 void PM_check_nickspam(entity this)
 538 {
 539 #ifdef SVQC
 540         if (time >= this.nickspamtime)
 541                 return;
 542         if (this.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 543         {
 544                 // slight annoyance for nick change scripts
 545                 this.movement = -1 * this.movement;
 546                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_ZOOM(this) = PHYS_INPUT_BUTTON_CROUCH(this) = PHYS_INPUT_BUTTON_HOOK(this) = PHYS_INPUT_BUTTON_USE(this) = false;
 547
 548                 if (this.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 549                 {
 550                         this.v_angle_x = random() * 360;
 551                         this.v_angle_y = random() * 360;
 552                         // at least I'm not forcing retardedview by also assigning to angles_z
 553                         this.fixangle = true;
 554                 }
 555         }
 556 #endif
 557 }
 558
 559 void PM_check_punch(entity this, float dt)
 560 {
 561 #ifdef SVQC
 562         if (this.punchangle != '0 0 0')
 563         {
 564                 float f = vlen(this.punchangle) - 10 * dt;
 565                 if (f > 0)
 566                         this.punchangle = normalize(this.punchangle) * f;
 567                 else
 568                         this.punchangle = '0 0 0';
 569         }
 570
 571         if (this.punchvector != '0 0 0')
 572         {
 573                 float f = vlen(this.punchvector) - 30 * dt;
 574                 if (f > 0)
 575                         this.punchvector = normalize(this.punchvector) * f;
 576                 else
 577                         this.punchvector = '0 0 0';
 578         }
 579 #endif
 580 }
 581
 582 // predict frozen movement, as frozen players CAN move in some cases
 583 void PM_check_frozen(entity this)
 584 {
 585         if (!PHYS_FROZEN(this))
 586                 return;
 587         if (PHYS_DODGING_FROZEN(this)
 588 #ifdef SVQC
 589         && IS_REAL_CLIENT(this)
 590 #endif
 591         )
 592         {
 593                 this.movement_x = bound(-5, this.movement.x, 5);
 594                 this.movement_y = bound(-5, this.movement.y, 5);
 595                 this.movement_z = bound(-5, this.movement.z, 5);
 596         }
 597         else
 598                 this.movement = '0 0 0';
 599
 600         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 601         if (pointcontents(midpoint) == CONTENT_WATER)
 602         {
 603                 this.velocity = this.velocity * 0.5;
 604
 605                 if (pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 606                         this.velocity_z = 200;
 607         }
 608 }
 609
 610 void PM_check_hitground(entity this)
 611 {
 612 #ifdef SVQC
 613         if (!this.wasFlying) return;
 614     this.wasFlying = false;
 615     if (this.waterlevel >= WATERLEVEL_SWIMMING) return;
 616     if (time < this.ladder_time) return;
 617     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 618     {
 619         .entity weaponentity = weaponentities[slot];
 620         if(this.(weaponentity).hook)
 621                 return;
 622     }
 623     this.nextstep = time + 0.3 + random() * 0.1;
 624     trace_dphitq3surfaceflags = 0;
 625     tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 626     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 627     entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 628         ? GS_FALL_METAL
 629         : GS_FALL;
 630     float vol = ((IS_DUCKED(this)) ? VOL_MUFFLED : VOL_BASE);
 631     GlobalSound(this, gs, CH_PLAYER, vol, VOICETYPE_PLAYERSOUND);
 632 #endif
 633 }
 634
 635 void PM_Footsteps(entity this)
 636 {
 637 #ifdef SVQC
 638         if (!g_footsteps) return;
 639         if (IS_DUCKED(this)) return;
 640         if (time >= this.lastground + 0.2) return;
 641         if (vdist(this.velocity, <=, autocvar_sv_maxspeed * 0.6)) return;
 642         if ((time > this.nextstep) || (time < (this.nextstep - 10.0)))
 643         {
 644                 this.nextstep = time + 0.3 + random() * 0.1;
 645                 trace_dphitq3surfaceflags = 0;
 646                 tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 647                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 648                 entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 649                         ? GS_STEP_METAL
 650                         : GS_STEP;
 651                 GlobalSound(this, gs, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 652         }
 653 #endif
 654 }
 655
 656 void PM_check_blocked(entity this)
 657 {
 658 #ifdef SVQC
 659         if (!this.player_blocked)
 660                 return;
 661         this.movement = '0 0 0';
 662         this.disableclientprediction = 1;
 663 #endif
 664 }
 665
 666 .vector oldmovement;
 667
 668 void PM_jetpack(entity this, float maxspd_mod, float dt)
 669 {
 670         //makevectors(this.v_angle.y * '0 1 0');
 671         makevectors(this.v_angle);
 672         vector wishvel = v_forward * this.movement_x
 673                                         + v_right * this.movement_y;
 674         // add remaining speed as Z component
 675         float maxairspd = PHYS_MAXAIRSPEED(this) * max(1, maxspd_mod);
 676         // fix speedhacks :P
 677         wishvel = normalize(wishvel) * min(1, vlen(wishvel) / maxairspd);
 678         // add the unused velocity as up component
 679         wishvel_z = 0;
 680
 681         // if (PHYS_INPUT_BUTTON_JUMP(this))
 682                 wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 683
 684         // it is now normalized, so...
 685         float a_side = PHYS_JETPACK_ACCEL_SIDE(this);
 686         float a_up = PHYS_JETPACK_ACCEL_UP(this);
 687         float a_add = PHYS_JETPACK_ANTIGRAVITY(this) * PHYS_GRAVITY(this);
 688
 689         if(PHYS_JETPACK_REVERSE_THRUST(this) && PHYS_INPUT_BUTTON_CROUCH(self)) { a_up = PHYS_JETPACK_REVERSE_THRUST(this); }
 690
 691         wishvel_x *= a_side;
 692         wishvel_y *= a_side;
 693         wishvel_z *= a_up;
 694         wishvel_z += a_add;
 695
 696         if(PHYS_JETPACK_REVERSE_THRUST(this) && PHYS_INPUT_BUTTON_CROUCH(self)) { wishvel_z *= -1; }
 697
 698         float best = 0;
 699         //////////////////////////////////////////////////////////////////////////////////////
 700         // finding the maximum over all vectors of above form
 701         // with wishvel having an absolute value of 1
 702         //////////////////////////////////////////////////////////////////////////////////////
 703         // we're finding the maximum over
 704         //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 705         // for z in the range from -1 to 1
 706         //////////////////////////////////////////////////////////////////////////////////////
 707         // maximum is EITHER attained at the single extreme point:
 708         float a_diff = a_side * a_side - a_up * a_up;
 709         float f;
 710         if (a_diff != 0)
 711         {
 712                 f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 713                 if (f > -1 && f < 1) // can it be attained?
 714                 {
 715                         best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 716                         //print("middle\n");
 717                 }
 718         }
 719         // OR attained at z = 1:
 720         f = (a_up + a_add) * (a_up + a_add);
 721         if (f > best)
 722         {
 723                 best = f;
 724                 //print("top\n");
 725         }
 726         // OR attained at z = -1:
 727         f = (a_up - a_add) * (a_up - a_add);
 728         if (f > best)
 729         {
 730                 best = f;
 731                 //print("bottom\n");
 732         }
 733         best = sqrt(best);
 734         //////////////////////////////////////////////////////////////////////////////////////
 735
 736         //print("best possible acceleration: ", ftos(best), "\n");
 737
 738         float fxy, fz;
 739         fxy = bound(0, 1 - (this.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / PHYS_JETPACK_MAXSPEED_SIDE(this), 1);
 740         if (wishvel_z - PHYS_GRAVITY(this) > 0)
 741                 fz = bound(0, 1 - this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
 742         else
 743                 fz = bound(0, 1 + this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
 744
 745         float fvel;
 746         fvel = vlen(wishvel);
 747         wishvel_x *= fxy;
 748         wishvel_y *= fxy;
 749         wishvel_z = (wishvel_z - PHYS_GRAVITY(this)) * fz + PHYS_GRAVITY(this);
 750
 751         fvel = min(1, vlen(wishvel) / best);
 752         if (PHYS_JETPACK_FUEL(this) && !(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
 753                 f = min(1, PHYS_AMMO_FUEL(this) / (PHYS_JETPACK_FUEL(this) * dt * fvel));
 754         else
 755                 f = 1;
 756
 757         //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
 758
 759         if (f > 0 && wishvel != '0 0 0')
 760         {
 761                 this.velocity = this.velocity + wishvel * f * dt;
 762                 UNSET_ONGROUND(this);
 763
 764 #ifdef SVQC
 765                 if (!(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
 766                         this.ammo_fuel -= PHYS_JETPACK_FUEL(this) * dt * fvel * f;
 767
 768                 ITEMS_STAT(this) |= IT_USING_JETPACK;
 769
 770                 // jetpack also inhibits health regeneration, but only for 1 second
 771                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 772 #endif
 773         }
 774 }
 775
 776 // used for calculating airshots
 777 bool IsFlying(entity this)
 778 {
 779         if(IS_ONGROUND(this))
 780                 return false;
 781         if(this.waterlevel >= WATERLEVEL_SWIMMING)
 782                 return false;
 783         traceline(this.origin, this.origin - '0 0 48', MOVE_NORMAL, this);
 784         if(trace_fraction < 1)
 785                 return false;
 786         return true;
 787 }
 788
 789
 790 void sys_phys_update(entity this, float dt);
 791 #if defined(SVQC)
 792 void SV_PlayerPhysics(entity this)
 793 #elif defined(CSQC)
 794 void CSQC_ClientMovement_PlayerMove_Frame(entity this)
 795 #endif
 796 {
 797         sys_phys_update(this, PHYS_INPUT_TIMELENGTH);
 798
 799 #ifdef SVQC
 800         this.pm_frametime = frametime;
 801 #endif
 802 }