qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 if (autocvar_cl_ghost_items_color)
  54                 {
  55                         this.alpha = autocvar_cl_ghost_items;
  56                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  57                 }
  58                 else
  59                         this.alpha = -1;
  60         }
  61
  62         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  63         {
  64                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  65                 this.alpha = autocvar_cl_weapon_stay_alpha;
  66         }
  67
  68         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  69 }
  70
  71 void ItemDraw(entity this)
  72 {
  73     if(this.gravity)
  74     {
  75         Movetype_Physics_MatchServer(this, false);
  76         if(IS_ONGROUND(this))
  77         { // For some reason avelocity gets set to '0 0 0' here ...
  78             this.oldorigin = this.origin;
  79             this.gravity = 0;
  80
  81             if(autocvar_cl_animate_items)
  82             { // ... so reset it if animations are requested.
  83                 if(this.ItemStatus & ITS_ANIMATE1)
  84                     this.avelocity = '0 180 0';
  85
  86                 if(this.ItemStatus & ITS_ANIMATE2)
  87                     this.avelocity = '0 -90 0';
  88             }
  89
  90             // delay is for blocking item's position for a while;
  91             // it's a workaround for dropped weapons that receive the position
  92             // another time right after they spawn overriding animation position
  93             this.onground_time = time + 0.5;
  94         }
  95     }
  96     else if (autocvar_cl_animate_items)
  97     {
  98         if(this.ItemStatus & ITS_ANIMATE1)
  99         {
 100                 if(!this.item_simple)
 101                 this.angles += this.avelocity * frametime;
 102             float fade_in = bound(0, time - this.onground_time, 1);
 103             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 104         }
 105
 106         if(this.ItemStatus & ITS_ANIMATE2)
 107         {
 108                 if(!this.item_simple)
 109                 this.angles += this.avelocity * frametime;
 110             float fade_in = bound(0, time - this.onground_time, 1);
 111             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 112         }
 113     }
 114
 115     Item_SetAlpha(this);
 116 }
 117
 118 void Item_PreDraw(entity this)
 119 {
 120         if(warpzone_warpzones_exist)
 121         {
 122                 setpredraw(this, func_null); // no need to keep running this
 123                 return;
 124         }
 125         float alph;
 126         vector org = getpropertyvec(VF_ORIGIN);
 127         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 128                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 129         if(this.fade_start)
 130         {
 131                 if(vdist(org - this.origin, >, this.fade_end))
 132                         alph = 0; // save on some processing
 133                 else if(vdist(org - this.origin, <, this.fade_start))
 134                         alph = 1; // more processing saved
 135                 else
 136                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 137         }
 138         else
 139                 alph = 1;
 140         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 141         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 142                 this.alpha = alph;
 143         if(alph <= 0)
 144                 this.drawmask = 0;
 145         //else
 146                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 147 }
 148
 149 void ItemRemove(entity this)
 150 {
 151         if(this.mdl)
 152                 strunzone(this.mdl);
 153 }
 154
 155 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 156 {
 157     int sf = ReadByte();
 158
 159     if(sf & ISF_LOCATION)
 160     {
 161         this.origin = ReadVector();
 162         setorigin(this, this.origin);
 163         this.oldorigin = this.origin;
 164     }
 165
 166     if(sf & ISF_ANGLES)
 167     {
 168         this.angles_x = ReadAngle();
 169         this.angles_y = ReadAngle();
 170         this.angles_z = ReadAngle();
 171     }
 172
 173     if(sf & ISF_SIZE)
 174     {
 175         float use_bigsize = ReadByte();
 176         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 177     }
 178
 179     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 180     {
 181         this.ItemStatus = ReadByte();
 182
 183         Item_SetAlpha(this);
 184
 185         if(autocvar_cl_fullbright_items)
 186             if(this.ItemStatus & ITS_ALLOWFB)
 187                 this.effects |= EF_FULLBRIGHT;
 188
 189         if(this.ItemStatus & ITS_GLOW)
 190         {
 191             if(this.ItemStatus & ITS_AVAILABLE)
 192                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 193             else
 194                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 195         }
 196     }
 197
 198     if(sf & ISF_MODEL)
 199     {
 200         this.drawmask  = MASK_NORMAL;
 201                 set_movetype(this, MOVETYPE_TOSS);
 202                 if (isnew) IL_PUSH(g_drawables, this);
 203         this.draw       = ItemDraw;
 204         this.solid = SOLID_TRIGGER;
 205         //this.flags |= FL_ITEM;
 206
 207         bool use_bigsize = ReadByte();
 208
 209         this.fade_end = ReadShort();
 210         this.fade_start = ReadShort();
 211         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 212                 setpredraw(this, Item_PreDraw);
 213
 214         if(this.mdl)
 215             strunzone(this.mdl);
 216
 217         this.mdl = "";
 218         string _fn = ReadString();
 219         this.item_simple = false; // reset it!
 220
 221         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 222         {
 223             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 224             this.item_simple = true;
 225
 226             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 227                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 228             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 229                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 230             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 231                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 232             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 233                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 234             else
 235             {
 236                 this.item_simple = false;
 237                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 238             }
 239         }
 240
 241         if(!this.item_simple)
 242             this.mdl = strzone(_fn);
 243
 244
 245         if(this.mdl == "")
 246             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 247
 248         precache_model(this.mdl);
 249         _setmodel(this, this.mdl);
 250
 251         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 252     }
 253
 254     if(sf & ISF_COLORMAP)
 255     {
 256         this.colormap = ReadShort();
 257         this.item_glowmod_x = ReadByte() / 255.0;
 258         this.item_glowmod_y = ReadByte() / 255.0;
 259         this.item_glowmod_z = ReadByte() / 255.0;
 260     }
 261
 262     if(sf & ISF_DROP)
 263     {
 264         this.gravity = 1;
 265         this.pushable = true;
 266         //this.angles = '0 0 0';
 267         set_movetype(this, MOVETYPE_TOSS);
 268         this.velocity = ReadVector();
 269         setorigin(this, this.oldorigin);
 270
 271         if(!this.move_time)
 272         {
 273             this.move_time = time;
 274             this.spawntime = time;
 275         }
 276         else
 277             this.move_time = max(this.move_time, time);
 278     }
 279
 280     if(autocvar_cl_animate_items)
 281     {
 282         if(this.ItemStatus & ITS_ANIMATE1)
 283             this.avelocity = '0 180 0';
 284
 285         if(this.ItemStatus & ITS_ANIMATE2)
 286             this.avelocity = '0 -90 0';
 287     }
 288
 289     this.entremove = ItemRemove;
 290
 291     return true;
 292 }
 293
 294 #endif
 295
 296 #ifdef SVQC
 297 bool ItemSend(entity this, entity to, int sf)
 298 {
 299         if(this.gravity)
 300                 sf |= ISF_DROP;
 301         else
 302                 sf &= ~ISF_DROP;
 303
 304         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 305         WriteByte(MSG_ENTITY, sf);
 306
 307         //WriteByte(MSG_ENTITY, this.cnt);
 308         if(sf & ISF_LOCATION)
 309         {
 310                 WriteVector(MSG_ENTITY, this.origin);
 311         }
 312
 313         if(sf & ISF_ANGLES)
 314         {
 315                 WriteAngle(MSG_ENTITY, this.angles_x);
 316                 WriteAngle(MSG_ENTITY, this.angles_y);
 317                 WriteAngle(MSG_ENTITY, this.angles_z);
 318         }
 319
 320         if(sf & ISF_SIZE)
 321         {
 322                 Pickup p = this.itemdef;
 323                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 324         }
 325
 326         if(sf & ISF_STATUS)
 327                 WriteByte(MSG_ENTITY, this.ItemStatus);
 328
 329         if(sf & ISF_MODEL)
 330         {
 331                 Pickup p = this.itemdef;
 332                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 333                 WriteShort(MSG_ENTITY, this.fade_end);
 334                 WriteShort(MSG_ENTITY, this.fade_start);
 335
 336                 if(this.mdl == "")
 337                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 338
 339                 WriteString(MSG_ENTITY, this.mdl);
 340         }
 341
 342
 343         if(sf & ISF_COLORMAP)
 344         {
 345                 WriteShort(MSG_ENTITY, this.colormap);
 346                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 347         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 348         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 349         }
 350
 351         if(sf & ISF_DROP)
 352         {
 353                 WriteVector(MSG_ENTITY, this.velocity);
 354         }
 355
 356         return true;
 357 }
 358
 359 void ItemUpdate(entity this)
 360 {
 361         this.oldorigin = this.origin;
 362         this.SendFlags |= ISF_LOCATION;
 363 }
 364
 365 void UpdateItemAfterTeleport(entity this)
 366 {
 367         if(getSendEntity(this) == ItemSend)
 368                 ItemUpdate(this);
 369 }
 370
 371 bool have_pickup_item(entity this)
 372 {
 373         if(this.itemdef.instanceOfPowerup)
 374         {
 375                 if(autocvar_g_powerups > 0)
 376                         return true;
 377                 if(autocvar_g_powerups == 0)
 378                         return false;
 379         }
 380         else
 381         {
 382                 if(autocvar_g_pickup_items > 0)
 383                         return true;
 384                 if(autocvar_g_pickup_items == 0)
 385                         return false;
 386                 if(g_weaponarena)
 387                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 388                                 return false;
 389         }
 390         return true;
 391 }
 392
 393 /*
 394 float Item_Customize()
 395 {
 396         if(this.spawnshieldtime)
 397                 return true;
 398         if(this.weapons & ~other.weapons)
 399         {
 400                 this.colormod = '0 0 0';
 401                 this.glowmod = this.colormod;
 402                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 403                 return true;
 404         }
 405         else
 406         {
 407                 if(g_ghost_items)
 408                 {
 409                         this.colormod = stov(autocvar_g_ghost_items_color);
 410                         this.glowmod = this.colormod;
 411                         this.alpha = g_ghost_items;
 412                         return true;
 413                 }
 414                 else
 415                         return false;
 416         }
 417 }
 418 */
 419
 420 void Item_Show (entity e, float mode)
 421 {
 422         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 423         e.ItemStatus &= ~ITS_STAYWEP;
 424         entity def = e.itemdef;
 425         if (mode > 0)
 426         {
 427                 // make the item look normal, and be touchable
 428                 e.model = e.mdl;
 429                 e.solid = SOLID_TRIGGER;
 430                 e.spawnshieldtime = 1;
 431                 e.ItemStatus |= ITS_AVAILABLE;
 432         }
 433         else if (mode < 0)
 434         {
 435                 // hide the item completely
 436                 e.model = string_null;
 437                 e.solid = SOLID_NOT;
 438                 e.spawnshieldtime = 1;
 439                 e.ItemStatus &= ~ITS_AVAILABLE;
 440         }
 441         else
 442         {
 443                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 444                         || e.team // weapon stay isn't supported for teamed weapons
 445                         ;
 446                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 447                 {
 448                         // make the item translucent and not touchable
 449                         e.model = e.mdl;
 450                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 451                         e.effects |= EF_STARDUST;
 452                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 453                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 454                 }
 455                 else
 456                 {
 457                         //setmodel(e, "null");
 458                         e.solid = SOLID_NOT;
 459                         e.colormod = '0 0 0';
 460                         //e.glowmod = e.colormod;
 461                         e.spawnshieldtime = 1;
 462                         e.ItemStatus &= ~ITS_AVAILABLE;
 463                 }
 464         }
 465
 466         if (def.m_glow)
 467                 e.ItemStatus |= ITS_GLOW;
 468
 469         if (autocvar_g_nodepthtestitems)
 470                 e.effects |= EF_NODEPTHTEST;
 471
 472
 473         if (autocvar_g_fullbrightitems)
 474                 e.ItemStatus |= ITS_ALLOWFB;
 475
 476         if (autocvar_sv_simple_items)
 477                 e.ItemStatus |= ITS_ALLOWSI;
 478
 479         // relink entity (because solid may have changed)
 480         setorigin(e, e.origin);
 481         e.SendFlags |= ISF_STATUS;
 482 }
 483
 484 void Item_Think(entity this)
 485 {
 486         this.nextthink = time;
 487         if(this.origin != this.oldorigin)
 488                 ItemUpdate(this);
 489 }
 490
 491 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 492 bool Item_ItemsTime_Allow(GameItem it);
 493 float Item_ItemsTime_UpdateTime(entity e, float t);
 494 void Item_ItemsTime_SetTime(entity e, float t);
 495 void Item_ItemsTime_SetTimesForAllPlayers();
 496
 497 void Item_Respawn (entity this)
 498 {
 499         Item_Show(this, 1);
 500         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 501         setorigin(this, this.origin);
 502
 503     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 504         {
 505                 float t = Item_ItemsTime_UpdateTime(this, 0);
 506                 Item_ItemsTime_SetTime(this, t);
 507                 Item_ItemsTime_SetTimesForAllPlayers();
 508         }
 509
 510         setthink(this, Item_Think);
 511         this.nextthink = time;
 512
 513         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 514         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 515 }
 516
 517 void Item_RespawnCountdown (entity this)
 518 {
 519         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 520         {
 521                 if(this.waypointsprite_attached)
 522                         WaypointSprite_Kill(this.waypointsprite_attached);
 523                 Item_Respawn(this);
 524         }
 525         else
 526         {
 527                 this.nextthink = time + 1;
 528                 this.item_respawncounter += 1;
 529                 if(this.item_respawncounter == 1)
 530                 {
 531                         do {
 532                                 {
 533                                         entity wi = Weapons_from(this.weapon);
 534                                         if (wi != WEP_Null) {
 535                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 536                                                 wp.wp_extra = wi.m_id;
 537                                                 break;
 538                                         }
 539                                 }
 540                                 {
 541                                         entity ii = this.itemdef;
 542                                         if (ii != NULL) {
 543                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 544                                                 wp.wp_extra = ii.m_id;
 545                                                 break;
 546                                         }
 547                                 }
 548                         } while (0);
 549                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 550             if(this.waypointsprite_attached)
 551             {
 552                 GameItem def = this.itemdef;
 553                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 554                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 555                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 556             }
 557                 }
 558
 559                 if(this.waypointsprite_attached)
 560                 {
 561                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 562                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 563                                 {
 564                                         msg_entity = it;
 565                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 566                                 }
 567                         });
 568
 569                         WaypointSprite_Ping(this.waypointsprite_attached);
 570                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 571                 }
 572         }
 573 }
 574
 575 void Item_RespawnThink(entity this)
 576 {
 577         this.nextthink = time;
 578         if(this.origin != this.oldorigin)
 579                 ItemUpdate(this);
 580
 581         if(time >= this.wait)
 582                 Item_Respawn(this);
 583 }
 584
 585 void Item_ScheduleRespawnIn(entity e, float t)
 586 {
 587         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 588         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 589         {
 590                 setthink(e, Item_RespawnCountdown);
 591                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 592                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 593                 e.item_respawncounter = 0;
 594                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 595                 {
 596                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 597                         Item_ItemsTime_SetTime(e, t);
 598                         Item_ItemsTime_SetTimesForAllPlayers();
 599                 }
 600         }
 601         else
 602         {
 603                 setthink(e, Item_RespawnThink);
 604                 e.nextthink = time;
 605                 e.scheduledrespawntime = time + t;
 606                 e.wait = time + t;
 607
 608                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 609                 {
 610                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 611                         Item_ItemsTime_SetTime(e, t);
 612                         Item_ItemsTime_SetTimesForAllPlayers();
 613                 }
 614         }
 615 }
 616
 617 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 618 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 619 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 620
 621 /// Adjust respawn time according to the number of players.
 622 float adjust_respawntime(float normal_respawntime) {
 623         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 624         float o = autocvar_g_pickup_respawntime_scaling_offset;
 625         float l = autocvar_g_pickup_respawntime_scaling_linear;
 626
 627         if (r == 0 && l == 1) {
 628                 return normal_respawntime;
 629         }
 630
 631         CheckAllowedTeams(NULL);
 632         GetTeamCounts(NULL);
 633         int players = 0;
 634         if (c1 != -1) players += c1;
 635         if (c2 != -1) players += c2;
 636         if (c3 != -1) players += c3;
 637         if (c4 != -1) players += c4;
 638
 639         if (players >= 2) {
 640                 return normal_respawntime * (r / (players + o) + l);
 641         } else {
 642                 return normal_respawntime;
 643         }
 644 }
 645
 646 void Item_ScheduleRespawn(entity e)
 647 {
 648         if(e.respawntime > 0)
 649         {
 650                 Item_Show(e, 0);
 651
 652                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 653                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 654
 655                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 656                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 657                 Item_ScheduleRespawnIn(e, respawn_in);
 658         }
 659         else // if respawntime is -1, this item does not respawn
 660                 Item_Show(e, -1);
 661 }
 662
 663 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 664         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 665
 666 float shared_random;
 667 STATIC_INIT(shared_random) { shared_random = random(); }
 668 void Item_ScheduleInitialRespawn(entity e)
 669 {
 670         Item_Show(e, 0);
 671
 672         float spawn_in;
 673         if (autocvar_g_pickup_respawntime_initial_random == 0)
 674         {
 675                 // range: respawntime .. respawntime + respawntimejitter
 676                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 677         }
 678         else if (autocvar_g_pickup_respawntime_initial_random == 1)
 679         {
 680                 // range:
 681                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 682                 // else: 0 .. ITEM_RESPAWN_TICKS
 683                 // this is to prevent powerups spawning unexpectedly without waypoints
 684                 spawn_in = ITEM_RESPAWN_TICKS + shared_random * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 685         }
 686         else
 687         {
 688                 // range: same as 1
 689                 spawn_in = ITEM_RESPAWN_TICKS + random() * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 690         }
 691
 692         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 693 }
 694
 695 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 696         entity ammo_entity)
 697 {
 698         if (num_weapons == 0)
 699         {
 700                 return;
 701         }
 702         int num_potential_weapons = tokenize_console(weapon_names);
 703         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 704         {
 705                 RandomSelection_Init();
 706                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 707                         ++weapon_index)
 708                 {
 709                         string weapon = argv(weapon_index);
 710                         FOREACH(Weapons, it != WEP_Null,
 711                         {
 712                                 // Finding a weapon which player doesn't have.
 713                                 if (!(receiver.weapons & it.m_wepset) && (it.netname == weapon))
 714                                 {
 715                                         RandomSelection_AddEnt(it, 1, 1);
 716                                         break;
 717                                 }
 718                         });
 719                 }
 720                 if (RandomSelection_chosen_ent == NULL)
 721                 {
 722                         return;
 723                 }
 724                 receiver.weapons |= RandomSelection_chosen_ent.m_wepset;
 725                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
 726                 {
 727                         continue;
 728                 }
 729                 if (GetResourceAmount(receiver,
 730                         RandomSelection_chosen_ent.ammo_type) != 0)
 731                 {
 732                         continue;
 733                 }
 734                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 735                         GetResourceAmount(ammo_entity,
 736                         RandomSelection_chosen_ent.ammo_type));
 737         }
 738 }
 739
 740 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 741 {
 742         float amount = GetResourceAmount(item, resource_type);
 743         if (amount == 0)
 744         {
 745                 return false;
 746         }
 747         float player_amount = GetResourceAmount(player, resource_type);
 748         if (item.spawnshieldtime)
 749         {
 750                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 751                 {
 752                         return false;
 753                 }
 754                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
 755                 return true;
 756         }
 757         if (g_weapon_stay != 2)
 758         {
 759                 return false;
 760         }
 761         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 762         return true;
 763 }
 764
 765 float Item_GiveTo(entity item, entity player)
 766 {
 767         float pickedup;
 768
 769         // if nothing happens to player, just return without taking the item
 770         pickedup = false;
 771         int _switchweapon = 0;
 772         // in case the player has autoswitch enabled do the following:
 773         // if the player is using their best weapon before items are given, they
 774         // probably want to switch to an even better weapon after items are given
 775
 776         if(CS(player).autoswitch)
 777         {
 778                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 779                 {
 780                         .entity weaponentity = weaponentities[slot];
 781                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 782                         {
 783                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 784                                         _switchweapon |= BIT(slot);
 785
 786                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 787                                         _switchweapon |= BIT(slot);
 788                         }
 789                 }
 790         }
 791         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 792         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 793         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 794         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 795         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 796         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 797         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 798         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 799         if (item.itemdef.instanceOfWeaponPickup)
 800         {
 801                 WepSet w;
 802                 w = item.weapons;
 803                 w &= ~player.weapons;
 804
 805                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 806                 {
 807                         pickedup = true;
 808                         FOREACH(Weapons, it != WEP_Null, {
 809                                 if(w & (it.m_wepset))
 810                                 {
 811                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 812                                         {
 813                                                 .entity weaponentity = weaponentities[slot];
 814                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 815                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 816                                         }
 817                                         W_GiveWeapon(player, it.m_id);
 818                                 }
 819                         });
 820                 }
 821         }
 822
 823         if (item.itemdef.instanceOfPowerup)
 824         {
 825                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 826                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 827                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 828                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 829         }
 830
 831         int its;
 832         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 833         {
 834                 pickedup = true;
 835                 player.items |= its;
 836                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 837         }
 838
 839         if (item.strength_finished)
 840         {
 841                 pickedup = true;
 842                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 843         }
 844         if (item.invincible_finished)
 845         {
 846                 pickedup = true;
 847                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 848         }
 849         if (item.superweapons_finished)
 850         {
 851                 pickedup = true;
 852                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 853         }
 854
 855         // always eat teamed entities
 856         if(item.team)
 857                 pickedup = true;
 858
 859         if (!pickedup)
 860                 return 0;
 861
 862         // crude hack to enforce switching weapons
 863         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 864         {
 865                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 866                 {
 867                         .entity weaponentity = weaponentities[slot];
 868                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 869                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 870                 }
 871                 return 1;
 872         }
 873
 874         if(_switchweapon)
 875         {
 876                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 877                 {
 878                         .entity weaponentity = weaponentities[slot];
 879                         if(_switchweapon & BIT(slot))
 880                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 881                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 882                 }
 883         }
 884
 885         return 1;
 886 }
 887
 888 void Item_Touch(entity this, entity toucher)
 889 {
 890         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 891         if (Item_IsLoot(this))
 892         {
 893                 if (ITEM_TOUCH_NEEDKILL())
 894                 {
 895                         delete(this);
 896                         return;
 897                 }
 898         }
 899
 900         if(!(toucher.flags & FL_PICKUPITEMS)
 901         || STAT(FROZEN, toucher)
 902         || IS_DEAD(toucher)
 903         || (this.solid != SOLID_TRIGGER)
 904         || (this.owner == toucher)
 905         || (time < this.item_spawnshieldtime)
 906         ) { return; }
 907
 908         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 909         {
 910                 case MUT_ITEMTOUCH_RETURN: { return; }
 911                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 912         }
 913
 914         toucher = M_ARGV(1, entity);
 915
 916         if (Item_IsExpiring(this))
 917         {
 918                 this.strength_finished = max(0, this.strength_finished - time);
 919                 this.invincible_finished = max(0, this.invincible_finished - time);
 920                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 921         }
 922         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 923         if (!gave)
 924         {
 925                 if (Item_IsExpiring(this))
 926                 {
 927                         // undo what we did above
 928                         this.strength_finished += time;
 929                         this.invincible_finished += time;
 930                         this.superweapons_finished += time;
 931                 }
 932                 return;
 933         }
 934
 935 LABEL(pickup)
 936
 937         STAT(LAST_PICKUP, toucher) = time;
 938
 939         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 940         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 941
 942         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 943         if (wasfreed(this))
 944         {
 945                 return;
 946         }
 947
 948         if (Item_IsLoot(this))
 949         {
 950                 delete(this);
 951                 return;
 952         }
 953         if (!this.spawnshieldtime)
 954         {
 955                 return;
 956         }
 957         entity e;
 958         if (this.team)
 959         {
 960                 RandomSelection_Init();
 961                 IL_EACH(g_items, it.team == this.team,
 962                 {
 963                         if (it.itemdef) // is a registered item
 964                         {
 965                                 Item_Show(it, -1);
 966                                 it.scheduledrespawntime = 0;
 967                                 RandomSelection_AddEnt(it, it.cnt, 0);
 968                         }
 969                 });
 970                 e = RandomSelection_chosen_ent;
 971                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 972         }
 973         else
 974                 e = this;
 975         Item_ScheduleRespawn(e);
 976 }
 977
 978 void Item_Reset(entity this)
 979 {
 980         Item_Show(this, !this.state);
 981         setorigin(this, this.origin);
 982
 983         if (Item_IsLoot(this))
 984         {
 985                 return;
 986         }
 987         setthink(this, Item_Think);
 988         this.nextthink = time;
 989         if (this.waypointsprite_attached)
 990         {
 991                 WaypointSprite_Kill(this.waypointsprite_attached);
 992         }
 993         if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 994         {
 995                 Item_ScheduleInitialRespawn(this);
 996         }
 997 }
 998
 999 void Item_FindTeam(entity this)
