qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/all.qc"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/bot.qh"
   8     #include "../server/bot/waypoints.qh"
   9
  10     #include <server/mutators/all.qh>
  11
  12     #include "../server/weapons/common.qh"
  13     #include "../server/weapons/selection.qh"
  14     #include "../server/weapons/weaponsystem.qh"
  15
  16     #include "constants.qh"
  17     #include <common/deathtypes/all.qh>
  18     #include <common/notifications/all.qh>
  19         #include "triggers/subs.qh"
  20     #include "util.qh"
  21
  22     #include <common/monsters/all.qh>
  23
  24     #include <common/weapons/all.qh>
  25
  26     #include "../lib/warpzone/util_server.qh"
  27 #elif defined(CSQC)
  28         #include "physics/movetypes/movetypes.qh"
  29         #include <common/weapons/all.qh>
  30         #include "../lib/csqcmodel/cl_model.qh"
  31         #include "../lib/csqcmodel/common.qh"
  32 #endif
  33
  34 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  35
  36 #ifdef CSQC
  37 bool autocvar_cl_ghost_items_vehicle = true;
  38 void Item_SetAlpha(entity this)
  39 {
  40         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  41
  42         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  43         {
  44                 this.alpha = 1;
  45                 this.colormod = this.glowmod = '1 1 1';
  46         }
  47         else
  48         {
  49                 if (autocvar_cl_ghost_items_color)
  50                 {
  51                         this.alpha = autocvar_cl_ghost_items;
  52                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  53                 }
  54                 else
  55                         this.alpha = -1;
  56         }
  57
  58         if(!veh_hud)
  59         if(this.ItemStatus & ITS_STAYWEP)
  60         {
  61                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  62                 this.alpha = autocvar_cl_weapon_stay_alpha;
  63         }
  64 }
  65
  66 void ItemDraw(entity this)
  67 {
  68     if(this.gravity)
  69     {
  70         Movetype_Physics_MatchServer(this, false);
  71         if(this.move_flags & FL_ONGROUND)
  72         { // For some reason move_avelocity gets set to '0 0 0' here ...
  73             this.oldorigin = this.origin;
  74             this.gravity = 0;
  75
  76             if(autocvar_cl_animate_items)
  77             { // ... so reset it if animations are requested.
  78                 if(this.ItemStatus & ITS_ANIMATE1)
  79                     this.move_avelocity = '0 180 0';
  80
  81                 if(this.ItemStatus & ITS_ANIMATE2)
  82                     this.move_avelocity = '0 -90 0';
  83             }
  84         }
  85     }
  86     else if (autocvar_cl_animate_items)
  87     {
  88         if(this.ItemStatus & ITS_ANIMATE1)
  89         {
  90             this.angles += this.move_avelocity * frametime;
  91             setorigin(this, '0 0 10' + this.oldorigin + '0 0 8' * sin(time * 2));
  92         }
  93
  94         if(this.ItemStatus & ITS_ANIMATE2)
  95         {
  96             this.angles += this.move_avelocity * frametime;
  97             setorigin(this, '0 0 8' + this.oldorigin + '0 0 4' * sin(time * 3));
  98         }
  99     }
 100
 101     Item_SetAlpha(this);
 102 }
 103
 104 void ItemDrawSimple(entity this)
 105 {
 106     if(this.gravity)
 107     {
 108         Movetype_Physics_MatchServer(this, false);
 109
 110         if(this.move_flags & FL_ONGROUND)
 111             this.gravity = 0;
 112     }
 113
 114     Item_SetAlpha(this);
 115 }
 116
 117 void Item_PreDraw(entity this)
 118 {
 119         if(warpzone_warpzones_exist)
 120         {
 121                 // just incase warpzones were initialized last, reset these
 122                 //this.alpha = 1; // alpha is already set by the draw function
 123                 this.drawmask = MASK_NORMAL;
 124                 return;
 125         }
 126         float alph;
 127         vector org = getpropertyvec(VF_ORIGIN);
 128         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 129                 alph = 0;
 130         else if(this.fade_start)
 131                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 132         else
 133                 alph = 1;
 134         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 135         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 136                 this.alpha = alph;
 137         if(alph <= 0)
 138                 this.drawmask = 0;
 139         else
 140                 this.drawmask = MASK_NORMAL;
 141 }
 142
 143 void ItemRemove(entity this)
 144 {
 145         if(this.mdl)
 146                 strunzone(this.mdl);
 147 }
 148
 149 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 150 {
 151     int sf = ReadByte();
 152
 153     if(sf & ISF_LOCATION)
 154     {
 155         this.origin_x = ReadCoord();
 156         this.origin_y = ReadCoord();
 157         this.origin_z = ReadCoord();
 158         setorigin(this, this.origin);
 159         this.oldorigin = this.origin;
 160     }
 161
 162     if(sf & ISF_ANGLES)
 163     {
 164         this.angles_x = ReadAngle();
 165         this.angles_y = ReadAngle();
 166         this.angles_z = ReadAngle();
 167         this.move_angles = this.angles;
 168     }
 169
 170     if(sf & ISF_SIZE)
 171     {
 172         float use_bigsize = ReadByte();
 173         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 174     }
 175
 176     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 177     {
 178         this.ItemStatus = ReadByte();
 179
 180         Item_SetAlpha(this);
 181
 182         if(autocvar_cl_fullbright_items)
 183             if(this.ItemStatus & ITS_ALLOWFB)
 184                 this.effects |= EF_FULLBRIGHT;
 185
 186         if(this.ItemStatus & ITS_POWERUP)
 187         {
 188             if(this.ItemStatus & ITS_AVAILABLE)
 189                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 190             else
 191                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 192         }
 193     }
 194
 195     if(sf & ISF_MODEL)
 196     {
 197         this.drawmask  = MASK_NORMAL;
 198                 this.move_movetype = MOVETYPE_TOSS;
 199         this.draw       = ItemDraw;
 200         this.solid = SOLID_TRIGGER;
 201         //this.move_flags |= FL_ITEM;
 202
 203         bool use_bigsize = ReadByte();
 204
 205         this.fade_end = ReadShort();
 206         this.fade_start = ReadShort();
 207         if(this.fade_start && !autocvar_cl_items_nofade)
 208                 setpredraw(this, Item_PreDraw);
 209
 210         if(this.mdl)
 211             strunzone(this.mdl);
 212
 213         this.mdl = "";
 214         string _fn = ReadString();
 215
 216         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 217         {
 218             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 219             this.draw = ItemDrawSimple;
 220
 221             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 222                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 223             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 224                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 225             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 226                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 227             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 228                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 229             else
 230             {
 231                 this.draw = ItemDraw;
 232                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it\n");
 233             }
 234         }
 235
 236         if(this.draw != ItemDrawSimple)
 237             this.mdl = strzone(_fn);
 238
 239
 240         if(this.mdl == "")
 241             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!\n");
 242
 243         precache_model(this.mdl);
 244         _setmodel(this, this.mdl);
 245
 246         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 247     }
 248
 249     if(sf & ISF_COLORMAP)
 250         this.colormap = ReadShort();
 251
 252     if(sf & ISF_DROP)
 253     {
 254         this.gravity = 1;
 255         this.pushable = true;
 256         //this.move_angles = '0 0 0';
 257         this.move_movetype = MOVETYPE_TOSS;
 258         this.move_velocity_x = ReadCoord();
 259         this.move_velocity_y = ReadCoord();
 260         this.move_velocity_z = ReadCoord();
 261         this.velocity = this.move_velocity;
 262         this.move_origin = this.oldorigin;
 263
 264         if(!this.move_time)
 265         {
 266             this.move_time = time;
 267             this.spawntime = time;
 268         }
 269         else
 270             this.move_time = max(this.move_time, time);
 271     }
 272
 273     if(autocvar_cl_animate_items)
 274     {
 275         if(this.ItemStatus & ITS_ANIMATE1)
 276             this.move_avelocity = '0 180 0';
 277
 278         if(this.ItemStatus & ITS_ANIMATE2)
 279             this.move_avelocity = '0 -90 0';
 280     }
 281
 282     this.entremove = ItemRemove;
 283
 284     return true;
 285 }
 286
 287 #endif
 288
 289 #ifdef SVQC
 290 bool ItemSend(entity this, entity to, int sf)
 291 {
 292         if(self.gravity)
 293                 sf |= ISF_DROP;
 294         else
 295                 sf &= ~ISF_DROP;
 296
 297         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 298         WriteByte(MSG_ENTITY, sf);
 299
 300         //WriteByte(MSG_ENTITY, self.cnt);
 301         if(sf & ISF_LOCATION)
 302         {
 303                 WriteCoord(MSG_ENTITY, self.origin.x);
 304                 WriteCoord(MSG_ENTITY, self.origin.y);
 305                 WriteCoord(MSG_ENTITY, self.origin.z);
 306         }
 307
 308         if(sf & ISF_ANGLES)
 309         {
 310                 WriteAngle(MSG_ENTITY, self.angles_x);
 311                 WriteAngle(MSG_ENTITY, self.angles_y);
 312                 WriteAngle(MSG_ENTITY, self.angles_z);
 313         }
 314
 315         if(sf & ISF_SIZE)
 316         {
 317                 Pickup p = this.itemdef;
 318                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 319         }
 320
 321         if(sf & ISF_STATUS)
 322                 WriteByte(MSG_ENTITY, self.ItemStatus);
 323
 324         if(sf & ISF_MODEL)
 325         {
 326                 Pickup p = this.itemdef;
 327                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 328                 WriteShort(MSG_ENTITY, self.fade_end);
 329                 WriteShort(MSG_ENTITY, self.fade_start);
 330
 331                 if(self.mdl == "")
 332                         LOG_TRACE("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 333
 334                 WriteString(MSG_ENTITY, self.mdl);
 335         }
 336
 337
 338         if(sf & ISF_COLORMAP)
 339                 WriteShort(MSG_ENTITY, self.colormap);
 340
 341         if(sf & ISF_DROP)
 342         {
 343                 WriteCoord(MSG_ENTITY, self.velocity.x);
 344                 WriteCoord(MSG_ENTITY, self.velocity.y);
 345                 WriteCoord(MSG_ENTITY, self.velocity.z);
 346         }
 347
 348         return true;
 349 }
 350
 351 void ItemUpdate(entity this)
 352 {
 353         this.oldorigin = this.origin;
 354         this.SendFlags |= ISF_LOCATION;
 355 }
 356
 357 void UpdateItemAfterTeleport(entity this)
 358 {
 359         if(this.SendEntity3 == ItemSend)
 360                 ItemUpdate(this);
 361 }
 362
 363 bool have_pickup_item(entity this)
 364 {
 365         if(this.itemdef.instanceOfPowerup)
 366         {
 367                 if(autocvar_g_powerups > 0)
 368                         return true;
 369                 if(autocvar_g_powerups == 0)
 370                         return false;
 371         }
 372         else
 373         {
 374                 if(autocvar_g_pickup_items > 0)
 375                         return true;
 376                 if(autocvar_g_pickup_items == 0)
 377                         return false;
 378                 if(g_weaponarena)
 379                         if(this.weapons || (this.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 380                                 return false;
 381         }
 382         return true;
 383 }
 384
 385 /*
 386 float Item_Customize()
 387 {
 388         if(self.spawnshieldtime)
 389                 return true;
 390         if(self.weapons & ~other.weapons)
 391         {
 392                 self.colormod = '0 0 0';
 393                 self.glowmod = self.colormod;
 394                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 395                 return true;
 396         }
 397         else
 398         {
 399                 if(g_ghost_items)
 400                 {
 401                         self.colormod = stov(autocvar_g_ghost_items_color);
 402                         self.glowmod = self.colormod;
 403                         self.alpha = g_ghost_items;
 404                         return true;
 405                 }
 406                 else
 407                         return false;
 408         }
 409 }
 410 */
 411
 412 void Item_Show (entity e, float mode)
 413 {
 414         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 415         e.ItemStatus &= ~ITS_STAYWEP;
 416         if (mode > 0)
 417         {
 418                 // make the item look normal, and be touchable
 419                 e.model = e.mdl;
 420                 e.solid = SOLID_TRIGGER;
 421                 e.spawnshieldtime = 1;
 422                 e.ItemStatus |= ITS_AVAILABLE;
 423         }
 424         else if (mode < 0)
 425         {
 426                 // hide the item completely
 427                 e.model = string_null;
 428                 e.solid = SOLID_NOT;
 429                 e.spawnshieldtime = 1;
 430                 e.ItemStatus &= ~ITS_AVAILABLE;
 431         }
 432         else {
 433         entity def = e.itemdef;
 434         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 435                 || e.team // weapon stay isn't supported for teamed weapons
 436                 ;
 437         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 438         {
 439                 // make the item translucent and not touchable
 440                 e.model = e.mdl;
 441                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 442                 e.effects |= EF_STARDUST;
 443                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 444                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 445         }
 446         else
 447         {
 448                 //setmodel(e, "null");
 449                 e.solid = SOLID_NOT;
 450                 e.colormod = '0 0 0';
 451                 e.glowmod = e.colormod;
 452                 e.spawnshieldtime = 1;
 453                 e.ItemStatus &= ~ITS_AVAILABLE;
 454         }}
 455
 456         if (e.items & ITEM_Strength.m_itemid || e.items & ITEM_Shield.m_itemid)
 457                 e.ItemStatus |= ITS_POWERUP;
 458
 459         if (autocvar_g_nodepthtestitems)
 460                 e.effects |= EF_NODEPTHTEST;
 461
 462
 463         if (autocvar_g_fullbrightitems)
 464                 e.ItemStatus |= ITS_ALLOWFB;
 465
 466         if (autocvar_sv_simple_items)
 467                 e.ItemStatus |= ITS_ALLOWSI;
 468
 469         // relink entity (because solid may have changed)
 470         setorigin(e, e.origin);
 471         e.SendFlags |= ISF_STATUS;
 472 }
 473
 474 void Item_Think(entity this)
 475 {
 476         self.nextthink = time;
 477         if(self.origin != self.oldorigin)
 478                 ItemUpdate(self);
 479 }
 480
 481 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 482 bool Item_ItemsTime_Allow(GameItem it);
 483 float Item_ItemsTime_UpdateTime(entity e, float t);
 484 void Item_ItemsTime_SetTime(entity e, float t);
 485 void Item_ItemsTime_SetTimesForAllPlayers();
 486
 487 void Item_Respawn (entity this)
 488 {
 489         Item_Show(self, 1);
 490         // this is ugly...
 491         if(self.items == ITEM_Strength.m_itemid)
 492                 sound (self, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTEN_NORM);   // play respawn sound
 493         else if(self.items == ITEM_Shield.m_itemid)
 494                 sound (self, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTEN_NORM);     // play respawn sound
 495         else
 496                 sound (self, CH_TRIGGER, SND_ITEMRESPAWN, VOL_BASE, ATTEN_NORM);        // play respawn sound
 497         setorigin (self, self.origin);
 498
 499     if (Item_ItemsTime_Allow(self.itemdef) || self.weapons & WEPSET_SUPERWEAPONS)
 500         {
 501                 float t = Item_ItemsTime_UpdateTime(self, 0);
 502                 Item_ItemsTime_SetTime(self, t);
 503                 Item_ItemsTime_SetTimesForAllPlayers();
 504         }
 505
 506         setthink(self, Item_Think);
 507         self.nextthink = time;
 508
 509         //Send_Effect(EFFECT_ITEM_RESPAWN, self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 510         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 511 }
 512
 513 void Item_RespawnCountdown (entity this)
 514 {
 515         if(self.count >= ITEM_RESPAWN_TICKS)
 516         {
 517                 if(self.waypointsprite_attached)
 518                         WaypointSprite_Kill(self.waypointsprite_attached);
 519                 Item_Respawn(self);
 520         }
 521         else
 522         {
 523                 self.nextthink = time + 1;
 524                 self.count += 1;
 525                 if(self.count == 1)
 526                 {
 527                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 528                         do {
 529                                 {
 530                                         entity wi = Weapons_from(self.weapon);
 531                                         if (wi != WEP_Null) {
 532                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Weapon);
 533                                                 wp.wp_extra = wi.m_id;
 534                                                 break;
 535                                         }
 536                                 }
 537                                 {
 538                                         entity ii = self.itemdef;
 539                                         if (ii != NULL) {
 540                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_Item);
 541                                                 wp.wp_extra = ii.m_id;
 542                                                 break;
 543                                         }
 544                                 }
 545                         } while (0);
 546             if(self.waypointsprite_attached)
 547             {
 548                 GameItem def = self.itemdef;
 549                 if (Item_ItemsTime_SpectatorOnly(def))
 550                     WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 551                 WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 552             }
 553                 }
 554
 555                 if(self.waypointsprite_attached)
 556                 {
 557                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 558                                 if(self.waypointsprite_attached.waypointsprite_visible_for_player(self.waypointsprite_attached, it, it))
 559                                 {
 560                                         msg_entity = it;
 561                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 562                                 }
 563                         });
 564
 565                         WaypointSprite_Ping(self.waypointsprite_attached);
 566                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 567                 }
 568         }
 569 }
 570
 571 void Item_RespawnThink(entity this)
 572 {
 573         self.nextthink = time;
 574         if(self.origin != self.oldorigin)
 575                 ItemUpdate(self);
 576
 577         if(time >= self.wait)
 578                 Item_Respawn(self);
 579 }
 580
 581 void Item_ScheduleRespawnIn(entity e, float t)
 582 {
 583         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 584         if ((Item_ItemsTime_Allow(e.itemdef) || e.weapons & WEPSET_SUPERWEAPONS) && (t - ITEM_RESPAWN_TICKS) > 0)
 585         {
 586                 setthink(e, Item_RespawnCountdown);
 587                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 588                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 589                 e.count = 0;
 590                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 591                 Item_ItemsTime_SetTime(e, t);
 592                 Item_ItemsTime_SetTimesForAllPlayers();
 593         }
 594         else
 595         {
 596                 setthink(e, Item_RespawnThink);
 597                 e.nextthink = time;
 598                 e.scheduledrespawntime = time + t;
 599                 e.wait = time + t;
 600         }
 601 }
 602
 603 void Item_ScheduleRespawn(entity e)
 604 {
 605         if(e.respawntime > 0)
 606         {
 607                 Item_Show(e, 0);
 608                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 609         }
 610         else // if respawntime is -1, this item does not respawn
 611                 Item_Show(e, -1);
 612 }
 613
 614 void Item_ScheduleInitialRespawn(entity e)
 615 {
 616         Item_Show(e, 0);
 617         Item_ScheduleRespawnIn(e, game_starttime - time + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 618 }
 619
 620 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 621 {
 622         if (!item.(ammotype))
 623                 return false;
 624
 625         if (item.spawnshieldtime)
 626         {
 627                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 628                 {
 629                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 630                         goto YEAH;
 631                 }
 632         }
 633         else if(g_weapon_stay == 2)
 634         {
 635                 float mi = min(item.(ammotype), ammomax);
 636                 if (player.(ammotype) < mi)
 637                 {
 638                         player.(ammotype) = mi;
 639                         goto YEAH;
 640                 }
 641         }
 642
 643         return false;
 644
 645 LABEL(YEAH)
 646         switch(mode)
 647         {
 648                 case ITEM_MODE_FUEL:
 649                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 650                         break;
 651                 case ITEM_MODE_HEALTH:
 652                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 653                         break;
 654                 case ITEM_MODE_ARMOR:
 655                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 656                         break;
 657                 default:
 658                         break;
 659         }
 660         return true;
 661 }
 662
 663 float Item_GiveTo(entity item, entity player)
 664 {
 665         float _switchweapon;
 666         float pickedup;
 667
 668         // if nothing happens to player, just return without taking the item
 669         pickedup = false;
 670         _switchweapon = false;
 671         // in case the player has autoswitch enabled do the following:
 672         // if the player is using their best weapon before items are given, they
 673         // probably want to switch to an even better weapon after items are given
 674         if (player.autoswitch)
 675         if (PS(player).m_switchweapon == w_getbestweapon(player))
 676                 _switchweapon = true;
 677
 678         if (!(player.weapons & WepSet_FromWeapon(PS(player).m_switchweapon)))
 679                 _switchweapon = true;
 680
 681         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 682         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 683         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 684         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 685         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 686         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 687         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 688         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 689
 690         if (item.itemdef.instanceOfWeaponPickup)
 691         {
 692                 WepSet w;
 693                 w = item.weapons;
 694                 w &= ~player.weapons;
 695
 696                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 697                 {
 698                         pickedup = true;
 699                         FOREACH(Weapons, it != WEP_Null, {
 700                                 if(w & (it.m_wepset))
 701                                 {
 702                                         W_DropEvent(wr_pickup, player, it.m_id, item);
 703                                         W_GiveWeapon(player, it.m_id);
 704                                 }
 705                         });
 706                 }
 707         }
 708
 709         if (item.itemdef.instanceOfPowerup)
 710         {
 711                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 712                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 713                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 714                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 715         }
 716
 717         int its;
 718         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 719         {
 720                 pickedup = true;
 721                 player.items |= its;
 722                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 723         }
 724
 725         if (item.strength_finished)
 726         {
 727                 pickedup = true;
 728                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 729         }
 730         if (item.invincible_finished)
 731         {
 732                 pickedup = true;
 733                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 734         }
 735         if (item.superweapons_finished)
 736         {
 737                 pickedup = true;
 738                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 739         }
 740
 741 LABEL(skip)
 742
 743         // always eat teamed entities
 744         if(item.team)
 745                 pickedup = true;
 746
 747         if (!pickedup)
 748                 return 0;
 749
 750         // crude hack to enforce switching weapons
 751         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 752         {
 753                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon));
 754                 return 1;
 755         }
 756
 757         if (_switchweapon)
 758                 if (PS(player).m_switchweapon != w_getbestweapon(player))
 759                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 760
 761         return 1;
 762 }
 763
 764 void Item_Touch(entity this)
 765 {
 766
 767         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 768         if (this.classname == "droppedweapon")
 769         {
 770                 if (ITEM_TOUCH_NEEDKILL())
 771                 {
 772                         remove(this);
 773                         return;
 774                 }
 775         }
 776
 777         if(!(other.flags & FL_PICKUPITEMS)
 778         || STAT(FROZEN, other)
 779         || IS_DEAD(other)
 780         || (this.solid != SOLID_TRIGGER)
 781         || (this.owner == other)
 782         || (time < this.item_spawnshieldtime)
 783         ) { return; }
 784
 785         switch (MUTATOR_CALLHOOK(ItemTouch, this, other))
 786         {
 787                 case MUT_ITEMTOUCH_RETURN: { return; }
 788                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 789         }
 790
 791         if (this.classname == "droppedweapon")
 792         {
 793                 this.strength_finished = max(0, this.strength_finished - time);
 794                 this.invincible_finished = max(0, this.invincible_finished - time);
 795                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 796         }
 797         entity it = this.itemdef;
 798         bool gave = ITEM_HANDLE(Pickup, it, this, other);
 799         if (!gave)
 800         {
 801                 if (this.classname == "droppedweapon")
 802                 {
 803                         // undo what we did above
 804                         this.strength_finished += time;
 805                         this.invincible_finished += time;
 806                         this.superweapons_finished += time;
 807                 }
 808                 return;
 809         }
 810
 811 LABEL(pickup)
 812
 813         other.last_pickup = time;
 814
 815         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 816         _sound (other, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 817
 818         if (this.classname == "droppedweapon")
 819                 remove (this);
 820         else if (this.spawnshieldtime)
 821         {
 822                 entity e;
 823                 if(this.team)
 824                 {
 825                         RandomSelection_Init();
 826                         for(entity head = world; (head = findfloat(head, team, this.team)); )
 827                         {
 828                                 if(head.flags & FL_ITEM)
 829                                 if(head.classname != "item_flag_team" && head.classname != "item_key_team")
 830                                 {
 831                                         Item_Show(head, -1);
 832                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 833                                 }
 834                         }
 835                         e = RandomSelection_chosen_ent;
 836
 837                 }
 838                 else
 839                         e = this;
 840                 Item_ScheduleRespawn(e);
 841         }
 842 }
 843
 844 void Item_Reset(entity this)
 845 {
 846         Item_Show(this, !this.state);
 847         setorigin(this, this.origin);
 848
 849         if (this.classname != "droppedweapon")
 850         {
 851                 setthink(this, Item_Think);
 852                 this.nextthink = time;
 853
 854                 if (this.waypointsprite_attached)
 855                         WaypointSprite_Kill(this.waypointsprite_attached);
 856
 857                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 858                         Item_ScheduleInitialRespawn(this);
 859         }
 860 }
 861
 862 void Item_FindTeam(entity this)
 863 {
 864         entity e;
 865
 866         if(self.effects & EF_NODRAW)
 867         {
 868                 // marker for item team search
 869                 LOG_TRACE("Initializing item team ", ftos(self.team), "\n");
 870                 RandomSelection_Init();
 871                 FOREACH_ENTITY_FLOAT(team, self.team,
 872                 {
 873                         if(it.flags & FL_ITEM)
 874                         if(it.classname != "item_flag_team" && it.classname != "item_key_team")
 875                                 RandomSelection_Add(it, 0, string_null, it.cnt, 0);
 876                 });
 877
 878                 e = RandomSelection_chosen_ent;
 879                 e.state = 0;
 880                 Item_Show(e, 1);
 881
 882                 FOREACH_ENTITY_FLOAT(team, self.team,
 883                 {
 884                         if(it.flags & FL_ITEM)
 885                         if(it.classname != "item_flag_team" && it.classname != "item_key_team")
 886                         {
 887                                 if(it != e)
 888                                 {
 889                                         // make it non-spawned
 890                                         Item_Show(it, -1);
 891                                         it.state = 1; // state 1 = initially hidden item, apparently
 892                                 }
 893                                 it.effects &= ~EF_NODRAW;
 894                         }
 895                 });
 896
 897                 Item_Reset(self);
 898         }
 899 }
 900
 901 // Savage: used for item garbage-collection
 902 void RemoveItem(entity this)
 903 {
 904         if(wasfreed(self) || !self) { return; }
 905         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 906         remove(self);
 907 }
 908
 909 // pickup evaluation functions
 910 // these functions decide how desirable an item is to the bots
 911
 912 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 913
 914 float weapon_pickupevalfunc(entity player, entity item)
 915 {
 916         float c;
 917
 918         // See if I have it already
 919         if(item.weapons & ~player.weapons)
 920         {
 921                 // If I can pick it up
 922                 if(!item.spawnshieldtime)
 923                         c = 0;
 924                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 925                 {
 926                         // Skilled bots will grab more
 927                         c = bound(0, skill / 10, 1) * 0.5;
 928                 }
 929                 else
 930                         c = 0;
 931         }
 932         else
 933                 c = 1;
 934
 935         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 936         if( bot_custom_weapon && c )
 937         {
 938                 // Find the highest position on any range
 939                 int position = -1;
 940                 for (int j = 0; j < WEP_LAST ; ++j){
 941                         if(
 942                                         bot_weapons_far[j] == item.weapon ||
 943                                         bot_weapons_mid[j] == item.weapon ||
 944                                         bot_weapons_close[j] == item.weapon
 945                           )
 946                         {
 947                                 position = j;
 948                                 break;
 949                         }
 950                 }
 951
 952                 // Rate it
 953                 if (position >= 0 )
 954                 {
 955                         position = WEP_LAST - position;
 956                         // item.bot_pickupbasevalue is overwritten here
 957                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 958                 }
 959         }
 960
 961         return item.bot_pickupbasevalue * c;
 962 }
 963
 964 float commodity_pickupevalfunc(entity player, entity item)
 965 {
 966         float c;
 967         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 968         c = 0;
 969
 970         // Detect needed ammo
 971         FOREACH(Weapons, it != WEP_Null, {
 972                 if(!(player.weapons & (it.m_wepset)))
 973                         continue;
 974
 975                 if(it.items & ITEM_Shells.m_itemid)
 976                         need_shells = true;
 977                 else if(it.items & ITEM_Bullets.m_itemid)
 978                         need_nails = true;
 979                 else if(it.items & ITEM_Rockets.m_itemid)
 980                         need_rockets = true;
 981                 else if(it.items & ITEM_Cells.m_itemid)
 982                         need_cells = true;
 983                 else if(it.items & ITEM_Plasma.m_itemid)
 984                         need_plasma = true;
 985                 else if(it.items & ITEM_JetpackFuel.m_itemid)
 986                         need_fuel = true;
 987         });
 988
 989         // TODO: figure out if the player even has the weapon this ammo is for?
 990         // may not affect strategy much though...
 991         // find out how much more ammo/armor/health the player can hold
 992         if (need_shells)
 993         if (item.ammo_shells)
 994         if (player.ammo_shells < g_pickup_shells_max)
 995                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 996         if (need_nails)
 997         if (item.ammo_nails)
 998         if (player.ammo_nails < g_pickup_nails_max)
 999                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1000         if (need_rockets)
1001         if (item.ammo_rockets)
1002         if (player.ammo_rockets < g_pickup_rockets_max)
1003                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1004         if (need_cells)
1005         if (item.ammo_cells)
1006         if (player.ammo_cells < g_pickup_cells_max)
1007                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1008         if (need_plasma)
1009         if (item.ammo_plasma)
1010         if (player.ammo_plasma < g_pickup_plasma_max)
1011                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1012         if (need_fuel)
1013         if (item.ammo_fuel)
1014         if (player.ammo_fuel < g_pickup_fuel_max)
1015                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1016         if (item.armorvalue)
1017         if (player.armorvalue < item.max_armorvalue)
1018                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1019         if (item.health)
1020         if (player.health < item.max_health)
1021                 c = c + max(0, 1 - player.health / item.max_health);
1022
1023         return item.bot_pickupbasevalue * c;
1024 }
1025
1026 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1027 {
1028         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1029                 WITHSELF(this, RemoveItem(this));
1030 }
1031
1032 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1033 {
1034         string itemname = def.m_name;
1035         Model itemmodel = def.m_model;
1036     Sound pickupsound = def.m_sound;
1037         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1038         float pickupbasevalue = def.m_botvalue;
1039         int itemflags = def.m_itemflags;
1040
1041         startitem_failed = false;
1042
1043         this.item_model_ent = itemmodel;
1044     this.item_pickupsound_ent = pickupsound;
1045
1046         if(!this.respawntime) // both need to be set
1047         {
1048                 this.respawntime = defaultrespawntime;
1049                 this.respawntimejitter = defaultrespawntimejitter;
1050         }
1051
1052         int itemid = def.m_itemid;
1053         this.items = itemid;
1054         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1055         this.weapon = weaponid;
1056
1057         if(!this.fade_end)
1058         {
1059                 this.fade_start = autocvar_g_items_mindist;
1060                 this.fade_end = autocvar_g_items_maxdist;
1061         }
1062
1063         if(weaponid)
1064                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1065
1066         this.flags = FL_ITEM | itemflags;
1067
1068         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1069         {
1070                 startitem_failed = true;
1071                 remove(this);
1072                 return;
1073         }
1074
1075         // is it a dropped weapon?
1076         if (this.classname == "droppedweapon")
1077         {
1078                 this.reset = SUB_Remove;
1079                 // it's a dropped weapon
1080                 this.movetype = MOVETYPE_TOSS;
1081
1082                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1083                 setthink(this, RemoveItem);
1084                 this.nextthink = time + 20;
1085
1086                 this.takedamage = DAMAGE_YES;
1087                 this.event_damage = Item_Damage;
1088
1089                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1090                 {
1091                         // if item is worthless after a timer, have it expire then
1092                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1093                 }
1094
1095                 // don't drop if in a NODROP zone (such as lava)
1096                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1097                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1098                 {
1099                         startitem_failed = true;
1100                         remove(this);
1101                         return;
1102                 }
1103         }
1104         else
1105         {
1106                 if(!have_pickup_item(this))
1107                 {
1108                         startitem_failed = true;
1109                         remove (this);
1110                         return;
1111                 }
1112
1113                 if(this.angles != '0 0 0')
1114                         this.SendFlags |= ISF_ANGLES;
1115
1116                 this.reset = Item_Reset;
1117                 // it's a level item
1118                 if(this.spawnflags & 1)
1119                         this.noalign = 1;
1120                 if (this.noalign > 0)
1121                         this.movetype = MOVETYPE_NONE;
1122                 else
1123                         this.movetype = MOVETYPE_TOSS;
1124                 // do item filtering according to game mode and other things
1125                 if (this.noalign <= 0)
1126                 {
1127                         // first nudge it off the floor a little bit to avoid math errors
1128                         setorigin(this, this.origin + '0 0 1');
1129                         // set item size before we spawn a spawnfunc_waypoint
1130                         setsize(this, def.m_mins, def.m_maxs);
1131                         this.SendFlags |= ISF_SIZE;
1132                         // note droptofloor returns false if stuck/or would fall too far
1133                         if (!this.noalign)
1134                                 WITHSELF(this, droptofloor());
1135                         waypoint_spawnforitem(this);
1136                 }
1137
1138                 /*
1139                  * can't do it that way, as it would break maps
1140                  * TODO make a target_give like entity another way, that perhaps has
1141                  * the weapon name in a key
1142                 if(this.targetname)
1143                 {
1144                         // target_give not yet supported; maybe later
1145                         print("removed targeted ", this.classname, "\n");
1146                         startitem_failed = true;
1147                         remove (this);
1148                         return;
1149                 }
1150                 */
1151
1152                 if(autocvar_spawn_debug >= 2)
1153                 {
1154             // why not flags & fl_item?
1155                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1156                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1157                 LOG_TRACE(" vs ", it.netname, vtos(it.origin), "\n");
1158                 error("Mapper sucks.");
1159             });
1160                         this.is_item = true;
1161                 }
1162
1163                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1164
1165                 precache_model(this.model);
1166                 precache_sound(this.item_pickupsound);
1167
1168                 if (   def.instanceOfPowerup
1169                         || def.instanceOfWeaponPickup
1170                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1171                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1172                         || (itemid & (IT_KEY1 | IT_KEY2))
1173                 ) this.target = "###item###"; // for finding the nearest item using find()
1174
1175                 Item_ItemsTime_SetTime(this, 0);
1176         }
1177
1178         this.bot_pickup = true;
1179         this.bot_pickupevalfunc = pickupevalfunc;
1180         this.bot_pickupbasevalue = pickupbasevalue;
1181         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1182         this.netname = itemname;
1183         settouch(this, Item_Touch);
1184         setmodel(this, MDL_Null); // precision set below
1185         //this.effects |= EF_LOWPRECISION;
1186
1187         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1188
1189         this.SendFlags |= ISF_SIZE;
1190
1191         if (!(this.spawnflags & 1024)) {
1192                 if(def.instanceOfPowerup)
1193                         this.ItemStatus |= ITS_ANIMATE1;
1194
1195                 if(this.armorvalue || this.health)
1196                         this.ItemStatus |= ITS_ANIMATE2;
1197         }
1198
1199         if(def.instanceOfWeaponPickup)
1200         {
1201                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1202                         this.colormap = 1024; // color shirt=0 pants=0 grey
1203                 else
1204                         this.gravity = 1;
1205                 if (!(this.spawnflags & 1024))
1206                         this.ItemStatus |= ITS_ANIMATE1;
1207                 this.ItemStatus |= ISF_COLORMAP;
1208         }
1209
1210         this.state = 0;
1211         if(this.team) // broken, no idea why.
1212         {
1213                 if(!this.cnt)
1214                         this.cnt = 1; // item probability weight
1215
1216                 this.effects |= EF_NODRAW; // marker for item team search
1217                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1218         }
1219         else
1220                 Item_Reset(this);
1221
1222         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1223
1224         // call this hook after everything else has been done
1225         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1226         {
1227                 startitem_failed = true;
1228                 remove(this);
1229                 return;
1230         }
1231 }
1232
1233 void StartItem(entity this, GameItem def)
1234 {
1235     _StartItem(
1236         this,
1237         this.itemdef = def,
1238         def.m_respawntime(), // defaultrespawntime
1239         def.m_respawntimejitter() // defaultrespawntimejitter
1240         );
1241 }
1242
1243 spawnfunc(item_rockets)
1244 {
1245         if(!this.ammo_rockets)
1246                 this.ammo_rockets = g_pickup_rockets;
1247         if(!this.pickup_anyway)
1248                 this.pickup_anyway = g_pickup_ammo_anyway;
1249     StartItem(this, ITEM_Rockets);
1250 }
1251
1252 spawnfunc(item_bullets)
1253 {
1254         if(!weaponswapping)
1255         if(autocvar_sv_q3acompat_machineshotgunswap)
1256         if(this.classname != "droppedweapon")
1257         {
1258                 weaponswapping = true;
1259                 spawnfunc_item_shells(this);
1260                 weaponswapping = false;
1261                 return;
1262         }
1263
1264         if(!this.ammo_nails)
1265                 this.ammo_nails = g_pickup_nails;
1266         if(!this.pickup_anyway)
1267                 this.pickup_anyway = g_pickup_ammo_anyway;
1268     StartItem(this, ITEM_Bullets);
1269 }
1270
1271 spawnfunc(item_cells)
1272 {
1273         if(!this.ammo_cells)
1274                 this.ammo_cells = g_pickup_cells;
1275         if(!this.pickup_anyway)
1276                 this.pickup_anyway = g_pickup_ammo_anyway;
1277         StartItem(this, ITEM_Cells);
1278 }
1279
1280 spawnfunc(item_plasma)
1281 {
1282         if(!this.ammo_plasma)
1283                 this.ammo_plasma = g_pickup_plasma;
1284         if(!this.pickup_anyway)
1285                 this.pickup_anyway = g_pickup_ammo_anyway;
1286         StartItem(this, ITEM_Plasma);
1287 }
1288
1289 spawnfunc(item_shells)
1290 {
1291         if(!weaponswapping)
1292         if(autocvar_sv_q3acompat_machineshotgunswap)
1293         if(this.classname != "droppedweapon")
1294         {
1295                 weaponswapping = true;
1296                 spawnfunc_item_bullets(this);
1297                 weaponswapping = false;
1298                 return;
1299         }
1300
1301         if(!this.ammo_shells)
1302                 this.ammo_shells = g_pickup_shells;
1303         if(!this.pickup_anyway)
1304                 this.pickup_anyway = g_pickup_ammo_anyway;
1305         StartItem(this, ITEM_Shells);
1306 }
1307
1308 spawnfunc(item_armor_small)
1309 {
1310         if(!this.armorvalue)
1311                 this.armorvalue = g_pickup_armorsmall;
1312         if(!this.max_armorvalue)
1313                 this.max_armorvalue = g_pickup_armorsmall_max;
1314         if(!this.pickup_anyway)
1315                 this.pickup_anyway = g_pickup_armorsmall_anyway;
1316         StartItem(this, ITEM_ArmorSmall);
1317 }
1318
1319 spawnfunc(item_armor_medium)
1320 {
1321         if(!this.armorvalue)
1322                 this.armorvalue = g_pickup_armormedium;
1323         if(!this.max_armorvalue)
1324                 this.max_armorvalue = g_pickup_armormedium_max;
1325         if(!this.pickup_anyway)
1326                 this.pickup_anyway = g_pickup_armormedium_anyway;
1327         StartItem(this, ITEM_ArmorMedium);
1328 }
1329
1330 spawnfunc(item_armor_big)
1331 {
1332         if(!this.armorvalue)
1333                 this.armorvalue = g_pickup_armorbig;
1334         if(!this.max_armorvalue)
1335                 this.max_armorvalue = g_pickup_armorbig_max;
1336         if(!this.pickup_anyway)
1337                 this.pickup_anyway = g_pickup_armorbig_anyway;
1338         StartItem(this, ITEM_ArmorLarge);
1339 }
1340
1341 spawnfunc(item_armor_large)
1342 {
1343         if(!this.armorvalue)
1344                 this.armorvalue = g_pickup_armorlarge;
1345         if(!this.max_armorvalue)
1346                 this.max_armorvalue = g_pickup_armorlarge_max;
1347         if(!this.pickup_anyway)
1348                 this.pickup_anyway = g_pickup_armorlarge_anyway;
1349         StartItem(this, ITEM_ArmorMega);
1350 }
1351
1352 spawnfunc(item_health_small)
1353 {
1354         if(!this.max_health)
1355                 this.max_health = g_pickup_healthsmall_max;
1356         if(!this.health)
1357                 this.health = g_pickup_healthsmall;
1358         if(!this.pickup_anyway)
1359                 this.pickup_anyway = g_pickup_healthsmall_anyway;
1360         StartItem(this, ITEM_HealthSmall);
1361 }
1362
1363 spawnfunc(item_health_medium)
1364 {
1365         if(!this.max_health)
1366                 this.max_health = g_pickup_healthmedium_max;
1367         if(!this.health)
1368                 this.health = g_pickup_healthmedium;
1369         if(!this.pickup_anyway)
1370                 this.pickup_anyway = g_pickup_healthmedium_anyway;
1371     StartItem(this, ITEM_HealthMedium);
1372 }
1373
1374 spawnfunc(item_health_large)
1375 {
1376         if(!this.max_health)
1377                 this.max_health = g_pickup_healthlarge_max;
1378         if(!this.health)
1379                 this.health = g_pickup_healthlarge;
1380         if(!this.pickup_anyway)
1381                 this.pickup_anyway = g_pickup_healthlarge_anyway;
1382         StartItem(this, ITEM_HealthLarge);
1383 }
1384
1385 spawnfunc(item_health_mega)
1386 {
1387     if(!this.max_health)
1388         this.max_health = g_pickup_healthmega_max;
1389     if(!this.health)
1390         this.health = g_pickup_healthmega;
1391     if(!this.pickup_anyway)
1392         this.pickup_anyway = g_pickup_healthmega_anyway;
1393     StartItem(this, ITEM_HealthMega);
1394 }
1395
1396 // support old misnamed entities
1397 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1398 spawnfunc(item_armor25) { spawnfunc_item_armor_large(this); }
1399 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1400 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1401 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1402
1403 spawnfunc(item_strength)
1404 {
1405                 if(!this.strength_finished)
1406                         this.strength_finished = autocvar_g_balance_powerup_strength_time;
1407                 StartItem(this, ITEM_Strength);
1408 }
1409
1410 spawnfunc(item_invincible)
1411 {
1412                 if(!this.invincible_finished)
1413                         this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1414                 StartItem(this, ITEM_Shield);
1415 }
1416
1417 // compatibility:
1418 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1419
1420 void target_items_use(entity this, entity actor, entity trigger)
1421 {
1422         other = trigger; // TODO
1423
1424         if(actor.classname == "droppedweapon")
1425         {
1426                 EXACTTRIGGER_TOUCH;
1427                 remove(actor);
1428                 return;
1429         }
1430
1431         if (!IS_PLAYER(actor))
1432                 return;
1433         if(IS_DEAD(actor))
1434                 return;
1435         EXACTTRIGGER_TOUCH;
1436
1437         FOREACH_ENTITY_ENT(enemy, actor,
1438         {
1439                 if(it.classname == "droppedweapon")
1440                         remove(it);
1441         });
1442
1443         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1444                 centerprint(actor, this.message);
1445 }
1446
1447 spawnfunc(target_items)
1448 {
1449         float n, i;
1450         string s;
1451
1452         self.use = target_items_use;
1453         if(!self.strength_finished)
1454                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1455         if(!self.invincible_finished)
1456                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1457         if(!self.superweapons_finished)
1458                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1459
1460         n = tokenize_console(self.netname);
1461         if(argv(0) == "give")
1462         {
1463                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1464         }
1465         else
1466         {
1467                 for(i = 0; i < n; ++i)
1468                 {
1469                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1470                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1471                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1472                         else if(argv(i) == "strength")               self.items |= ITEM_Strength.m_itemid;
1473                         else if(argv(i) == "invincible")             self.items |= ITEM_Shield.m_itemid;
1474                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1475                         else if(argv(i) == "jetpack")                self.items |= ITEM_Jetpack.m_itemid;
1476                         else if(argv(i) == "fuel_regen")             self.items |= ITEM_JetpackRegen.m_itemid;
1477                         else
1478                         {
1479                                 FOREACH(Weapons, it != WEP_Null, {
1480                                         s = W_UndeprecateName(argv(i));
1481                                         if(s == it.netname)
1482                                         {
1483                                                 self.weapons |= (it.m_wepset);
1484                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1485                                                         it.wr_init(it);
1486                                                 break;
1487                                         }
1488                                 });
1489                         }
1490                 }
1491
1492                 string itemprefix, valueprefix;
1493                 if(self.spawnflags == 0)
1494                 {
1495                         itemprefix = "";
1496                         valueprefix = "";
1497                 }
1498                 else if(self.spawnflags == 1)
1499                 {
1500                         itemprefix = "max ";
1501                         valueprefix = "max ";
1502                 }
1503                 else if(self.spawnflags == 2)
1504                 {
1505                         itemprefix = "min ";
1506                         valueprefix = "min ";
1507                 }
1508                 else if(self.spawnflags == 4)
1509                 {
1510                         itemprefix = "minus ";
1511                         valueprefix = "max ";
1512                 }
1513                 else
1514                 {
1515                         error("invalid spawnflags");
1516                         itemprefix = valueprefix = string_null;
1517                 }
1518
1519                 self.netname = "";
1520                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1521                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1522                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * boolean(self.items & ITEM_Strength.m_itemid), "strength");
1523                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * boolean(self.items & ITEM_Shield.m_itemid), "invincible");
1524                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * boolean(self.items & IT_SUPERWEAPON), "superweapons");
1525                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & ITEM_Jetpack.m_itemid), "jetpack");
1526                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, boolean(self.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1527                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1528                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1529                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1530                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1531                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1532                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1533                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1534                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.armorvalue), "armor");
1535                 FOREACH(Weapons, it != WEP_Null, self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & (it.m_wepset)), it.netname));
1536         }
1537         self.netname = strzone(self.netname);
1538         //print(self.netname, "\n");
1539
1540         n = tokenize_console(self.netname);
1541         for(i = 0; i < n; ++i)
1542         {
1543                 FOREACH(Weapons, it != WEP_Null && argv(i) == it.netname, {
1544             it.wr_init(it);
1545             break;
1546                 });
1547         }
1548 }
1549
1550 spawnfunc(item_fuel)
1551 {
1552         if(!this.ammo_fuel)
1553                 this.ammo_fuel = g_pickup_fuel;
1554         if(!this.pickup_anyway)
1555                 this.pickup_anyway = g_pickup_ammo_anyway;
1556         StartItem(this, ITEM_JetpackFuel);
1557 }
1558
1559 spawnfunc(item_fuel_regen)
1560 {
1561         if(start_items & ITEM_JetpackRegen.m_itemid)
1562         {
1563                 spawnfunc_item_fuel(this);
1564                 return;
1565         }
1566         StartItem(this, ITEM_JetpackRegen);
1567 }
1568
1569 spawnfunc(item_jetpack)
1570 {
1571         if(!this.ammo_fuel)
1572                 this.ammo_fuel = g_pickup_fuel_jetpack;
1573         if(start_items & ITEM_Jetpack.m_itemid)
1574         {
1575                 spawnfunc_item_fuel(this);
1576                 return;
1577         }
1578         StartItem(this, ITEM_Jetpack);
1579 }
1580
1581 float GiveWeapon(entity e, float wpn, float op, float val)
1582 {
1583         WepSet v0, v1;
1584         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1585         v0 = (e.weapons & s);
1586         switch(op)
1587         {
1588                 case OP_SET:
1589                         if(val > 0)
1590                                 e.weapons |= s;
1591                         else
1592                                 e.weapons &= ~s;
1593                         break;
1594                 case OP_MIN:
1595                 case OP_PLUS:
1596                         if(val > 0)
1597                                 e.weapons |= s;
1598                         break;
1599                 case OP_MAX:
1600                         if(val <= 0)
1601                                 e.weapons &= ~s;
1602                         break;
1603                 case OP_MINUS:
1604                         if(val > 0)
1605                                 e.weapons &= ~s;
1606                         break;
1607         }
1608         v1 = (e.weapons & s);
1609         return (v0 != v1);
1610 }
1611
1612 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1613 {
1614         if(v1 == v0)
1615                 return;
1616         if(v1 <= v0 - t)
1617         {
1618                 if(snd_decr != NULL)
1619                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1620         }
1621         else if(v0 >= v0 + t)
1622         {
1623                 if(snd_incr != NULL)
1624                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1625         }
1626 }
1627
1628 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1629 {
1630         if(v0 < v1)
1631                 e.(rotfield) = max(e.(rotfield), time + rottime);
1632         else if(v0 > v1)
1633                 e.(regenfield) = max(e.(regenfield), time + regentime);
1634 }
1635 float GiveItems(entity e, float beginarg, float endarg)
1636 {
1637         float got, i, val, op;
1638         float _switchweapon;
1639         string cmd;
1640
1641         val = 999;
1642         op = OP_SET;
1643
1644         got = 0;
1645
1646         _switchweapon = false;
1647         if (e.autoswitch)
1648                 if (PS(e).m_switchweapon == w_getbestweapon(e))
1649                         _switchweapon = true;
1650
1651         e.strength_finished = max(0, e.strength_finished - time);
1652         e.invincible_finished = max(0, e.invincible_finished - time);
1653         e.superweapons_finished = max(0, e.superweapons_finished - time);
1654
1655         PREGIVE(e, items);
1656         PREGIVE_WEAPONS(e);
1657         PREGIVE(e, strength_finished);
1658         PREGIVE(e, invincible_finished);
1659         PREGIVE(e, superweapons_finished);
1660         PREGIVE(e, ammo_nails);
1661         PREGIVE(e, ammo_cells);
1662         PREGIVE(e, ammo_plasma);
1663         PREGIVE(e, ammo_shells);
1664         PREGIVE(e, ammo_rockets);
1665         PREGIVE(e, ammo_fuel);
1666         PREGIVE(e, armorvalue);
1667         PREGIVE(e, health);
1668
1669         for(i = beginarg; i < endarg; ++i)
1670         {
1671                 cmd = argv(i);
1672
1673                 if(cmd == "0" || stof(cmd))
1674                 {
1675                         val = stof(cmd);
1676                         continue;
1677                 }
1678                 switch(cmd)
1679                 {
1680                         case "no":
1681                                 op = OP_MAX;
1682                                 val = 0;
1683                                 continue;
1684                         case "max":
1685                                 op = OP_MAX;
1686                                 continue;
1687                         case "min":
1688                                 op = OP_MIN;
1689                                 continue;
1690                         case "plus":
1691                                 op = OP_PLUS;
1692                                 continue;
1693                         case "minus":
1694                                 op = OP_MINUS;
1695                                 continue;
1696                         case "ALL":
1697                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1698                                 got += GiveValue(e, strength_finished, op, val);
1699                                 got += GiveValue(e, invincible_finished, op, val);
1700                                 got += GiveValue(e, superweapons_finished, op, val);
1701                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1702                         case "all":
1703                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1704                                 got += GiveValue(e, health, op, val);
1705                                 got += GiveValue(e, armorvalue, op, val);
1706                         case "allweapons":
1707                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1708                         case "allammo":
1709                                 got += GiveValue(e, ammo_cells, op, val);
1710                                 got += GiveValue(e, ammo_plasma, op, val);
1711                                 got += GiveValue(e, ammo_shells, op, val);
1712                                 got += GiveValue(e, ammo_nails, op, val);
1713                                 got += GiveValue(e, ammo_rockets, op, val);
1714                                 got += GiveValue(e, ammo_fuel, op, val);
1715                                 break;
1716                         case "unlimited_ammo":
1717                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1718                                 break;
1719                         case "unlimited_weapon_ammo":
1720                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1721                                 break;
1722                         case "unlimited_superweapons":
1723                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1724                                 break;
1725                         case "jetpack":
1726                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1727                                 break;
1728                         case "fuel_regen":
1729                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1730                                 break;
1731                         case "strength":
1732                                 got += GiveValue(e, strength_finished, op, val);
1733                                 break;
1734                         case "invincible":
1735                                 got += GiveValue(e, invincible_finished, op, val);
1736                                 break;
1737                         case "superweapons":
1738                                 got += GiveValue(e, superweapons_finished, op, val);
1739                                 break;
1740                         case "cells":
1741                                 got += GiveValue(e, ammo_cells, op, val);
1742                                 break;
1743                         case "plasma":
1744                                 got += GiveValue(e, ammo_plasma, op, val);
1745                                 break;
1746                         case "shells":
1747                                 got += GiveValue(e, ammo_shells, op, val);
1748                                 break;
1749                         case "nails":
1750                         case "bullets":
1751                                 got += GiveValue(e, ammo_nails, op, val);
1752                                 break;
1753                         case "rockets":
1754                                 got += GiveValue(e, ammo_rockets, op, val);
1755                                 break;
1756                         case "health":
1757                                 got += GiveValue(e, health, op, val);
1758                                 break;
1759                         case "armor":
1760                                 got += GiveValue(e, armorvalue, op, val);
1761                                 break;
1762                         case "fuel":
1763                                 got += GiveValue(e, ammo_fuel, op, val);
1764                                 break;
1765                         default:
1766                                 FOREACH(Weapons, it != WEP_Null && cmd == it.netname, {
1767                     got += GiveWeapon(e, it.m_id, op, val);
1768                     break;
1769                                 });
1770                                 break;
1771                 }
1772                 val = 999;
1773                 op = OP_SET;
1774         }
1775
1776         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1777         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1778         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1779         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1780         FOREACH(Weapons, it != WEP_Null, {
1781                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1782                 if(!(save_weapons & (it.m_wepset)))
1783                         if(e.weapons & (it.m_wepset))
1784                                 it.wr_init(it);
1785         });
1786         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1787         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1788         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1789         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1790         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1791         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1792         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1793         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1794         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1795         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1796
1797         if(e.superweapons_finished <= 0)
1798                 if(e.weapons & WEPSET_SUPERWEAPONS)
1799                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1800
1801         if(e.strength_finished <= 0)
1802                 e.strength_finished = 0;
1803         else
1804                 e.strength_finished += time;
1805         if(e.invincible_finished <= 0)
1806                 e.invincible_finished = 0;
1807         else
1808                 e.invincible_finished += time;
1809         if(e.superweapons_finished <= 0)
1810                 e.superweapons_finished = 0;
1811         else
1812                 e.superweapons_finished += time;
1813
1814         if (!(e.weapons & WepSet_FromWeapon(PS(e).m_switchweapon)))
1815                 _switchweapon = true;
1816         if(_switchweapon)
1817                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1818
1819         return got;
1820 }
1821 #endif