qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66 }
  67
  68 void ItemDraw(entity this)
  69 {
  70     if(this.gravity)
  71     {
  72         Movetype_Physics_MatchServer(this, false);
  73         if(IS_ONGROUND(this))
  74         { // For some reason avelocity gets set to '0 0 0' here ...
  75             this.oldorigin = this.origin;
  76             this.gravity = 0;
  77
  78             if(autocvar_cl_animate_items)
  79             { // ... so reset it if animations are requested.
  80                 if(this.ItemStatus & ITS_ANIMATE1)
  81                     this.avelocity = '0 180 0';
  82
  83                 if(this.ItemStatus & ITS_ANIMATE2)
  84                     this.avelocity = '0 -90 0';
  85             }
  86
  87             // delay is for blocking item's position for a while;
  88             // it's a workaround for dropped weapons that receive the position
  89             // another time right after they spawn overriding animation position
  90             this.onground_time = time + 0.5;
  91         }
  92     }
  93     else if (autocvar_cl_animate_items)
  94     {
  95         if(this.ItemStatus & ITS_ANIMATE1)
  96         {
  97             this.angles += this.avelocity * frametime;
  98             float fade_in = bound(0, time - this.onground_time, 1);
  99             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 100         }
 101
 102         if(this.ItemStatus & ITS_ANIMATE2)
 103         {
 104             this.angles += this.avelocity * frametime;
 105             float fade_in = bound(0, time - this.onground_time, 1);
 106             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 107         }
 108     }
 109
 110     Item_SetAlpha(this);
 111 }
 112
 113 void ItemDrawSimple(entity this)
 114 {
 115     if(this.gravity)
 116     {
 117         Movetype_Physics_MatchServer(this, false);
 118
 119         if(IS_ONGROUND(this))
 120             this.gravity = 0;
 121     }
 122
 123     Item_SetAlpha(this);
 124 }
 125
 126 void Item_PreDraw(entity this)
 127 {
 128         if(warpzone_warpzones_exist)
 129         {
 130                 // just incase warpzones were initialized last, reset these
 131                 //this.alpha = 1; // alpha is already set by the draw function
 132                 this.drawmask = MASK_NORMAL;
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 alph = 0;
 139         else if(this.fade_start)
 140                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 141         else
 142                 alph = 1;
 143         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 144         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 145                 this.alpha = alph;
 146         if(alph <= 0)
 147                 this.drawmask = 0;
 148         else
 149                 this.drawmask = MASK_NORMAL;
 150 }
 151
 152 void ItemRemove(entity this)
 153 {
 154         if(this.mdl)
 155                 strunzone(this.mdl);
 156 }
 157
 158 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 159 {
 160     int sf = ReadByte();
 161
 162     if(sf & ISF_LOCATION)
 163     {
 164         this.origin_x = ReadCoord();
 165         this.origin_y = ReadCoord();
 166         this.origin_z = ReadCoord();
 167         setorigin(this, this.origin);
 168         this.oldorigin = this.origin;
 169     }
 170
 171     if(sf & ISF_ANGLES)
 172     {
 173         this.angles_x = ReadAngle();
 174         this.angles_y = ReadAngle();
 175         this.angles_z = ReadAngle();
 176     }
 177
 178     if(sf & ISF_SIZE)
 179     {
 180         float use_bigsize = ReadByte();
 181         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 182     }
 183
 184     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 185     {
 186         this.ItemStatus = ReadByte();
 187
 188         Item_SetAlpha(this);
 189
 190         if(autocvar_cl_fullbright_items)
 191             if(this.ItemStatus & ITS_ALLOWFB)
 192                 this.effects |= EF_FULLBRIGHT;
 193
 194         if(this.ItemStatus & ITS_GLOW)
 195         {
 196             if(this.ItemStatus & ITS_AVAILABLE)
 197                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 198             else
 199                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 200         }
 201     }
 202
 203     if(sf & ISF_MODEL)
 204     {
 205         this.drawmask  = MASK_NORMAL;
 206                 set_movetype(this, MOVETYPE_TOSS);
 207                 if (isnew) IL_PUSH(g_drawables, this);
 208         this.draw       = ItemDraw;
 209         this.solid = SOLID_TRIGGER;
 210         //this.flags |= FL_ITEM;
 211
 212         bool use_bigsize = ReadByte();
 213
 214         this.fade_end = ReadShort();
 215         this.fade_start = ReadShort();
 216         if(this.fade_start && !autocvar_cl_items_nofade)
 217                 setpredraw(this, Item_PreDraw);
 218
 219         if(this.mdl)
 220             strunzone(this.mdl);
 221
 222         this.mdl = "";
 223         string _fn = ReadString();
 224
 225         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 226         {
 227             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 228             this.draw = ItemDrawSimple;
 229
 230             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 231                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 232             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 233                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 234             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 235                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 236             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 237                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 238             else
 239             {
 240                 this.draw = ItemDraw;
 241                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 242             }
 243         }
 244
 245         if(this.draw != ItemDrawSimple)
 246             this.mdl = strzone(_fn);
 247
 248
 249         if(this.mdl == "")
 250             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 251
 252         precache_model(this.mdl);
 253         _setmodel(this, this.mdl);
 254
 255         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 256     }
 257
 258     if(sf & ISF_COLORMAP)
 259     {
 260         this.colormap = ReadShort();
 261         this.item_glowmod_x = ReadByte() / 255.0;
 262         this.item_glowmod_y = ReadByte() / 255.0;
 263         this.item_glowmod_z = ReadByte() / 255.0;
 264     }
 265
 266     if(sf & ISF_DROP)
 267     {
 268         this.gravity = 1;
 269         this.pushable = true;
 270         //this.angles = '0 0 0';
 271         set_movetype(this, MOVETYPE_TOSS);
 272         this.velocity_x = ReadCoord();
 273         this.velocity_y = ReadCoord();
 274         this.velocity_z = ReadCoord();
 275         setorigin(this, this.oldorigin);
 276
 277         if(!this.move_time)
 278         {
 279             this.move_time = time;
 280             this.spawntime = time;
 281         }
 282         else
 283             this.move_time = max(this.move_time, time);
 284     }
 285
 286     if(autocvar_cl_animate_items)
 287     {
 288         if(this.ItemStatus & ITS_ANIMATE1)
 289             this.avelocity = '0 180 0';
 290
 291         if(this.ItemStatus & ITS_ANIMATE2)
 292             this.avelocity = '0 -90 0';
 293     }
 294
 295     this.entremove = ItemRemove;
 296
 297     return true;
 298 }
 299
 300 #endif
 301
 302 #ifdef SVQC
 303 bool ItemSend(entity this, entity to, int sf)
 304 {
 305         if(this.gravity)
 306                 sf |= ISF_DROP;
 307         else
 308                 sf &= ~ISF_DROP;
 309
 310         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 311         WriteByte(MSG_ENTITY, sf);
 312
 313         //WriteByte(MSG_ENTITY, this.cnt);
 314         if(sf & ISF_LOCATION)
 315         {
 316                 WriteCoord(MSG_ENTITY, this.origin.x);
 317                 WriteCoord(MSG_ENTITY, this.origin.y);
 318                 WriteCoord(MSG_ENTITY, this.origin.z);
 319         }
 320
 321         if(sf & ISF_ANGLES)
 322         {
 323                 WriteAngle(MSG_ENTITY, this.angles_x);
 324                 WriteAngle(MSG_ENTITY, this.angles_y);
 325                 WriteAngle(MSG_ENTITY, this.angles_z);
 326         }
 327
 328         if(sf & ISF_SIZE)
 329         {
 330                 Pickup p = this.itemdef;
 331                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 332         }
 333
 334         if(sf & ISF_STATUS)
 335                 WriteByte(MSG_ENTITY, this.ItemStatus);
 336
 337         if(sf & ISF_MODEL)
 338         {
 339                 Pickup p = this.itemdef;
 340                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 341                 WriteShort(MSG_ENTITY, this.fade_end);
 342                 WriteShort(MSG_ENTITY, this.fade_start);
 343
 344                 if(this.mdl == "")
 345                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 346
 347                 WriteString(MSG_ENTITY, this.mdl);
 348         }
 349
 350
 351         if(sf & ISF_COLORMAP)
 352         {
 353                 WriteShort(MSG_ENTITY, this.colormap);
 354                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 355         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 356         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 357         }
 358
 359         if(sf & ISF_DROP)
 360         {
 361                 WriteCoord(MSG_ENTITY, this.velocity.x);
 362                 WriteCoord(MSG_ENTITY, this.velocity.y);
 363                 WriteCoord(MSG_ENTITY, this.velocity.z);
 364         }
 365
 366         return true;
 367 }
 368
 369 void ItemUpdate(entity this)
 370 {
 371         this.oldorigin = this.origin;
 372         this.SendFlags |= ISF_LOCATION;
 373 }
 374
 375 void UpdateItemAfterTeleport(entity this)
 376 {
 377         if(getSendEntity(this) == ItemSend)
 378                 ItemUpdate(this);
 379 }
 380
 381 bool have_pickup_item(entity this)
 382 {
 383         if(this.itemdef.instanceOfPowerup)
 384         {
 385                 if(autocvar_g_powerups > 0)
 386                         return true;
 387                 if(autocvar_g_powerups == 0)
 388                         return false;
 389         }
 390         else
 391         {
 392                 if(autocvar_g_pickup_items > 0)
 393                         return true;
 394                 if(autocvar_g_pickup_items == 0)
 395                         return false;
 396                 if(g_weaponarena)
 397                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 398                                 return false;
 399         }
 400         return true;
 401 }
 402
 403 /*
 404 float Item_Customize()
 405 {
 406         if(this.spawnshieldtime)
 407                 return true;
 408         if(this.weapons & ~other.weapons)
 409         {
 410                 this.colormod = '0 0 0';
 411                 this.glowmod = this.colormod;
 412                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 413                 return true;
 414         }
 415         else
 416         {
 417                 if(g_ghost_items)
 418                 {
 419                         this.colormod = stov(autocvar_g_ghost_items_color);
 420                         this.glowmod = this.colormod;
 421                         this.alpha = g_ghost_items;
 422                         return true;
 423                 }
 424                 else
 425                         return false;
 426         }
 427 }
 428 */
 429
 430 void Item_Show (entity e, float mode)
 431 {
 432         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 433         e.ItemStatus &= ~ITS_STAYWEP;
 434         entity def = e.itemdef;
 435         if (mode > 0)
 436         {
 437                 // make the item look normal, and be touchable
 438                 e.model = e.mdl;
 439                 e.solid = SOLID_TRIGGER;
 440                 e.spawnshieldtime = 1;
 441                 e.ItemStatus |= ITS_AVAILABLE;
 442         }
 443         else if (mode < 0)
 444         {
 445                 // hide the item completely
 446                 e.model = string_null;
 447                 e.solid = SOLID_NOT;
 448                 e.spawnshieldtime = 1;
 449                 e.ItemStatus &= ~ITS_AVAILABLE;
 450         }
 451         else
 452         {
 453                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 454                         || e.team // weapon stay isn't supported for teamed weapons
 455                         ;
 456                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 457                 {
 458                         // make the item translucent and not touchable
 459                         e.model = e.mdl;
 460                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 461                         e.effects |= EF_STARDUST;
 462                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 463                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 464                 }
 465                 else
 466                 {
 467                         //setmodel(e, "null");
 468                         e.solid = SOLID_NOT;
 469                         e.colormod = '0 0 0';
 470                         //e.glowmod = e.colormod;
 471                         e.spawnshieldtime = 1;
 472                         e.ItemStatus &= ~ITS_AVAILABLE;
 473                 }
 474         }
 475
 476         if (def.m_glow)
 477                 e.ItemStatus |= ITS_GLOW;
 478
 479         if (autocvar_g_nodepthtestitems)
 480                 e.effects |= EF_NODEPTHTEST;
 481
 482
 483         if (autocvar_g_fullbrightitems)
 484                 e.ItemStatus |= ITS_ALLOWFB;
 485
 486         if (autocvar_sv_simple_items)
 487                 e.ItemStatus |= ITS_ALLOWSI;
 488
 489         // relink entity (because solid may have changed)
 490         setorigin(e, e.origin);
 491         e.SendFlags |= ISF_STATUS;
 492 }
 493
 494 void Item_Think(entity this)
 495 {
 496         this.nextthink = time;
 497         if(this.origin != this.oldorigin)
 498                 ItemUpdate(this);
 499 }
 500
 501 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 502 bool Item_ItemsTime_Allow(GameItem it);
 503 float Item_ItemsTime_UpdateTime(entity e, float t);
 504 void Item_ItemsTime_SetTime(entity e, float t);
 505 void Item_ItemsTime_SetTimesForAllPlayers();
 506
 507 void Item_Respawn (entity this)
 508 {
 509         Item_Show(this, 1);
 510         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 511         setorigin(this, this.origin);
 512
 513     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 514         {
 515                 float t = Item_ItemsTime_UpdateTime(this, 0);
 516                 Item_ItemsTime_SetTime(this, t);
 517                 Item_ItemsTime_SetTimesForAllPlayers();
 518         }
 519
 520         setthink(this, Item_Think);
 521         this.nextthink = time;
 522
 523         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 524         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 525 }
 526
 527 void Item_RespawnCountdown (entity this)
 528 {
 529         if(this.count >= ITEM_RESPAWN_TICKS)
 530         {
 531                 if(this.waypointsprite_attached)
 532                         WaypointSprite_Kill(this.waypointsprite_attached);
 533                 Item_Respawn(this);
 534         }
 535         else
 536         {
 537                 this.nextthink = time + 1;
 538                 this.count += 1;
 539                 if(this.count == 1)
 540                 {
 541                         do {
 542                                 {
 543                                         entity wi = Weapons_from(this.weapon);
 544                                         if (wi != WEP_Null) {
 545                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 546                                                 wp.wp_extra = wi.m_id;
 547                                                 break;
 548                                         }
 549                                 }
 550                                 {
 551                                         entity ii = this.itemdef;
 552                                         if (ii != NULL) {
 553                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 554                                                 wp.wp_extra = ii.m_id;
 555                                                 break;
 556                                         }
 557                                 }
 558                         } while (0);
 559                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 560             if(this.waypointsprite_attached)
 561             {
 562                 GameItem def = this.itemdef;
 563                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 564                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 565                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 566             }
 567                 }
 568
 569                 if(this.waypointsprite_attached)
 570                 {
 571                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 572                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 573                                 {
 574                                         msg_entity = it;
 575                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 576                                 }
 577                         });
 578
 579                         WaypointSprite_Ping(this.waypointsprite_attached);
 580                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 581                 }
 582         }
 583 }
 584
 585 void Item_RespawnThink(entity this)
 586 {
 587         this.nextthink = time;
 588         if(this.origin != this.oldorigin)
 589                 ItemUpdate(this);
 590
 591         if(time >= this.wait)
 592                 Item_Respawn(this);
 593 }
 594
 595 void Item_ScheduleRespawnIn(entity e, float t)
 596 {
 597         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 598         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 599         {
 600                 setthink(e, Item_RespawnCountdown);
 601                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 602                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 603                 e.count = 0;
 604                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 605                 {
 606                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 607                         Item_ItemsTime_SetTime(e, t);
 608                         Item_ItemsTime_SetTimesForAllPlayers();
 609                 }
 610         }
 611         else
 612         {
 613                 setthink(e, Item_RespawnThink);
 614                 e.nextthink = time;
 615                 e.scheduledrespawntime = time + t;
 616                 e.wait = time + t;
 617
 618                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 619                 {
 620                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 621                         Item_ItemsTime_SetTime(e, t);
 622                         Item_ItemsTime_SetTimesForAllPlayers();
 623                 }
 624         }
 625 }
 626
 627 void Item_ScheduleRespawn(entity e)
 628 {
 629         if(e.respawntime > 0)
 630         {
 631                 Item_Show(e, 0);
 632                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 633         }
 634         else // if respawntime is -1, this item does not respawn
 635                 Item_Show(e, -1);
 636 }
 637
 638 void Item_ScheduleInitialRespawn(entity e)
 639 {
 640         Item_Show(e, 0);
 641         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 642 }
 643
 644 void GivePlayerHealth(entity player, float amount)
 645 {
 646         if (amount == 0)
 647         {
 648                 return;
 649         }
 650         player.health = bound(player.health, player.health + amount,
 651                  g_pickup_healthmega_max);
 652         player.pauserothealth_finished = max(player.pauserothealth_finished, time +
 653                 autocvar_g_balance_pause_health_rot);
 654 }
 655
 656 void GivePlayerArmor(entity player, float amount)
 657 {
 658         if (amount == 0)
 659         {
 660                 return;
 661         }
 662         player.armorvalue = bound(player.armorvalue, player.armorvalue + amount,
 663                  g_pickup_armormega_max);
 664         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time +
 665                 autocvar_g_balance_pause_armor_rot);
 666 }
 667
 668 void GivePlayerShells(entity player, float amount)
 669 {
 670         player.ammo_shells = bound(player.ammo_shells, player.ammo_shells + amount,
 671                 g_pickup_shells_max);
 672 }
 673
 674 void GivePlayerBullets(entity player, float amount)
 675 {
 676         player.ammo_nails = bound(player.ammo_nails, player.ammo_nails + amount,
 677                 g_pickup_nails_max);
 678 }
 679
 680 void GivePlayerRockets(entity player, float amount)
 681 {
 682         player.ammo_rockets = bound(player.ammo_rockets, player.ammo_rockets +
 683                 amount, g_pickup_rockets_max);
 684 }
 685
 686 void GivePlayerCells(entity player, float amount)
 687 {
 688         player.ammo_cells = bound(player.ammo_cells, player.ammo_cells + amount,
 689                 g_pickup_cells_max);
 690 }
 691
 692 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 693 {
 694         if (!item.(ammotype))
 695                 return false;
 696
 697         if (item.spawnshieldtime)
 698         {
 699                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 700                 {
 701                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 702                         goto YEAH;
 703                 }
 704         }
 705         else if(g_weapon_stay == 2)
 706         {
 707                 float mi = min(item.(ammotype), ammomax);
 708                 if (player.(ammotype) < mi)
 709                 {
 710                         player.(ammotype) = mi;
 711                         goto YEAH;
 712                 }
 713         }
 714
 715         return false;
 716
 717 LABEL(YEAH)
 718         switch(mode)
 719         {
 720                 case ITEM_MODE_FUEL:
 721                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 722                         break;
 723                 case ITEM_MODE_HEALTH:
 724                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 725                         break;
 726                 case ITEM_MODE_ARMOR:
 727                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 728                         break;
 729                 default:
 730                         break;
 731         }
 732         return true;
 733 }
 734
 735 float Item_GiveTo(entity item, entity player)
 736 {
 737         float pickedup;
 738
 739         // if nothing happens to player, just return without taking the item
 740         pickedup = false;
 741         int _switchweapon = 0;
 742         // in case the player has autoswitch enabled do the following:
 743         // if the player is using their best weapon before items are given, they
 744         // probably want to switch to an even better weapon after items are given
 745
 746         if(player.autoswitch)
 747         {
 748                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 749                 {
 750                         .entity weaponentity = weaponentities[slot];
 751                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 752                         {
 753                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 754                                         _switchweapon |= BIT(slot);
 755
 756                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 757                                         _switchweapon |= BIT(slot);
 758                         }
 759                 }
 760         }
 761
 762         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 763         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 764         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 765         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 766         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 767         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 768         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 769         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 770
 771         if (item.itemdef.instanceOfWeaponPickup)
 772         {
 773                 WepSet w;
 774                 w = item.weapons;
 775                 w &= ~player.weapons;
 776
 777                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 778                 {
 779                         pickedup = true;
 780                         FOREACH(Weapons, it != WEP_Null, {
 781                                 if(w & (it.m_wepset))
 782                                 {
 783                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 784                                         {
 785                                                 .entity weaponentity = weaponentities[slot];
 786                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 787                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 788                                         }
 789                                         W_GiveWeapon(player, it.m_id);
 790                                 }
 791                         });
 792                 }
 793         }
 794
 795         if (item.itemdef.instanceOfPowerup)
 796         {
 797                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 798                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 799                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 800                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 801         }
 802
 803         int its;
 804         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 805         {
 806                 pickedup = true;
 807                 player.items |= its;
 808                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 809         }
 810
 811         if (item.strength_finished)
 812         {
 813                 pickedup = true;
 814                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 815         }
 816         if (item.invincible_finished)
 817         {
 818                 pickedup = true;
 819                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 820         }
 821         if (item.superweapons_finished)
 822         {
 823                 pickedup = true;
 824                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 825         }
 826
 827 LABEL(skip)
 828
 829         // always eat teamed entities
 830         if(item.team)
 831                 pickedup = true;
 832
 833         if (!pickedup)
 834                 return 0;
 835
 836         // crude hack to enforce switching weapons
 837         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 838         {
 839                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 840                 {
 841                         .entity weaponentity = weaponentities[slot];
 842                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 843                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 844                 }
 845                 return 1;
 846         }
 847
 848         if(_switchweapon)
 849         {
 850                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 851                 {
 852                         .entity weaponentity = weaponentities[slot];
 853                         if(_switchweapon & BIT(slot))
 854                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 855                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 856                 }
 857         }
 858
 859         return 1;
 860 }
 861
 862 void Item_Touch(entity this, entity toucher)
 863 {
 864
 865         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 866         if (this.classname == "droppedweapon")
 867         {
 868                 if (ITEM_TOUCH_NEEDKILL())
 869                 {
 870                         delete(this);
 871                         return;
 872                 }
 873         }
 874
 875         if(!(toucher.flags & FL_PICKUPITEMS)
 876         || STAT(FROZEN, toucher)
 877         || IS_DEAD(toucher)
 878         || (this.solid != SOLID_TRIGGER)
 879         || (this.owner == toucher)
 880         || (time < this.item_spawnshieldtime)
 881         ) { return; }
 882
 883         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 884         {
 885                 case MUT_ITEMTOUCH_RETURN: { return; }
 886                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 887         }
 888
 889         toucher = M_ARGV(1, entity);
 890
 891         if (this.classname == "droppedweapon")
 892         {
 893                 this.strength_finished = max(0, this.strength_finished - time);
 894                 this.invincible_finished = max(0, this.invincible_finished - time);
 895                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 896         }
 897         entity it = this.itemdef;
 898         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 899         if (!gave)
 900         {
 901                 if (this.classname == "droppedweapon")
 902                 {
 903                         // undo what we did above
 904                         this.strength_finished += time;
 905                         this.invincible_finished += time;
 906                         this.superweapons_finished += time;
 907                 }
 908                 return;
 909         }
 910
 911 LABEL(pickup)
 912
 913         toucher.last_pickup = time;
 914
 915         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 916         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 917
 918         if (this.classname == "droppedweapon")
 919                 delete (this);
 920         else if (this.spawnshieldtime)
 921         {
 922                 entity e;
 923                 if(this.team)
 924                 {
 925                         RandomSelection_Init();
 926                         IL_EACH(g_items, it.team == this.team,
 927                         {
 928                                 if(it.itemdef) // is a registered item
 929                                 {
 930                                         Item_Show(it, -1);
 931                                         RandomSelection_AddEnt(it, it.cnt, 0);
 932                                 }
 933                         });
 934                         e = RandomSelection_chosen_ent;
 935                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 936                 }
 937                 else
 938                         e = this;
 939                 Item_ScheduleRespawn(e);
 940         }
 941 }
 942
 943 void Item_Reset(entity this)
 944 {
 945         Item_Show(this, !this.state);
 946         setorigin(this, this.origin);
 947
 948         if (this.classname != "droppedweapon")
 949         {
 950                 setthink(this, Item_Think);
 951                 this.nextthink = time;
 952
 953                 if (this.waypointsprite_attached)
 954                         WaypointSprite_Kill(this.waypointsprite_attached);
 955
 956                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 957                         Item_ScheduleInitialRespawn(this);
 958         }
 959 }
 960
 961 void Item_FindTeam(entity this)
 962 {
 963         entity e;
 964
 965         if(this.effects & EF_NODRAW)
 966         {
 967                 // marker for item team search
 968                 LOG_TRACE("Initializing item team ", ftos(this.team));
 969                 RandomSelection_Init();
 970                 IL_EACH(g_items, it.team == this.team,
 971                 {
 972                         if(it.itemdef) // is a registered item
 973                                 RandomSelection_AddEnt(it, it.cnt, 0);
 974                 });
 975
 976                 e = RandomSelection_chosen_ent;
 977                 e.state = 0;
 978                 Item_Show(e, 1);
 979
 980                 IL_EACH(g_items, it.team == this.team,
 981                 {
 982                         if(it.itemdef) // is a registered item
 983                         {
 984                                 if(it != e)
 985                                 {
 986                                         // make it non-spawned
 987                                         Item_Show(it, -1);
 988                                         it.state = 1; // state 1 = initially hidden item, apparently
 989                                 }
 990                                 it.effects &= ~EF_NODRAW;
 991                         }
 992                 });
 993
 994                 Item_Reset(this);
 995         }
 996 }
 997
 998 // Savage: used for item garbage-collection
 999 void RemoveItem(entity this)
