qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "mapobjects/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 this.alpha = autocvar_cl_ghost_items;
  54                 this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  55         }
  56
  57         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  58         {
  59                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  60                 this.alpha = autocvar_cl_weapon_stay_alpha;
  61         }
  62
  63         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  64 }
  65
  66 void ItemDraw(entity this)
  67 {
  68     if(this.gravity)
  69     {
  70         Movetype_Physics_MatchServer(this, false);
  71         if(IS_ONGROUND(this))
  72         { // For some reason avelocity gets set to '0 0 0' here ...
  73             this.oldorigin = this.origin;
  74             this.gravity = 0;
  75
  76             if(autocvar_cl_animate_items)
  77             { // ... so reset it if animations are requested.
  78                 if(this.ItemStatus & ITS_ANIMATE1)
  79                     this.avelocity = '0 180 0';
  80
  81                 if(this.ItemStatus & ITS_ANIMATE2)
  82                     this.avelocity = '0 -90 0';
  83             }
  84
  85             // delay is for blocking item's position for a while;
  86             // it's a workaround for dropped weapons that receive the position
  87             // another time right after they spawn overriding animation position
  88             this.onground_time = time + 0.5;
  89         }
  90     }
  91     else if (autocvar_cl_animate_items)
  92     {
  93         if(this.ItemStatus & ITS_ANIMATE1)
  94         {
  95                 if(!this.item_simple)
  96                 this.angles += this.avelocity * frametime;
  97             float fade_in = bound(0, time - this.onground_time, 1);
  98             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
  99         }
 100
 101         if(this.ItemStatus & ITS_ANIMATE2)
 102         {
 103                 if(!this.item_simple)
 104                 this.angles += this.avelocity * frametime;
 105             float fade_in = bound(0, time - this.onground_time, 1);
 106             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 107         }
 108     }
 109
 110     Item_SetAlpha(this);
 111 }
 112
 113 void Item_PreDraw(entity this)
 114 {
 115         if(warpzone_warpzones_exist)
 116         {
 117                 setpredraw(this, func_null); // no need to keep running this
 118                 return;
 119         }
 120         float alph;
 121         vector org = getpropertyvec(VF_ORIGIN);
 122         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 123                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 124         if(this.fade_start)
 125         {
 126                 if(vdist(org - this.origin, >, this.fade_end))
 127                         alph = 0; // save on some processing
 128                 else if(vdist(org - this.origin, <, this.fade_start))
 129                         alph = 1; // more processing saved
 130                 else
 131                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 132         }
 133         else
 134                 alph = 1;
 135         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 136         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 137                 this.alpha = alph;
 138         if(alph <= 0)
 139                 this.drawmask = 0;
 140         //else
 141                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 142 }
 143
 144 void ItemRemove(entity this)
 145 {
 146         strfree(this.mdl);
 147 }
 148
 149 HashMap ENT_CLIENT_ITEM_simple;
 150 STATIC_INIT(ENT_CLIENT_ITEM_simple)
 151 {
 152         HM_NEW(ENT_CLIENT_ITEM_simple);
 153 }
 154 SHUTDOWN(ENT_CLIENT_ITEM_simple)
 155 {
 156         HM_DELETE(ENT_CLIENT_ITEM_simple);
 157 }
 158
 159 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 160 {
 161     int sf = ReadByte();
 162
 163     if(sf & ISF_LOCATION)
 164     {
 165         this.origin = ReadVector();
 166         setorigin(this, this.origin);
 167         this.oldorigin = this.origin;
 168     }
 169
 170     if(sf & ISF_ANGLES)
 171     {
 172         this.angles_x = ReadAngle();
 173         this.angles_y = ReadAngle();
 174         this.angles_z = ReadAngle();
 175     }
 176
 177     if(sf & ISF_SIZE)
 178     {
 179         float use_bigsize = ReadByte();
 180         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 181     }
 182
 183     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 184     {
 185         this.ItemStatus = ReadByte();
 186
 187         Item_SetAlpha(this);
 188
 189         if(autocvar_cl_fullbright_items)
 190             if(this.ItemStatus & ITS_ALLOWFB)
 191                 this.effects |= EF_FULLBRIGHT;
 192
 193         if(this.ItemStatus & ITS_GLOW)
 194         {
 195             if(this.ItemStatus & ITS_AVAILABLE)
 196                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 197             else
 198                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 199         }
 200     }
 201
 202     if(sf & ISF_MODEL)
 203     {
 204         this.drawmask  = MASK_NORMAL;
 205                 set_movetype(this, MOVETYPE_TOSS);
 206                 if (isnew) IL_PUSH(g_drawables, this);
 207         this.draw       = ItemDraw;
 208         this.solid = SOLID_TRIGGER;
 209         //this.flags |= FL_ITEM;
 210
 211         bool use_bigsize = ReadByte();
 212
 213         this.fade_end = ReadShort();
 214         this.fade_start = ReadShort();
 215         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 216                 setpredraw(this, Item_PreDraw);
 217
 218                 strfree(this.mdl);
 219
 220         string _fn = ReadString();
 221         this.item_simple = false; // reset it!
 222
 223         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 224         {
 225             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 226             this.item_simple = true;
 227
 228                         #define extensions(x) \
 229                                 x(md3) \
 230                                 x(dpm) \
 231                                 x(iqm) \
 232                                 x(mdl) \
 233                                 /**/
 234                         #define tryext(ext) { \
 235                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
 236                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
 237                                 if (cached == "") { \
 238                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
 239                                 } \
 240                                 if (cached != "0") { \
 241                                         strcpy(this.mdl, s); \
 242                                         break; \
 243                                 } \
 244                         }
 245                         do {
 246                                 extensions(tryext);
 247                                 this.item_simple = false;
 248                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
 249                         } while (0);
 250                         #undef tryext
 251                         #undef extensions
 252         }
 253
 254         if(!this.item_simple)
 255             strcpy(this.mdl, _fn);
 256
 257         if(this.mdl == "")
 258             LOG_WARNF("this.mdl is unset for item %s", this.classname);
 259
 260         precache_model(this.mdl);
 261         _setmodel(this, this.mdl);
 262
 263         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 264     }
 265
 266     if(sf & ISF_COLORMAP)
 267     {
 268         this.colormap = ReadShort();
 269         this.item_glowmod_x = ReadByte() / 255.0;
 270         this.item_glowmod_y = ReadByte() / 255.0;
 271         this.item_glowmod_z = ReadByte() / 255.0;
 272     }
 273
 274     if(sf & ISF_DROP)
 275     {
 276         this.gravity = 1;
 277         this.pushable = true;
 278         //this.angles = '0 0 0';
 279         set_movetype(this, MOVETYPE_TOSS);
 280         this.velocity = ReadVector();
 281         setorigin(this, this.oldorigin);
 282
 283         if(!this.move_time)
 284         {
 285             this.move_time = time;
 286             this.spawntime = time;
 287         }
 288         else
 289             this.move_time = max(this.move_time, time);
 290     }
 291
 292     if(autocvar_cl_animate_items)
 293     {
 294         if(this.ItemStatus & ITS_ANIMATE1)
 295             this.avelocity = '0 180 0';
 296
 297         if(this.ItemStatus & ITS_ANIMATE2)
 298             this.avelocity = '0 -90 0';
 299     }
 300
 301     this.entremove = ItemRemove;
 302
 303     return true;
 304 }
 305
 306 #endif
 307
 308 #ifdef SVQC
 309 bool ItemSend(entity this, entity to, int sf)
 310 {
 311         if(this.gravity)
 312                 sf |= ISF_DROP;
 313         else
 314                 sf &= ~ISF_DROP;
 315
 316         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 317         WriteByte(MSG_ENTITY, sf);
 318
 319         //WriteByte(MSG_ENTITY, this.cnt);
 320         if(sf & ISF_LOCATION)
 321         {
 322                 WriteVector(MSG_ENTITY, this.origin);
 323         }
 324
 325         if(sf & ISF_ANGLES)
 326         {
 327                 WriteAngle(MSG_ENTITY, this.angles_x);
 328                 WriteAngle(MSG_ENTITY, this.angles_y);
 329                 WriteAngle(MSG_ENTITY, this.angles_z);
 330         }
 331
 332         if(sf & ISF_SIZE)
 333         {
 334                 Pickup p = this.itemdef;
 335                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 336         }
 337
 338         if(sf & ISF_STATUS)
 339                 WriteByte(MSG_ENTITY, this.ItemStatus);
 340
 341         if(sf & ISF_MODEL)
 342         {
 343                 Pickup p = this.itemdef;
 344                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 345                 WriteShort(MSG_ENTITY, this.fade_end);
 346                 WriteShort(MSG_ENTITY, this.fade_start);
 347
 348                 if(this.mdl == "")
 349                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 350
 351                 WriteString(MSG_ENTITY, this.mdl);
 352         }
 353
 354
 355         if(sf & ISF_COLORMAP)
 356         {
 357                 WriteShort(MSG_ENTITY, this.colormap);
 358                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 359         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 360         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 361         }
 362
 363         if(sf & ISF_DROP)
 364         {
 365                 WriteVector(MSG_ENTITY, this.velocity);
 366         }
 367
 368         return true;
 369 }
 370
 371 void ItemUpdate(entity this)
 372 {
 373         this.oldorigin = this.origin;
 374         this.SendFlags |= ISF_LOCATION;
 375 }
 376
 377 void UpdateItemAfterTeleport(entity this)
 378 {
 379         if(getSendEntity(this) == ItemSend)
 380                 ItemUpdate(this);
 381 }
 382
 383 bool have_pickup_item(entity this)
 384 {
 385         if(this.itemdef.instanceOfPowerup)
 386         {
 387                 if(autocvar_g_powerups > 0)
 388                         return true;
 389                 if(autocvar_g_powerups == 0)
 390                         return false;
 391         }
 392         else
 393         {
 394                 if(autocvar_g_pickup_items > 0)
 395                         return true;
 396                 if(autocvar_g_pickup_items == 0)
 397                         return false;
 398                 if(g_weaponarena)
 399                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 400                                 return false;
 401         }
 402         return true;
 403 }
 404
 405 void Item_Show (entity e, float mode)
 406 {
 407         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 408         e.ItemStatus &= ~ITS_STAYWEP;
 409         entity def = e.itemdef;
 410         if (mode > 0)
 411         {
 412                 // make the item look normal, and be touchable
 413                 e.model = e.mdl;
 414                 e.solid = SOLID_TRIGGER;
 415                 e.spawnshieldtime = 1;
 416                 e.ItemStatus |= ITS_AVAILABLE;
 417         }
 418         else if (mode < 0)
 419         {
 420                 // hide the item completely
 421                 e.model = string_null;
 422                 e.solid = SOLID_NOT;
 423                 e.spawnshieldtime = 1;
 424                 e.ItemStatus &= ~ITS_AVAILABLE;
 425         }
 426         else
 427         {
 428                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 429                         || e.team // weapon stay isn't supported for teamed weapons
 430                         ;
 431                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 432                 {
 433                         // make the item translucent and not touchable
 434                         e.model = e.mdl;
 435                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 436                         e.effects |= EF_STARDUST;
 437                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 438                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 439                 }
 440                 else
 441                 {
 442                         //setmodel(e, "null");
 443                         e.solid = SOLID_NOT;
 444                         e.colormod = '0 0 0';
 445                         //e.glowmod = e.colormod;
 446                         e.spawnshieldtime = 1;
 447                         e.ItemStatus &= ~ITS_AVAILABLE;
 448                 }
 449         }
 450
 451         if (def.m_glow)
 452                 e.ItemStatus |= ITS_GLOW;
 453
 454         if (autocvar_g_nodepthtestitems)
 455                 e.effects |= EF_NODEPTHTEST;
 456
 457
 458         if (autocvar_g_fullbrightitems)
 459                 e.ItemStatus |= ITS_ALLOWFB;
 460
 461         if (autocvar_sv_simple_items)
 462                 e.ItemStatus |= ITS_ALLOWSI;
 463
 464         // relink entity (because solid may have changed)
 465         setorigin(e, e.origin);
 466         e.SendFlags |= ISF_STATUS;
 467 }
 468
 469 void Item_Think(entity this)
 470 {
 471         this.nextthink = time;
 472         if(this.origin != this.oldorigin)
 473                 ItemUpdate(this);
 474 }
 475
 476 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 477 bool Item_ItemsTime_Allow(GameItem it);
 478 float Item_ItemsTime_UpdateTime(entity e, float t);
 479 void Item_ItemsTime_SetTime(entity e, float t);
 480 void Item_ItemsTime_SetTimesForAllPlayers();
 481
 482 void Item_Respawn (entity this)
 483 {
 484         Item_Show(this, 1);
 485         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 486         setorigin(this, this.origin);
 487
 488     if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
 489         {
 490                 float t = Item_ItemsTime_UpdateTime(this, 0);
 491                 Item_ItemsTime_SetTime(this, t);
 492                 Item_ItemsTime_SetTimesForAllPlayers();
 493         }
 494
 495         setthink(this, Item_Think);
 496         this.nextthink = time;
 497
 498         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 499         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 500 }
 501
 502 void Item_RespawnCountdown (entity this)
 503 {
 504         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 505         {
 506                 if(this.waypointsprite_attached)
 507                         WaypointSprite_Kill(this.waypointsprite_attached);
 508                 Item_Respawn(this);
 509         }
 510         else
 511         {
 512                 this.nextthink = time + 1;
 513                 this.item_respawncounter += 1;
 514                 if(this.item_respawncounter == 1)
 515                 {
 516                         do {
 517                                 {
 518                                         entity wi = Weapons_from(this.weapon);
 519                                         if (wi != WEP_Null) {
 520                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 521                                                 wp.wp_extra = wi.m_id;
 522                                                 break;
 523                                         }
 524                                 }
 525                                 {
 526                                         entity ii = this.itemdef;
 527                                         if (ii != NULL) {
 528                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 529                                                 wp.wp_extra = ii.m_id;
 530                                                 break;
 531                                         }
 532                                 }
 533                         } while (0);
 534                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 535             if(this.waypointsprite_attached)
 536             {
 537                 GameItem def = this.itemdef;
 538                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 539                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 540                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 541             }
 542                 }
 543
 544                 if(this.waypointsprite_attached)
 545                 {
 546                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 547                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 548                                 {
 549                                         msg_entity = it;
 550                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 551                                 }
 552                         });
 553
 554                         WaypointSprite_Ping(this.waypointsprite_attached);
 555                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 556                 }
 557         }
 558 }
 559
 560 void Item_RespawnThink(entity this)
 561 {
 562         this.nextthink = time;
 563         if(this.origin != this.oldorigin)
 564                 ItemUpdate(this);
 565
 566         if(time >= this.wait)
 567                 Item_Respawn(this);
 568 }
 569
 570 void Item_ScheduleRespawnIn(entity e, float t)
 571 {
 572         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 573         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 574         {
 575                 setthink(e, Item_RespawnCountdown);
 576                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 577                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 578                 e.item_respawncounter = 0;
 579                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 580                 {
 581                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 582                         Item_ItemsTime_SetTime(e, t);
 583                         Item_ItemsTime_SetTimesForAllPlayers();
 584                 }
 585         }
 586         else
 587         {
 588                 setthink(e, Item_RespawnThink);
 589                 e.nextthink = time;
 590                 e.scheduledrespawntime = time + t;
 591                 e.wait = time + t;
 592
 593                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 594                 {
 595                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 596                         Item_ItemsTime_SetTime(e, t);
 597                         Item_ItemsTime_SetTimesForAllPlayers();
 598                 }
 599         }
 600 }
 601
 602 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 603 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 604 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 605
 606 /// Adjust respawn time according to the number of players.
 607 float adjust_respawntime(float normal_respawntime) {
 608         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 609         float o = autocvar_g_pickup_respawntime_scaling_offset;
 610         float l = autocvar_g_pickup_respawntime_scaling_linear;
 611
 612         if (r == 0 && l == 1) {
 613                 return normal_respawntime;
 614         }
 615
 616         CheckAllowedTeams(NULL);
 617         GetTeamCounts(NULL);
 618         int players = 0;
 619         if (c1 != -1) players += c1;
 620         if (c2 != -1) players += c2;
 621         if (c3 != -1) players += c3;
 622         if (c4 != -1) players += c4;
 623
 624         if (players >= 2) {
 625                 return normal_respawntime * (r / (players + o) + l);
 626         } else {
 627                 return normal_respawntime;
 628         }
 629 }
 630
 631 void Item_ScheduleRespawn(entity e)
 632 {
 633         if(e.respawntime > 0)
 634         {
 635                 Item_Show(e, 0);
 636
 637                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 638                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 639
 640                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 641                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 642                 Item_ScheduleRespawnIn(e, respawn_in);
 643         }
 644         else // if respawntime is -1, this item does not respawn
 645                 Item_Show(e, -1);
 646 }
 647
 648 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 649         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 650
 651 void Item_ScheduleInitialRespawn(entity e)
 652 {
 653         Item_Show(e, 0);
 654
 655         float spawn_in;
 656         if (autocvar_g_pickup_respawntime_initial_random == 0)
 657         {
 658                 // range: respawntime .. respawntime + respawntimejitter
 659                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 660         }
 661         else
 662         {
 663                 float rnd;
 664                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 665                 {
 666                         static float shared_random = 0;
 667                         // NOTE this code works only if items are scheduled at the same time (normal case)
 668                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 669                         if (!shared_random || floor(time) > shared_random)
 670                                 shared_random = floor(time) + random();
 671                         rnd = shared_random - floor(time);
 672                 }
 673                 else
 674                         rnd = random();
 675
 676                 // range:
 677                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 678                 // else: 0 .. ITEM_RESPAWN_TICKS
 679                 // this is to prevent powerups spawning unexpectedly without waypoints
 680                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 681         }
 682
 683         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 684 }
 685
 686 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 687         entity ammo_entity)
 688 {
 689         if (num_weapons == 0)
 690         {
 691                 return;
 692         }
 693         int num_potential_weapons = tokenize_console(weapon_names);
 694         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 695         {
 696                 RandomSelection_Init();
 697                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 698                         ++weapon_index)
 699                 {
 700                         string weapon = argv(weapon_index);
 701                         FOREACH(Weapons, it != WEP_Null,
 702                         {
 703                                 // Finding a weapon which player doesn't have.
 704                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
 705                                 {
 706                                         RandomSelection_AddEnt(it, 1, 1);
 707                                         break;
 708                                 }
 709                         });
 710                 }
 711                 if (RandomSelection_chosen_ent == NULL)
 712                 {
 713                         return;
 714                 }
 715                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
 716                 if (RandomSelection_chosen_ent.ammo_type == RESOURCE_NONE)
 717                 {
 718                         continue;
 719                 }
 720                 if (GetResourceAmount(receiver,
 721                         RandomSelection_chosen_ent.ammo_type) != 0)
 722                 {
 723                         continue;
 724                 }
 725                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 726                         GetResourceAmount(ammo_entity,
 727                         RandomSelection_chosen_ent.ammo_type));
 728         }
 729 }
 730
 731 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
 732 {
 733         float amount = GetResourceAmount(item, resource_type);
 734         if (amount == 0)
 735         {
 736                 return false;
 737         }
 738         float player_amount = GetResourceAmount(player, resource_type);
 739         if (item.spawnshieldtime)
 740         {
 741                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 742                 {
 743                         return false;
 744                 }
 745                 GiveOrTakeResourceWithLimit(player, resource_type, amount, ammomax);
 746                 return true;
 747         }
 748         if (g_weapon_stay != 2)
 749         {
 750                 return false;
 751         }
 752         GiveOrTakeResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
 753         return true;
 754 }
 755
 756 float Item_GiveTo(entity item, entity player)
 757 {
 758         float pickedup;
 759
 760         // if nothing happens to player, just return without taking the item
 761         pickedup = false;
 762         int _switchweapon = 0;
 763         // in case the player has autoswitch enabled do the following:
 764         // if the player is using their best weapon before items are given, they
 765         // probably want to switch to an even better weapon after items are given
 766
 767         if(CS(player).autoswitch)
 768         {
 769                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 770                 {
 771                         .entity weaponentity = weaponentities[slot];
 772                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 773                         {
 774                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 775                                         _switchweapon |= BIT(slot);
 776
 777                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 778                                         _switchweapon |= BIT(slot);
 779                         }
 780                 }
 781         }
 782         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
 783         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
 784         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
 785         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
 786         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
 787         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
 788         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
 789         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
 790         if (item.itemdef.instanceOfWeaponPickup)
 791         {
 792                 WepSet w;
 793                 w = STAT(WEAPONS, item);
 794                 w &= ~STAT(WEAPONS, player);
 795
 796                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 797                 {
 798                         pickedup = true;
 799                         FOREACH(Weapons, it != WEP_Null, {
 800                                 if(w & (it.m_wepset))
 801                                 {
 802                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 803                                         {
 804                                                 .entity weaponentity = weaponentities[slot];
 805                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 806                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 807                                         }
 808                                         W_GiveWeapon(player, it.m_id);
 809                                 }
 810                         });
 811                 }
 812         }
 813
 814         if (item.itemdef.instanceOfPowerup)
 815         {
 816                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 817                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 818                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 819                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 820         }
 821
 822         int its;
 823         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 824         {
 825                 pickedup = true;
 826                 player.items |= its;
 827                 // TODO: we probably want to show a message in the console, but not this one!
 828                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 829         }
 830
 831         if (item.strength_finished)
 832         {
 833                 pickedup = true;
 834                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 835         }
 836         if (item.invincible_finished)
 837         {
 838                 pickedup = true;
 839                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 840         }
 841         if (item.superweapons_finished)
 842         {
 843                 pickedup = true;
 844                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 845         }
 846
 847         // always eat teamed entities
 848         if(item.team)
 849                 pickedup = true;
 850
 851         if (!pickedup)
 852                 return 0;
 853
 854         // crude hack to enforce switching weapons
 855         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 856         {
 857                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 858                 {
 859                         .entity weaponentity = weaponentities[slot];
 860                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 861                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 862                 }
 863                 return 1;
 864         }
 865
 866         if(_switchweapon)
 867         {
 868                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 869                 {
 870                         .entity weaponentity = weaponentities[slot];
 871                         if(_switchweapon & BIT(slot))
 872                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 873                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 874                 }
 875         }
 876
 877         return 1;
 878 }
 879
 880 void Item_Touch(entity this, entity toucher)
 881 {
 882         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 883         if (Item_IsLoot(this))
 884         {
 885                 if (ITEM_TOUCH_NEEDKILL())
 886                 {
 887                         delete(this);
 888                         return;
 889                 }
 890         }
 891
 892         if(!(toucher.flags & FL_PICKUPITEMS)
 893         || STAT(FROZEN, toucher)
 894         || IS_DEAD(toucher)
 895         || (this.solid != SOLID_TRIGGER)
 896         || (this.owner == toucher)
 897         || (time < this.item_spawnshieldtime)
 898         ) { return; }
 899
 900         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 901         {
 902                 case MUT_ITEMTOUCH_RETURN: { return; }
 903                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 904         }
 905
 906         toucher = M_ARGV(1, entity);
 907
 908         if (Item_IsExpiring(this))
 909         {
 910                 this.strength_finished = max(0, this.strength_finished - time);
 911                 this.invincible_finished = max(0, this.invincible_finished - time);
 912                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 913         }
 914         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 915         if (!gave)
 916         {
 917                 if (Item_IsExpiring(this))
 918                 {
 919                         // undo what we did above
 920                         this.strength_finished += time;
 921                         this.invincible_finished += time;
 922                         this.superweapons_finished += time;
 923                 }
 924                 return;
 925         }
 926
 927 LABEL(pickup)
 928
 929         STAT(LAST_PICKUP, toucher) = time;
 930
 931         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 932         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 933
 934         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 935         if (wasfreed(this))
 936         {
 937                 return;
 938         }
 939
 940         if (Item_IsLoot(this))
 941         {
 942                 delete(this);
 943                 return;
 944         }
 945         if (!this.spawnshieldtime)
 946         {
 947                 return;
 948         }
 949         entity e;
 950         if (this.team)
 951         {
 952                 RandomSelection_Init();
 953                 IL_EACH(g_items, it.team == this.team,
 954                 {
 955                         if (it.itemdef) // is a registered item
 956                         {
 957                                 Item_Show(it, -1);
 958                                 it.scheduledrespawntime = 0;
 959                                 RandomSelection_AddEnt(it, it.cnt, 0);
 960                         }
 961                 });
 962                 e = RandomSelection_chosen_ent;
 963                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 964         }
 965         else
 966                 e = this;
 967         Item_ScheduleRespawn(e);
 968 }
 969
 970 void Item_Reset(entity this)
 971 {
 972         Item_Show(this, !this.state);
 973         setorigin(this, this.origin);
 974
 975         if (Item_IsLoot(this))
 976         {
 977                 return;
 978         }
 979         setthink(this, Item_Think);
 980         this.nextthink = time;
 981         if (this.waypointsprite_attached)
 982         {
 983                 WaypointSprite_Kill(this.waypointsprite_attached);
 984         }
 985         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 986         {
 987                 Item_ScheduleInitialRespawn(this);
 988         }
 989 }
 990
 991 void Item_FindTeam(entity this)
 992 {
 993         entity e;
 994
 995         if(this.effects & EF_NODRAW)
 996         {
 997                 // marker for item team search
 998                 LOG_TRACE("Initializing item team ", ftos(this.team));
 999                 RandomSelection_Init();
1000                 IL_EACH(g_items, it.team == this.team,
1001                 {
1002                         if(it.itemdef) // is a registered item
1003                                 RandomSelection_AddEnt(it, it.cnt, 0);
1004                 });
1005
1006                 e = RandomSelection_chosen_ent;
1007                 e.state = 0;
1008                 Item_Show(e, 1);
1009
1010                 IL_EACH(g_items, it.team == this.team,
1011                 {
1012                         if(it.itemdef) // is a registered item
1013                         {
1014                                 if(it != e)
1015                                 {
1016                                         // make it non-spawned
1017                                         Item_Show(it, -1);
1018                                         it.state = 1; // state 1 = initially hidden item, apparently
1019                                 }
1020                                 it.effects &= ~EF_NODRAW;
1021                         }
1022                 });
1023
1024                 Item_Reset(this);
1025         }
1026 }
1027
1028 // Savage: used for item garbage-collection
1029 void RemoveItem(entity this)
1030 {
1031         if(wasfreed(this) || !this) { return; }
1032         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1033         delete(this);
1034 }
1035
1036 // pickup evaluation functions
1037 // these functions decide how desirable an item is to the bots
1038
1039 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1040
1041 float weapon_pickupevalfunc(entity player, entity item)
1042 {
1043         // See if I have it already
1044         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
1045         {
1046                 // If I can pick it up
1047                 if(!item.spawnshieldtime)
1048                         return 0;
1049                 return ammo_pickupevalfunc(player, item);
1050         }
1051
1052         // reduce weapon value if bot already got a good arsenal
1053         float c = 1;
1054         int weapons_value = 0;
1055         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
1056                 weapons_value += it.bot_pickupbasevalue;
1057         });
1058         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1059
1060         return item.bot_pickupbasevalue * c;
1061 }
1062
1063 float ammo_pickupevalfunc(entity player, entity item)
1064 {
1065         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1066         entity wpn = NULL;
1067         float c = 0;
1068         float rating = 0;
1069
1070         // Detect needed ammo
1071         if(item.itemdef.instanceOfWeaponPickup)
1072         {
1073                 entity ammo = NULL;
1074                 if(GetResourceAmount(item, RESOURCE_SHELLS))       { need_shells  = true; ammo = ITEM_Shells;      }
1075                 else if(GetResourceAmount(item, RESOURCE_BULLETS))   { need_nails   = true; ammo = ITEM_Bullets;     }
1076                 else if(GetResourceAmount(item, RESOURCE_ROCKETS)) { need_rockets = true; ammo = ITEM_Rockets;     }
1077                 else if(GetResourceAmount(item, RESOURCE_CELLS))   { need_cells   = true; ammo = ITEM_Cells;       }
1078                 else if(GetResourceAmount(item, RESOURCE_PLASMA))  { need_plasma  = true; ammo = ITEM_Plasma;      }
1079                 else if(GetResourceAmount(item, RESOURCE_FUEL))    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1080
1081                 if(!ammo)
1082                         return 0;
1083                 wpn = item;
1084                 rating = ammo.m_botvalue;
1085         }
1086         else
1087         {
1088                 FOREACH(Weapons, it != WEP_Null, {
1089                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
1090                                 continue;
1091
1092                         switch(it.ammo_type)
1093                         {
1094                                 case RESOURCE_SHELLS:  need_shells  = true; break;
1095                                 case RESOURCE_BULLETS: need_nails   = true; break;
1096                                 case RESOURCE_ROCKETS: need_rockets = true; break;
1097                                 case RESOURCE_CELLS:   need_cells   = true; break;
1098                                 case RESOURCE_PLASMA:  need_plasma  = true; break;
1099                                 case RESOURCE_FUEL:    need_fuel    = true; break;
1100                         }
1101                 });
1102                 rating = item.bot_pickupbasevalue;
1103         }
1104
1105         float noammorating = 0.5;
1106
1107         if ((need_shells) && GetResourceAmount(item, RESOURCE_SHELLS) && (GetResourceAmount(player, RESOURCE_SHELLS) < g_pickup_shells_max))
1108                 c = GetResourceAmount(item, RESOURCE_SHELLS) / max(noammorating, GetResourceAmount(player, RESOURCE_SHELLS));
1109
1110         if ((need_nails) && GetResourceAmount(item, RESOURCE_BULLETS) && (GetResourceAmount(player, RESOURCE_BULLETS) < g_pickup_nails_max))
1111                 c = GetResourceAmount(item, RESOURCE_BULLETS) / max(noammorating, GetResourceAmount(player, RESOURCE_BULLETS));
1112
1113         if ((need_rockets) && GetResourceAmount(item, RESOURCE_ROCKETS) && (GetResourceAmount(player, RESOURCE_ROCKETS) < g_pickup_rockets_max))
1114                 c = GetResourceAmount(item, RESOURCE_ROCKETS) / max(noammorating, GetResourceAmount(player, RESOURCE_ROCKETS));
1115
1116         if ((need_cells) && GetResourceAmount(item, RESOURCE_CELLS) && (GetResourceAmount(player, RESOURCE_CELLS) < g_pickup_cells_max))
1117                 c = GetResourceAmount(item, RESOURCE_CELLS) / max(noammorating, GetResourceAmount(player, RESOURCE_CELLS));
1118
1119         if ((need_plasma) && GetResourceAmount(item, RESOURCE_PLASMA) && (GetResourceAmount(player, RESOURCE_PLASMA) < g_pickup_plasma_max))
1120                 c = GetResourceAmount(item, RESOURCE_PLASMA) / max(noammorating, GetResourceAmount(player, RESOURCE_PLASMA));
1121
1122         if ((need_fuel) && GetResourceAmount(item, RESOURCE_FUEL) && (GetResourceAmount(player, RESOURCE_FUEL) < g_pickup_fuel_max))
1123                 c = GetResourceAmount(item, RESOURCE_FUEL) / max(noammorating, GetResourceAmount(player, RESOURCE_FUEL));
1124
1125         rating *= min(c, 2);
1126         if(wpn)
1127                 rating += wpn.bot_pickupbasevalue * 0.1;
1128         return rating;
1129 }
1130
1131 float healtharmor_pickupevalfunc(entity player, entity item)
1132 {
1133         float c = 0;
1134         float rating = item.bot_pickupbasevalue;
1135
1136         float itemarmor = GetResourceAmount(item, RESOURCE_ARMOR);
1137         float itemhealth = GetResourceAmount(item, RESOURCE_HEALTH);
1138
1139         if(item.item_group)
1140         {
1141                 itemarmor *= min(4, item.item_group_count);
1142                 itemhealth *= min(4, item.item_group_count);
1143         }
1144
1145         if (itemarmor && (GetResourceAmount(player, RESOURCE_ARMOR) < item.max_armorvalue))
1146                 c = itemarmor / max(1, GetResourceAmount(player, RESOURCE_ARMOR) * 2/3 + GetResourceAmount(player, RESOURCE_HEALTH) * 1/3);
1147
1148         if (itemhealth && (GetResourceAmount(player, RESOURCE_HEALTH) < item.max_health))
1149                 c = itemhealth / max(1, GetResourceAmount(player, RESOURCE_HEALTH));
1150
1151         rating *= min(2, c);
1152         return rating;
1153 }
1154
1155 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1156 {
1157         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1158                 RemoveItem(this);
1159 }
1160
1161 void item_use(entity this, entity actor, entity trigger)
1162 {
1163         // use the touch function to handle collection
1164         gettouch(this)(this, actor);
1165 }
1166
1167 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1168 {
1169         string itemname = def.m_name;
1170         Model itemmodel = def.m_model;
1171     Sound pickupsound = def.m_sound;
1172         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1173         float pickupbasevalue = def.m_botvalue;
1174         int itemflags = def.m_itemflags;
1175
1176         startitem_failed = false;
1177
1178         this.item_model_ent = itemmodel;
1179     this.item_pickupsound_ent = pickupsound;
1180
1181     if(def.m_iteminit)
1182         def.m_iteminit(def, this);
1183
1184         if(!this.respawntime) // both need to be set
1185         {
1186                 this.respawntime = defaultrespawntime;
1187                 this.respawntimejitter = defaultrespawntimejitter;
1188         }
1189
1190         if(!this.pickup_anyway && def.m_pickupanyway)
1191                 this.pickup_anyway = def.m_pickupanyway();
1192
1193         int itemid = def.m_itemid;
1194         this.items = itemid;
1195         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1196         this.weapon = weaponid;
1197
1198         if(!this.fade_end)
1199         {
1200                 this.fade_start = autocvar_g_items_mindist;
1201                 this.fade_end = autocvar_g_items_maxdist;
1202         }
1203
1204         if(weaponid)
1205                 STAT(WEAPONS, this) = WepSet_FromWeapon(Weapons_from(weaponid));
1206
1207         this.flags = FL_ITEM | itemflags;
1208         IL_PUSH(g_items, this);
1209
1210         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1211         {
1212                 startitem_failed = true;
1213                 delete(this);
1214                 return;
1215         }
1216
1217         if (Item_IsLoot(this))
1218         {
1219                 this.reset = SUB_Remove;
1220                 set_movetype(this, MOVETYPE_TOSS);
1221
1222                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1223                 setthink(this, RemoveItem);
1224                 this.nextthink = time + 20;
1225
1226                 this.takedamage = DAMAGE_YES;
1227                 this.event_damage = Item_Damage;
1228
1229                 if (Item_IsExpiring(this))
1230                 {
1231                         // if item is worthless after a timer, have it expire then
1232                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1233                 }
1234
1235                 // don't drop if in a NODROP zone (such as lava)
1236                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1237                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1238                 {
1239                         startitem_failed = true;
1240                         delete(this);
1241                         return;
1242                 }
1243         }
1244         else
1245         {
1246                 if(!have_pickup_item(this))
1247                 {
1248                         startitem_failed = true;
1249                         delete(this);
1250                         return;
1251                 }
1252
1253                 if(this.angles != '0 0 0')
1254                         this.SendFlags |= ISF_ANGLES;
1255
1256                 this.reset = Item_Reset;
1257                 // it's a level item
1258                 if(this.spawnflags & 1)
1259                         this.noalign = 1;
1260                 if (this.noalign > 0)
1261                         set_movetype(this, MOVETYPE_NONE);
1262                 else
1263                         set_movetype(this, MOVETYPE_TOSS);
1264                 // do item filtering according to game mode and other things
1265                 if (this.noalign <= 0)
1266                 {
1267                         // first nudge it off the floor a little bit to avoid math errors
1268                         setorigin(this, this.origin + '0 0 1');
1269                         // set item size before we spawn a spawnfunc_waypoint
1270                         setsize(this, def.m_mins, def.m_maxs);
1271                         this.SendFlags |= ISF_SIZE;
1272                         // note droptofloor returns false if stuck/or would fall too far
1273                         if (!this.noalign)
1274                                 droptofloor(this);
1275                         waypoint_spawnforitem(this);
1276                 }
1277
1278                 /*
1279                  * can't do it that way, as it would break maps
1280                  * TODO make a target_give like entity another way, that perhaps has
1281                  * the weapon name in a key
1282                 if(this.targetname)
1283                 {
1284                         // target_give not yet supported; maybe later
1285                         print("removed targeted ", this.classname, "\n");
1286                         startitem_failed = true;
1287                         delete(this);
1288                         return;
1289                 }
1290                 */
1291
1292                 if(this.targetname != "" && (this.spawnflags & 16))
1293                         this.use = item_use;
1294
1295                 if(autocvar_spawn_debug >= 2)
1296                 {
1297             // why not flags & fl_item?
1298                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1299                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1300                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1301                 error("Mapper sucks.");
1302             });
1303                         this.is_item = true;
1304                 }
1305
1306                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1307
1308                 precache_model(this.model);
1309                 precache_sound(this.item_pickupsound);
1310
1311                 if (   def.instanceOfPowerup
1312                         || def.instanceOfWeaponPickup
1313                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1314                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1315                         || (itemid & (IT_KEY1 | IT_KEY2))
1316                 ) this.target = "###item###"; // for finding the nearest item using find()
1317
1318                 Item_ItemsTime_SetTime(this, 0);
1319         }
1320
1321         this.bot_pickup = true;
1322         this.bot_pickupevalfunc = pickupevalfunc;
1323         this.bot_pickupbasevalue = pickupbasevalue;
1324         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1325         this.netname = itemname;
1326         settouch(this, Item_Touch);
1327         setmodel(this, MDL_Null); // precision set below
1328         //this.effects |= EF_LOWPRECISION;
1329
1330         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1331
1332         this.SendFlags |= ISF_SIZE;
1333
1334         if (!(this.spawnflags & 1024)) {
1335                 if(def.instanceOfPowerup)
1336                         this.ItemStatus |= ITS_ANIMATE1;
1337
1338                 if(GetResourceAmount(this, RESOURCE_ARMOR) || GetResourceAmount(this, RESOURCE_HEALTH))
1339                         this.ItemStatus |= ITS_ANIMATE2;
1340         }
1341
1342         if(def.instanceOfWeaponPickup)
1343         {
1344                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1345                         this.colormap = 1024; // color shirt=0 pants=0 grey
1346                 else
1347                         this.gravity = 1;
1348                 if (!(this.spawnflags & 1024))
1349                         this.ItemStatus |= ITS_ANIMATE1;
1350                 this.SendFlags |= ISF_COLORMAP;
1351         }
1352
1353         this.state = 0;
1354         if(this.team) // broken, no idea why.
1355         {
1356                 if(!this.cnt)
1357                         this.cnt = 1; // item probability weight
1358
1359                 this.effects |= EF_NODRAW; // marker for item team search
1360                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1361         }
1362         else
1363                 Item_Reset(this);
1364
1365         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1366
1367         // call this hook after everything else has been done
1368         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1369         {
1370                 startitem_failed = true;
1371                 delete(this);
1372                 return;
1373         }
1374
1375         setItemGroup(this);
1376 }
1377
1378 void StartItem(entity this, GameItem def)
1379 {
1380     def = def.m_spawnfunc_hookreplace(def, this);
1381     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1382     {
1383         delete(this);
1384         return;
1385     }
1386     this.classname = def.m_canonical_spawnfunc;
1387     _StartItem(
1388         this,
1389         this.itemdef = def,
1390         def.m_respawntime(), // defaultrespawntime
1391         def.m_respawntimejitter() // defaultrespawntimejitter
1392         );
1393 }
1394
1395 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1396 int group_count = 1;
1397
1398 void setItemGroup(entity this)
1399 {
1400         if(!IS_SMALL(this.itemdef))
1401                 return;
1402
1403         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1404         {
1405                 if(!this.item_group)
1406                 {
1407                         if(!it.item_group)
1408                         {
1409                                 it.item_group = group_count;
1410                                 group_count++;
1411                         }
1412                         this.item_group = it.item_group;
1413                 }
1414                 else // spawning item is already part of a item_group X
1415                 {
1416                         if(!it.item_group)
1417                                 it.item_group = this.item_group;
1418                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1419                         {
1420                                 int grY = it.item_group;
1421                                 // move all items of item_group Y to item_group X
1422                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1423                                 {
1424                                         if(it.item_group == grY)
1425                                                 it.item_group = this.item_group;
1426                                 });
1427                         }
1428                 }
1429         });
1430 }
1431
1432 void setItemGroupCount()
1433 {
1434         for (int k = 1; k <= group_count; k++)
1435         {
1436                 int count = 0;
1437                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1438                 if (count)
1439                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1440         }
1441 }
1442
1443 void target_items_use(entity this, entity actor, entity trigger)
1444 {
1445         if(Item_IsLoot(actor))
1446         {
1447                 EXACTTRIGGER_TOUCH(this, trigger);
1448                 delete(actor);
1449                 return;
1450         }
1451
1452         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1453                 return;
1454
1455         if(trigger.solid == SOLID_TRIGGER)
1456         {
1457                 EXACTTRIGGER_TOUCH(this, trigger);
1458         }
1459
1460         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1461         {
1462                 delete(it);
1463         });
1464
1465         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1466                 centerprint(actor, this.message);
1467 }
1468
1469 spawnfunc(target_items)
1470 {
1471         int n;
1472         string s;
1473
1474         this.use = target_items_use;
1475         if(!this.strength_finished)
1476                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1477         if(!this.invincible_finished)
1478                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1479         if(!this.superweapons_finished)
1480                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1481
1482         n = tokenize_console(this.netname);
1483         if(argv(0) == "give")
1484         {
1485                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1486         }
1487         else
1488         {
1489                 for(int j = 0; j < n; ++j)
1490                 {
1491                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1492                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1493                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1494                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1495                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1496                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1497                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1498                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1499                         else
1500                         {
1501                                 FOREACH(Buffs, it != BUFF_Null,
1502                                 {
1503                                         s = Buff_UndeprecateName(argv(j));
1504                                         if(s == it.m_name)
1505                                         {
1506                                                 STAT(BUFFS, this) |= (it.m_itemid);
1507                                                 break;
1508                                         }
1509                                 });
1510                                 FOREACH(Weapons, it != WEP_Null, {
1511                                         s = W_UndeprecateName(argv(j));
1512                                         if(s == it.netname)
1513                                         {
1514                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1515                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1516                                                         it.wr_init(it);
1517                                                 break;
1518                                         }
1519                                 });
1520                         }
1521                 }
1522
1523                 string itemprefix, valueprefix;
1524                 if(this.spawnflags == 0)
1525                 {
1526                         itemprefix = "";
1527                         valueprefix = "";
1528                 }
1529                 else if(this.spawnflags == 1)
1530                 {
1531                         itemprefix = "max ";
1532                         valueprefix = "max ";
1533                 }
1534                 else if(this.spawnflags == 2)
1535                 {
1536                         itemprefix = "min ";
1537                         valueprefix = "min ";
1538                 }
1539                 else if(this.spawnflags == 4)
1540                 {
1541                         itemprefix = "minus ";
1542                         valueprefix = "max ";
1543                 }
1544                 else
1545                 {
1546                         error("invalid spawnflags");
1547                         itemprefix = valueprefix = string_null;
1548                 }
1549
1550                 this.netname = "";
1551                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1552                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1553                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1554                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1555                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1556                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1557                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1558                 if(GetResourceAmount(this, RESOURCE_SHELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_SHELLS)), "shells");
1559                 if(GetResourceAmount(this, RESOURCE_BULLETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_BULLETS)), "nails");
1560                 if(GetResourceAmount(this, RESOURCE_ROCKETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_ROCKETS)), "rockets");
1561                 if(GetResourceAmount(this, RESOURCE_CELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_CELLS)), "cells");
1562                 if(GetResourceAmount(this, RESOURCE_PLASMA) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_PLASMA)), "plasma");
1563                 if(GetResourceAmount(this, RESOURCE_FUEL) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_FUEL)), "fuel");
1564                 if(GetResourceAmount(this, RESOURCE_HEALTH) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_HEALTH)), "health");
1565                 if(GetResourceAmount(this, RESOURCE_ARMOR) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResourceAmount(this, RESOURCE_ARMOR)), "armor");
1566                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(BUFFS, this) & (it.m_itemid)), it.m_name));
1567                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1568         }
1569         this.netname = strzone(this.netname);
1570         //print(this.netname, "\n");
1571
1572         n = tokenize_console(this.netname);
1573         for(int j = 0; j < n; ++j)
1574         {
1575                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1576             it.wr_init(it);
1577             break;
1578                 });
1579         }
1580 }
1581
1582 float GiveWeapon(entity e, float wpn, float op, float val)
1583 {
1584         WepSet v0, v1;
1585         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1586         v0 = (STAT(WEAPONS, e) & s);
1587         switch(op)
1588         {
1589                 case OP_SET:
1590                         if(val > 0)
1591                                 STAT(WEAPONS, e) |= s;
1592                         else
1593                                 STAT(WEAPONS, e) &= ~s;
1594                         break;
1595                 case OP_MIN:
1596                 case OP_PLUS:
1597                         if(val > 0)
1598                                 STAT(WEAPONS, e) |= s;
1599                         break;
1600                 case OP_MAX:
1601                         if(val <= 0)
1602                                 STAT(WEAPONS, e) &= ~s;
1603                         break;
1604                 case OP_MINUS:
1605                         if(val > 0)
1606                                 STAT(WEAPONS, e) &= ~s;
1607                         break;
1608         }
1609         v1 = (STAT(WEAPONS, e) & s);
1610         return (v0 != v1);
1611 }
1612
1613 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1614 {
1615         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1616         switch(op)
1617         {
1618                 case OP_SET:
1619                         if(val > 0)
1620                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1621                         else
1622                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1623                         break;
1624                 case OP_MIN:
1625                 case OP_PLUS:
1626                         if(val > 0)
1627                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1628                         break;
1629                 case OP_MAX:
1630                         if(val <= 0)
1631                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1632                         break;
1633                 case OP_MINUS:
1634                         if(val > 0)
1635                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1636                         break;
1637         }
1638         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1639         return (had_buff != have_buff);
1640 }
1641
1642 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1643 {
1644         if(v1 == v0)
1645                 return;
1646         if(v1 <= v0 - t)
1647         {
1648                 if(snd_decr != NULL)
1649                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1650         }
1651         else if(v0 >= v0 + t)
1652         {
1653                 if(snd_incr != NULL)
1654                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1655         }
1656 }
1657
1658 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1659 {
1660         if(v0 < v1)
1661                 e.(rotfield) = max(e.(rotfield), time + rottime);
1662         else if(v0 > v1)
1663                 e.(regenfield) = max(e.(regenfield), time + regentime);
1664 }
1665 bool GiveResourceValue(entity e, int resource_type, int op, int val)
1666 {
1667         int v0 = GetResourceAmount(e, resource_type);
1668         switch (op)
1669         {
1670                 case OP_SET:
1671                         SetResourceAmount(e, resource_type, val);
1672                         break;
1673                 case OP_MIN:
1674                         SetResourceAmount(e, resource_type, max(v0, val)); // min 100 cells = at least 100 cells
1675                         break;
1676                 case OP_MAX:
1677                         SetResourceAmount(e, resource_type, min(v0, val));
1678                         break;
1679                 case OP_PLUS:
1680                         SetResourceAmount(e, resource_type, v0 + val);
1681                         break;
1682                 case OP_MINUS:
1683                         SetResourceAmount(e, resource_type, v0 - val);
1684                         break;
1685         }
1686         int v1 = GetResourceAmount(e, resource_type);
1687         return v0 != v1;
1688 }
1689
1690 float GiveItems(entity e, float beginarg, float endarg)
1691 {
1692         float got, i, val, op;
1693         string cmd;
1694
1695         val = 999;
1696         op = OP_SET;
1697
1698         got = 0;
1699
1700         int _switchweapon = 0;
1701
1702         if(CS(e).autoswitch)
1703         {
1704                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1705                 {
1706                         .entity weaponentity = weaponentities[slot];
1707                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1708                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1709                                 _switchweapon |= BIT(slot);
1710                 }
1711         }
1712
1713         e.strength_finished = max(0, e.strength_finished - time);
1714         e.invincible_finished = max(0, e.invincible_finished - time);
1715         e.superweapons_finished = max(0, e.superweapons_finished - time);
1716
1717         PREGIVE(e, items);
1718         PREGIVE_WEAPONS(e);
1719         PREGIVE(e, strength_finished);
1720         PREGIVE(e, invincible_finished);
1721         PREGIVE(e, superweapons_finished);
1722         PREGIVE_RESOURCE(e, RESOURCE_BULLETS);
1723         PREGIVE_RESOURCE(e, RESOURCE_CELLS);
1724         PREGIVE_RESOURCE(e, RESOURCE_PLASMA);
1725         PREGIVE_RESOURCE(e, RESOURCE_SHELLS);
1726         PREGIVE_RESOURCE(e, RESOURCE_ROCKETS);
1727         PREGIVE_RESOURCE(e, RESOURCE_FUEL);
1728         PREGIVE_RESOURCE(e, RESOURCE_ARMOR);
1729         PREGIVE_RESOURCE(e, RESOURCE_HEALTH);
1730
1731         for(i = beginarg; i < endarg; ++i)
1732         {
1733                 cmd = argv(i);
1734
1735                 if(cmd == "0" || stof(cmd))
1736                 {
1737                         val = stof(cmd);
1738                         continue;
1739                 }
1740                 switch(cmd)
1741                 {
1742                         case "no":
1743                                 op = OP_MAX;
1744                                 val = 0;
1745                                 continue;
1746                         case "max":
1747                                 op = OP_MAX;
1748                                 continue;
1749                         case "min":
1750                                 op = OP_MIN;
1751                                 continue;
1752                         case "plus":
1753                                 op = OP_PLUS;
1754                                 continue;
1755                         case "minus":
1756                                 op = OP_MINUS;
1757                                 continue;
1758                         case "ALL":
1759                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1760                                 got += GiveValue(e, strength_finished, op, val);
1761                                 got += GiveValue(e, invincible_finished, op, val);
1762                                 got += GiveValue(e, superweapons_finished, op, val);
1763                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1764                         case "all":
1765                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1766                                 got += GiveResourceValue(e, RESOURCE_HEALTH, op, val);
1767                                 got += GiveResourceValue(e, RESOURCE_ARMOR, op, val);
1768                         case "allweapons":
1769                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1770                         //case "allbuffs": // all buffs makes a player god, do not want!
1771                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1772                         case "allammo":
1773                                 got += GiveResourceValue(e, RESOURCE_CELLS, op, val);
1774                                 got += GiveResourceValue(e, RESOURCE_PLASMA, op, val);
1775                                 got += GiveResourceValue(e, RESOURCE_SHELLS, op, val);
1776                                 got += GiveResourceValue(e, RESOURCE_BULLETS, op, val);
1777                                 got += GiveResourceValue(e, RESOURCE_ROCKETS, op, val);
1778                                 got += GiveResourceValue(e, RESOURCE_FUEL, op, val);
1779                                 break;
1780                         case "unlimited_ammo":
1781                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1782                                 break;
1783                         case "unlimited_weapon_ammo":
1784                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1785                                 break;
1786                         case "unlimited_superweapons":
1787                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1788                                 break;
1789                         case "jetpack":
1790                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1791                                 break;
1792                         case "fuel_regen":
1793                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1794                                 break;
1795                         case "strength":
1796                                 got += GiveValue(e, strength_finished, op, val);
1797                                 break;
1798                         case "invincible":
1799                                 got += GiveValue(e, invincible_finished, op, val);
1800                                 break;
1801                         case "superweapons":
1802                                 got += GiveValue(e, superweapons_finished, op, val);
1803                                 break;
1804                         case "cells":
1805                                 got += GiveResourceValue(e, RESOURCE_CELLS, op, val);
1806                                 break;
1807                         case "plasma":
1808                                 got += GiveResourceValue(e, RESOURCE_PLASMA, op, val);
1809                                 break;
1810                         case "shells":
1811                                 got += GiveResourceValue(e, RESOURCE_SHELLS, op, val);
1812                                 break;
1813                         case "nails":
1814                         case "bullets":
1815                                 got += GiveResourceValue(e, RESOURCE_BULLETS, op, val);
1816                                 break;
1817                         case "rockets":
1818                                 got += GiveResourceValue(e, RESOURCE_ROCKETS, op, val);
1819                                 break;
1820                         case "health":
1821                                 got += GiveResourceValue(e, RESOURCE_HEALTH, op, val);
1822                                 break;
1823                         case "armor":
1824                                 got += GiveResourceValue(e, RESOURCE_ARMOR, op, val);
1825                                 break;
1826                         case "fuel":
1827                                 got += GiveResourceValue(e, RESOURCE_FUEL, op, val);
1828                                 break;
1829                         default:
1830                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1831                                 {
1832                                         got += GiveBuff(e, it, op, val);
1833                                         break;
1834                                 });
1835                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1836                     got += GiveWeapon(e, it.m_id, op, val);
1837                     break;
1838                                 });
1839                                 break;
1840                 }
1841                 val = 999;
1842                 op = OP_SET;
1843         }
1844
1845         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1846         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1847         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1848         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1849         FOREACH(Weapons, it != WEP_Null, {
1850                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1851                 if(!(save_weapons & (it.m_wepset)))
1852                         if(STAT(WEAPONS, e) & (it.m_wepset))
1853                                 it.wr_init(it);
1854         });
1855         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1856         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1857         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1858         POSTGIVE_RESOURCE(e, RESOURCE_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1859         POSTGIVE_RESOURCE(e, RESOURCE_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1860         POSTGIVE_RESOURCE(e, RESOURCE_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1861         POSTGIVE_RESOURCE(e, RESOURCE_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1862         POSTGIVE_RESOURCE(e, RESOURCE_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1863         POSTGIVE_RESOURCE_ROT(e, RESOURCE_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1864         POSTGIVE_RESOURCE_ROT(e, RESOURCE_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1865         POSTGIVE_RESOURCE_ROT(e, RESOURCE_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1866
1867         if(e.superweapons_finished <= 0)
1868                 if(STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS)
1869                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1870
1871         if(e.strength_finished <= 0)
1872                 e.strength_finished = 0;
1873         else
1874                 e.strength_finished += time;
1875         if(e.invincible_finished <= 0)
1876                 e.invincible_finished = 0;
1877         else
1878                 e.invincible_finished += time;
1879         if(e.superweapons_finished <= 0)
1880                 e.superweapons_finished = 0;
1881         else
1882                 e.superweapons_finished += time;
1883
1884         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1885         {
1886                 .entity weaponentity = weaponentities[slot];
1887                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1888                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1889                         _switchweapon |= BIT(slot);
1890         }
1891
1892         if(_switchweapon)
1893         {
1894                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1895                 {
1896                         .entity weaponentity = weaponentities[slot];
1897                         if(_switchweapon & BIT(slot))
1898                         {
1899                                 Weapon wep = w_getbestweapon(e, weaponentity);
1900                                 if(wep != e.(weaponentity).m_switchweapon)
1901                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1902                         }
1903                 }
1904         }
1905
1906         return got;
1907 }
1908 #endif