1000 {
1001         entity e;
1002
1003         if(this.effects & EF_NODRAW)
1004         {
1005                 // marker for item team search
1006                 LOG_TRACE("Initializing item team ", ftos(this.team));
1007                 RandomSelection_Init();
1008                 IL_EACH(g_items, it.team == this.team,
1009                 {
1010                         if(it.itemdef) // is a registered item
1011                                 RandomSelection_AddEnt(it, it.cnt, 0);
1012                 });
1013
1014                 e = RandomSelection_chosen_ent;
1015                 e.state = 0;
1016                 Item_Show(e, 1);
1017
1018                 IL_EACH(g_items, it.team == this.team,
1019                 {
1020                         if(it.itemdef) // is a registered item
1021                         {
1022                                 if(it != e)
1023                                 {
1024                                         // make it non-spawned
1025                                         Item_Show(it, -1);
1026                                         it.state = 1; // state 1 = initially hidden item, apparently
1027                                 }
1028                                 it.effects &= ~EF_NODRAW;
1029                         }
1030                 });
1031
1032                 Item_Reset(this);
1033         }
1034 }
1035
1036 // Savage: used for item garbage-collection
1037 void RemoveItem(entity this)
1038 {
1039         if(wasfreed(this) || !this) { return; }
1040         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1041         delete(this);
1042 }
1043
1044 // pickup evaluation functions
1045 // these functions decide how desirable an item is to the bots
1046
1047 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1048
1049 float weapon_pickupevalfunc(entity player, entity item)
1050 {
1051         // See if I have it already
1052         if(player.weapons & item.weapons)
1053         {
1054                 // If I can pick it up
1055                 if(!item.spawnshieldtime)
1056                         return 0;
1057                 return ammo_pickupevalfunc(player, item);
1058         }
1059
1060         // reduce weapon value if bot already got a good arsenal
1061         float c = 1;
1062         int weapons_value = 0;
1063         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1064                 weapons_value += it.bot_pickupbasevalue;
1065         });
1066         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1067
1068         return item.bot_pickupbasevalue * c;
1069 }
1070
1071 float ammo_pickupevalfunc(entity player, entity item)
1072 {
1073         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1074         entity wpn = NULL;
1075         float c = 0;
1076         float rating = 0;
1077
1078         // Detect needed ammo
1079         if(item.itemdef.instanceOfWeaponPickup)
1080         {
1081                 entity ammo = NULL;
1082                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1083                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1084                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1085                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1086                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1087                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1088
1089                 if(!ammo)
1090                         return 0;
1091                 wpn = item;
1092                 rating = ammo.m_botvalue;
1093         }
1094         else
1095         {
1096                 FOREACH(Weapons, it != WEP_Null, {
1097                         if(!(player.weapons & (it.m_wepset)))
1098                                 continue;
1099
1100                         switch(it.ammo_type)
1101                         {
1102                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1103                                 case RESOURCE_BULLETS: need_nails   = true; break;
1104                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1105                                 case RESOURCE_CELLS:   need_cells   = true; break;
1106                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1107                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1108                         }
1109                 });
1110                 rating = item.bot_pickupbasevalue;
1111         }
1112
1113         float noammorating = 0.5;
1114
1115         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1116                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1117
1118         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1119                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1120
1121         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1122                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1123
1124         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1125                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1126
1127         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1128                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1129
1130         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1131                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1132
1133         rating *= min(c, 2);
1134         if(wpn)
1135                 rating += wpn.bot_pickupbasevalue * 0.1;
1136         return rating;
1137 }
1138
1139 float healtharmor_pickupevalfunc(entity player, entity item)
1140 {
1141         float c = 0;
1142         float rating = item.bot_pickupbasevalue;
1143
1144         float itemarmor = item.armorvalue;
1145         float itemhealth = item.health;
1146
1147         if(item.item_group)
1148         {
1149                 itemarmor *= min(4, item.item_group_count);
1150                 itemhealth *= min(4, item.item_group_count);
1151         }
1152
1153         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1154                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1155
1156         if (itemhealth && (player.health < item.max_health))
1157                 c = itemhealth / max(1, player.health);
1158
1159         rating *= min(2, c);
1160         return rating;
1161 }
1162
1163 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1164 {
1165         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1166                 RemoveItem(this);
1167 }
1168
1169 void item_use(entity this, entity actor, entity trigger)
1170 {
1171         // use the touch function to handle collection
1172         gettouch(this)(this, actor);
1173 }
1174
1175 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1176 {
1177         string itemname = def.m_name;
1178         Model itemmodel = def.m_model;
1179     Sound pickupsound = def.m_sound;
1180         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1181         float pickupbasevalue = def.m_botvalue;
1182         int itemflags = def.m_itemflags;
1183
1184         startitem_failed = false;
1185
1186         this.item_model_ent = itemmodel;
1187     this.item_pickupsound_ent = pickupsound;
1188
1189     if(def.m_iteminit)
1190         def.m_iteminit(this);
1191
1192         if(!this.respawntime) // both need to be set
1193         {
1194                 this.respawntime = defaultrespawntime;
1195                 this.respawntimejitter = defaultrespawntimejitter;
1196         }
1197
1198         if(!this.pickup_anyway && def.m_pickupanyway)
1199                 this.pickup_anyway = def.m_pickupanyway();
1200
1201         int itemid = def.m_itemid;
1202         this.items = itemid;
1203         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1204         this.weapon = weaponid;
1205
1206         if(!this.fade_end)
1207         {
1208                 this.fade_start = autocvar_g_items_mindist;
1209                 this.fade_end = autocvar_g_items_maxdist;
1210         }
1211
1212         if(weaponid)
1213                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1214
1215         this.flags = FL_ITEM | itemflags;
1216         IL_PUSH(g_items, this);
1217
1218         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1219         {
1220                 startitem_failed = true;
1221                 delete(this);
1222                 return;
1223         }
1224
1225         if (Item_IsLoot(this))
1226         {
1227                 this.reset = SUB_Remove;
1228                 set_movetype(this, MOVETYPE_TOSS);
1229
1230                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1231                 setthink(this, RemoveItem);
1232                 this.nextthink = time + 20;
1233
1234                 this.takedamage = DAMAGE_YES;
1235                 this.event_damage = Item_Damage;
1236
1237                 if (Item_IsExpiring(this))
1238                 {
1239                         // if item is worthless after a timer, have it expire then
1240                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1241                 }
1242
1243                 // don't drop if in a NODROP zone (such as lava)
1244                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1245                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1246                 {
1247                         startitem_failed = true;
1248                         delete(this);
1249                         return;
1250                 }
1251         }
1252         else
1253         {
1254                 if(!have_pickup_item(this))
1255                 {
1256                         startitem_failed = true;
1257                         delete(this);
1258                         return;
1259                 }
1260
1261                 if(this.angles != '0 0 0')
1262                         this.SendFlags |= ISF_ANGLES;
1263
1264                 this.reset = Item_Reset;
1265                 // it's a level item
1266                 if(this.spawnflags & 1)
1267                         this.noalign = 1;
1268                 if (this.noalign > 0)
1269                         set_movetype(this, MOVETYPE_NONE);
1270                 else
1271                         set_movetype(this, MOVETYPE_TOSS);
1272                 // do item filtering according to game mode and other things
1273                 if (this.noalign <= 0)
1274                 {
1275                         // first nudge it off the floor a little bit to avoid math errors
1276                         setorigin(this, this.origin + '0 0 1');
1277                         // set item size before we spawn a spawnfunc_waypoint
1278                         setsize(this, def.m_mins, def.m_maxs);
1279                         this.SendFlags |= ISF_SIZE;
1280                         // note droptofloor returns false if stuck/or would fall too far
1281                         if (!this.noalign)
1282                                 droptofloor(this);
1283                         waypoint_spawnforitem(this);
1284                 }
1285
1286                 /*
1287                  * can't do it that way, as it would break maps
1288                  * TODO make a target_give like entity another way, that perhaps has
1289                  * the weapon name in a key
1290                 if(this.targetname)
1291                 {
1292                         // target_give not yet supported; maybe later
1293                         print("removed targeted ", this.classname, "\n");
1294                         startitem_failed = true;
1295                         delete(this);
1296                         return;
1297                 }
1298                 */
1299
1300                 if(this.targetname != "" && (this.spawnflags & 16))
1301                         this.use = item_use;
1302
1303                 if(autocvar_spawn_debug >= 2)
1304                 {
1305             // why not flags & fl_item?
1306                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1307                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1308                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1309                 error("Mapper sucks.");
1310             });
1311                         this.is_item = true;
1312                 }
1313
1314                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1315
1316                 precache_model(this.model);
1317                 precache_sound(this.item_pickupsound);
1318
1319                 if (   def.instanceOfPowerup
1320                         || def.instanceOfWeaponPickup
1321                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1322                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1323                         || (itemid & (IT_KEY1 | IT_KEY2))
1324                 ) this.target = "###item###"; // for finding the nearest item using find()
1325
1326                 Item_ItemsTime_SetTime(this, 0);
1327         }
1328
1329         this.bot_pickup = true;
1330         this.bot_pickupevalfunc = pickupevalfunc;
1331         this.bot_pickupbasevalue = pickupbasevalue;
1332         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1333         this.netname = itemname;
1334         settouch(this, Item_Touch);
1335         setmodel(this, MDL_Null); // precision set below
1336         //this.effects |= EF_LOWPRECISION;
1337
1338         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1339
1340         this.SendFlags |= ISF_SIZE;
1341
1342         if (!(this.spawnflags & 1024)) {
1343                 if(def.instanceOfPowerup)
1344                         this.ItemStatus |= ITS_ANIMATE1;
1345
1346                 if(this.armorvalue || this.health)
1347                         this.ItemStatus |= ITS_ANIMATE2;
1348         }
1349
1350         if(def.instanceOfWeaponPickup)
1351         {
1352                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1353                         this.colormap = 1024; // color shirt=0 pants=0 grey
1354                 else
1355                         this.gravity = 1;
1356                 if (!(this.spawnflags & 1024))
1357                         this.ItemStatus |= ITS_ANIMATE1;
1358                 this.SendFlags |= ISF_COLORMAP;
1359         }
1360
1361         this.state = 0;
1362         if(this.team) // broken, no idea why.
1363         {
1364                 if(!this.cnt)
1365                         this.cnt = 1; // item probability weight
1366
1367                 this.effects |= EF_NODRAW; // marker for item team search
1368                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1369         }
1370         else
1371                 Item_Reset(this);
1372
1373         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1374
1375         // call this hook after everything else has been done
1376         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1377         {
1378                 startitem_failed = true;
1379                 delete(this);
1380                 return;
1381         }
1382
1383         setItemGroup(this);
1384 }
1385
1386 void StartItem(entity this, GameItem def)
1387 {
1388     def = def.m_spawnfunc_hookreplace(def, this);
1389     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1390     {
1391         delete(this);
1392         return;
1393     }
1394     this.classname = def.m_canonical_spawnfunc;
1395     _StartItem(
1396         this,
1397         this.itemdef = def,
1398         def.m_respawntime(), // defaultrespawntime
1399         def.m_respawntimejitter() // defaultrespawntimejitter
1400         );
1401 }
1402
1403 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1404 int group_count = 1;
1405
1406 void setItemGroup(entity this)
1407 {
1408         if(!IS_SMALL(this.itemdef))
1409                 return;
1410
1411         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1412         {
1413                 if(!this.item_group)
1414                 {
1415                         if(!it.item_group)
1416                         {
1417                                 it.item_group = group_count;
1418                                 group_count++;
1419                         }
1420                         this.item_group = it.item_group;
1421                 }
1422                 else // spawning item is already part of a item_group X
1423                 {
1424                         if(!it.item_group)
1425                                 it.item_group = this.item_group;
1426                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1427                         {
1428                                 int grY = it.item_group;
1429                                 // move all items of item_group Y to item_group X
1430                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1431                                 {
1432                                         if(it.item_group == grY)
1433                                                 it.item_group = this.item_group;
1434                                 });
1435                         }
1436                 }
1437         });
1438 }
1439
1440 void setItemGroupCount()
1441 {
1442         for (int k = 1; k <= group_count; k++)
1443         {
1444                 int count = 0;
1445                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1446                 if (count)
1447                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1448         }
1449 }
1450
1451 void target_items_use(entity this, entity actor, entity trigger)
1452 {
1453         if(Item_IsLoot(actor))
1454         {
1455                 EXACTTRIGGER_TOUCH(this, trigger);
1456                 delete(actor);
1457                 return;
1458         }
1459
1460         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1461                 return;
1462
1463         if(trigger.solid == SOLID_TRIGGER)
1464         {
1465                 EXACTTRIGGER_TOUCH(this, trigger);
1466         }
1467
1468         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1469         {
1470                 delete(it);
1471         });
1472
1473         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1474                 centerprint(actor, this.message);
1475 }
1476
1477 spawnfunc(target_items)
1478 {
1479         int n;
1480         string s;
1481
1482         this.use = target_items_use;
1483         if(!this.strength_finished)
1484                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1485         if(!this.invincible_finished)
1486                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1487         if(!this.superweapons_finished)
1488                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1489
1490         n = tokenize_console(this.netname);
1491         if(argv(0) == "give")
1492         {
1493                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1494         }
1495         else
1496         {
1497                 for(int j = 0; j < n; ++j)
1498                 {
1499                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1500                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1501                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1502                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1503                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1504                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1505                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1506                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1507                         else
1508                         {
1509                                 FOREACH(Buffs, it != BUFF_Null,
1510                                 {
1511                                         s = Buff_UndeprecateName(argv(j));
1512                                         if(s == it.m_name)
1513                                         {
1514                                                 STAT(BUFFS, this) |= (it.m_itemid);
1515                                                 break;
1516                                         }
1517                                 });
1518                                 FOREACH(Weapons, it != WEP_Null, {
1519                                         s = W_UndeprecateName(argv(j));
1520                                         if(s == it.netname)
1521                                         {
1522                                                 this.weapons |= (it.m_wepset);
1523                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1524                                                         it.wr_init(it);
1525                                                 break;
1526                                         }
1527                                 });
1528                         }
1529                 }
1530
1531                 string itemprefix, valueprefix;
1532                 if(this.spawnflags == 0)
1533                 {
1534                         itemprefix = "";
1535                         valueprefix = "";
1536                 }
1537                 else if(this.spawnflags == 1)
1538                 {
1539                         itemprefix = "max ";
1540                         valueprefix = "max ";
1541                 }
1542                 else if(this.spawnflags == 2)
1543                 {
1544                         itemprefix = "min ";
1545                         valueprefix = "min ";
1546                 }
1547                 else if(this.spawnflags == 4)
1548                 {
1549                         itemprefix = "minus ";
1550                         valueprefix = "max ";
1551                 }
1552                 else
1553                 {
1554                         error("invalid spawnflags");
1555                         itemprefix = valueprefix = string_null;
1556                 }
1557
1558                 this.netname = "";
1559                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1560                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1561                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1562                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1563                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1564                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1565                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1566                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1567                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1568                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1569                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1570                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1571                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1572                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1573                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1574                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(BUFFS, this) & (it.m_itemid)), it.m_name));
1575                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1576         }
1577         this.netname = strzone(this.netname);
1578         //print(this.netname, "\n");
1579
1580         n = tokenize_console(this.netname);
1581         for(int j = 0; j < n; ++j)
1582         {
1583                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1584             it.wr_init(it);
1585             break;
1586                 });
1587         }
1588 }
1589
1590 float GiveWeapon(entity e, float wpn, float op, float val)
1591 {
1592         WepSet v0, v1;
1593         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1594         v0 = (e.weapons & s);
1595         switch(op)
1596         {
1597                 case OP_SET:
1598                         if(val > 0)
1599                                 e.weapons |= s;
1600                         else
1601                                 e.weapons &= ~s;
1602                         break;
1603                 case OP_MIN:
1604                 case OP_PLUS:
1605                         if(val > 0)
1606                                 e.weapons |= s;
1607                         break;
1608                 case OP_MAX:
1609                         if(val <= 0)
1610                                 e.weapons &= ~s;
1611                         break;
1612                 case OP_MINUS:
1613                         if(val > 0)
1614                                 e.weapons &= ~s;
1615                         break;
1616         }
1617         v1 = (e.weapons & s);
1618         return (v0 != v1);
1619 }
1620
1621 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1622 {
1623         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1624         switch(op)
1625         {
1626                 case OP_SET:
1627                         if(val > 0)
1628                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1629                         else
1630                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1631                         break;
1632                 case OP_MIN:
1633                 case OP_PLUS:
1634                         if(val > 0)
1635                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1636                         break;
1637                 case OP_MAX:
1638                         if(val <= 0)
1639                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1640                         break;
1641                 case OP_MINUS:
1642                         if(val > 0)
1643                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1644                         break;
1645         }
1646         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1647         return (had_buff != have_buff);
1648 }
1649
1650 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1651 {
1652         if(v1 == v0)
1653                 return;
1654         if(v1 <= v0 - t)
1655         {
1656                 if(snd_decr != NULL)
1657                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1658         }
1659         else if(v0 >= v0 + t)
1660         {
1661                 if(snd_incr != NULL)
1662                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1663         }
1664 }
1665
1666 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1667 {
1668         if(v0 < v1)
1669                 e.(rotfield) = max(e.(rotfield), time + rottime);
1670         else if(v0 > v1)
1671                 e.(regenfield) = max(e.(regenfield), time + regentime);
1672 }
1673 float GiveItems(entity e, float beginarg, float endarg)
1674 {
1675         float got, i, val, op;
1676         string cmd;
1677
1678         val = 999;
1679         op = OP_SET;
1680
1681         got = 0;
1682
1683         int _switchweapon = 0;
1684
1685         if(CS(e).autoswitch)
1686         {
1687                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1688                 {
1689                         .entity weaponentity = weaponentities[slot];
1690                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1691                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1692                                 _switchweapon |= BIT(slot);
1693                 }
1694         }
1695
1696         e.strength_finished = max(0, e.strength_finished - time);
1697         e.invincible_finished = max(0, e.invincible_finished - time);
1698         e.superweapons_finished = max(0, e.superweapons_finished - time);
1699
1700         PREGIVE(e, items);
1701         PREGIVE_WEAPONS(e);
1702         PREGIVE(e, strength_finished);
1703         PREGIVE(e, invincible_finished);
1704         PREGIVE(e, superweapons_finished);
1705         PREGIVE(e, ammo_nails);
1706         PREGIVE(e, ammo_cells);
1707         PREGIVE(e, ammo_plasma);
1708         PREGIVE(e, ammo_shells);
1709         PREGIVE(e, ammo_rockets);
1710         PREGIVE(e, ammo_fuel);
1711         PREGIVE(e, armorvalue);
1712         PREGIVE(e, health);
1713
1714         for(i = beginarg; i < endarg; ++i)
1715         {
1716                 cmd = argv(i);
1717
1718                 if(cmd == "0" || stof(cmd))
1719                 {
1720                         val = stof(cmd);
1721                         continue;
1722                 }
1723                 switch(cmd)
1724                 {
1725                         case "no":
1726                                 op = OP_MAX;
1727                                 val = 0;
1728                                 continue;
1729                         case "max":
1730                                 op = OP_MAX;
1731                                 continue;
1732                         case "min":
1733                                 op = OP_MIN;
1734                                 continue;
1735                         case "plus":
1736                                 op = OP_PLUS;
1737                                 continue;
1738                         case "minus":
1739                                 op = OP_MINUS;
1740                                 continue;
1741                         case "ALL":
1742                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1743                                 got += GiveValue(e, strength_finished, op, val);
1744                                 got += GiveValue(e, invincible_finished, op, val);
1745                                 got += GiveValue(e, superweapons_finished, op, val);
1746                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1747                         case "all":
1748                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1749                                 got += GiveValue(e, health, op, val);
1750                                 got += GiveValue(e, armorvalue, op, val);
1751                         case "allweapons":
1752                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1753                         //case "allbuffs": // all buffs makes a player god, do not want!
1754                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1755                         case "allammo":
1756                                 got += GiveValue(e, ammo_cells, op, val);
1757                                 got += GiveValue(e, ammo_plasma, op, val);
1758                                 got += GiveValue(e, ammo_shells, op, val);
1759                                 got += GiveValue(e, ammo_nails, op, val);
1760                                 got += GiveValue(e, ammo_rockets, op, val);
1761                                 got += GiveValue(e, ammo_fuel, op, val);
1762                                 break;
1763                         case "unlimited_ammo":
1764                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1765                                 break;
1766                         case "unlimited_weapon_ammo":
1767                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1768                                 break;
1769                         case "unlimited_superweapons":
1770                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1771                                 break;
1772                         case "jetpack":
1773                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1774                                 break;
1775                         case "fuel_regen":
1776                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1777                                 break;
1778                         case "strength":
1779                                 got += GiveValue(e, strength_finished, op, val);
1780                                 break;
1781                         case "invincible":
1782                                 got += GiveValue(e, invincible_finished, op, val);
1783                                 break;
1784                         case "superweapons":
1785                                 got += GiveValue(e, superweapons_finished, op, val);
1786                                 break;
1787                         case "cells":
1788                                 got += GiveValue(e, ammo_cells, op, val);
1789                                 break;
1790                         case "plasma":
1791                                 got += GiveValue(e, ammo_plasma, op, val);
1792                                 break;
1793                         case "shells":
1794                                 got += GiveValue(e, ammo_shells, op, val);
1795                                 break;
1796                         case "nails":
1797                         case "bullets":
1798                                 got += GiveValue(e, ammo_nails, op, val);
1799                                 break;
1800                         case "rockets":
1801                                 got += GiveValue(e, ammo_rockets, op, val);
1802                                 break;
1803                         case "health":
1804                                 got += GiveValue(e, health, op, val);
1805                                 break;
1806                         case "armor":
1807                                 got += GiveValue(e, armorvalue, op, val);
1808                                 break;
1809                         case "fuel":
1810                                 got += GiveValue(e, ammo_fuel, op, val);
1811                                 break;
1812                         default:
1813                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1814                                 {
1815                                         got += GiveBuff(e, it, op, val);
1816                                         break;
1817                                 });
1818                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1819                     got += GiveWeapon(e, it.m_id, op, val);
1820                     break;
1821                                 });
1822                                 break;
1823                 }
1824                 val = 999;
1825                 op = OP_SET;
1826         }
1827
1828         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1829         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1830         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1831         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1832         FOREACH(Weapons, it != WEP_Null, {
1833                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1834                 if(!(save_weapons & (it.m_wepset)))
1835                         if(e.weapons & (it.m_wepset))
1836                                 it.wr_init(it);
1837         });
1838         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1839         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1840         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1841         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1842         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1843         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1844         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1845         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1846         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1847         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1848         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1849
1850         if(e.superweapons_finished <= 0)
1851                 if(e.weapons & WEPSET_SUPERWEAPONS)
1852                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1853
1854         if(e.strength_finished <= 0)
1855                 e.strength_finished = 0;
1856         else
1857                 e.strength_finished += time;
1858         if(e.invincible_finished <= 0)
1859                 e.invincible_finished = 0;
1860         else
1861                 e.invincible_finished += time;
1862         if(e.superweapons_finished <= 0)
1863                 e.superweapons_finished = 0;
1864         else
1865                 e.superweapons_finished += time;
1866
1867         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1868         {
1869                 .entity weaponentity = weaponentities[slot];
1870                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1871                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1872                         _switchweapon |= BIT(slot);
1873         }
1874
1875         if(_switchweapon)
1876         {
1877                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1878                 {
1879                         .entity weaponentity = weaponentities[slot];
1880                         if(_switchweapon & BIT(slot))
1881                         {
1882                                 Weapon wep = w_getbestweapon(e, weaponentity);
1883                                 if(wep != e.(weaponentity).m_switchweapon)
1884                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1885                         }
1886                 }
1887         }
1888
1889         return got;
1890 }
1891 #endif