642c29d29a85e580143bedde5e20b3a542319eb1
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "triggers/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26
27     #include "../lib/warpzone/util_server.qh"
28 #elif defined(CSQC)
29         #include "physics/movetypes/movetypes.qh"
30         #include <common/weapons/_all.qh>
31         #include "../lib/csqcmodel/cl_model.qh"
32         #include "../lib/csqcmodel/common.qh"
33 #endif
34
35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
36
37 #ifdef CSQC
38 bool autocvar_cl_ghost_items_vehicle = true;
39 .vector item_glowmod;
40 void Item_SetAlpha(entity this)
41 {
42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
43
44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
45         {
46                 this.alpha = 1;
47                 this.colormod = '1 1 1';
48                 this.glowmod = this.item_glowmod;
49         }
50         else
51         {
52                 if (autocvar_cl_ghost_items_color)
53                 {
54                         this.alpha = autocvar_cl_ghost_items;
55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
56                 }
57                 else
58                         this.alpha = -1;
59         }
60
61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
62         {
63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
64                 this.alpha = autocvar_cl_weapon_stay_alpha;
65         }
66 }
67
68 void ItemDraw(entity this)
69 {
70     if(this.gravity)
71     {
72         Movetype_Physics_MatchServer(this, false);
73         if(IS_ONGROUND(this))
74         { // For some reason avelocity gets set to '0 0 0' here ...
75             this.oldorigin = this.origin;
76             this.gravity = 0;
77
78             if(autocvar_cl_animate_items)
79             { // ... so reset it if animations are requested.
80                 if(this.ItemStatus & ITS_ANIMATE1)
81                     this.avelocity = '0 180 0';
82
83                 if(this.ItemStatus & ITS_ANIMATE2)
84                     this.avelocity = '0 -90 0';
85             }
86
87             // delay is for blocking item's position for a while;
88             // it's a workaround for dropped weapons that receive the position
89             // another time right after they spawn overriding animation position
90             this.onground_time = time + 0.5;
91         }
92     }
93     else if (autocvar_cl_animate_items)
94     {
95         if(this.ItemStatus & ITS_ANIMATE1)
96         {
97             this.angles += this.avelocity * frametime;
98             float fade_in = bound(0, time - this.onground_time, 1);
99             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
100         }
101
102         if(this.ItemStatus & ITS_ANIMATE2)
103         {
104             this.angles += this.avelocity * frametime;
105             float fade_in = bound(0, time - this.onground_time, 1);
106             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
107         }
108     }
109
110     Item_SetAlpha(this);
111 }
112
113 void ItemDrawSimple(entity this)
114 {
115     if(this.gravity)
116     {
117         Movetype_Physics_MatchServer(this, false);
118
119         if(IS_ONGROUND(this))
120             this.gravity = 0;
121     }
122
123     Item_SetAlpha(this);
124 }
125
126 void Item_PreDraw(entity this)
127 {
128         if(warpzone_warpzones_exist)
129         {
130                 // just incase warpzones were initialized last, reset these
131                 //this.alpha = 1; // alpha is already set by the draw function
132                 this.drawmask = MASK_NORMAL;
133                 return;
134         }
135         float alph;
136         vector org = getpropertyvec(VF_ORIGIN);
137         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
138                 alph = 0;
139         else if(this.fade_start)
140                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
141         else
142                 alph = 1;
143         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
144         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
145                 this.alpha = alph;
146         if(alph <= 0)
147                 this.drawmask = 0;
148         else
149                 this.drawmask = MASK_NORMAL;
150 }
151
152 void ItemRemove(entity this)
153 {
154         if(this.mdl)
155                 strunzone(this.mdl);
156 }
157
158 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
159 {
160     int sf = ReadByte();
161
162     if(sf & ISF_LOCATION)
163     {
164         this.origin_x = ReadCoord();
165         this.origin_y = ReadCoord();
166         this.origin_z = ReadCoord();
167         setorigin(this, this.origin);
168         this.oldorigin = this.origin;
169     }
170
171     if(sf & ISF_ANGLES)
172     {
173         this.angles_x = ReadAngle();
174         this.angles_y = ReadAngle();
175         this.angles_z = ReadAngle();
176     }
177
178     if(sf & ISF_SIZE)
179     {
180         float use_bigsize = ReadByte();
181         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
182     }
183
184     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
185     {
186         this.ItemStatus = ReadByte();
187
188         Item_SetAlpha(this);
189
190         if(autocvar_cl_fullbright_items)
191             if(this.ItemStatus & ITS_ALLOWFB)
192                 this.effects |= EF_FULLBRIGHT;
193
194         if(this.ItemStatus & ITS_GLOW)
195         {
196             if(this.ItemStatus & ITS_AVAILABLE)
197                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
198             else
199                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
200         }
201     }
202
203     if(sf & ISF_MODEL)
204     {
205         this.drawmask  = MASK_NORMAL;
206                 set_movetype(this, MOVETYPE_TOSS);
207                 if (isnew) IL_PUSH(g_drawables, this);
208         this.draw       = ItemDraw;
209         this.solid = SOLID_TRIGGER;
210         //this.flags |= FL_ITEM;
211
212         bool use_bigsize = ReadByte();
213
214         this.fade_end = ReadShort();
215         this.fade_start = ReadShort();
216         if(this.fade_start && !autocvar_cl_items_nofade)
217                 setpredraw(this, Item_PreDraw);
218
219         if(this.mdl)
220             strunzone(this.mdl);
221
222         this.mdl = "";
223         string _fn = ReadString();
224
225         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
226         {
227             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
228             this.draw = ItemDrawSimple;
229
230             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
231                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
232             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
233                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
234             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
235                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
236             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
237                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
238             else
239             {
240                 this.draw = ItemDraw;
241                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
242             }
243         }
244
245         if(this.draw != ItemDrawSimple)
246             this.mdl = strzone(_fn);
247
248
249         if(this.mdl == "")
250             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
251
252         precache_model(this.mdl);
253         _setmodel(this, this.mdl);
254
255         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
256     }
257
258     if(sf & ISF_COLORMAP)
259     {
260         this.colormap = ReadShort();
261         this.item_glowmod_x = ReadByte() / 255.0;
262         this.item_glowmod_y = ReadByte() / 255.0;
263         this.item_glowmod_z = ReadByte() / 255.0;
264     }
265
266     if(sf & ISF_DROP)
267     {
268         this.gravity = 1;
269         this.pushable = true;
270         //this.angles = '0 0 0';
271         set_movetype(this, MOVETYPE_TOSS);
272         this.velocity_x = ReadCoord();
273         this.velocity_y = ReadCoord();
274         this.velocity_z = ReadCoord();
275         setorigin(this, this.oldorigin);
276
277         if(!this.move_time)
278         {
279             this.move_time = time;
280             this.spawntime = time;
281         }
282         else
283             this.move_time = max(this.move_time, time);
284     }
285
286     if(autocvar_cl_animate_items)
287     {
288         if(this.ItemStatus & ITS_ANIMATE1)
289             this.avelocity = '0 180 0';
290
291         if(this.ItemStatus & ITS_ANIMATE2)
292             this.avelocity = '0 -90 0';
293     }
294
295     this.entremove = ItemRemove;
296
297     return true;
298 }
299
300 #endif
301
302 #ifdef SVQC
303 bool ItemSend(entity this, entity to, int sf)
304 {
305         if(this.gravity)
306                 sf |= ISF_DROP;
307         else
308                 sf &= ~ISF_DROP;
309
310         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
311         WriteByte(MSG_ENTITY, sf);
312
313         //WriteByte(MSG_ENTITY, this.cnt);
314         if(sf & ISF_LOCATION)
315         {
316                 WriteCoord(MSG_ENTITY, this.origin.x);
317                 WriteCoord(MSG_ENTITY, this.origin.y);
318                 WriteCoord(MSG_ENTITY, this.origin.z);
319         }
320
321         if(sf & ISF_ANGLES)
322         {
323                 WriteAngle(MSG_ENTITY, this.angles_x);
324                 WriteAngle(MSG_ENTITY, this.angles_y);
325                 WriteAngle(MSG_ENTITY, this.angles_z);
326         }
327
328         if(sf & ISF_SIZE)
329         {
330                 Pickup p = this.itemdef;
331                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
332         }
333
334         if(sf & ISF_STATUS)
335                 WriteByte(MSG_ENTITY, this.ItemStatus);
336
337         if(sf & ISF_MODEL)
338         {
339                 Pickup p = this.itemdef;
340                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
341                 WriteShort(MSG_ENTITY, this.fade_end);
342                 WriteShort(MSG_ENTITY, this.fade_start);
343
344                 if(this.mdl == "")
345                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
346
347                 WriteString(MSG_ENTITY, this.mdl);
348         }
349
350
351         if(sf & ISF_COLORMAP)
352         {
353                 WriteShort(MSG_ENTITY, this.colormap);
354                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
355         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
356         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
357         }
358
359         if(sf & ISF_DROP)
360         {
361                 WriteCoord(MSG_ENTITY, this.velocity.x);
362                 WriteCoord(MSG_ENTITY, this.velocity.y);
363                 WriteCoord(MSG_ENTITY, this.velocity.z);
364         }
365
366         return true;
367 }
368
369 void ItemUpdate(entity this)
370 {
371         this.oldorigin = this.origin;
372         this.SendFlags |= ISF_LOCATION;
373 }
374
375 void UpdateItemAfterTeleport(entity this)
376 {
377         if(getSendEntity(this) == ItemSend)
378                 ItemUpdate(this);
379 }
380
381 bool have_pickup_item(entity this)
382 {
383         if(this.itemdef.instanceOfPowerup)
384         {
385                 if(autocvar_g_powerups > 0)
386                         return true;
387                 if(autocvar_g_powerups == 0)
388                         return false;
389         }
390         else
391         {
392                 if(autocvar_g_pickup_items > 0)
393                         return true;
394                 if(autocvar_g_pickup_items == 0)
395                         return false;
396                 if(g_weaponarena)
397                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
398                                 return false;
399         }
400         return true;
401 }
402
403 /*
404 float Item_Customize()
405 {
406         if(this.spawnshieldtime)
407                 return true;
408         if(this.weapons & ~other.weapons)
409         {
410                 this.colormod = '0 0 0';
411                 this.glowmod = this.colormod;
412                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
413                 return true;
414         }
415         else
416         {
417                 if(g_ghost_items)
418                 {
419                         this.colormod = stov(autocvar_g_ghost_items_color);
420                         this.glowmod = this.colormod;
421                         this.alpha = g_ghost_items;
422                         return true;
423                 }
424                 else
425                         return false;
426         }
427 }
428 */
429
430 void Item_Show (entity e, float mode)
431 {
432         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
433         e.ItemStatus &= ~ITS_STAYWEP;
434         entity def = e.itemdef;
435         if (mode > 0)
436         {
437                 // make the item look normal, and be touchable
438                 e.model = e.mdl;
439                 e.solid = SOLID_TRIGGER;
440                 e.spawnshieldtime = 1;
441                 e.ItemStatus |= ITS_AVAILABLE;
442         }
443         else if (mode < 0)
444         {
445                 // hide the item completely
446                 e.model = string_null;
447                 e.solid = SOLID_NOT;
448                 e.spawnshieldtime = 1;
449                 e.ItemStatus &= ~ITS_AVAILABLE;
450         }
451         else
452         {
453                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
454                         || e.team // weapon stay isn't supported for teamed weapons
455                         ;
456                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
457                 {
458                         // make the item translucent and not touchable
459                         e.model = e.mdl;
460                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
461                         e.effects |= EF_STARDUST;
462                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
463                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
464                 }
465                 else
466                 {
467                         //setmodel(e, "null");
468                         e.solid = SOLID_NOT;
469                         e.colormod = '0 0 0';
470                         //e.glowmod = e.colormod;
471                         e.spawnshieldtime = 1;
472                         e.ItemStatus &= ~ITS_AVAILABLE;
473                 }
474         }
475
476         if (def.m_glow)
477                 e.ItemStatus |= ITS_GLOW;
478
479         if (autocvar_g_nodepthtestitems)
480                 e.effects |= EF_NODEPTHTEST;
481
482
483         if (autocvar_g_fullbrightitems)
484                 e.ItemStatus |= ITS_ALLOWFB;
485
486         if (autocvar_sv_simple_items)
487                 e.ItemStatus |= ITS_ALLOWSI;
488
489         // relink entity (because solid may have changed)
490         setorigin(e, e.origin);
491         e.SendFlags |= ISF_STATUS;
492 }
493
494 void Item_Think(entity this)
495 {
496         this.nextthink = time;
497         if(this.origin != this.oldorigin)
498                 ItemUpdate(this);
499 }
500
501 bool Item_ItemsTime_SpectatorOnly(GameItem it);
502 bool Item_ItemsTime_Allow(GameItem it);
503 float Item_ItemsTime_UpdateTime(entity e, float t);
504 void Item_ItemsTime_SetTime(entity e, float t);
505 void Item_ItemsTime_SetTimesForAllPlayers();
506
507 void Item_Respawn (entity this)
508 {
509         Item_Show(this, 1);
510         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
511         setorigin(this, this.origin);
512
513     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
514         {
515                 float t = Item_ItemsTime_UpdateTime(this, 0);
516                 Item_ItemsTime_SetTime(this, t);
517                 Item_ItemsTime_SetTimesForAllPlayers();
518         }
519
520         setthink(this, Item_Think);
521         this.nextthink = time;
522
523         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
524         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
525 }
526
527 void Item_RespawnCountdown (entity this)
528 {
529         if(this.count >= ITEM_RESPAWN_TICKS)
530         {
531                 if(this.waypointsprite_attached)
532                         WaypointSprite_Kill(this.waypointsprite_attached);
533                 Item_Respawn(this);
534         }
535         else
536         {
537                 this.nextthink = time + 1;
538                 this.count += 1;
539                 if(this.count == 1)
540                 {
541                         do {
542                                 {
543                                         entity wi = Weapons_from(this.weapon);
544                                         if (wi != WEP_Null) {
545                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
546                                                 wp.wp_extra = wi.m_id;
547                                                 break;
548                                         }
549                                 }
550                                 {
551                                         entity ii = this.itemdef;
552                                         if (ii != NULL) {
553                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
554                                                 wp.wp_extra = ii.m_id;
555                                                 break;
556                                         }
557                                 }
558                         } while (0);
559                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
560             if(this.waypointsprite_attached)
561             {
562                 GameItem def = this.itemdef;
563                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
564                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
565                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
566             }
567                 }
568
569                 if(this.waypointsprite_attached)
570                 {
571                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
572                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
573                                 {
574                                         msg_entity = it;
575                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
576                                 }
577                         });
578
579                         WaypointSprite_Ping(this.waypointsprite_attached);
580                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
581                 }
582         }
583 }
584
585 void Item_RespawnThink(entity this)
586 {
587         this.nextthink = time;
588         if(this.origin != this.oldorigin)
589                 ItemUpdate(this);
590
591         if(time >= this.wait)
592                 Item_Respawn(this);
593 }
594
595 void Item_ScheduleRespawnIn(entity e, float t)
596 {
597         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
598         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
599         {
600                 setthink(e, Item_RespawnCountdown);
601                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
602                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
603                 e.count = 0;
604                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
605                 {
606                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
607                         Item_ItemsTime_SetTime(e, t);
608                         Item_ItemsTime_SetTimesForAllPlayers();
609                 }
610         }
611         else
612         {
613                 setthink(e, Item_RespawnThink);
614                 e.nextthink = time;
615                 e.scheduledrespawntime = time + t;
616                 e.wait = time + t;
617
618                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
619                 {
620                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
621                         Item_ItemsTime_SetTime(e, t);
622                         Item_ItemsTime_SetTimesForAllPlayers();
623                 }
624         }
625 }
626
627 void Item_ScheduleRespawn(entity e)
628 {
629         if(e.respawntime > 0)
630         {
631                 Item_Show(e, 0);
632                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
633         }
634         else // if respawntime is -1, this item does not respawn
635                 Item_Show(e, -1);
636 }
637
638 void Item_ScheduleInitialRespawn(entity e)
639 {
640         Item_Show(e, 0);
641         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
642 }
643
644 void GivePlayerHealth(entity player, float amount)
645 {
646         if (amount == 0)
647         {
648                 return;
649         }
650         player.health = bound(player.health, player.health + amount,
651                  g_pickup_healthmega_max);
652         player.pauserothealth_finished = max(player.pauserothealth_finished, time +
653                 autocvar_g_balance_pause_health_rot);
654 }
655
656 void GivePlayerArmor(entity player, float amount)
657 {
658         if (amount == 0)
659         {
660                 return;
661         }
662         player.armorvalue = bound(player.armorvalue, player.armorvalue + amount,
663                  g_pickup_armormega_max);
664         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time +
665                 autocvar_g_balance_pause_armor_rot);
666 }
667
668 void GivePlayerAmmo(entity player, .float ammotype, float amount)
669 {
670         float maxvalue = 999;
671         switch(ammotype)
672         {
673                 case ammo_shells: maxvalue = g_pickup_shells_max;
674                 case ammo_cells: maxvalue = g_pickup_cells_max;
675                 case ammo_rockets: maxvalue = g_pickup_rockets_max;
676                 case ammo_plasma: maxvalue = g_pickup_plasma_max;
677                 case ammo_nails: maxvalue = g_pickup_nails_max;
678                 case ammo_fuel: maxvalue = g_pickup_fuel_max;
679         }
680         player.(ammotype) = min(player.(ammotype) + amount, maxvalue);
681 }
682
683 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
684 {
685         if (!item.(ammotype))
686                 return false;
687
688         if (item.spawnshieldtime)
689         {
690                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
691                 {
692                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
693                         goto YEAH;
694                 }
695         }
696         else if(g_weapon_stay == 2)
697         {
698                 float mi = min(item.(ammotype), ammomax);
699                 if (player.(ammotype) < mi)
700                 {
701                         player.(ammotype) = mi;
702                         goto YEAH;
703                 }
704         }
705
706         return false;
707
708 LABEL(YEAH)
709         switch(mode)
710         {
711                 case ITEM_MODE_FUEL:
712                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
713                         break;
714                 case ITEM_MODE_HEALTH:
715                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
716                         break;
717                 case ITEM_MODE_ARMOR:
718                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
719                         break;
720                 default:
721                         break;
722         }
723         return true;
724 }
725
726 float Item_GiveTo(entity item, entity player)
727 {
728         float pickedup;
729
730         // if nothing happens to player, just return without taking the item
731         pickedup = false;
732         int _switchweapon = 0;
733         // in case the player has autoswitch enabled do the following:
734         // if the player is using their best weapon before items are given, they
735         // probably want to switch to an even better weapon after items are given
736
737         if(player.autoswitch)
738         {
739                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
740                 {
741                         .entity weaponentity = weaponentities[slot];
742                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
743                         {
744                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
745                                         _switchweapon |= BIT(slot);
746
747                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
748                                         _switchweapon |= BIT(slot);
749                         }
750                 }
751         }
752
753         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
754         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
755         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
756         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
757         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
758         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
759         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
760         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
761
762         if (item.itemdef.instanceOfWeaponPickup)
763         {
764                 WepSet w;
765                 w = item.weapons;
766                 w &= ~player.weapons;
767
768                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
769                 {
770                         pickedup = true;
771                         FOREACH(Weapons, it != WEP_Null, {
772                                 if(w & (it.m_wepset))
773                                 {
774                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
775                                         {
776                                                 .entity weaponentity = weaponentities[slot];
777                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
778                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
779                                         }
780                                         W_GiveWeapon(player, it.m_id);
781                                 }
782                         });
783                 }
784         }
785
786         if (item.itemdef.instanceOfPowerup)
787         {
788                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
789                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
790                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
791                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
792         }
793
794         int its;
795         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
796         {
797                 pickedup = true;
798                 player.items |= its;
799                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
800         }
801
802         if (item.strength_finished)
803         {
804                 pickedup = true;
805                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
806         }
807         if (item.invincible_finished)
808         {
809                 pickedup = true;
810                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
811         }
812         if (item.superweapons_finished)
813         {
814                 pickedup = true;
815                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
816         }
817
818 LABEL(skip)
819
820         // always eat teamed entities
821         if(item.team)
822                 pickedup = true;
823
824         if (!pickedup)
825                 return 0;
826
827         // crude hack to enforce switching weapons
828         if(g_cts && item.itemdef.instanceOfWeaponPickup)
829         {
830                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
831                 {
832                         .entity weaponentity = weaponentities[slot];
833                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
834                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
835                 }
836                 return 1;
837         }
838
839         if(_switchweapon)
840         {
841                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
842                 {
843                         .entity weaponentity = weaponentities[slot];
844                         if(_switchweapon & BIT(slot))
845                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
846                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
847                 }
848         }
849
850         return 1;
851 }
852
853 void Item_Touch(entity this, entity toucher)
854 {
855
856         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
857         if (this.classname == "droppedweapon")
858         {
859                 if (ITEM_TOUCH_NEEDKILL())
860                 {
861                         delete(this);
862                         return;
863                 }
864         }
865
866         if(!(toucher.flags & FL_PICKUPITEMS)
867         || STAT(FROZEN, toucher)
868         || IS_DEAD(toucher)
869         || (this.solid != SOLID_TRIGGER)
870         || (this.owner == toucher)
871         || (time < this.item_spawnshieldtime)
872         ) { return; }
873
874         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
875         {
876                 case MUT_ITEMTOUCH_RETURN: { return; }
877                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
878         }
879
880         toucher = M_ARGV(1, entity);
881
882         if (this.classname == "droppedweapon")
883         {
884                 this.strength_finished = max(0, this.strength_finished - time);
885                 this.invincible_finished = max(0, this.invincible_finished - time);
886                 this.superweapons_finished = max(0, this.superweapons_finished - time);
887         }
888         entity it = this.itemdef;
889         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
890         if (!gave)
891         {
892                 if (this.classname == "droppedweapon")
893                 {
894                         // undo what we did above
895                         this.strength_finished += time;
896                         this.invincible_finished += time;
897                         this.superweapons_finished += time;
898                 }
899                 return;
900         }
901
902 LABEL(pickup)
903
904         toucher.last_pickup = time;
905
906         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
907         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
908
909         if (this.classname == "droppedweapon")
910                 delete (this);
911         else if (this.spawnshieldtime)
912         {
913                 entity e;
914                 if(this.team)
915                 {
916                         RandomSelection_Init();
917                         IL_EACH(g_items, it.team == this.team,
918                         {
919                                 if(it.itemdef) // is a registered item
920                                 {
921                                         Item_Show(it, -1);
922                                         RandomSelection_AddEnt(it, it.cnt, 0);
923                                 }
924                         });
925                         e = RandomSelection_chosen_ent;
926                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
927                 }
928                 else
929                         e = this;
930                 Item_ScheduleRespawn(e);
931         }
932 }
933
934 void Item_Reset(entity this)
935 {
936         Item_Show(this, !this.state);
937         setorigin(this, this.origin);
938
939         if (this.classname != "droppedweapon")
940         {
941                 setthink(this, Item_Think);
942                 this.nextthink = time;
943
944                 if (this.waypointsprite_attached)
945                         WaypointSprite_Kill(this.waypointsprite_attached);
946
947                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
948                         Item_ScheduleInitialRespawn(this);
949         }
950 }
951
952 void Item_FindTeam(entity this)
953 {
954         entity e;
955
956         if(this.effects & EF_NODRAW)
957         {
958                 // marker for item team search
959                 LOG_TRACE("Initializing item team ", ftos(this.team));
960                 RandomSelection_Init();
961                 IL_EACH(g_items, it.team == this.team,
962                 {
963                         if(it.itemdef) // is a registered item
964                                 RandomSelection_AddEnt(it, it.cnt, 0);
965                 });
966
967                 e = RandomSelection_chosen_ent;
968                 e.state = 0;
969                 Item_Show(e, 1);
970
971                 IL_EACH(g_items, it.team == this.team,
972                 {
973                         if(it.itemdef) // is a registered item
974                         {
975                                 if(it != e)
976                                 {
977                                         // make it non-spawned
978                                         Item_Show(it, -1);
979                                         it.state = 1; // state 1 = initially hidden item, apparently
980                                 }
981                                 it.effects &= ~EF_NODRAW;
982                         }
983                 });
984
985                 Item_Reset(this);
986         }
987 }
988
989 // Savage: used for item garbage-collection
990 void RemoveItem(entity this)
991 {
992         if(wasfreed(this) || !this) { return; }
993         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
994         delete(this);
995 }
996
997 // pickup evaluation functions
998 // these functions decide how desirable an item is to the bots
999
1000 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1001
1002 float weapon_pickupevalfunc(entity player, entity item)
1003 {
1004         // See if I have it already
1005         if(player.weapons & item.weapons)
1006         {
1007                 // If I can pick it up
1008                 if(!item.spawnshieldtime)
1009                         return 0;
1010                 return ammo_pickupevalfunc(player, item);
1011         }
1012
1013         // reduce weapon value if bot already got a good arsenal
1014         float c = 1;
1015         int weapons_value = 0;
1016         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1017                 weapons_value += it.bot_pickupbasevalue;
1018         });
1019         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1020
1021         return item.bot_pickupbasevalue * c;
1022 }
1023
1024 float ammo_pickupevalfunc(entity player, entity item)
1025 {
1026         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1027         entity wpn = NULL;
1028         float c = 0;
1029         float rating = 0;
1030
1031         // Detect needed ammo
1032         if(item.itemdef.instanceOfWeaponPickup)
1033         {
1034                 entity ammo = NULL;
1035                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1036                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1037                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1038                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1039                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1040                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1041
1042                 if(!ammo)
1043                         return 0;
1044                 wpn = item;
1045                 rating = ammo.m_botvalue;
1046         }
1047         else
1048         {
1049                 FOREACH(Weapons, it != WEP_Null, {
1050                         if(!(player.weapons & (it.m_wepset)))
1051                                 continue;
1052
1053                         switch(it.ammo_field)
1054                         {
1055                                 case ammo_shells:  need_shells  = true; break;
1056                                 case ammo_nails:   need_nails   = true; break;
1057                                 case ammo_rockets: need_rockets = true; break;
1058                                 case ammo_cells:   need_cells   = true; break;
1059                                 case ammo_plasma:  need_plasma  = true; break;
1060                                 case ammo_fuel:    need_fuel    = true; break;
1061                         }
1062                 });
1063                 rating = item.bot_pickupbasevalue;
1064         }
1065
1066         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1067                 c = item.ammo_shells / player.ammo_shells;
1068
1069         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1070                 c = item.ammo_nails / player.ammo_nails;
1071
1072         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1073                 c = item.ammo_rockets / player.ammo_rockets;
1074
1075         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1076                 c = item.ammo_cells / player.ammo_cells;
1077
1078         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1079                 c = item.ammo_plasma / player.ammo_plasma;
1080
1081         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1082                 c = item.ammo_fuel / player.ammo_fuel;
1083
1084         rating *= min(2, c);
1085         if(wpn)
1086                 rating += wpn.bot_pickupbasevalue * 0.1;
1087         return rating;
1088 }
1089
1090 .int item_group;
1091 .int item_group_count;
1092 float healtharmor_pickupevalfunc(entity player, entity item)
1093 {
1094         float c = 0;
1095         float rating = item.bot_pickupbasevalue;
1096
1097         float itemarmor = item.armorvalue;
1098         float itemhealth = item.health;
1099
1100         if(item.item_group)
1101         {
1102                 itemarmor *= min(4, item.item_group_count);
1103                 itemhealth *= min(4, item.item_group_count);
1104         }
1105
1106         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1107                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1108
1109         if (itemhealth && (player.health < item.max_health))
1110                 c = itemhealth / max(1, player.health);
1111
1112         rating *= min(2, c);
1113         return rating;
1114 }
1115
1116 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1117 {
1118         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1119                 RemoveItem(this);
1120 }
1121
1122 void item_use(entity this, entity actor, entity trigger)
1123 {
1124         // use the touch function to handle collection
1125         gettouch(this)(this, actor);
1126 }
1127
1128 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1129 {
1130         string itemname = def.m_name;
1131         Model itemmodel = def.m_model;
1132     Sound pickupsound = def.m_sound;
1133         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1134         float pickupbasevalue = def.m_botvalue;
1135         int itemflags = def.m_itemflags;
1136
1137         startitem_failed = false;
1138
1139         this.item_model_ent = itemmodel;
1140     this.item_pickupsound_ent = pickupsound;
1141
1142     if(def.m_iteminit)
1143         def.m_iteminit(this);
1144
1145         if(!this.respawntime) // both need to be set
1146         {
1147                 this.respawntime = defaultrespawntime;
1148                 this.respawntimejitter = defaultrespawntimejitter;
1149         }
1150
1151         if(!this.pickup_anyway && def.m_pickupanyway)
1152                 this.pickup_anyway = def.m_pickupanyway();
1153
1154         int itemid = def.m_itemid;
1155         this.items = itemid;
1156         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1157         this.weapon = weaponid;
1158
1159         if(!this.fade_end)
1160         {
1161                 this.fade_start = autocvar_g_items_mindist;
1162                 this.fade_end = autocvar_g_items_maxdist;
1163         }
1164
1165         if(weaponid)
1166                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1167
1168         this.flags = FL_ITEM | itemflags;
1169         IL_PUSH(g_items, this);
1170
1171         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1172         {
1173                 startitem_failed = true;
1174                 delete(this);
1175                 return;
1176         }
1177
1178         // is it a dropped weapon?
1179         if (this.classname == "droppedweapon")
1180         {
1181                 this.reset = SUB_Remove;
1182                 // it's a dropped weapon
1183                 set_movetype(this, MOVETYPE_TOSS);
1184
1185                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1186                 setthink(this, RemoveItem);
1187                 this.nextthink = time + 20;
1188
1189                 this.takedamage = DAMAGE_YES;
1190                 this.event_damage = Item_Damage;
1191
1192                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1193                 {
1194                         // if item is worthless after a timer, have it expire then
1195                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1196                 }
1197
1198                 // don't drop if in a NODROP zone (such as lava)
1199                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1200                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1201                 {
1202                         startitem_failed = true;
1203                         delete(this);
1204                         return;
1205                 }
1206         }
1207         else
1208         {
1209                 if(!have_pickup_item(this))
1210                 {
1211                         startitem_failed = true;
1212                         delete (this);
1213                         return;
1214                 }
1215
1216                 if(this.angles != '0 0 0')
1217                         this.SendFlags |= ISF_ANGLES;
1218
1219                 this.reset = Item_Reset;
1220                 // it's a level item
1221                 if(this.spawnflags & 1)
1222                         this.noalign = 1;
1223                 if (this.noalign > 0)
1224                         set_movetype(this, MOVETYPE_NONE);
1225                 else
1226                         set_movetype(this, MOVETYPE_TOSS);
1227                 // do item filtering according to game mode and other things
1228                 if (this.noalign <= 0)
1229                 {
1230                         // first nudge it off the floor a little bit to avoid math errors
1231                         setorigin(this, this.origin + '0 0 1');
1232                         // set item size before we spawn a spawnfunc_waypoint
1233                         setsize(this, def.m_mins, def.m_maxs);
1234                         this.SendFlags |= ISF_SIZE;
1235                         // note droptofloor returns false if stuck/or would fall too far
1236                         if (!this.noalign)
1237                                 droptofloor(this);
1238                         waypoint_spawnforitem(this);
1239                 }
1240
1241                 /*
1242                  * can't do it that way, as it would break maps
1243                  * TODO make a target_give like entity another way, that perhaps has
1244                  * the weapon name in a key
1245                 if(this.targetname)
1246                 {
1247                         // target_give not yet supported; maybe later
1248                         print("removed targeted ", this.classname, "\n");
1249                         startitem_failed = true;
1250                         remove (this);
1251                         return;
1252                 }
1253                 */
1254
1255                 if(this.targetname != "" && (this.spawnflags & 16))
1256                         this.use = item_use;
1257
1258                 if(autocvar_spawn_debug >= 2)
1259                 {
1260             // why not flags & fl_item?
1261                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1262                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1263                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1264                 error("Mapper sucks.");
1265             });
1266                         this.is_item = true;
1267                 }
1268
1269                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1270
1271                 precache_model(this.model);
1272                 precache_sound(this.item_pickupsound);
1273
1274                 if (   def.instanceOfPowerup
1275                         || def.instanceOfWeaponPickup
1276                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1277                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1278                         || (itemid & (IT_KEY1 | IT_KEY2))
1279                 ) this.target = "###item###"; // for finding the nearest item using find()
1280
1281                 Item_ItemsTime_SetTime(this, 0);
1282         }
1283
1284         this.bot_pickup = true;
1285         this.bot_pickupevalfunc = pickupevalfunc;
1286         this.bot_pickupbasevalue = pickupbasevalue;
1287         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1288         this.netname = itemname;
1289         settouch(this, Item_Touch);
1290         setmodel(this, MDL_Null); // precision set below
1291         //this.effects |= EF_LOWPRECISION;
1292
1293         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1294
1295         this.SendFlags |= ISF_SIZE;
1296
1297         if (!(this.spawnflags & 1024)) {
1298                 if(def.instanceOfPowerup)
1299                         this.ItemStatus |= ITS_ANIMATE1;
1300
1301                 if(this.armorvalue || this.health)
1302                         this.ItemStatus |= ITS_ANIMATE2;
1303         }
1304
1305         if(def.instanceOfWeaponPickup)
1306         {
1307                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1308                         this.colormap = 1024; // color shirt=0 pants=0 grey
1309                 else
1310                         this.gravity = 1;
1311                 if (!(this.spawnflags & 1024))
1312                         this.ItemStatus |= ITS_ANIMATE1;
1313                 this.SendFlags |= ISF_COLORMAP;
1314         }
1315
1316         this.state = 0;
1317         if(this.team) // broken, no idea why.
1318         {
1319                 if(!this.cnt)
1320                         this.cnt = 1; // item probability weight
1321
1322                 this.effects |= EF_NODRAW; // marker for item team search
1323                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1324         }
1325         else
1326                 Item_Reset(this);
1327
1328         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1329
1330         // call this hook after everything else has been done
1331         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1332         {
1333                 startitem_failed = true;
1334                 delete(this);
1335                 return;
1336         }
1337
1338         setItemGroup(this);
1339 }
1340
1341 void StartItem(entity this, GameItem def)
1342 {
1343     _StartItem(
1344         this,
1345         this.itemdef = def,
1346         def.m_respawntime(), // defaultrespawntime
1347         def.m_respawntimejitter() // defaultrespawntimejitter
1348         );
1349 }
1350
1351 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1352 int group_count = 1;
1353
1354 void setItemGroup(entity this)
1355 {
1356         if(!IS_SMALL(this.itemdef))
1357                 return;
1358
1359         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1360         {
1361                 if(!this.item_group)
1362                 {
1363                         if(!it.item_group)
1364                         {
1365                                 it.item_group = group_count;
1366                                 group_count++;
1367                         }
1368                         this.item_group = it.item_group;
1369                 }
1370                 else // spawning item is already part of a item_group X
1371                 {
1372                         if(!it.item_group)
1373                                 it.item_group = this.item_group;
1374                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1375                         {
1376                                 int grY = it.item_group;
1377                                 // move all items of item_group Y to item_group X
1378                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1379                                 {
1380                                         if(it.item_group == grY)
1381                                                 it.item_group = this.item_group;
1382                                 });
1383                         }
1384                 }
1385         });
1386 }
1387
1388 void setItemGroupCount()
1389 {
1390         for (int k = 1; k <= group_count; k++)
1391         {
1392                 int count = 0;
1393                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1394                 if (count)
1395                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1396         }
1397 }
1398
1399 spawnfunc(item_rockets)
1400 {
1401     StartItem(this, ITEM_Rockets);
1402 }
1403
1404 spawnfunc(item_bullets)
1405 {
1406         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap && 
1407            (this.classname != "droppedweapon"))
1408         {
1409                 weaponswapping = true;
1410                 spawnfunc_item_shells(this);
1411                 weaponswapping = false;
1412                 return;
1413         }
1414
1415     StartItem(this, ITEM_Bullets);
1416 }
1417
1418 spawnfunc(item_cells)
1419 {
1420         StartItem(this, ITEM_Cells);
1421 }
1422
1423 spawnfunc(item_plasma)
1424 {
1425         StartItem(this, ITEM_Plasma);
1426 }
1427
1428 spawnfunc(item_shells)
1429 {
1430         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1431            (this.classname != "droppedweapon"))
1432         {
1433                 weaponswapping = true;
1434                 spawnfunc_item_bullets(this);
1435                 weaponswapping = false;
1436                 return;
1437         }
1438
1439         StartItem(this, ITEM_Shells);
1440 }
1441
1442 spawnfunc(item_armor_small)
1443 {
1444         StartItem(this, ITEM_ArmorSmall);
1445 }
1446
1447 spawnfunc(item_armor_medium)
1448 {
1449         StartItem(this, ITEM_ArmorMedium);
1450 }
1451
1452 spawnfunc(item_armor_big)
1453 {
1454         StartItem(this, ITEM_ArmorBig);
1455 }
1456
1457 spawnfunc(item_armor_mega)
1458 {
1459         StartItem(this, ITEM_ArmorMega);
1460 }
1461
1462 spawnfunc(item_health_small)
1463 {
1464         StartItem(this, ITEM_HealthSmall);
1465 }
1466
1467 spawnfunc(item_health_medium)
1468 {
1469     StartItem(this, ITEM_HealthMedium);
1470 }
1471
1472 spawnfunc(item_health_big)
1473 {
1474         StartItem(this, ITEM_HealthBig);
1475 }
1476
1477 spawnfunc(item_health_mega)
1478 {
1479     StartItem(this, ITEM_HealthMega);
1480 }
1481
1482 // support old misnamed entities
1483 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1484 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1485 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1486 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1487 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1488 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1489 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1490
1491 spawnfunc(item_strength)
1492 {
1493         StartItem(this, ITEM_Strength);
1494 }
1495
1496 spawnfunc(item_invincible)
1497 {
1498         StartItem(this, ITEM_Shield);
1499 }
1500
1501 // compatibility:
1502 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1503
1504 void target_items_use(entity this, entity actor, entity trigger)
1505 {
1506         if(actor.classname == "droppedweapon")
1507         {
1508                 EXACTTRIGGER_TOUCH(this, trigger);
1509                 delete(actor);
1510                 return;
1511         }
1512
1513         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1514                 return;
1515
1516         if(trigger.solid == SOLID_TRIGGER)
1517         {
1518                 EXACTTRIGGER_TOUCH(this, trigger);
1519         }
1520
1521         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1522         {
1523                 delete(it);
1524         });
1525
1526         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1527                 centerprint(actor, this.message);
1528 }
1529
1530 spawnfunc(target_items)
1531 {
1532         int n;
1533         string s;
1534
1535         this.use = target_items_use;
1536         if(!this.strength_finished)
1537                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1538         if(!this.invincible_finished)
1539                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1540         if(!this.superweapons_finished)
1541                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1542
1543         n = tokenize_console(this.netname);
1544         if(argv(0) == "give")
1545         {
1546                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1547         }
1548         else
1549         {
1550                 for(int j = 0; j < n; ++j)
1551                 {
1552                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1553                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1554                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1555                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1556                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1557                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1558                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1559                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1560                         else
1561                         {
1562                                 FOREACH(Buffs, it != BUFF_Null,
1563                                 {
1564                                         s = Buff_UndeprecateName(argv(j));
1565                                         if(s == it.m_name)
1566                                         {
1567                                                 this.buffs |= (it.m_itemid);
1568                                                 break;
1569                                         }
1570                                 });
1571                                 FOREACH(Weapons, it != WEP_Null, {
1572                                         s = W_UndeprecateName(argv(j));
1573                                         if(s == it.netname)
1574                                         {
1575                                                 this.weapons |= (it.m_wepset);
1576                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1577                                                         it.wr_init(it);
1578                                                 break;
1579                                         }
1580                                 });
1581                         }
1582                 }
1583
1584                 string itemprefix, valueprefix;
1585                 if(this.spawnflags == 0)
1586                 {
1587                         itemprefix = "";
1588                         valueprefix = "";
1589                 }
1590                 else if(this.spawnflags == 1)
1591                 {
1592                         itemprefix = "max ";
1593                         valueprefix = "max ";
1594                 }
1595                 else if(this.spawnflags == 2)
1596                 {
1597                         itemprefix = "min ";
1598                         valueprefix = "min ";
1599                 }
1600                 else if(this.spawnflags == 4)
1601                 {
1602                         itemprefix = "minus ";
1603                         valueprefix = "max ";
1604                 }
1605                 else
1606                 {
1607                         error("invalid spawnflags");
1608                         itemprefix = valueprefix = string_null;
1609                 }
1610
1611                 this.netname = "";
1612                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1613                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1614                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1615                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1616                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1617                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1618                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1619                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1620                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1621                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1622                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1623                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1624                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1625                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1626                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1627                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1628                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1629         }
1630         this.netname = strzone(this.netname);
1631         //print(this.netname, "\n");
1632
1633         n = tokenize_console(this.netname);
1634         for(int j = 0; j < n; ++j)
1635         {
1636                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1637             it.wr_init(it);
1638             break;
1639                 });
1640         }
1641 }
1642
1643 spawnfunc(item_fuel)
1644 {
1645         StartItem(this, ITEM_JetpackFuel);
1646 }
1647
1648 spawnfunc(item_fuel_regen)
1649 {
1650         if(start_items & ITEM_JetpackRegen.m_itemid)
1651         {
1652                 spawnfunc_item_fuel(this);
1653                 return;
1654         }
1655         StartItem(this, ITEM_JetpackRegen);
1656 }
1657
1658 spawnfunc(item_jetpack)
1659 {
1660         if(start_items & ITEM_Jetpack.m_itemid)
1661         {
1662                 spawnfunc_item_fuel(this);
1663                 return;
1664         }
1665         StartItem(this, ITEM_Jetpack);
1666 }
1667
1668 float GiveWeapon(entity e, float wpn, float op, float val)
1669 {
1670         WepSet v0, v1;
1671         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1672         v0 = (e.weapons & s);
1673         switch(op)
1674         {
1675                 case OP_SET:
1676                         if(val > 0)
1677                                 e.weapons |= s;
1678                         else
1679                                 e.weapons &= ~s;
1680                         break;
1681                 case OP_MIN:
1682                 case OP_PLUS:
1683                         if(val > 0)
1684                                 e.weapons |= s;
1685                         break;
1686                 case OP_MAX:
1687                         if(val <= 0)
1688                                 e.weapons &= ~s;
1689                         break;
1690                 case OP_MINUS:
1691                         if(val > 0)
1692                                 e.weapons &= ~s;
1693                         break;
1694         }
1695         v1 = (e.weapons & s);
1696         return (v0 != v1);
1697 }
1698
1699 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1700 {
1701         bool had_buff = (e.buffs & thebuff.m_itemid);
1702         switch(op)
1703         {
1704                 case OP_SET:
1705                         if(val > 0)
1706                                 e.buffs |= thebuff.m_itemid;
1707                         else
1708                                 e.buffs &= ~thebuff.m_itemid;
1709                         break;
1710                 case OP_MIN:
1711                 case OP_PLUS:
1712                         if(val > 0)
1713                                 e.buffs |= thebuff.m_itemid;
1714                         break;
1715                 case OP_MAX:
1716                         if(val <= 0)
1717                                 e.buffs &= ~thebuff.m_itemid;
1718                         break;
1719                 case OP_MINUS:
1720                         if(val > 0)
1721                                 e.buffs &= ~thebuff.m_itemid;
1722                         break;
1723         }
1724         bool have_buff = (e.buffs & thebuff.m_itemid);
1725         return (had_buff != have_buff);
1726 }
1727
1728 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1729 {
1730         if(v1 == v0)
1731                 return;
1732         if(v1 <= v0 - t)
1733         {
1734                 if(snd_decr != NULL)
1735                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1736         }
1737         else if(v0 >= v0 + t)
1738         {
1739                 if(snd_incr != NULL)
1740                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1741         }
1742 }
1743
1744 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1745 {
1746         if(v0 < v1)
1747                 e.(rotfield) = max(e.(rotfield), time + rottime);
1748         else if(v0 > v1)
1749                 e.(regenfield) = max(e.(regenfield), time + regentime);
1750 }
1751 float GiveItems(entity e, float beginarg, float endarg)
1752 {
1753         float got, i, val, op;
1754         string cmd;
1755
1756         val = 999;
1757         op = OP_SET;
1758
1759         got = 0;
1760
1761         int _switchweapon = 0;
1762
1763         if(e.autoswitch)
1764         {
1765                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1766                 {
1767                         .entity weaponentity = weaponentities[slot];
1768                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1769                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1770                                 _switchweapon |= BIT(slot);
1771                 }
1772         }
1773
1774         e.strength_finished = max(0, e.strength_finished - time);
1775         e.invincible_finished = max(0, e.invincible_finished - time);
1776         e.superweapons_finished = max(0, e.superweapons_finished - time);
1777
1778         PREGIVE(e, items);
1779         PREGIVE_WEAPONS(e);
1780         PREGIVE(e, strength_finished);
1781         PREGIVE(e, invincible_finished);
1782         PREGIVE(e, superweapons_finished);
1783         PREGIVE(e, ammo_nails);
1784         PREGIVE(e, ammo_cells);
1785         PREGIVE(e, ammo_plasma);
1786         PREGIVE(e, ammo_shells);
1787         PREGIVE(e, ammo_rockets);
1788         PREGIVE(e, ammo_fuel);
1789         PREGIVE(e, armorvalue);
1790         PREGIVE(e, health);
1791
1792         for(i = beginarg; i < endarg; ++i)
1793         {
1794                 cmd = argv(i);
1795
1796                 if(cmd == "0" || stof(cmd))
1797                 {
1798                         val = stof(cmd);
1799                         continue;
1800                 }
1801                 switch(cmd)
1802                 {
1803                         case "no":
1804                                 op = OP_MAX;
1805                                 val = 0;
1806                                 continue;
1807                         case "max":
1808                                 op = OP_MAX;
1809                                 continue;
1810                         case "min":
1811                                 op = OP_MIN;
1812                                 continue;
1813                         case "plus":
1814                                 op = OP_PLUS;
1815                                 continue;
1816                         case "minus":
1817                                 op = OP_MINUS;
1818                                 continue;
1819                         case "ALL":
1820                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1821                                 got += GiveValue(e, strength_finished, op, val);
1822                                 got += GiveValue(e, invincible_finished, op, val);
1823                                 got += GiveValue(e, superweapons_finished, op, val);
1824                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1825                         case "all":
1826                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1827                                 got += GiveValue(e, health, op, val);
1828                                 got += GiveValue(e, armorvalue, op, val);
1829                         case "allweapons":
1830                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1831                         //case "allbuffs": // all buffs makes a player god, do not want!
1832                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1833                         case "allammo":
1834                                 got += GiveValue(e, ammo_cells, op, val);
1835                                 got += GiveValue(e, ammo_plasma, op, val);
1836                                 got += GiveValue(e, ammo_shells, op, val);
1837                                 got += GiveValue(e, ammo_nails, op, val);
1838                                 got += GiveValue(e, ammo_rockets, op, val);
1839                                 got += GiveValue(e, ammo_fuel, op, val);
1840                                 break;
1841                         case "unlimited_ammo":
1842                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1843                                 break;
1844                         case "unlimited_weapon_ammo":
1845                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1846                                 break;
1847                         case "unlimited_superweapons":
1848                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1849                                 break;
1850                         case "jetpack":
1851                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1852                                 break;
1853                         case "fuel_regen":
1854                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1855                                 break;
1856                         case "strength":
1857                                 got += GiveValue(e, strength_finished, op, val);
1858                                 break;
1859                         case "invincible":
1860                                 got += GiveValue(e, invincible_finished, op, val);
1861                                 break;
1862                         case "superweapons":
1863                                 got += GiveValue(e, superweapons_finished, op, val);
1864                                 break;
1865                         case "cells":
1866                                 got += GiveValue(e, ammo_cells, op, val);
1867                                 break;
1868                         case "plasma":
1869                                 got += GiveValue(e, ammo_plasma, op, val);
1870                                 break;
1871                         case "shells":
1872                                 got += GiveValue(e, ammo_shells, op, val);
1873                                 break;
1874                         case "nails":
1875                         case "bullets":
1876                                 got += GiveValue(e, ammo_nails, op, val);
1877                                 break;
1878                         case "rockets":
1879                                 got += GiveValue(e, ammo_rockets, op, val);
1880                                 break;
1881                         case "health":
1882                                 got += GiveValue(e, health, op, val);
1883                                 break;
1884                         case "armor":
1885                                 got += GiveValue(e, armorvalue, op, val);
1886                                 break;
1887                         case "fuel":
1888                                 got += GiveValue(e, ammo_fuel, op, val);
1889                                 break;
1890                         default:
1891                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1892                                 {
1893                                         got += GiveBuff(e, it, op, val);
1894                                         break;
1895                                 });
1896                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1897                     got += GiveWeapon(e, it.m_id, op, val);
1898                     break;
1899                                 });
1900                                 break;
1901                 }
1902                 val = 999;
1903                 op = OP_SET;
1904         }
1905
1906         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1907         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1908         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1909         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1910         FOREACH(Weapons, it != WEP_Null, {
1911                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1912                 if(!(save_weapons & (it.m_wepset)))
1913                         if(e.weapons & (it.m_wepset))
1914                                 it.wr_init(it);
1915         });
1916         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1917         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1918         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1919         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1920         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1921         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1922         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1923         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1924         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1925         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1926         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1927
1928         if(e.superweapons_finished <= 0)
1929                 if(e.weapons & WEPSET_SUPERWEAPONS)
1930                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1931
1932         if(e.strength_finished <= 0)
1933                 e.strength_finished = 0;
1934         else
1935                 e.strength_finished += time;
1936         if(e.invincible_finished <= 0)
1937                 e.invincible_finished = 0;
1938         else
1939                 e.invincible_finished += time;
1940         if(e.superweapons_finished <= 0)
1941                 e.superweapons_finished = 0;
1942         else
1943                 e.superweapons_finished += time;
1944
1945         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1946         {
1947                 .entity weaponentity = weaponentities[slot];
1948                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1949                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1950                         _switchweapon |= BIT(slot);
1951         }
1952
1953         if(_switchweapon)
1954         {
1955                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1956                 {
1957                         .entity weaponentity = weaponentities[slot];
1958                         if(_switchweapon & BIT(slot))
1959                         {
1960                                 Weapon wep = w_getbestweapon(e, weaponentity);
1961                                 if(wep != e.(weaponentity).m_switchweapon)
1962                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1963                         }
1964                 }
1965         }
1966
1967         return got;
1968 }
1969 #endif