qcsrc/common/physics/player.qc

   1 #include "player.qh"
   2 #include "../triggers/include.qh"
   3 #include "../viewloc.qh"
   4
   5 #ifdef SVQC
   6
   7 #include <server/miscfunctions.qh>
   8 #include "../triggers/trigger/viewloc.qh"
   9
  10 // client side physics
  11 bool Physics_Valid(string thecvar)
  12 {
  13         return autocvar_g_physics_clientselect && strhasword(autocvar_g_physics_clientselect_options, thecvar);
  14 }
  15
  16 float Physics_ClientOption(entity this, string option)
  17 {
  18         if(Physics_Valid(this.cvar_cl_physics))
  19         {
  20                 string s = sprintf("g_physics_%s_%s", this.cvar_cl_physics, option);
  21                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  22                         return cvar(s);
  23         }
  24         if(autocvar_g_physics_clientselect && autocvar_g_physics_clientselect_default)
  25         {
  26                 string s = sprintf("g_physics_%s_%s", autocvar_g_physics_clientselect_default, option);
  27                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  28                         return cvar(s);
  29         }
  30         return cvar(strcat("sv_", option));
  31 }
  32
  33 void Physics_UpdateStats(entity this, float maxspd_mod)
  34 {
  35         STAT(MOVEVARS_AIRACCEL_QW, this) = AdjustAirAccelQW(Physics_ClientOption(this, "airaccel_qw"), maxspd_mod);
  36         STAT(MOVEVARS_AIRSTRAFEACCEL_QW, this) = (Physics_ClientOption(this, "airstrafeaccel_qw"))
  37                 ? AdjustAirAccelQW(Physics_ClientOption(this, "airstrafeaccel_qw"), maxspd_mod)
  38                 : 0;
  39         STAT(MOVEVARS_AIRSPEEDLIMIT_NONQW, this) = Physics_ClientOption(this, "airspeedlimit_nonqw") * maxspd_mod;
  40         STAT(MOVEVARS_MAXSPEED, this) = Physics_ClientOption(this, "maxspeed") * maxspd_mod; // also slow walking
  41
  42         // old stats
  43         // fix some new settings
  44         STAT(MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, this) = Physics_ClientOption(this, "airaccel_qw_stretchfactor");
  45         STAT(MOVEVARS_MAXAIRSTRAFESPEED, this) = Physics_ClientOption(this, "maxairstrafespeed");
  46         STAT(MOVEVARS_MAXAIRSPEED, this) = Physics_ClientOption(this, "maxairspeed");
  47         STAT(MOVEVARS_AIRSTRAFEACCELERATE, this) = Physics_ClientOption(this, "airstrafeaccelerate");
  48         STAT(MOVEVARS_WARSOWBUNNY_TURNACCEL, this) = Physics_ClientOption(this, "warsowbunny_turnaccel");
  49         STAT(MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, this) = Physics_ClientOption(this, "airaccel_sideways_friction");
  50         STAT(MOVEVARS_AIRCONTROL, this) = Physics_ClientOption(this, "aircontrol");
  51         STAT(MOVEVARS_AIRCONTROL_POWER, this) = Physics_ClientOption(this, "aircontrol_power");
  52         STAT(MOVEVARS_AIRCONTROL_PENALTY, this) = Physics_ClientOption(this, "aircontrol_penalty");
  53         STAT(MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, this) = Physics_ClientOption(this, "warsowbunny_airforwardaccel");
  54         STAT(MOVEVARS_WARSOWBUNNY_TOPSPEED, this) = Physics_ClientOption(this, "warsowbunny_topspeed");
  55         STAT(MOVEVARS_WARSOWBUNNY_ACCEL, this) = Physics_ClientOption(this, "warsowbunny_accel");
  56         STAT(MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, this) = Physics_ClientOption(this, "warsowbunny_backtosideratio");
  57         STAT(MOVEVARS_FRICTION, this) = Physics_ClientOption(this, "friction");
  58         STAT(MOVEVARS_ACCELERATE, this) = Physics_ClientOption(this, "accelerate");
  59         STAT(MOVEVARS_STOPSPEED, this) = Physics_ClientOption(this, "stopspeed");
  60         STAT(MOVEVARS_AIRACCELERATE, this) = Physics_ClientOption(this, "airaccelerate");
  61         STAT(MOVEVARS_AIRSTOPACCELERATE, this) = Physics_ClientOption(this, "airstopaccelerate");
  62         STAT(MOVEVARS_JUMPVELOCITY, this) = Physics_ClientOption(this, "jumpvelocity");
  63         STAT(MOVEVARS_TRACK_CANJUMP, this) = Physics_ClientOption(this, "track_canjump");
  64 }
  65 #endif
  66
  67 float IsMoveInDirection(vector mv, float ang) // key mix factor
  68 {
  69         if (mv_x == 0 && mv_y == 0)
  70                 return 0; // avoid division by zero
  71         ang -= RAD2DEG * atan2(mv_y, mv_x);
  72         ang = remainder(ang, 360) / 45;
  73         return ang > 1 ? 0 : ang < -1 ? 0 : 1 - fabs(ang);
  74 }
  75
  76 float GeomLerp(float a, float lerp, float b)
  77 {
  78         return a == 0 ? (lerp < 1 ? 0 : b)
  79                 : b == 0 ? (lerp > 0 ? 0 : a)
  80                 : a * pow(fabs(b / a), lerp);
  81 }
  82
  83 #define unstick_offsets(X) \
  84 /* 1 no nudge (just return the original if this test passes) */ \
  85         X(' 0.000  0.000  0.000') \
  86 /* 6 simple nudges */ \
  87         X(' 0.000  0.000  0.125') X('0.000  0.000 -0.125') \
  88         X('-0.125  0.000  0.000') X('0.125  0.000  0.000') \
  89         X(' 0.000 -0.125  0.000') X('0.000  0.125  0.000') \
  90 /* 4 diagonal flat nudges */ \
  91         X('-0.125 -0.125  0.000') X('0.125 -0.125  0.000') \
  92         X('-0.125  0.125  0.000') X('0.125  0.125  0.000') \
  93 /* 8 diagonal upward nudges */ \
  94         X('-0.125  0.000  0.125') X('0.125  0.000  0.125') \
  95         X(' 0.000 -0.125  0.125') X('0.000  0.125  0.125') \
  96         X('-0.125 -0.125  0.125') X('0.125 -0.125  0.125') \
  97         X('-0.125  0.125  0.125') X('0.125  0.125  0.125') \
  98 /* 8 diagonal downward nudges */ \
  99         X('-0.125  0.000 -0.125') X('0.125  0.000 -0.125') \
 100         X(' 0.000 -0.125 -0.125') X('0.000  0.125 -0.125') \
 101         X('-0.125 -0.125 -0.125') X('0.125 -0.125 -0.125') \
 102         X('-0.125  0.125 -0.125') X('0.125  0.125 -0.125') \
 103 /**/
 104
 105 void PM_ClientMovement_Unstick(entity this)
 106 {
 107         #define X(unstick_offset) \
 108         { \
 109                 vector neworigin = unstick_offset + this.origin; \
 110                 tracebox(neworigin, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL), neworigin, MOVE_NORMAL, this); \
 111                 if (!trace_startsolid) \
 112                 { \
 113                         setorigin(this, neworigin); \
 114                         return; \
 115                 } \
 116         }
 117         unstick_offsets(X);
 118         #undef X
 119 }
 120
 121 void PM_ClientMovement_UpdateStatus(entity this, bool ground)
 122 {
 123 #ifdef CSQC
 124         if(!IS_PLAYER(this))
 125                 return;
 126         // make sure player is not stuck
 127         if(autocvar_cl_movement == 3)
 128                 PM_ClientMovement_Unstick(this);
 129
 130         // set crouched
 131         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
 132         if(this.hook && !wasfreed(this.hook))
 133                 do_crouch = false;
 134         if(hud != HUD_NORMAL)
 135                 do_crouch = false;
 136         if(STAT(FROZEN, this))
 137                 do_crouch = false;
 138         if((activeweapon == WEP_SHOCKWAVE || activeweapon == WEP_SHOTGUN) && viewmodel.animstate_startframe == viewmodel.anim_fire2_x && time < viewmodel.weapon_nextthink)
 139                 do_crouch = false;
 140
 141         if (do_crouch)
 142         {
 143                 // wants to crouch, this always works
 144                 if (!IS_DUCKED(this)) SET_DUCKED(this);
 145         }
 146         else
 147         {
 148                 // wants to stand, if currently crouching we need to check for a low ceiling first
 149                 if (IS_DUCKED(this))
 150                 {
 151                         tracebox(this.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), this.origin, MOVE_NORMAL, this);
 152                         if (!trace_startsolid) UNSET_DUCKED(this);
 153                 }
 154         }
 155
 156         // set onground
 157         vector origin1 = this.origin + '0 0 1';
 158         vector origin2 = this.origin - '0 0 1';
 159
 160         if (ground && autocvar_cl_movement == 3)
 161         {
 162                 tracebox(origin1, this.mins, this.maxs, origin2, MOVE_NORMAL, this);
 163                 if (trace_fraction < 1.0 && trace_plane_normal.z > 0.7)
 164                 {
 165                         SET_ONGROUND(this);
 166
 167                         // this code actually "predicts" an impact; so let's clip velocity first
 168                         this.velocity -= this.velocity * trace_plane_normal * trace_plane_normal;
 169                 }
 170                 else
 171                         UNSET_ONGROUND(this);
 172         }
 173
 174         if(autocvar_cl_movement == 3)
 175         {
 176                 // set watertype/waterlevel
 177                 origin1 = this.origin;
 178                 origin1.z += this.mins_z + 1;
 179                 this.waterlevel = WATERLEVEL_NONE;
 180
 181                 int thepoint = pointcontents(origin1);
 182
 183                 this.watertype = (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME);
 184
 185                 if (this.watertype)
 186                 {
 187                         this.waterlevel = WATERLEVEL_WETFEET;
 188                         origin1.z = this.origin.z + (this.mins.z + this.maxs.z) * 0.5;
 189                         thepoint = pointcontents(origin1);
 190                         if (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME)
 191                         {
 192                                 this.waterlevel = WATERLEVEL_SWIMMING;
 193                                 origin1.z = this.origin.z + 22;
 194                                 thepoint = pointcontents(origin1);
 195                                 if (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME)
 196                                         this.waterlevel = WATERLEVEL_SUBMERGED;
 197                         }
 198                 }
 199         }
 200
 201         if (IS_ONGROUND(this) || this.velocity.z <= 0 || pmove_waterjumptime <= 0)
 202                 pmove_waterjumptime = 0;
 203 #endif
 204 }
 205
 206 void PM_ClientMovement_Move(entity this)
 207 {
 208 #ifdef CSQC
 209
 210         PM_ClientMovement_UpdateStatus(this, false);
 211         if(autocvar_cl_movement == 1)
 212                 return;
 213
 214         int bump;
 215         float t;
 216         float f;
 217         vector neworigin;
 218         vector currentorigin2;
 219         vector neworigin2;
 220         vector primalvelocity;
 221
 222         vector trace1_endpos = '0 0 0';
 223         vector trace2_endpos = '0 0 0';
 224         vector trace3_endpos = '0 0 0';
 225         float trace1_fraction = 0;
 226         float trace2_fraction = 0;
 227         float trace3_fraction = 0;
 228         vector trace1_plane_normal = '0 0 0';
 229         vector trace2_plane_normal = '0 0 0';
 230         vector trace3_plane_normal = '0 0 0';
 231
 232         primalvelocity = this.velocity;
 233         for(bump = 0, t = PHYS_INPUT_TIMELENGTH; bump < 8 && (this.velocity * this.velocity) > 0; bump++)
 234         {
 235                 neworigin = this.origin + t * this.velocity;
 236                 tracebox(this.origin, this.mins, this.maxs, neworigin, MOVE_NORMAL, this);
 237                 trace1_endpos = trace_endpos;
 238                 trace1_fraction = trace_fraction;
 239                 trace1_plane_normal = trace_plane_normal;
 240                 if(trace1_fraction < 1 && trace1_plane_normal_z == 0)
 241                 {
 242                         // may be a step or wall, try stepping up
 243                         // first move forward at a higher level
 244                         currentorigin2 = this.origin;
 245                         currentorigin2_z += PHYS_STEPHEIGHT(this);
 246                         neworigin2 = neworigin;
 247                         neworigin2_z += PHYS_STEPHEIGHT(this);
 248                         tracebox(currentorigin2, this.mins, this.maxs, neworigin2, MOVE_NORMAL, this);
 249                         trace2_endpos = trace_endpos;
 250                         trace2_fraction = trace_fraction;
 251                         trace2_plane_normal = trace_plane_normal;
 252                         if(!trace_startsolid)
 253                         {
 254                                 // then move down from there
 255                                 currentorigin2 = trace2_endpos;
 256                                 neworigin2 = trace2_endpos;
 257                                 neworigin2_z = this.origin_z;
 258                                 tracebox(currentorigin2, this.mins, this.maxs, neworigin2, MOVE_NORMAL, this);
 259                                 trace3_endpos = trace_endpos;
 260                                 trace3_fraction = trace_fraction;
 261                                 trace3_plane_normal = trace_plane_normal;
 262                                 // accept the new trace if it made some progress
 263                                 if(fabs(trace3_endpos_x - trace1_endpos_x) >= 0.03125 || fabs(trace3_endpos_y - trace1_endpos_y) >= 0.03125)
 264                                 {
 265                                         trace1_endpos = trace2_endpos;
 266                                         trace1_fraction = trace2_fraction;
 267                                         trace1_plane_normal = trace2_plane_normal;
 268                                         trace1_endpos = trace3_endpos;
 269                                 }
 270                         }
 271                 }
 272
 273                 // check if it moved at all
 274                 if(trace1_fraction >= 0.001)
 275                         setorigin(this, trace1_endpos);
 276
 277                 // check if it moved all the way
 278                 if(trace1_fraction == 1)
 279                         break;
 280
 281                 // this is only really needed for nogravityonground combined with gravityunaffectedbyticrate
 282                 // <LordHavoc> I'm pretty sure I commented it out solely because it seemed redundant
 283                 // this got commented out in a change that supposedly makes the code match QW better
 284                 // so if this is broken, maybe put it in an if(cls.protocol != PROTOCOL_QUAKEWORLD) block
 285                 if(trace1_plane_normal_z > 0.7)
 286                         SET_ONGROUND(this);
 287
 288                 t -= t * trace1_fraction;
 289
 290                 f = (this.velocity * trace1_plane_normal);
 291                 this.velocity = this.velocity + -f * trace1_plane_normal;
 292         }
 293         if(PHYS_TELEPORT_TIME(this) > 0)
 294                 this.velocity = primalvelocity;
 295 #endif
 296 }
 297
 298 void CPM_PM_Aircontrol(entity this, vector wishdir, float wishspeed)
 299 {
 300         float k = 32 * (2 * IsMoveInDirection(this.movement, 0) - 1);
 301         if (k <= 0)
 302                 return;
 303
 304         k *= bound(0, wishspeed / PHYS_MAXAIRSPEED(this), 1);
 305
 306         float zspeed = this.velocity_z;
 307         this.velocity_z = 0;
 308         float xyspeed = vlen(this.velocity);
 309         this.velocity = normalize(this.velocity);
 310
 311         float dot = this.velocity * wishdir;
 312
 313         if (dot > 0) // we can't change direction while slowing down
 314         {
 315                 k *= pow(dot, PHYS_AIRCONTROL_POWER(this)) * PHYS_INPUT_TIMELENGTH;
 316                 xyspeed = max(0, xyspeed - PHYS_AIRCONTROL_PENALTY(this) * sqrt(max(0, 1 - dot*dot)) * k/32);
 317                 k *= PHYS_AIRCONTROL(this);
 318                 this.velocity = normalize(this.velocity * xyspeed + wishdir * k);
 319         }
 320
 321         this.velocity = this.velocity * xyspeed;
 322         this.velocity_z = zspeed;
 323 }
 324
 325 float AdjustAirAccelQW(float accelqw, float factor)
 326 {
 327         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 328 }
 329
 330 // example config for alternate speed clamping:
 331 //   sv_airaccel_qw 0.8
 332 //   sv_airaccel_sideways_friction 0
 333 //   prvm_globalset server speedclamp_mode 1
 334 //     (or 2)
 335 void PM_Accelerate(entity this, vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 336 {
 337         float speedclamp = stretchfactor > 0 ? stretchfactor
 338         : accelqw < 0 ? 1 // full clamping, no stretch
 339         : -1; // no clamping
 340
 341         accelqw = fabs(accelqw);
 342
 343         if (GAMEPLAYFIX_Q2AIRACCELERATE)
 344                 wishspeed0 = wishspeed; // don't need to emulate this Q1 bug
 345
 346         float vel_straight = this.velocity * wishdir;
 347         float vel_z = this.velocity_z;
 348         vector vel_xy = vec2(this.velocity);
 349         vector vel_perpend = vel_xy - vel_straight * wishdir;
 350
 351         float step = accel * PHYS_INPUT_TIMELENGTH * wishspeed0;
 352
 353         float vel_xy_current  = vlen(vel_xy);
 354         if (speedlimit)
 355                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 356         float vel_xy_forward =  vel_xy_current  + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 357         float vel_xy_backward = vel_xy_current  - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 358         vel_xy_backward = max(0, vel_xy_backward); // not that it REALLY occurs that this would cause wrong behaviour afterwards
 359         vel_straight =          vel_straight    + bound(0, wishspeed - vel_straight,   step) * accelqw + step * (1 - accelqw);
 360
 361         if (sidefric < 0 && (vel_perpend*vel_perpend))
 362                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 363         {
 364                 float f = max(0, 1 + PHYS_INPUT_TIMELENGTH * wishspeed * sidefric);
 365                 float themin = (vel_xy_backward * vel_xy_backward - vel_straight * vel_straight) / (vel_perpend * vel_perpend);
 366                 // assume: themin > 1
 367                 // vel_xy_backward*vel_xy_backward - vel_straight*vel_straight > vel_perpend*vel_perpend
 368                 // vel_xy_backward*vel_xy_backward > vel_straight*vel_straight + vel_perpend*vel_perpend
 369                 // vel_xy_backward*vel_xy_backward > vel_xy * vel_xy
 370                 // obviously, this cannot be
 371                 if (themin <= 0)
 372                         vel_perpend *= f;
 373                 else
 374                 {
 375                         themin = sqrt(themin);
 376                         vel_perpend *= max(themin, f);
 377                 }
 378         }
 379         else
 380                 vel_perpend *= max(0, 1 - PHYS_INPUT_TIMELENGTH * wishspeed * sidefric);
 381
 382         vel_xy = vel_straight * wishdir + vel_perpend;
 383
 384         if (speedclamp >= 0)
 385         {
 386                 float vel_xy_preclamp;
 387                 vel_xy_preclamp = vlen(vel_xy);
 388                 if (vel_xy_preclamp > 0) // prevent division by zero
 389                 {
 390                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 391                         if (vel_xy_current < vel_xy_preclamp)
 392                                 vel_xy *= (vel_xy_current / vel_xy_preclamp);
 393                 }
 394         }
 395
 396         this.velocity = vel_xy + vel_z * '0 0 1';
 397 }
 398
 399 void PM_AirAccelerate(entity this, vector wishdir, float wishspeed)
 400 {
 401         if (wishspeed == 0)
 402                 return;
 403
 404         vector curvel = this.velocity;
 405         curvel_z = 0;
 406         float curspeed = vlen(curvel);
 407
 408         if (wishspeed > curspeed * 1.01)
 409                 wishspeed = min(wishspeed, curspeed + PHYS_WARSOWBUNNY_AIRFORWARDACCEL(this) * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH);
 410         else
 411         {
 412                 float f = max(0, (PHYS_WARSOWBUNNY_TOPSPEED(this) - curspeed) / (PHYS_WARSOWBUNNY_TOPSPEED(this) - PHYS_MAXSPEED(this)));
 413                 wishspeed = max(curspeed, PHYS_MAXSPEED(this)) + PHYS_WARSOWBUNNY_ACCEL(this) * f * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH;
 414         }
 415         vector wishvel = wishdir * wishspeed;
 416         vector acceldir = wishvel - curvel;
 417         float addspeed = vlen(acceldir);
 418         acceldir = normalize(acceldir);
 419
 420         float accelspeed = min(addspeed, PHYS_WARSOWBUNNY_TURNACCEL(this) * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH);
 421
 422         if (PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this) < 1)
 423         {
 424                 vector curdir = normalize(curvel);
 425                 float dot = acceldir * curdir;
 426                 if (dot < 0)
 427                         acceldir -= (1 - PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this)) * dot * curdir;
 428         }
 429
 430         this.velocity += accelspeed * acceldir;
 431 }
 432
 433
 434 /*
 435 =============
 436 PlayerJump
 437
 438 When you press the jump key
 439 returns true if handled
 440 =============
 441 */
 442 bool PlayerJump(entity this)
 443 {
 444         if (PHYS_FROZEN(this))
 445                 return true; // no jumping in freezetag when frozen
 446
 447 #ifdef SVQC
 448         if (this.player_blocked)
 449                 return true; // no jumping while blocked
 450 #endif
 451
 452         bool doublejump = false;
 453         float mjumpheight = PHYS_JUMPVELOCITY(this);
 454
 455         if (MUTATOR_CALLHOOK(PlayerJump, this, doublejump, mjumpheight))
 456                 return true;
 457
 458         doublejump = player_multijump;
 459         mjumpheight = player_jumpheight;
 460
 461         if (this.waterlevel >= WATERLEVEL_SWIMMING)
 462         {
 463                 if(this.viewloc)
 464                 {
 465                         doublejump = true;
 466                         mjumpheight *= 0.7;
 467                 }
 468                 else
 469                 {
 470                         this.velocity_z = PHYS_MAXSPEED(this) * 0.7;
 471                         return true;
 472                 }
 473         }
 474
 475         if (!doublejump)
 476                 if (!IS_ONGROUND(this))
 477                         return IS_JUMP_HELD(this);
 478
 479         bool track_jump = PHYS_CL_TRACK_CANJUMP(this);
 480         if(PHYS_TRACK_CANJUMP(this))
 481                 track_jump = true;
 482
 483         if (track_jump)
 484                 if (IS_JUMP_HELD(this))
 485                         return true;
 486
 487         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 488         // velocity bounds.  Final velocity is bound between (jumpheight *
 489         // min + jumpheight) and (jumpheight * max + jumpheight);
 490
 491         if(PHYS_JUMPSPEEDCAP_MIN != "")
 492         {
 493                 float minjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MIN);
 494
 495                 if (this.velocity_z < minjumpspeed)
 496                         mjumpheight += minjumpspeed - this.velocity_z;
 497         }
 498
 499         if(PHYS_JUMPSPEEDCAP_MAX != "")
 500         {
 501                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 502                 tracebox(this.origin + '0 0 0.01', this.mins, this.maxs, this.origin - '0 0 0.01', MOVE_NORMAL, this);
 503
 504                 if (!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS(this)))
 505                 {
 506                         float maxjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MAX);
 507
 508                         if (this.velocity_z > maxjumpspeed)
 509                                 mjumpheight -= this.velocity_z - maxjumpspeed;
 510                 }
 511         }
 512
 513         if (!WAS_ONGROUND(this))
 514         {
 515 #ifdef SVQC
 516                 if(autocvar_speedmeter)
 517                         LOG_TRACE(strcat("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")\n"));
 518 #endif
 519                 if(this.lastground < time - 0.3)
 520                 {
 521                         float f = (1 - PHYS_FRICTION_ONLAND(this));
 522                         this.velocity_x *= f;
 523                         this.velocity_y *= f;
 524                 }
 525 #ifdef SVQC
 526                 if(this.jumppadcount > 1)
 527                         LOG_TRACE(strcat(ftos(this.jumppadcount), "x jumppad combo\n"));
 528                 this.jumppadcount = 0;
 529 #endif
 530         }
 531
 532         this.velocity_z += mjumpheight;
 533
 534         UNSET_ONGROUND(this);
 535         SET_JUMP_HELD(this);
 536
 537 #ifdef SVQC
 538
 539         this.oldvelocity_z = this.velocity_z;
 540
 541         animdecide_setaction(this, ANIMACTION_JUMP, true);
 542
 543         if (autocvar_g_jump_grunt)
 544                 PlayerSound(this, playersound_jump, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 545 #endif
 546         return true;
 547 }
 548
 549 void CheckWaterJump(entity this)
 550 {
 551 // check for a jump-out-of-water
 552         makevectors(this.v_angle);
 553         vector start = this.origin;
 554         start_z += 8;
 555         v_forward_z = 0;
 556         normalize(v_forward);
 557         vector end = start + v_forward*24;
 558         traceline (start, end, true, this);
 559         if (trace_fraction < 1)
 560         {       // solid at waist
 561                 start_z = start_z + this.maxs_z - 8;
 562                 end = start + v_forward*24;
 563                 this.movedir = trace_plane_normal * -50;
 564                 traceline(start, end, true, this);
 565                 if (trace_fraction == 1)
 566                 {       // open at eye level
 567                         this.velocity_z = 225;
 568                         this.flags |= FL_WATERJUMP;
 569                         SET_JUMP_HELD(this);
 570                 #ifdef SVQC
 571                         PHYS_TELEPORT_TIME(this) = time + 2;    // safety net
 572                 #elif defined(CSQC)
 573                         pmove_waterjumptime = 2;
 574                 #endif
 575                 }
 576         }
 577 }
 578
 579
 580 #ifdef SVQC
 581         #define JETPACK_JUMP(s) s.cvar_cl_jetpack_jump
 582 #elif defined(CSQC)
 583         float autocvar_cl_jetpack_jump;
 584         #define JETPACK_JUMP(s) autocvar_cl_jetpack_jump
 585 #endif
 586 .float jetpack_stopped;
 587 void CheckPlayerJump(entity this)
 588 {
 589 #ifdef SVQC
 590         float was_flying = ITEMS_STAT(this) & IT_USING_JETPACK;
 591 #endif
 592         if (JETPACK_JUMP(this) < 2)
 593                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 594
 595         if(PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this))
 596         {
 597                 float air_jump = !PlayerJump(this) || player_multijump; // PlayerJump() has important side effects
 598                 float activate = JETPACK_JUMP(this) && air_jump && PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this);
 599                 float has_fuel = !PHYS_JETPACK_FUEL(this) || PHYS_AMMO_FUEL(this) || (ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO);
 600
 601                 if (!(ITEMS_STAT(this) & ITEM_Jetpack.m_itemid)) { }
 602                 else if (this.jetpack_stopped) { }
 603                 else if (!has_fuel)
 604                 {
 605 #ifdef SVQC
 606                         if (was_flying) // TODO: ran out of fuel message
 607                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 608                         else if (activate)
 609                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 610 #endif
 611                         this.jetpack_stopped = true;
 612                         ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 613                 }
 614                 else if (activate && !PHYS_FROZEN(this))
 615                         ITEMS_STAT(this) |= IT_USING_JETPACK;
 616         }
 617         else
 618         {
 619                 this.jetpack_stopped = false;
 620                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 621         }
 622         if (!PHYS_INPUT_BUTTON_JUMP(this))
 623                 UNSET_JUMP_HELD(this);
 624
 625         if (this.waterlevel == WATERLEVEL_SWIMMING)
 626                 CheckWaterJump(this);
 627 }
 628
 629 float racecar_angle(float forward, float down)
 630 {
 631         if (forward < 0)
 632         {
 633                 forward = -forward;
 634                 down = -down;
 635         }
 636
 637         float ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 638
 639         float angle_mult = forward / (800 + forward);
 640
 641         if (ret > 180)
 642                 return ret * angle_mult + 360 * (1 - angle_mult);
 643         else
 644                 return ret * angle_mult;
 645 }
 646
 647 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 648 .float specialcommand_pos;
 649 void SpecialCommand(entity this)
 650 {
 651 #ifdef SVQC
 652         if (!CheatImpulse(this, CHIMPULSE_GIVE_ALL.impulse))
 653                 LOG_INFO("A hollow voice says \"Plugh\".\n");
 654 #endif
 655 }
 656
 657 bool PM_check_specialcommand(entity this, int buttons)
 658 {
 659 #ifdef SVQC
 660         string c;
 661         if (!buttons)
 662                 c = "x";
 663         else if (buttons == 1)
 664                 c = "1";
 665         else if (buttons == 2)
 666                 c = " ";
 667         else if (buttons == 128)
 668                 c = "s";
 669         else if (buttons == 256)
 670                 c = "w";
 671         else if (buttons == 512)
 672                 c = "a";
 673         else if (buttons == 1024)
 674                 c = "d";
 675         else
 676                 c = "?";
 677
 678         if (c == substring(specialcommand, this.specialcommand_pos, 1))
 679         {
 680                 this.specialcommand_pos += 1;
 681                 if (this.specialcommand_pos >= strlen(specialcommand))
 682                 {
 683                         this.specialcommand_pos = 0;
 684                         SpecialCommand(this);
 685                         return true;
 686                 }
 687         }
 688         else if (this.specialcommand_pos && (c != substring(specialcommand, this.specialcommand_pos - 1, 1)))
 689                 this.specialcommand_pos = 0;
 690 #endif
 691         return false;
 692 }
 693
 694 void PM_check_nickspam(entity this)
 695 {
 696 #ifdef SVQC
 697         if (time >= this.nickspamtime)
 698                 return;
 699         if (this.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 700         {
 701                 // slight annoyance for nick change scripts
 702                 this.movement = -1 * this.movement;
 703                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_ZOOM(this) = PHYS_INPUT_BUTTON_CROUCH(this) = PHYS_INPUT_BUTTON_HOOK(this) = PHYS_INPUT_BUTTON_USE(this) = false;
 704
 705                 if (this.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 706                 {
 707                         this.v_angle_x = random() * 360;
 708                         this.v_angle_y = random() * 360;
 709                         // at least I'm not forcing retardedview by also assigning to angles_z
 710                         this.fixangle = true;
 711                 }
 712         }
 713 #endif
 714 }
 715
 716 void PM_check_punch(entity this)
 717 {
 718 #ifdef SVQC
 719         if (this.punchangle != '0 0 0')
 720         {
 721                 float f = vlen(this.punchangle) - 10 * PHYS_INPUT_TIMELENGTH;
 722                 if (f > 0)
 723                         this.punchangle = normalize(this.punchangle) * f;
 724                 else
 725                         this.punchangle = '0 0 0';
 726         }
 727
 728         if (this.punchvector != '0 0 0')
 729         {
 730                 float f = vlen(this.punchvector) - 30 * PHYS_INPUT_TIMELENGTH;
 731                 if (f > 0)
 732                         this.punchvector = normalize(this.punchvector) * f;
 733                 else
 734                         this.punchvector = '0 0 0';
 735         }
 736 #endif
 737 }
 738
 739 // predict frozen movement, as frozen players CAN move in some cases
 740 void PM_check_frozen(entity this)
 741 {
 742         if (!PHYS_FROZEN(this))
 743                 return;
 744         if (PHYS_DODGING_FROZEN(this)
 745 #ifdef SVQC
 746         && IS_REAL_CLIENT(this)
 747 #endif
 748         )
 749         {
 750                 this.movement_x = bound(-5, this.movement.x, 5);
 751                 this.movement_y = bound(-5, this.movement.y, 5);
 752                 this.movement_z = bound(-5, this.movement.z, 5);
 753         }
 754         else
 755                 this.movement = '0 0 0';
 756
 757         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 758         if (pointcontents(midpoint) == CONTENT_WATER)
 759         {
 760                 this.velocity = this.velocity * 0.5;
 761
 762                 if (pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 763                         this.velocity_z = 200;
 764         }
 765 }
 766
 767 void PM_check_hitground(entity this)
 768 {
 769 #ifdef SVQC
 770         if (!this.wasFlying) return;
 771     this.wasFlying = false;
 772     if (this.waterlevel >= WATERLEVEL_SWIMMING) return;
 773     if (time < this.ladder_time) return;
 774     if (this.hook) return;
 775     this.nextstep = time + 0.3 + random() * 0.1;
 776     trace_dphitq3surfaceflags = 0;
 777     tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 778     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 779     entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 780         ? GS_FALL_METAL
 781         : GS_FALL;
 782     GlobalSound(this, gs, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 783 #endif
 784 }
 785
 786 void PM_Footsteps(entity this)
 787 {
 788 #ifdef SVQC
 789         if (!g_footsteps) return;
 790         if (IS_DUCKED(this)) return;
 791         if (time >= this.lastground + 0.2) return;
 792         if (vdist(this.velocity, <=, autocvar_sv_maxspeed * 0.6)) return;
 793         if ((time > this.nextstep) || (time < (this.nextstep - 10.0)))
 794         {
 795                 this.nextstep = time + 0.3 + random() * 0.1;
 796                 trace_dphitq3surfaceflags = 0;
 797                 tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 798                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
 799                 entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 800                         ? GS_STEP_METAL
 801                         : GS_STEP;
 802                 GlobalSound(this, gs, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 803         }
 804 #endif
 805 }
 806
 807 void PM_check_blocked(entity this)
 808 {
 809 #ifdef SVQC
 810         if (!this.player_blocked)
 811                 return;
 812         this.movement = '0 0 0';
 813         this.disableclientprediction = 1;
 814 #endif
 815 }
 816
 817 void PM_fly(entity this, float maxspd_mod)
 818 {
 819         // noclipping or flying
 820         UNSET_ONGROUND(this);
 821
 822         this.velocity = this.velocity * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this));
 823         makevectors(this.v_angle);
 824         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 825         vector wishvel = v_forward * this.movement.x
 826                                         + v_right * this.movement.y
 827                                         + '0 0 1' * this.movement.z;
 828         // acceleration
 829         vector wishdir = normalize(wishvel);
 830         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod);
 831 #ifdef SVQC
 832         if(time >= PHYS_TELEPORT_TIME(this))
 833 #endif
 834                 PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this) * maxspd_mod, 1, 0, 0, 0);
 835         PM_ClientMovement_Move(this);
 836 }
 837
 838 void PM_swim(entity this, float maxspd_mod)
 839 {
 840         // swimming
 841         UNSET_ONGROUND(this);
 842
 843         float jump = PHYS_INPUT_BUTTON_JUMP(this);
 844         // water jump only in certain situations
 845         // this mimics quakeworld code
 846         if (jump && this.waterlevel == WATERLEVEL_SWIMMING && this.velocity_z >= -180 && !this.viewloc)
 847         {
 848                 vector yawangles = '0 1 0' * this.v_angle.y;
 849                 makevectors(yawangles);
 850                 vector forward = v_forward;
 851                 vector spot = this.origin + 24 * forward;
 852                 spot_z += 8;
 853                 traceline(spot, spot, MOVE_NOMONSTERS, this);
 854                 if (trace_startsolid)
 855                 {
 856                         spot_z += 24;
 857                         traceline(spot, spot, MOVE_NOMONSTERS, this);
 858                         if (!trace_startsolid)
 859                         {
 860                                 this.velocity = forward * 50;
 861                                 this.velocity_z = 310;
 862                         #ifdef CSQC
 863                                 pmove_waterjumptime = 2;
 864                         #endif
 865                                 UNSET_ONGROUND(this);
 866                                 SET_JUMP_HELD(this);
 867                         }
 868                 }
 869         }
 870         makevectors(this.v_angle);
 871         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 872         vector wishvel = v_forward * this.movement.x
 873                                         + v_right * this.movement.y
 874                                         + '0 0 1' * this.movement.z;
 875         if(this.viewloc)
 876                 wishvel.z = -160; // drift anyway
 877         else if (wishvel == '0 0 0')
 878                 wishvel = '0 0 -60'; // drift towards bottom
 879
 880
 881         vector wishdir = normalize(wishvel);
 882         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod) * 0.7;
 883
 884         if (IS_DUCKED(this))
 885         wishspeed *= 0.5;
 886
 887 //      if (pmove_waterjumptime <= 0) // TODO: use
 888     {
 889                 // water friction
 890                 float f = 1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this);
 891                 f = min(max(0, f), 1);
 892                 this.velocity *= f;
 893
 894                 f = wishspeed - this.velocity * wishdir;
 895                 if (f > 0)
 896                 {
 897                         float accelspeed = min(PHYS_ACCELERATE(this) * PHYS_INPUT_TIMELENGTH * wishspeed, f);
 898                         this.velocity += accelspeed * wishdir;
 899                 }
 900
 901                 // holding jump button swims upward slowly
 902                 if (jump && !this.viewloc)
 903                 {
 904 #if 0
 905                         if (this.watertype & CONTENT_LAVA)
 906                                 this.velocity_z =  50;
 907                         else if (this.watertype & CONTENT_SLIME)
 908                                 this.velocity_z =  80;
 909                         else
 910                         {
 911                                 if (IS_NEXUIZ_DERIVED(gamemode))
 912 #endif
 913                                         this.velocity_z = 200;
 914 #if 0
 915                                 else
 916                                         this.velocity_z = 100;
 917                         }
 918 #endif
 919                 }
 920         }
 921         if(this.viewloc)
 922         {
 923                 const float addspeed = wishspeed - this.velocity * wishdir;
 924                 if (addspeed > 0)
 925                 {
 926                         const float accelspeed = min(PHYS_ACCELERATE(this) * PHYS_INPUT_TIMELENGTH * wishspeed, addspeed);
 927                         this.velocity += accelspeed * wishdir;
 928                 }
 929         }
 930         else
 931         {
 932                 // water acceleration
 933                 PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this) * maxspd_mod, 1, 0, 0, 0);
 934                 PM_ClientMovement_Move(this);
 935         }
 936 }
 937
 938 .vector oldmovement;
 939 void PM_ladder(entity this, float maxspd_mod)
 940 {
 941         // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 942         UNSET_ONGROUND(this);
 943
 944         float g;
 945         g = PHYS_GRAVITY(this) * PHYS_INPUT_TIMELENGTH;
 946         if (PHYS_ENTGRAVITY(this))
 947                 g *= PHYS_ENTGRAVITY(this);
 948         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 949         {
 950                 g *= 0.5;
 951                 this.velocity_z += g;
 952         }
 953
 954         this.velocity = this.velocity * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this));
 955         makevectors(this.v_angle);
 956         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 957         vector wishvel = v_forward * this.movement_x
 958                                         + v_right * this.movement_y
 959                                         + '0 0 1' * this.movement_z;
 960         if(this.viewloc)
 961                 wishvel.z = this.oldmovement.x;
 962         this.velocity_z += g;
 963         if (this.ladder_entity.classname == "func_water")
 964         {
 965                 float f = vlen(wishvel);
 966                 if (f > this.ladder_entity.speed)
 967                         wishvel *= (this.ladder_entity.speed / f);
 968
 969                 this.watertype = this.ladder_entity.skin;
 970                 f = this.ladder_entity.origin_z + this.ladder_entity.maxs_z;
 971                 if ((this.origin_z + this.view_ofs_z) < f)
 972                         this.waterlevel = WATERLEVEL_SUBMERGED;
 973                 else if ((this.origin_z + (this.mins_z + this.maxs_z) * 0.5) < f)
 974                         this.waterlevel = WATERLEVEL_SWIMMING;
 975                 else if ((this.origin_z + this.mins_z + 1) < f)
 976                         this.waterlevel = WATERLEVEL_WETFEET;
 977                 else
 978                 {
 979                         this.waterlevel = WATERLEVEL_NONE;
 980                         this.watertype = CONTENT_EMPTY;
 981                 }
 982         }
 983         // acceleration
 984         vector wishdir = normalize(wishvel);
 985         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod);
 986         if(time >= PHYS_TELEPORT_TIME(this))
 987                 // water acceleration
 988                 PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this)*maxspd_mod, 1, 0, 0, 0);
 989         PM_ClientMovement_Move(this);
 990 }
 991
 992 void PM_jetpack(entity this, float maxspd_mod)
 993 {
 994         //makevectors(this.v_angle.y * '0 1 0');
 995         makevectors(this.v_angle);
 996         vector wishvel = v_forward * this.movement_x
 997                                         + v_right * this.movement_y;
 998         // add remaining speed as Z component
 999         float maxairspd = PHYS_MAXAIRSPEED(this) * max(1, maxspd_mod);
1000         // fix speedhacks :P
1001         wishvel = normalize(wishvel) * min(1, vlen(wishvel) / maxairspd);
1002         // add the unused velocity as up component
1003         wishvel_z = 0;
1004
1005         // if (PHYS_INPUT_BUTTON_JUMP(this))
1006                 wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1007
1008         // it is now normalized, so...
1009         float a_side = PHYS_JETPACK_ACCEL_SIDE(this);
1010         float a_up = PHYS_JETPACK_ACCEL_UP(this);
1011         float a_add = PHYS_JETPACK_ANTIGRAVITY(this) * PHYS_GRAVITY(this);
1012
1013         wishvel_x *= a_side;
1014         wishvel_y *= a_side;
1015         wishvel_z *= a_up;
1016         wishvel_z += a_add;
1017
1018         float best = 0;
1019         //////////////////////////////////////////////////////////////////////////////////////
1020         // finding the maximum over all vectors of above form
1021         // with wishvel having an absolute value of 1
1022         //////////////////////////////////////////////////////////////////////////////////////
1023         // we're finding the maximum over
1024         //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1025         // for z in the range from -1 to 1
1026         //////////////////////////////////////////////////////////////////////////////////////
1027         // maximum is EITHER attained at the single extreme point:
1028         float a_diff = a_side * a_side - a_up * a_up;
1029         float f;
1030         if (a_diff != 0)
1031         {
1032                 f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1033                 if (f > -1 && f < 1) // can it be attained?
1034                 {
1035                         best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1036                         //print("middle\n");
1037                 }
1038         }
1039         // OR attained at z = 1:
1040         f = (a_up + a_add) * (a_up + a_add);
1041         if (f > best)
1042         {
1043                 best = f;
1044                 //print("top\n");
1045         }
1046         // OR attained at z = -1:
1047         f = (a_up - a_add) * (a_up - a_add);
1048         if (f > best)
1049         {
1050                 best = f;
1051                 //print("bottom\n");
1052         }
1053         best = sqrt(best);
1054         //////////////////////////////////////////////////////////////////////////////////////
1055
1056         //print("best possible acceleration: ", ftos(best), "\n");
1057
1058         float fxy, fz;
1059         fxy = bound(0, 1 - (this.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / PHYS_JETPACK_MAXSPEED_SIDE(this), 1);
1060         if (wishvel_z - PHYS_GRAVITY(this) > 0)
1061                 fz = bound(0, 1 - this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
1062         else
1063                 fz = bound(0, 1 + this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
1064
1065         float fvel;
1066         fvel = vlen(wishvel);
1067         wishvel_x *= fxy;
1068         wishvel_y *= fxy;
1069         wishvel_z = (wishvel_z - PHYS_GRAVITY(this)) * fz + PHYS_GRAVITY(this);
1070
1071         fvel = min(1, vlen(wishvel) / best);
1072         if (PHYS_JETPACK_FUEL(this) && !(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
1073                 f = min(1, PHYS_AMMO_FUEL(this) / (PHYS_JETPACK_FUEL(this) * PHYS_INPUT_TIMELENGTH * fvel));
1074         else
1075                 f = 1;
1076
1077         //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1078
1079         if (f > 0 && wishvel != '0 0 0')
1080         {
1081                 this.velocity = this.velocity + wishvel * f * PHYS_INPUT_TIMELENGTH;
1082                 UNSET_ONGROUND(this);
1083
1084 #ifdef SVQC
1085                 if (!(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
1086                         this.ammo_fuel -= PHYS_JETPACK_FUEL(this) * PHYS_INPUT_TIMELENGTH * fvel * f;
1087
1088                 ITEMS_STAT(this) |= IT_USING_JETPACK;
1089
1090                 // jetpack also inhibits health regeneration, but only for 1 second
1091                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1092 #endif
1093         }
1094
1095 #ifdef CSQC
1096         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1097         if(autocvar_cl_movement == 3)
1098         {
1099                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1100                         this.velocity_z -= g * 0.5;
1101                 else
1102                         this.velocity_z -= g;
1103         }
1104         PM_ClientMovement_Move(this);
1105         if(autocvar_cl_movement == 3)
1106         {
1107                 if (!IS_ONGROUND(this) || !(GAMEPLAYFIX_NOGRAVITYONGROUND))
1108                         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1109                                 this.velocity_z -= g * 0.5;
1110         }
1111 #endif
1112 }
1113
1114 void PM_walk(entity this, float maxspd_mod)
1115 {
1116         if (!WAS_ONGROUND(this))
1117         {
1118 #ifdef SVQC
1119                 if (autocvar_speedmeter)
1120                         LOG_TRACE(strcat("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")\n"));
1121 #endif
1122                 if (this.lastground < time - 0.3)
1123                         this.velocity *= (1 - PHYS_FRICTION_ONLAND(this));
1124 #ifdef SVQC
1125                 if (this.jumppadcount > 1)
1126                         LOG_TRACE(strcat(ftos(this.jumppadcount), "x jumppad combo\n"));
1127                 this.jumppadcount = 0;
1128 #endif
1129         }
1130
1131         // walking
1132         makevectors(this.v_angle.y * '0 1 0');
1133         const vector wishvel = v_forward * this.movement.x
1134                                                 + v_right * this.movement.y;
1135         // acceleration
1136         const vector wishdir = normalize(wishvel);
1137         float wishspeed = vlen(wishvel);
1138         wishspeed = min(wishspeed, PHYS_MAXSPEED(this) * maxspd_mod);
1139         if (IS_DUCKED(this)) wishspeed *= 0.5;
1140
1141         // apply edge friction
1142         const float f2 = vlen2(vec2(this.velocity));
1143         if (f2 > 0)
1144         {
1145                 trace_dphitq3surfaceflags = 0;
1146                 tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
1147                 // TODO: apply edge friction
1148                 // apply ground friction
1149                 const int realfriction = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
1150                         ? PHYS_FRICTION_SLICK(this)
1151                         : PHYS_FRICTION(this);
1152
1153                 float f = sqrt(f2);
1154                 f = 1 - PHYS_INPUT_TIMELENGTH * realfriction * ((f < PHYS_STOPSPEED(this)) ? (PHYS_STOPSPEED(this) / f) : 1);
1155                 f = max(0, f);
1156                 this.velocity *= f;
1157                 /*
1158                    Mathematical analysis time!
1159
1160                    Our goal is to invert this mess.
1161
1162                    For the two cases we get:
1163                         v = v0 * (1 - PHYS_INPUT_TIMELENGTH * (PHYS_STOPSPEED(this) / v0) * PHYS_FRICTION(this))
1164                           = v0 - PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
1165                         v0 = v + PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
1166                    and
1167                         v = v0 * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1168                         v0 = v / (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1169
1170                    These cases would be chosen ONLY if:
1171                         v0 < PHYS_STOPSPEED(this)
1172                         v + PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this) < PHYS_STOPSPEED(this)
1173                         v < PHYS_STOPSPEED(this) * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1174                    and, respectively:
1175                         v0 >= PHYS_STOPSPEED(this)
1176                         v / (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this)) >= PHYS_STOPSPEED(this)
1177                         v >= PHYS_STOPSPEED(this) * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1178                  */
1179         }
1180         const float addspeed = wishspeed - this.velocity * wishdir;
1181         if (addspeed > 0)
1182         {
1183                 const float accelspeed = min(PHYS_ACCELERATE(this) * PHYS_INPUT_TIMELENGTH * wishspeed, addspeed);
1184                 this.velocity += accelspeed * wishdir;
1185         }
1186 #ifdef CSQC
1187         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1188         if(autocvar_cl_movement == 3)
1189         {
1190                 if (!(GAMEPLAYFIX_NOGRAVITYONGROUND))
1191                         this.velocity_z -= g * (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE ? 0.5 : 1);
1192         }
1193         if (vdist(this.velocity, >, 0))
1194                 PM_ClientMovement_Move(this);
1195         if(autocvar_cl_movement == 3)
1196         {
1197                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1198                         if (!IS_ONGROUND(this) || !GAMEPLAYFIX_NOGRAVITYONGROUND)
1199                                 this.velocity_z -= g * 0.5;
1200         }
1201 #endif
1202 }
1203
1204 void PM_air(entity this, float buttons_prev, float maxspd_mod)
1205 {
1206         makevectors(this.v_angle.y * '0 1 0');
1207         vector wishvel = v_forward * this.movement.x
1208                                         + v_right * this.movement.y;
1209         // acceleration
1210         vector wishdir = normalize(wishvel);
1211         float wishspeed = vlen(wishvel);
1212
1213 #ifdef SVQC
1214         if(time >= PHYS_TELEPORT_TIME(this))
1215 #elif defined(CSQC)
1216         if(pmove_waterjumptime <= 0)
1217 #endif
1218         {
1219                 float maxairspd = PHYS_MAXAIRSPEED(this) * min(maxspd_mod, 1);
1220
1221                 // apply air speed limit
1222                 float airaccelqw = PHYS_AIRACCEL_QW(this);
1223                 float wishspeed0 = wishspeed;
1224                 wishspeed = min(wishspeed, maxairspd);
1225                 if (IS_DUCKED(this))
1226                         wishspeed *= 0.5;
1227                 float airaccel = PHYS_AIRACCELERATE(this) * min(maxspd_mod, 1);
1228
1229                 float accelerating = (this.velocity * wishdir > 0);
1230                 float wishspeed2 = wishspeed;
1231
1232                 // CPM: air control
1233                 if (PHYS_AIRSTOPACCELERATE(this))
1234                 {
1235                         vector curdir = normalize(vec2(this.velocity));
1236                         airaccel += (PHYS_AIRSTOPACCELERATE(this)*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1237                 }
1238                 // note that for straight forward jumping:
1239                 // step = accel * PHYS_INPUT_TIMELENGTH * wishspeed0;
1240                 // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1241                 // -->
1242                 // dv/dt = accel * maxspeed (when slow)
1243                 // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1244                 // log dv/dt = logaccel + logmaxspeed (when slow)
1245                 // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1246                 float strafity = IsMoveInDirection(this.movement, -90) + IsMoveInDirection(this.movement, +90); // if one is nonzero, other is always zero
1247                 if (PHYS_MAXAIRSTRAFESPEED(this))
1248                         wishspeed = min(wishspeed, GeomLerp(PHYS_MAXAIRSPEED(this)*maxspd_mod, strafity, PHYS_MAXAIRSTRAFESPEED(this)*maxspd_mod));
1249                 if (PHYS_AIRSTRAFEACCELERATE(this))
1250                         airaccel = GeomLerp(airaccel, strafity, PHYS_AIRSTRAFEACCELERATE(this)*maxspd_mod);
1251                 if (PHYS_AIRSTRAFEACCEL_QW(this))
1252                         airaccelqw =
1253                 (((strafity > 0.5 ? PHYS_AIRSTRAFEACCEL_QW(this) : PHYS_AIRACCEL_QW(this)) >= 0) ? +1 : -1)
1254                 *
1255                 (1 - GeomLerp(1 - fabs(PHYS_AIRACCEL_QW(this)), strafity, 1 - fabs(PHYS_AIRSTRAFEACCEL_QW(this))));
1256                 // !CPM
1257
1258                 if (PHYS_WARSOWBUNNY_TURNACCEL(this) && accelerating && this.movement.y == 0 && this.movement.x != 0)
1259                         PM_AirAccelerate(this, wishdir, wishspeed2);
1260                 else {
1261                     float sidefric = maxairspd ? (PHYS_AIRACCEL_SIDEWAYS_FRICTION(this) / maxairspd) : 0;
1262                         PM_Accelerate(this, wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, PHYS_AIRACCEL_QW_STRETCHFACTOR(this), sidefric, PHYS_AIRSPEEDLIMIT_NONQW(this));
1263         }
1264
1265                 if (PHYS_AIRCONTROL(this))
1266                         CPM_PM_Aircontrol(this, wishdir, wishspeed2);
1267         }
1268 #ifdef CSQC
1269         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1270         if(autocvar_cl_movement == 3)
1271         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1272                 this.velocity_z -= g * 0.5;
1273         else
1274                 this.velocity_z -= g;
1275 #endif
1276         PM_ClientMovement_Move(this);
1277 #ifdef CSQC
1278         if(autocvar_cl_movement == 3)
1279         if (!IS_ONGROUND(this) || !(GAMEPLAYFIX_NOGRAVITYONGROUND))
1280                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1281                         this.velocity_z -= g * 0.5;
1282 #endif
1283 }
1284
1285 // used for calculating airshots
1286 bool IsFlying(entity this)
1287 {
1288         if(IS_ONGROUND(this))
1289                 return false;
1290         if(this.waterlevel >= WATERLEVEL_SWIMMING)
1291                 return false;
1292         traceline(this.origin, this.origin - '0 0 48', MOVE_NORMAL, this);
1293         if(trace_fraction < 1)
1294                 return false;
1295         return true;
1296 }
1297
1298 void PM_Main(entity this)
1299 {
1300         int buttons = PHYS_INPUT_BUTTON_MASK(this);
1301 #ifdef CSQC
1302         this.items = STAT(ITEMS);
1303
1304         this.movement = PHYS_INPUT_MOVEVALUES(this);
1305
1306         this.spectatorspeed = STAT(SPECTATORSPEED);
1307
1308         this.team = myteam + 1; // is this correct?
1309         if (!(PHYS_INPUT_BUTTON_JUMP(this))) // !jump
1310                 UNSET_JUMP_HELD(this); // canjump = true
1311         pmove_waterjumptime -= PHYS_INPUT_TIMELENGTH;
1312
1313         PM_ClientMovement_UpdateStatus(this, true);
1314 #endif
1315
1316         this.oldmovement = this.movement;
1317
1318
1319 #ifdef SVQC
1320         WarpZone_PlayerPhysics_FixVAngle(this);
1321 #endif
1322         float maxspeed_mod = 1;
1323         maxspeed_mod *= PHYS_HIGHSPEED(this);
1324
1325 #ifdef SVQC
1326         Physics_UpdateStats(this, maxspeed_mod);
1327
1328         if (this.PlayerPhysplug)
1329                 if (this.PlayerPhysplug(this))
1330                         return;
1331 #endif
1332
1333 #ifdef SVQC
1334         anticheat_physics(this);
1335 #endif
1336
1337         if (PM_check_specialcommand(this, buttons))
1338                 return;
1339 #ifdef SVQC
1340         if (sv_maxidle > 0)
1341         {
1342                 if (buttons != this.buttons_old || this.movement != this.movement_old || this.v_angle != this.v_angle_old)
1343                         this.parm_idlesince = time;
1344         }
1345 #endif
1346         int buttons_prev = this.buttons_old;
1347         this.buttons_old = buttons;
1348         this.movement_old = this.movement;
1349         this.v_angle_old = this.v_angle;
1350
1351         PM_check_nickspam(this);
1352
1353         PM_check_punch(this);
1354 #ifdef SVQC
1355         if (IS_BOT_CLIENT(this))
1356         {
1357                 if (playerdemo_read(this))
1358                         return;
1359                 bot_think(this);
1360         }
1361 #endif
1362
1363 #ifdef SVQC
1364         if (IS_PLAYER(this))
1365         {
1366                 const bool allowed_to_move = (time >= game_starttime);
1367                 if (!allowed_to_move)
1368                 {
1369                         this.velocity = '0 0 0';
1370                         this.movetype = MOVETYPE_NONE;
1371                         this.disableclientprediction = 2;
1372                 }
1373                 else if (this.disableclientprediction == 2)
1374                 {
1375                         if (this.movetype == MOVETYPE_NONE)
1376                                 this.movetype = MOVETYPE_WALK;
1377                         this.disableclientprediction = 0;
1378                 }
1379         }
1380 #endif
1381
1382 #ifdef SVQC
1383         if (this.movetype == MOVETYPE_NONE)
1384                 return;
1385
1386         // when we get here, disableclientprediction cannot be 2
1387         this.disableclientprediction = 0;
1388 #endif
1389
1390         viewloc_PlayerPhysics(this);
1391
1392         PM_check_frozen(this);
1393
1394         PM_check_blocked(this);
1395
1396         maxspeed_mod = 1;
1397
1398         if (this.in_swamp)
1399                 maxspeed_mod *= this.swamp_slowdown; //cvar("g_balance_swamp_moverate");
1400
1401         // conveyors: first fix velocity
1402         if (this.conveyor.state)
1403                 this.velocity -= this.conveyor.movedir;
1404
1405         MUTATOR_CALLHOOK(PlayerPhysics, this);
1406
1407         if (!IS_PLAYER(this))
1408         {
1409 #ifdef SVQC
1410                 maxspeed_mod = autocvar_sv_spectator_speed_multiplier;
1411                 if (!this.spectatorspeed)
1412                         this.spectatorspeed = maxspeed_mod;
1413                 if (this.impulse && this.impulse <= 19 || (this.impulse >= 200 && this.impulse <= 209) || (this.impulse >= 220 && this.impulse <= 229))
1414                 {
1415                         if (this.lastclassname != STR_PLAYER)
1416                         {
1417                                 if (this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209))
1418                                         this.spectatorspeed = bound(1, this.spectatorspeed + 0.5, 5);
1419                                 else if (this.impulse == 11)
1420                                         this.spectatorspeed = maxspeed_mod;
1421                                 else if (this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229))
1422                                         this.spectatorspeed = bound(1, this.spectatorspeed - 0.5, 5);
1423                                 else if (this.impulse >= 1 && this.impulse <= 9)
1424                                         this.spectatorspeed = 1 + 0.5 * (this.impulse - 1);
1425                         } // otherwise just clear
1426                         this.impulse = 0;
1427                 }
1428 #endif
1429                 maxspeed_mod = this.spectatorspeed;
1430         }
1431 #ifdef SVQC
1432
1433         float spd = max(PHYS_MAXSPEED(this), PHYS_MAXAIRSPEED(this)) * maxspeed_mod;
1434         if(this.speed != spd)
1435         {
1436                 this.speed = spd;
1437                 string temps = ftos(spd);
1438                 stuffcmd(this, strcat("cl_forwardspeed ", temps, "\n"));
1439                 stuffcmd(this, strcat("cl_backspeed ", temps, "\n"));
1440                 stuffcmd(this, strcat("cl_sidespeed ", temps, "\n"));
1441                 stuffcmd(this, strcat("cl_upspeed ", temps, "\n"));
1442         }
1443
1444         if(this.jumpspeedcap_min != autocvar_sv_jumpspeedcap_min)
1445         {
1446                 this.jumpspeedcap_min = autocvar_sv_jumpspeedcap_min;
1447                 stuffcmd(this, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1448         }
1449         if(this.jumpspeedcap_max != autocvar_sv_jumpspeedcap_max)
1450         {
1451                 this.jumpspeedcap_max = autocvar_sv_jumpspeedcap_max;
1452                 stuffcmd(this, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1453         }
1454 #endif
1455
1456         if(IS_DEAD(this))
1457         {
1458                 // handle water here
1459                 vector midpoint = ((this.absmin + this.absmax) * 0.5);
1460                 if(pointcontents(midpoint) == CONTENT_WATER)
1461                 {
1462                         this.velocity = this.velocity * 0.5;
1463
1464                         // do we want this?
1465                         //if(pointcontents(midpoint + '0 0 2') == CONTENT_WATER)
1466                                 //{ this.velocity_z = 70; }
1467                 }
1468                 goto end;
1469         }
1470
1471 #ifdef SVQC
1472         if (!this.fixangle)
1473                 this.angles = '0 1 0' * this.v_angle.y;
1474 #endif
1475
1476         if (IS_PLAYER(this) && IS_ONGROUND(this))
1477         {
1478                 PM_check_hitground(this);
1479                 PM_Footsteps(this);
1480         }
1481
1482 #ifdef SVQC
1483         if(IsFlying(this))
1484                 this.wasFlying = 1;
1485 #endif
1486
1487         if (IS_PLAYER(this))
1488                 CheckPlayerJump(this);
1489
1490         if (this.flags & FL_WATERJUMP)
1491         {
1492                 this.velocity_x = this.movedir.x;
1493                 this.velocity_y = this.movedir.y;
1494                 if (time > PHYS_TELEPORT_TIME(this) || this.waterlevel == WATERLEVEL_NONE
1495                 #ifdef CSQC
1496                         || pmove_waterjumptime <= 0
1497                 #endif
1498                         )
1499                 {
1500                         this.flags &= ~FL_WATERJUMP;
1501                         PHYS_TELEPORT_TIME(this) = 0;
1502                 #ifdef CSQC
1503                         pmove_waterjumptime = 0;
1504                 #endif
1505                 }
1506         }
1507
1508         else if (MUTATOR_CALLHOOK(PM_Physics, this, maxspeed_mod))
1509                 { }
1510
1511 #ifdef SVQC
1512         else if (this.movetype == MOVETYPE_NOCLIP || this.movetype == MOVETYPE_FLY || this.movetype == MOVETYPE_FLY_WORLDONLY || MUTATOR_CALLHOOK(IsFlying, this))
1513 #elif defined(CSQC)
1514         else if (this.move_movetype == MOVETYPE_NOCLIP || this.move_movetype == MOVETYPE_FLY || this.move_movetype == MOVETYPE_FLY_WORLDONLY || MUTATOR_CALLHOOK(IsFlying, this))
1515 #endif
1516                 PM_fly(this, maxspeed_mod);
1517
1518         else if (this.waterlevel >= WATERLEVEL_SWIMMING)
1519                 PM_swim(this, maxspeed_mod);
1520
1521         else if (time < this.ladder_time)
1522                 PM_ladder(this, maxspeed_mod);
1523
1524         else if (ITEMS_STAT(this) & IT_USING_JETPACK)
1525                 PM_jetpack(this, maxspeed_mod);
1526
1527         else if (IS_ONGROUND(this))
1528                 PM_walk(this, maxspeed_mod);
1529
1530         else
1531                 PM_air(this, buttons_prev, maxspeed_mod);
1532
1533 LABEL(end)
1534         if (IS_ONGROUND(this))
1535                 this.lastground = time;
1536
1537         // conveyors: then break velocity again
1538         if(this.conveyor.state)
1539                 this.velocity += this.conveyor.movedir;
1540
1541         this.lastflags = this.flags;
1542
1543         this.lastclassname = this.classname;
1544 }
1545
1546 #if defined(SVQC)
1547 void SV_PlayerPhysics()
1548 #elif defined(CSQC)
1549 void CSQC_ClientMovement_PlayerMove_Frame(entity this)
1550 #endif
1551 {
1552 #ifdef SVQC
1553         SELFPARAM();
1554 #endif
1555         PM_Main(this);
1556 }