1000 {
1001         if(wasfreed(this) || !this) { return; }
1002         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1003         delete(this);
1004 }
1005
1006 // pickup evaluation functions
1007 // these functions decide how desirable an item is to the bots
1008
1009 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1010
1011 float weapon_pickupevalfunc(entity player, entity item)
1012 {
1013         // See if I have it already
1014         if(player.weapons & item.weapons)
1015         {
1016                 // If I can pick it up
1017                 if(!item.spawnshieldtime)
1018                         return 0;
1019                 return ammo_pickupevalfunc(player, item);
1020         }
1021
1022         // reduce weapon value if bot already got a good arsenal
1023         float c = 1;
1024         int weapons_value = 0;
1025         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1026                 weapons_value += it.bot_pickupbasevalue;
1027         });
1028         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1029
1030         return item.bot_pickupbasevalue * c;
1031 }
1032
1033 float ammo_pickupevalfunc(entity player, entity item)
1034 {
1035         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1036         entity wpn = NULL;
1037         float c = 0;
1038         float rating = 0;
1039
1040         // Detect needed ammo
1041         if(item.itemdef.instanceOfWeaponPickup)
1042         {
1043                 entity ammo = NULL;
1044                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1045                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1046                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1047                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1048                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1049                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1050
1051                 if(!ammo)
1052                         return 0;
1053                 wpn = item;
1054                 rating = ammo.m_botvalue;
1055         }
1056         else
1057         {
1058                 FOREACH(Weapons, it != WEP_Null, {
1059                         if(!(player.weapons & (it.m_wepset)))
1060                                 continue;
1061
1062                         switch(it.ammo_field)
1063                         {
1064                                 case ammo_shells:  need_shells  = true; break;
1065                                 case ammo_nails:   need_nails   = true; break;
1066                                 case ammo_rockets: need_rockets = true; break;
1067                                 case ammo_cells:   need_cells   = true; break;
1068                                 case ammo_plasma:  need_plasma  = true; break;
1069                                 case ammo_fuel:    need_fuel    = true; break;
1070                         }
1071                 });
1072                 rating = item.bot_pickupbasevalue;
1073         }
1074
1075         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1076                 c = item.ammo_shells / player.ammo_shells;
1077
1078         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1079                 c = item.ammo_nails / player.ammo_nails;
1080
1081         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1082                 c = item.ammo_rockets / player.ammo_rockets;
1083
1084         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1085                 c = item.ammo_cells / player.ammo_cells;
1086
1087         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1088                 c = item.ammo_plasma / player.ammo_plasma;
1089
1090         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1091                 c = item.ammo_fuel / player.ammo_fuel;
1092
1093         rating *= min(2, c);
1094         if(wpn)
1095                 rating += wpn.bot_pickupbasevalue * 0.1;
1096         return rating;
1097 }
1098
1099 .int item_group;
1100 .int item_group_count;
1101 float healtharmor_pickupevalfunc(entity player, entity item)
1102 {
1103         float c = 0;
1104         float rating = item.bot_pickupbasevalue;
1105
1106         float itemarmor = item.armorvalue;
1107         float itemhealth = item.health;
1108
1109         if(item.item_group)
1110         {
1111                 itemarmor *= min(4, item.item_group_count);
1112                 itemhealth *= min(4, item.item_group_count);
1113         }
1114
1115         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1116                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1117
1118         if (itemhealth && (player.health < item.max_health))
1119                 c = itemhealth / max(1, player.health);
1120
1121         rating *= min(2, c);
1122         return rating;
1123 }
1124
1125 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1126 {
1127         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1128                 RemoveItem(this);
1129 }
1130
1131 void item_use(entity this, entity actor, entity trigger)
1132 {
1133         // use the touch function to handle collection
1134         gettouch(this)(this, actor);
1135 }
1136
1137 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1138 {
1139         string itemname = def.m_name;
1140         Model itemmodel = def.m_model;
1141     Sound pickupsound = def.m_sound;
1142         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1143         float pickupbasevalue = def.m_botvalue;
1144         int itemflags = def.m_itemflags;
1145
1146         startitem_failed = false;
1147
1148         this.item_model_ent = itemmodel;
1149     this.item_pickupsound_ent = pickupsound;
1150
1151     if(def.m_iteminit)
1152         def.m_iteminit(this);
1153
1154         if(!this.respawntime) // both need to be set
1155         {
1156                 this.respawntime = defaultrespawntime;
1157                 this.respawntimejitter = defaultrespawntimejitter;
1158         }
1159
1160         if(!this.pickup_anyway && def.m_pickupanyway)
1161                 this.pickup_anyway = def.m_pickupanyway();
1162
1163         int itemid = def.m_itemid;
1164         this.items = itemid;
1165         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1166         this.weapon = weaponid;
1167
1168         if(!this.fade_end)
1169         {
1170                 this.fade_start = autocvar_g_items_mindist;
1171                 this.fade_end = autocvar_g_items_maxdist;
1172         }
1173
1174         if(weaponid)
1175                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1176
1177         this.flags = FL_ITEM | itemflags;
1178         IL_PUSH(g_items, this);
1179
1180         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1181         {
1182                 startitem_failed = true;
1183                 delete(this);
1184                 return;
1185         }
1186
1187         // is it a dropped weapon?
1188         if (this.classname == "droppedweapon")
1189         {
1190                 this.reset = SUB_Remove;
1191                 // it's a dropped weapon
1192                 set_movetype(this, MOVETYPE_TOSS);
1193
1194                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1195                 setthink(this, RemoveItem);
1196                 this.nextthink = time + 20;
1197
1198                 this.takedamage = DAMAGE_YES;
1199                 this.event_damage = Item_Damage;
1200
1201                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1202                 {
1203                         // if item is worthless after a timer, have it expire then
1204                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1205                 }
1206
1207                 // don't drop if in a NODROP zone (such as lava)
1208                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1209                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1210                 {
1211                         startitem_failed = true;
1212                         delete(this);
1213                         return;
1214                 }
1215         }
1216         else
1217         {
1218                 if(!have_pickup_item(this))
1219                 {
1220                         startitem_failed = true;
1221                         delete (this);
1222                         return;
1223                 }
1224
1225                 if(this.angles != '0 0 0')
1226                         this.SendFlags |= ISF_ANGLES;
1227
1228                 this.reset = Item_Reset;
1229                 // it's a level item
1230                 if(this.spawnflags & 1)
1231                         this.noalign = 1;
1232                 if (this.noalign > 0)
1233                         set_movetype(this, MOVETYPE_NONE);
1234                 else
1235                         set_movetype(this, MOVETYPE_TOSS);
1236                 // do item filtering according to game mode and other things
1237                 if (this.noalign <= 0)
1238                 {
1239                         // first nudge it off the floor a little bit to avoid math errors
1240                         setorigin(this, this.origin + '0 0 1');
1241                         // set item size before we spawn a spawnfunc_waypoint
1242                         setsize(this, def.m_mins, def.m_maxs);
1243                         this.SendFlags |= ISF_SIZE;
1244                         // note droptofloor returns false if stuck/or would fall too far
1245                         if (!this.noalign)
1246                                 droptofloor(this);
1247                         waypoint_spawnforitem(this);
1248                 }
1249
1250                 /*
1251                  * can't do it that way, as it would break maps
1252                  * TODO make a target_give like entity another way, that perhaps has
1253                  * the weapon name in a key
1254                 if(this.targetname)
1255                 {
1256                         // target_give not yet supported; maybe later
1257                         print("removed targeted ", this.classname, "\n");
1258                         startitem_failed = true;
1259                         remove (this);
1260                         return;
1261                 }
1262                 */
1263
1264                 if(this.targetname != "" && (this.spawnflags & 16))
1265                         this.use = item_use;
1266
1267                 if(autocvar_spawn_debug >= 2)
1268                 {
1269             // why not flags & fl_item?
1270                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1271                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1272                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1273                 error("Mapper sucks.");
1274             });
1275                         this.is_item = true;
1276                 }
1277
1278                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1279
1280                 precache_model(this.model);
1281                 precache_sound(this.item_pickupsound);
1282
1283                 if (   def.instanceOfPowerup
1284                         || def.instanceOfWeaponPickup
1285                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1286                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1287                         || (itemid & (IT_KEY1 | IT_KEY2))
1288                 ) this.target = "###item###"; // for finding the nearest item using find()
1289
1290                 Item_ItemsTime_SetTime(this, 0);
1291         }
1292
1293         this.bot_pickup = true;
1294         this.bot_pickupevalfunc = pickupevalfunc;
1295         this.bot_pickupbasevalue = pickupbasevalue;
1296         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1297         this.netname = itemname;
1298         settouch(this, Item_Touch);
1299         setmodel(this, MDL_Null); // precision set below
1300         //this.effects |= EF_LOWPRECISION;
1301
1302         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1303
1304         this.SendFlags |= ISF_SIZE;
1305
1306         if (!(this.spawnflags & 1024)) {
1307                 if(def.instanceOfPowerup)
1308                         this.ItemStatus |= ITS_ANIMATE1;
1309
1310                 if(this.armorvalue || this.health)
1311                         this.ItemStatus |= ITS_ANIMATE2;
1312         }
1313
1314         if(def.instanceOfWeaponPickup)
1315         {
1316                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1317                         this.colormap = 1024; // color shirt=0 pants=0 grey
1318                 else
1319                         this.gravity = 1;
1320                 if (!(this.spawnflags & 1024))
1321                         this.ItemStatus |= ITS_ANIMATE1;
1322                 this.SendFlags |= ISF_COLORMAP;
1323         }
1324
1325         this.state = 0;
1326         if(this.team) // broken, no idea why.
1327         {
1328                 if(!this.cnt)
1329                         this.cnt = 1; // item probability weight
1330
1331                 this.effects |= EF_NODRAW; // marker for item team search
1332                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1333         }
1334         else
1335                 Item_Reset(this);
1336
1337         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1338
1339         // call this hook after everything else has been done
1340         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1341         {
1342                 startitem_failed = true;
1343                 delete(this);
1344                 return;
1345         }
1346
1347         setItemGroup(this);
1348 }
1349
1350 void StartItem(entity this, GameItem def)
1351 {
1352     _StartItem(
1353         this,
1354         this.itemdef = def,
1355         def.m_respawntime(), // defaultrespawntime
1356         def.m_respawntimejitter() // defaultrespawntimejitter
1357         );
1358 }
1359
1360 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1361 int group_count = 1;
1362
1363 void setItemGroup(entity this)
1364 {
1365         if(!IS_SMALL(this.itemdef))
1366                 return;
1367
1368         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1369         {
1370                 if(!this.item_group)
1371                 {
1372                         if(!it.item_group)
1373                         {
1374                                 it.item_group = group_count;
1375                                 group_count++;
1376                         }
1377                         this.item_group = it.item_group;
1378                 }
1379                 else // spawning item is already part of a item_group X
1380                 {
1381                         if(!it.item_group)
1382                                 it.item_group = this.item_group;
1383                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1384                         {
1385                                 int grY = it.item_group;
1386                                 // move all items of item_group Y to item_group X
1387                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1388                                 {
1389                                         if(it.item_group == grY)
1390                                                 it.item_group = this.item_group;
1391                                 });
1392                         }
1393                 }
1394         });
1395 }
1396
1397 void setItemGroupCount()
1398 {
1399         for (int k = 1; k <= group_count; k++)
1400         {
1401                 int count = 0;
1402                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1403                 if (count)
1404                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1405         }
1406 }
1407
1408 spawnfunc(item_rockets)
1409 {
1410     StartItem(this, ITEM_Rockets);
1411 }
1412
1413 spawnfunc(item_bullets)
1414 {
1415         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1416            (this.classname != "droppedweapon"))
1417         {
1418                 weaponswapping = true;
1419                 spawnfunc_item_shells(this);
1420                 weaponswapping = false;
1421                 return;
1422         }
1423
1424     StartItem(this, ITEM_Bullets);
1425 }
1426
1427 spawnfunc(item_cells)
1428 {
1429         StartItem(this, ITEM_Cells);
1430 }
1431
1432 spawnfunc(item_plasma)
1433 {
1434         StartItem(this, ITEM_Plasma);
1435 }
1436
1437 spawnfunc(item_shells)
1438 {
1439         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1440            (this.classname != "droppedweapon"))
1441         {
1442                 weaponswapping = true;
1443                 spawnfunc_item_bullets(this);
1444                 weaponswapping = false;
1445                 return;
1446         }
1447
1448         StartItem(this, ITEM_Shells);
1449 }
1450
1451 spawnfunc(item_armor_small)
1452 {
1453         StartItem(this, ITEM_ArmorSmall);
1454 }
1455
1456 spawnfunc(item_armor_medium)
1457 {
1458         StartItem(this, ITEM_ArmorMedium);
1459 }
1460
1461 spawnfunc(item_armor_big)
1462 {
1463         StartItem(this, ITEM_ArmorBig);
1464 }
1465
1466 spawnfunc(item_armor_mega)
1467 {
1468         StartItem(this, ITEM_ArmorMega);
1469 }
1470
1471 spawnfunc(item_health_small)
1472 {
1473         StartItem(this, ITEM_HealthSmall);
1474 }
1475
1476 spawnfunc(item_health_medium)
1477 {
1478     StartItem(this, ITEM_HealthMedium);
1479 }
1480
1481 spawnfunc(item_health_big)
1482 {
1483         StartItem(this, ITEM_HealthBig);
1484 }
1485
1486 spawnfunc(item_health_mega)
1487 {
1488     StartItem(this, ITEM_HealthMega);
1489 }
1490
1491 // support old misnamed entities
1492 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1493 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1494 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1495 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1496 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1497 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1498 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1499
1500 spawnfunc(item_strength)
1501 {
1502         StartItem(this, ITEM_Strength);
1503 }
1504
1505 spawnfunc(item_invincible)
1506 {
1507         StartItem(this, ITEM_Shield);
1508 }
1509
1510 // compatibility:
1511 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1512
1513 void target_items_use(entity this, entity actor, entity trigger)
1514 {
1515         if(actor.classname == "droppedweapon")
1516         {
1517                 EXACTTRIGGER_TOUCH(this, trigger);
1518                 delete(actor);
1519                 return;
1520         }
1521
1522         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1523                 return;
1524
1525         if(trigger.solid == SOLID_TRIGGER)
1526         {
1527                 EXACTTRIGGER_TOUCH(this, trigger);
1528         }
1529
1530         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1531         {
1532                 delete(it);
1533         });
1534
1535         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1536                 centerprint(actor, this.message);
1537 }
1538
1539 spawnfunc(target_items)
1540 {
1541         int n;
1542         string s;
1543
1544         this.use = target_items_use;
1545         if(!this.strength_finished)
1546                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1547         if(!this.invincible_finished)
1548                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1549         if(!this.superweapons_finished)
1550                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1551
1552         n = tokenize_console(this.netname);
1553         if(argv(0) == "give")
1554         {
1555                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1556         }
1557         else
1558         {
1559                 for(int j = 0; j < n; ++j)
1560                 {
1561                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1562                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1563                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1564                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1565                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1566                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1567                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1568                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1569                         else
1570                         {
1571                                 FOREACH(Buffs, it != BUFF_Null,
1572                                 {
1573                                         s = Buff_UndeprecateName(argv(j));
1574                                         if(s == it.m_name)
1575                                         {
1576                                                 this.buffs |= (it.m_itemid);
1577                                                 break;
1578                                         }
1579                                 });
1580                                 FOREACH(Weapons, it != WEP_Null, {
1581                                         s = W_UndeprecateName(argv(j));
1582                                         if(s == it.netname)
1583                                         {
1584                                                 this.weapons |= (it.m_wepset);
1585                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1586                                                         it.wr_init(it);
1587                                                 break;
1588                                         }
1589                                 });
1590                         }
1591                 }
1592
1593                 string itemprefix, valueprefix;
1594                 if(this.spawnflags == 0)
1595                 {
1596                         itemprefix = "";
1597                         valueprefix = "";
1598                 }
1599                 else if(this.spawnflags == 1)
1600                 {
1601                         itemprefix = "max ";
1602                         valueprefix = "max ";
1603                 }
1604                 else if(this.spawnflags == 2)
1605                 {
1606                         itemprefix = "min ";
1607                         valueprefix = "min ";
1608                 }
1609                 else if(this.spawnflags == 4)
1610                 {
1611                         itemprefix = "minus ";
1612                         valueprefix = "max ";
1613                 }
1614                 else
1615                 {
1616                         error("invalid spawnflags");
1617                         itemprefix = valueprefix = string_null;
1618                 }
1619
1620                 this.netname = "";
1621                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1622                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1623                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1624                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1625                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1626                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1627                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1628                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1629                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1630                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1631                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1632                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1633                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1634                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1635                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1636                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1637                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1638         }
1639         this.netname = strzone(this.netname);
1640         //print(this.netname, "\n");
1641
1642         n = tokenize_console(this.netname);
1643         for(int j = 0; j < n; ++j)
1644         {
1645                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1646             it.wr_init(it);
1647             break;
1648                 });
1649         }
1650 }
1651
1652 spawnfunc(item_fuel)
1653 {
1654         StartItem(this, ITEM_JetpackFuel);
1655 }
1656
1657 spawnfunc(item_fuel_regen)
1658 {
1659         if(start_items & ITEM_JetpackRegen.m_itemid)
1660         {
1661                 spawnfunc_item_fuel(this);
1662                 return;
1663         }
1664         StartItem(this, ITEM_JetpackRegen);
1665 }
1666
1667 spawnfunc(item_jetpack)
1668 {
1669         if(start_items & ITEM_Jetpack.m_itemid)
1670         {
1671                 spawnfunc_item_fuel(this);
1672                 return;
1673         }
1674         StartItem(this, ITEM_Jetpack);
1675 }
1676
1677 float GiveWeapon(entity e, float wpn, float op, float val)
1678 {
1679         WepSet v0, v1;
1680         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1681         v0 = (e.weapons & s);
1682         switch(op)
1683         {
1684                 case OP_SET:
1685                         if(val > 0)
1686                                 e.weapons |= s;
1687                         else
1688                                 e.weapons &= ~s;
1689                         break;
1690                 case OP_MIN:
1691                 case OP_PLUS:
1692                         if(val > 0)
1693                                 e.weapons |= s;
1694                         break;
1695                 case OP_MAX:
1696                         if(val <= 0)
1697                                 e.weapons &= ~s;
1698                         break;
1699                 case OP_MINUS:
1700                         if(val > 0)
1701                                 e.weapons &= ~s;
1702                         break;
1703         }
1704         v1 = (e.weapons & s);
1705         return (v0 != v1);
1706 }
1707
1708 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1709 {
1710         bool had_buff = (e.buffs & thebuff.m_itemid);
1711         switch(op)
1712         {
1713                 case OP_SET:
1714                         if(val > 0)
1715                                 e.buffs |= thebuff.m_itemid;
1716                         else
1717                                 e.buffs &= ~thebuff.m_itemid;
1718                         break;
1719                 case OP_MIN:
1720                 case OP_PLUS:
1721                         if(val > 0)
1722                                 e.buffs |= thebuff.m_itemid;
1723                         break;
1724                 case OP_MAX:
1725                         if(val <= 0)
1726                                 e.buffs &= ~thebuff.m_itemid;
1727                         break;
1728                 case OP_MINUS:
1729                         if(val > 0)
1730                                 e.buffs &= ~thebuff.m_itemid;
1731                         break;
1732         }
1733         bool have_buff = (e.buffs & thebuff.m_itemid);
1734         return (had_buff != have_buff);
1735 }
1736
1737 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1738 {
1739         if(v1 == v0)
1740                 return;
1741         if(v1 <= v0 - t)
1742         {
1743                 if(snd_decr != NULL)
1744                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1745         }
1746         else if(v0 >= v0 + t)
1747         {
1748                 if(snd_incr != NULL)
1749                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1750         }
1751 }
1752
1753 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1754 {
1755         if(v0 < v1)
1756                 e.(rotfield) = max(e.(rotfield), time + rottime);
1757         else if(v0 > v1)
1758                 e.(regenfield) = max(e.(regenfield), time + regentime);
1759 }
1760 float GiveItems(entity e, float beginarg, float endarg)
1761 {
1762         float got, i, val, op;
1763         string cmd;
1764
1765         val = 999;
1766         op = OP_SET;
1767
1768         got = 0;
1769
1770         int _switchweapon = 0;
1771
1772         if(e.autoswitch)
1773         {
1774                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1775                 {
1776                         .entity weaponentity = weaponentities[slot];
1777                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1778                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1779                                 _switchweapon |= BIT(slot);
1780                 }
1781         }
1782
1783         e.strength_finished = max(0, e.strength_finished - time);
1784         e.invincible_finished = max(0, e.invincible_finished - time);
1785         e.superweapons_finished = max(0, e.superweapons_finished - time);
1786
1787         PREGIVE(e, items);
1788         PREGIVE_WEAPONS(e);
1789         PREGIVE(e, strength_finished);
1790         PREGIVE(e, invincible_finished);
1791         PREGIVE(e, superweapons_finished);
1792         PREGIVE(e, ammo_nails);
1793         PREGIVE(e, ammo_cells);
1794         PREGIVE(e, ammo_plasma);
1795         PREGIVE(e, ammo_shells);
1796         PREGIVE(e, ammo_rockets);
1797         PREGIVE(e, ammo_fuel);
1798         PREGIVE(e, armorvalue);
1799         PREGIVE(e, health);
1800
1801         for(i = beginarg; i < endarg; ++i)
1802         {
1803                 cmd = argv(i);
1804
1805                 if(cmd == "0" || stof(cmd))
1806                 {
1807                         val = stof(cmd);
1808                         continue;
1809                 }
1810                 switch(cmd)
1811                 {
1812                         case "no":
1813                                 op = OP_MAX;
1814                                 val = 0;
1815                                 continue;
1816                         case "max":
1817                                 op = OP_MAX;
1818                                 continue;
1819                         case "min":
1820                                 op = OP_MIN;
1821                                 continue;
1822                         case "plus":
1823                                 op = OP_PLUS;
1824                                 continue;
1825                         case "minus":
1826                                 op = OP_MINUS;
1827                                 continue;
1828                         case "ALL":
1829                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1830                                 got += GiveValue(e, strength_finished, op, val);
1831                                 got += GiveValue(e, invincible_finished, op, val);
1832                                 got += GiveValue(e, superweapons_finished, op, val);
1833                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1834                         case "all":
1835                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1836                                 got += GiveValue(e, health, op, val);
1837                                 got += GiveValue(e, armorvalue, op, val);
1838                         case "allweapons":
1839                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1840                         //case "allbuffs": // all buffs makes a player god, do not want!
1841                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1842                         case "allammo":
1843                                 got += GiveValue(e, ammo_cells, op, val);
1844                                 got += GiveValue(e, ammo_plasma, op, val);
1845                                 got += GiveValue(e, ammo_shells, op, val);
1846                                 got += GiveValue(e, ammo_nails, op, val);
1847                                 got += GiveValue(e, ammo_rockets, op, val);
1848                                 got += GiveValue(e, ammo_fuel, op, val);
1849                                 break;
1850                         case "unlimited_ammo":
1851                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1852                                 break;
1853                         case "unlimited_weapon_ammo":
1854                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1855                                 break;
1856                         case "unlimited_superweapons":
1857                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1858                                 break;
1859                         case "jetpack":
1860                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1861                                 break;
1862                         case "fuel_regen":
1863                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1864                                 break;
1865                         case "strength":
1866                                 got += GiveValue(e, strength_finished, op, val);
1867                                 break;
1868                         case "invincible":
1869                                 got += GiveValue(e, invincible_finished, op, val);
1870                                 break;
1871                         case "superweapons":
1872                                 got += GiveValue(e, superweapons_finished, op, val);
1873                                 break;
1874                         case "cells":
1875                                 got += GiveValue(e, ammo_cells, op, val);
1876                                 break;
1877                         case "plasma":
1878                                 got += GiveValue(e, ammo_plasma, op, val);
1879                                 break;
1880                         case "shells":
1881                                 got += GiveValue(e, ammo_shells, op, val);
1882                                 break;
1883                         case "nails":
1884                         case "bullets":
1885                                 got += GiveValue(e, ammo_nails, op, val);
1886                                 break;
1887                         case "rockets":
1888                                 got += GiveValue(e, ammo_rockets, op, val);
1889                                 break;
1890                         case "health":
1891                                 got += GiveValue(e, health, op, val);
1892                                 break;
1893                         case "armor":
1894                                 got += GiveValue(e, armorvalue, op, val);
1895                                 break;
1896                         case "fuel":
1897                                 got += GiveValue(e, ammo_fuel, op, val);
1898                                 break;
1899                         default:
1900                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1901                                 {
1902                                         got += GiveBuff(e, it, op, val);
1903                                         break;
1904                                 });
1905                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1906                     got += GiveWeapon(e, it.m_id, op, val);
1907                     break;
1908                                 });
1909                                 break;
1910                 }
1911                 val = 999;
1912                 op = OP_SET;
1913         }
1914
1915         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1916         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1917         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1918         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1919         FOREACH(Weapons, it != WEP_Null, {
1920                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1921                 if(!(save_weapons & (it.m_wepset)))
1922                         if(e.weapons & (it.m_wepset))
1923                                 it.wr_init(it);
1924         });
1925         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1926         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1927         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1928         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1929         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1930         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1931         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1932         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1933         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1934         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1935         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1936
1937         if(e.superweapons_finished <= 0)
1938                 if(e.weapons & WEPSET_SUPERWEAPONS)
1939                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1940
1941         if(e.strength_finished <= 0)
1942                 e.strength_finished = 0;
1943         else
1944                 e.strength_finished += time;
1945         if(e.invincible_finished <= 0)
1946                 e.invincible_finished = 0;
1947         else
1948                 e.invincible_finished += time;
1949         if(e.superweapons_finished <= 0)
1950                 e.superweapons_finished = 0;
1951         else
1952                 e.superweapons_finished += time;
1953
1954         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1955         {
1956                 .entity weaponentity = weaponentities[slot];
1957                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1958                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1959                         _switchweapon |= BIT(slot);
1960         }
1961
1962         if(_switchweapon)
1963         {
1964                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1965                 {
1966                         .entity weaponentity = weaponentities[slot];
1967                         if(_switchweapon & BIT(slot))
1968                         {
1969                                 Weapon wep = w_getbestweapon(e, weaponentity);
1970                                 if(wep != e.(weaponentity).m_switchweapon)
1971                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1972                         }
1973                 }
1974         }
1975
1976         return got;
1977 }
1978 #endif