qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66 }
  67
  68 void ItemDraw(entity this)
  69 {
  70     if(this.gravity)
  71     {
  72         Movetype_Physics_MatchServer(this, false);
  73         if(IS_ONGROUND(this))
  74         { // For some reason avelocity gets set to '0 0 0' here ...
  75             this.oldorigin = this.origin;
  76             this.gravity = 0;
  77
  78             if(autocvar_cl_animate_items)
  79             { // ... so reset it if animations are requested.
  80                 if(this.ItemStatus & ITS_ANIMATE1)
  81                     this.avelocity = '0 180 0';
  82
  83                 if(this.ItemStatus & ITS_ANIMATE2)
  84                     this.avelocity = '0 -90 0';
  85             }
  86
  87             // delay is for blocking item's position for a while;
  88             // it's a workaround for dropped weapons that receive the position
  89             // another time right after they spawn overriding animation position
  90             this.onground_time = time + 0.5;
  91         }
  92     }
  93     else if (autocvar_cl_animate_items)
  94     {
  95         if(this.ItemStatus & ITS_ANIMATE1)
  96         {
  97             this.angles += this.avelocity * frametime;
  98             float fade_in = bound(0, time - this.onground_time, 1);
  99             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 100         }
 101
 102         if(this.ItemStatus & ITS_ANIMATE2)
 103         {
 104             this.angles += this.avelocity * frametime;
 105             float fade_in = bound(0, time - this.onground_time, 1);
 106             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 107         }
 108     }
 109
 110     Item_SetAlpha(this);
 111 }
 112
 113 void ItemDrawSimple(entity this)
 114 {
 115     if(this.gravity)
 116     {
 117         Movetype_Physics_MatchServer(this, false);
 118
 119         if(IS_ONGROUND(this))
 120             this.gravity = 0;
 121     }
 122
 123     Item_SetAlpha(this);
 124 }
 125
 126 void Item_PreDraw(entity this)
 127 {
 128         if(warpzone_warpzones_exist)
 129         {
 130                 // just incase warpzones were initialized last, reset these
 131                 //this.alpha = 1; // alpha is already set by the draw function
 132                 this.drawmask = MASK_NORMAL;
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 alph = 0;
 139         else if(this.fade_start)
 140                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 141         else
 142                 alph = 1;
 143         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 144         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 145                 this.alpha = alph;
 146         if(alph <= 0)
 147                 this.drawmask = 0;
 148         else
 149                 this.drawmask = MASK_NORMAL;
 150 }
 151
 152 void ItemRemove(entity this)
 153 {
 154         if(this.mdl)
 155                 strunzone(this.mdl);
 156 }
 157
 158 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 159 {
 160     int sf = ReadByte();
 161
 162     if(sf & ISF_LOCATION)
 163     {
 164         this.origin_x = ReadCoord();
 165         this.origin_y = ReadCoord();
 166         this.origin_z = ReadCoord();
 167         setorigin(this, this.origin);
 168         this.oldorigin = this.origin;
 169     }
 170
 171     if(sf & ISF_ANGLES)
 172     {
 173         this.angles_x = ReadAngle();
 174         this.angles_y = ReadAngle();
 175         this.angles_z = ReadAngle();
 176     }
 177
 178     if(sf & ISF_SIZE)
 179     {
 180         float use_bigsize = ReadByte();
 181         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 182     }
 183
 184     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 185     {
 186         this.ItemStatus = ReadByte();
 187
 188         Item_SetAlpha(this);
 189
 190         if(autocvar_cl_fullbright_items)
 191             if(this.ItemStatus & ITS_ALLOWFB)
 192                 this.effects |= EF_FULLBRIGHT;
 193
 194         if(this.ItemStatus & ITS_GLOW)
 195         {
 196             if(this.ItemStatus & ITS_AVAILABLE)
 197                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 198             else
 199                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 200         }
 201     }
 202
 203     if(sf & ISF_MODEL)
 204     {
 205         this.drawmask  = MASK_NORMAL;
 206                 set_movetype(this, MOVETYPE_TOSS);
 207                 if (isnew) IL_PUSH(g_drawables, this);
 208         this.draw       = ItemDraw;
 209         this.solid = SOLID_TRIGGER;
 210         //this.flags |= FL_ITEM;
 211
 212         bool use_bigsize = ReadByte();
 213
 214         this.fade_end = ReadShort();
 215         this.fade_start = ReadShort();
 216         if(this.fade_start && !autocvar_cl_items_nofade)
 217                 setpredraw(this, Item_PreDraw);
 218
 219         if(this.mdl)
 220             strunzone(this.mdl);
 221
 222         this.mdl = "";
 223         string _fn = ReadString();
 224
 225         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 226         {
 227             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 228             this.draw = ItemDrawSimple;
 229
 230             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 231                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 232             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 233                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 234             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 235                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 236             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 237                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 238             else
 239             {
 240                 this.draw = ItemDraw;
 241                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 242             }
 243         }
 244
 245         if(this.draw != ItemDrawSimple)
 246             this.mdl = strzone(_fn);
 247
 248
 249         if(this.mdl == "")
 250             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 251
 252         precache_model(this.mdl);
 253         _setmodel(this, this.mdl);
 254
 255         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 256     }
 257
 258     if(sf & ISF_COLORMAP)
 259     {
 260         this.colormap = ReadShort();
 261         this.item_glowmod_x = ReadByte() / 255.0;
 262         this.item_glowmod_y = ReadByte() / 255.0;
 263         this.item_glowmod_z = ReadByte() / 255.0;
 264     }
 265
 266     if(sf & ISF_DROP)
 267     {
 268         this.gravity = 1;
 269         this.pushable = true;
 270         //this.angles = '0 0 0';
 271         set_movetype(this, MOVETYPE_TOSS);
 272         this.velocity_x = ReadCoord();
 273         this.velocity_y = ReadCoord();
 274         this.velocity_z = ReadCoord();
 275         setorigin(this, this.oldorigin);
 276
 277         if(!this.move_time)
 278         {
 279             this.move_time = time;
 280             this.spawntime = time;
 281         }
 282         else
 283             this.move_time = max(this.move_time, time);
 284     }
 285
 286     if(autocvar_cl_animate_items)
 287     {
 288         if(this.ItemStatus & ITS_ANIMATE1)
 289             this.avelocity = '0 180 0';
 290
 291         if(this.ItemStatus & ITS_ANIMATE2)
 292             this.avelocity = '0 -90 0';
 293     }
 294
 295     this.entremove = ItemRemove;
 296
 297     return true;
 298 }
 299
 300 #endif
 301
 302 #ifdef SVQC
 303 bool ItemSend(entity this, entity to, int sf)
 304 {
 305         if(this.gravity)
 306                 sf |= ISF_DROP;
 307         else
 308                 sf &= ~ISF_DROP;
 309
 310         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 311         WriteByte(MSG_ENTITY, sf);
 312
 313         //WriteByte(MSG_ENTITY, this.cnt);
 314         if(sf & ISF_LOCATION)
 315         {
 316                 WriteCoord(MSG_ENTITY, this.origin.x);
 317                 WriteCoord(MSG_ENTITY, this.origin.y);
 318                 WriteCoord(MSG_ENTITY, this.origin.z);
 319         }
 320
 321         if(sf & ISF_ANGLES)
 322         {
 323                 WriteAngle(MSG_ENTITY, this.angles_x);
 324                 WriteAngle(MSG_ENTITY, this.angles_y);
 325                 WriteAngle(MSG_ENTITY, this.angles_z);
 326         }
 327
 328         if(sf & ISF_SIZE)
 329         {
 330                 Pickup p = this.itemdef;
 331                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 332         }
 333
 334         if(sf & ISF_STATUS)
 335                 WriteByte(MSG_ENTITY, this.ItemStatus);
 336
 337         if(sf & ISF_MODEL)
 338         {
 339                 Pickup p = this.itemdef;
 340                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 341                 WriteShort(MSG_ENTITY, this.fade_end);
 342                 WriteShort(MSG_ENTITY, this.fade_start);
 343
 344                 if(this.mdl == "")
 345                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 346
 347                 WriteString(MSG_ENTITY, this.mdl);
 348         }
 349
 350
 351         if(sf & ISF_COLORMAP)
 352         {
 353                 WriteShort(MSG_ENTITY, this.colormap);
 354                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 355         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 356         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 357         }
 358
 359         if(sf & ISF_DROP)
 360         {
 361                 WriteCoord(MSG_ENTITY, this.velocity.x);
 362                 WriteCoord(MSG_ENTITY, this.velocity.y);
 363                 WriteCoord(MSG_ENTITY, this.velocity.z);
 364         }
 365
 366         return true;
 367 }
 368
 369 void ItemUpdate(entity this)
 370 {
 371         this.oldorigin = this.origin;
 372         this.SendFlags |= ISF_LOCATION;
 373 }
 374
 375 void UpdateItemAfterTeleport(entity this)
 376 {
 377         if(getSendEntity(this) == ItemSend)
 378                 ItemUpdate(this);
 379 }
 380
 381 bool have_pickup_item(entity this)
 382 {
 383         if(this.itemdef.instanceOfPowerup)
 384         {
 385                 if(autocvar_g_powerups > 0)
 386                         return true;
 387                 if(autocvar_g_powerups == 0)
 388                         return false;
 389         }
 390         else
 391         {
 392                 if(autocvar_g_pickup_items > 0)
 393                         return true;
 394                 if(autocvar_g_pickup_items == 0)
 395                         return false;
 396                 if(g_weaponarena)
 397                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 398                                 return false;
 399         }
 400         return true;
 401 }
 402
 403 /*
 404 float Item_Customize()
 405 {
 406         if(this.spawnshieldtime)
 407                 return true;
 408         if(this.weapons & ~other.weapons)
 409         {
 410                 this.colormod = '0 0 0';
 411                 this.glowmod = this.colormod;
 412                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 413                 return true;
 414         }
 415         else
 416         {
 417                 if(g_ghost_items)
 418                 {
 419                         this.colormod = stov(autocvar_g_ghost_items_color);
 420                         this.glowmod = this.colormod;
 421                         this.alpha = g_ghost_items;
 422                         return true;
 423                 }
 424                 else
 425                         return false;
 426         }
 427 }
 428 */
 429
 430 void Item_Show (entity e, float mode)
 431 {
 432         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 433         e.ItemStatus &= ~ITS_STAYWEP;
 434         entity def = e.itemdef;
 435         if (mode > 0)
 436         {
 437                 // make the item look normal, and be touchable
 438                 e.model = e.mdl;
 439                 e.solid = SOLID_TRIGGER;
 440                 e.spawnshieldtime = 1;
 441                 e.ItemStatus |= ITS_AVAILABLE;
 442         }
 443         else if (mode < 0)
 444         {
 445                 // hide the item completely
 446                 e.model = string_null;
 447                 e.solid = SOLID_NOT;
 448                 e.spawnshieldtime = 1;
 449                 e.ItemStatus &= ~ITS_AVAILABLE;
 450         }
 451         else {
 452         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 453                 || e.team // weapon stay isn't supported for teamed weapons
 454                 ;
 455         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 456         {
 457                 // make the item translucent and not touchable
 458                 e.model = e.mdl;
 459                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 460                 e.effects |= EF_STARDUST;
 461                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 462                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 463         }
 464         else
 465         {
 466                 //setmodel(e, "null");
 467                 e.solid = SOLID_NOT;
 468                 e.colormod = '0 0 0';
 469                 //e.glowmod = e.colormod;
 470                 e.spawnshieldtime = 1;
 471                 e.ItemStatus &= ~ITS_AVAILABLE;
 472         }}
 473
 474         if (def.m_glow)
 475                 e.ItemStatus |= ITS_GLOW;
 476
 477         if (autocvar_g_nodepthtestitems)
 478                 e.effects |= EF_NODEPTHTEST;
 479
 480
 481         if (autocvar_g_fullbrightitems)
 482                 e.ItemStatus |= ITS_ALLOWFB;
 483
 484         if (autocvar_sv_simple_items)
 485                 e.ItemStatus |= ITS_ALLOWSI;
 486
 487         // relink entity (because solid may have changed)
 488         setorigin(e, e.origin);
 489         e.SendFlags |= ISF_STATUS;
 490 }
 491
 492 void Item_Think(entity this)
 493 {
 494         this.nextthink = time;
 495         if(this.origin != this.oldorigin)
 496                 ItemUpdate(this);
 497 }
 498
 499 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 500 bool Item_ItemsTime_Allow(GameItem it);
 501 float Item_ItemsTime_UpdateTime(entity e, float t);
 502 void Item_ItemsTime_SetTime(entity e, float t);
 503 void Item_ItemsTime_SetTimesForAllPlayers();
 504
 505 void Item_Respawn (entity this)
 506 {
 507         Item_Show(this, 1);
 508         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 509         setorigin(this, this.origin);
 510
 511     if (Item_ItemsTime_Allow(this.itemdef) || this.weapons & WEPSET_SUPERWEAPONS)
 512         {
 513                 float t = Item_ItemsTime_UpdateTime(this, 0);
 514                 Item_ItemsTime_SetTime(this, t);
 515                 Item_ItemsTime_SetTimesForAllPlayers();
 516         }
 517
 518         setthink(this, Item_Think);
 519         this.nextthink = time;
 520
 521         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 522         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 523 }
 524
 525 void Item_RespawnCountdown (entity this)
 526 {
 527         if(this.count >= ITEM_RESPAWN_TICKS)
 528         {
 529                 if(this.waypointsprite_attached)
 530                         WaypointSprite_Kill(this.waypointsprite_attached);
 531                 Item_Respawn(this);
 532         }
 533         else
 534         {
 535                 this.nextthink = time + 1;
 536                 this.count += 1;
 537                 if(this.count == 1)
 538                 {
 539                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 540                         do {
 541                                 {
 542                                         entity wi = Weapons_from(this.weapon);
 543                                         if (wi != WEP_Null) {
 544                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 545                                                 wp.wp_extra = wi.m_id;
 546                                                 break;
 547                                         }
 548                                 }
 549                                 {
 550                                         entity ii = this.itemdef;
 551                                         if (ii != NULL) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 553                                                 wp.wp_extra = ii.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                         } while (0);
 558             if(this.waypointsprite_attached)
 559             {
 560                 GameItem def = this.itemdef;
 561                 if (Item_ItemsTime_SpectatorOnly(def))
 562                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 563                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 564             }
 565                 }
 566
 567                 if(this.waypointsprite_attached)
 568                 {
 569                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 570                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 571                                 {
 572                                         msg_entity = it;
 573                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 574                                 }
 575                         });
 576
 577                         WaypointSprite_Ping(this.waypointsprite_attached);
 578                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 579                 }
 580         }
 581 }
 582
 583 void Item_RespawnThink(entity this)
 584 {
 585         this.nextthink = time;
 586         if(this.origin != this.oldorigin)
 587                 ItemUpdate(this);
 588
 589         if(time >= this.wait)
 590                 Item_Respawn(this);
 591 }
 592
 593 void Item_ScheduleRespawnIn(entity e, float t)
 594 {
 595         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 596         if ((Item_ItemsTime_Allow(e.itemdef) || e.weapons & WEPSET_SUPERWEAPONS) && (t - ITEM_RESPAWN_TICKS) > 0)
 597         {
 598                 setthink(e, Item_RespawnCountdown);
 599                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 600                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 601                 e.count = 0;
 602                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 603                 Item_ItemsTime_SetTime(e, t);
 604                 Item_ItemsTime_SetTimesForAllPlayers();
 605         }
 606         else
 607         {
 608                 setthink(e, Item_RespawnThink);
 609                 e.nextthink = time;
 610                 e.scheduledrespawntime = time + t;
 611                 e.wait = time + t;
 612         }
 613 }
 614
 615 void Item_ScheduleRespawn(entity e)
 616 {
 617         if(e.respawntime > 0)
 618         {
 619                 Item_Show(e, 0);
 620                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 621         }
 622         else // if respawntime is -1, this item does not respawn
 623                 Item_Show(e, -1);
 624 }
 625
 626 void Item_ScheduleInitialRespawn(entity e)
 627 {
 628         Item_Show(e, 0);
 629         Item_ScheduleRespawnIn(e, game_starttime - time + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 630 }
 631
 632 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 633 {
 634         if (!item.(ammotype))
 635                 return false;
 636
 637         if (item.spawnshieldtime)
 638         {
 639                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 640                 {
 641                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 642                         goto YEAH;
 643                 }
 644         }
 645         else if(g_weapon_stay == 2)
 646         {
 647                 float mi = min(item.(ammotype), ammomax);
 648                 if (player.(ammotype) < mi)
 649                 {
 650                         player.(ammotype) = mi;
 651                         goto YEAH;
 652                 }
 653         }
 654
 655         return false;
 656
 657 LABEL(YEAH)
 658         switch(mode)
 659         {
 660                 case ITEM_MODE_FUEL:
 661                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 662                         break;
 663                 case ITEM_MODE_HEALTH:
 664                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 665                         break;
 666                 case ITEM_MODE_ARMOR:
 667                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 668                         break;
 669                 default:
 670                         break;
 671         }
 672         return true;
 673 }
 674
 675 float Item_GiveTo(entity item, entity player)
 676 {
 677         float pickedup;
 678
 679         // if nothing happens to player, just return without taking the item
 680         pickedup = false;
 681         int _switchweapon = 0;
 682         // in case the player has autoswitch enabled do the following:
 683         // if the player is using their best weapon before items are given, they
 684         // probably want to switch to an even better weapon after items are given
 685
 686         if(player.autoswitch)
 687         {
 688                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 689                 {
 690                         .entity weaponentity = weaponentities[slot];
 691                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 692                         {
 693                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 694                                         _switchweapon |= BIT(slot);
 695
 696                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 697                                         _switchweapon |= BIT(slot);
 698                         }
 699                 }
 700         }
 701
 702         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 703         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 704         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 705         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 706         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 707         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 708         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 709         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 710
 711         if (item.itemdef.instanceOfWeaponPickup)
 712         {
 713                 WepSet w;
 714                 w = item.weapons;
 715                 w &= ~player.weapons;
 716
 717                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 718                 {
 719                         pickedup = true;
 720                         FOREACH(Weapons, it != WEP_Null, {
 721                                 if(w & (it.m_wepset))
 722                                 {
 723                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 724                                         {
 725                                                 .entity weaponentity = weaponentities[slot];
 726                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 727                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 728                                         }
 729                                         W_GiveWeapon(player, it.m_id);
 730                                 }
 731                         });
 732                 }
 733         }
 734
 735         if (item.itemdef.instanceOfPowerup)
 736         {
 737                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 738                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 739                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 740                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 741         }
 742
 743         int its;
 744         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 745         {
 746                 pickedup = true;
 747                 player.items |= its;
 748                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 749         }
 750
 751         if (item.strength_finished)
 752         {
 753                 pickedup = true;
 754                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 755         }
 756         if (item.invincible_finished)
 757         {
 758                 pickedup = true;
 759                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 760         }
 761         if (item.superweapons_finished)
 762         {
 763                 pickedup = true;
 764                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 765         }
 766
 767 LABEL(skip)
 768
 769         // always eat teamed entities
 770         if(item.team)
 771                 pickedup = true;
 772
 773         if (!pickedup)
 774                 return 0;
 775
 776         // crude hack to enforce switching weapons
 777         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 778         {
 779                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 780                 {
 781                         .entity weaponentity = weaponentities[slot];
 782                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 783                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 784                 }
 785                 return 1;
 786         }
 787
 788         if(_switchweapon)
 789         {
 790                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 791                 {
 792                         .entity weaponentity = weaponentities[slot];
 793                         if(_switchweapon & BIT(slot))
 794                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 795                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 796                 }
 797         }
 798
 799         return 1;
 800 }
 801
 802 void Item_Touch(entity this, entity toucher)
 803 {
 804
 805         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 806         if (this.classname == "droppedweapon")
 807         {
 808                 if (ITEM_TOUCH_NEEDKILL())
 809                 {
 810                         delete(this);
 811                         return;
 812                 }
 813         }
 814
 815         if(!(toucher.flags & FL_PICKUPITEMS)
 816         || STAT(FROZEN, toucher)
 817         || IS_DEAD(toucher)
 818         || (this.solid != SOLID_TRIGGER)
 819         || (this.owner == toucher)
 820         || (time < this.item_spawnshieldtime)
 821         ) { return; }
 822
 823         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 824         {
 825                 case MUT_ITEMTOUCH_RETURN: { return; }
 826                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 827         }
 828
 829         toucher = M_ARGV(1, entity);
 830
 831         if (this.classname == "droppedweapon")
 832         {
 833                 this.strength_finished = max(0, this.strength_finished - time);
 834                 this.invincible_finished = max(0, this.invincible_finished - time);
 835                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 836         }
 837         entity it = this.itemdef;
 838         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 839         if (!gave)
 840         {
 841                 if (this.classname == "droppedweapon")
 842                 {
 843                         // undo what we did above
 844                         this.strength_finished += time;
 845                         this.invincible_finished += time;
 846                         this.superweapons_finished += time;
 847                 }
 848                 return;
 849         }
 850
 851 LABEL(pickup)
 852
 853         toucher.last_pickup = time;
 854
 855         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 856         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 857
 858         if (this.classname == "droppedweapon")
 859                 delete (this);
 860         else if (this.spawnshieldtime)
 861         {
 862                 entity e;
 863                 if(this.team)
 864                 {
 865                         RandomSelection_Init();
 866                         IL_EACH(g_items, it.team == this.team,
 867                         {
 868                                 if(it.itemdef) // is a registered item
 869                                 {
 870                                         Item_Show(it, -1);
 871                                         RandomSelection_AddEnt(it, it.cnt, 0);
 872                                 }
 873                         });
 874                         e = RandomSelection_chosen_ent;
 875
 876                 }
 877                 else
 878                         e = this;
 879                 Item_ScheduleRespawn(e);
 880         }
 881 }
 882
 883 void Item_Reset(entity this)
 884 {
 885         Item_Show(this, !this.state);
 886         setorigin(this, this.origin);
 887
 888         if (this.classname != "droppedweapon")
 889         {
 890                 setthink(this, Item_Think);
 891                 this.nextthink = time;
 892
 893                 if (this.waypointsprite_attached)
 894                         WaypointSprite_Kill(this.waypointsprite_attached);
 895
 896                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 897                         Item_ScheduleInitialRespawn(this);
 898         }
 899 }
 900
 901 void Item_FindTeam(entity this)
 902 {
 903         entity e;
 904
 905         if(this.effects & EF_NODRAW)
 906         {
 907                 // marker for item team search
 908                 LOG_TRACE("Initializing item team ", ftos(this.team));
 909                 RandomSelection_Init();
 910                 IL_EACH(g_items, it.team == this.team,
 911                 {
 912                         if(it.itemdef) // is a registered item
 913                                 RandomSelection_AddEnt(it, it.cnt, 0);
 914                 });
 915
 916                 e = RandomSelection_chosen_ent;
 917                 e.state = 0;
 918                 Item_Show(e, 1);
 919
 920                 IL_EACH(g_items, it.team == this.team,
 921                 {
 922                         if(it.itemdef) // is a registered item
 923                         {
 924                                 if(it != e)
 925                                 {
 926                                         // make it non-spawned
 927                                         Item_Show(it, -1);
 928                                         it.state = 1; // state 1 = initially hidden item, apparently
 929                                 }
 930                                 it.effects &= ~EF_NODRAW;
 931                         }
 932                 });
 933
 934                 Item_Reset(this);
 935         }
 936 }
 937
 938 // Savage: used for item garbage-collection
 939 void RemoveItem(entity this)
 940 {
 941         if(wasfreed(this) || !this) { return; }
 942         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 943         delete(this);
 944 }
 945
 946 // pickup evaluation functions
 947 // these functions decide how desirable an item is to the bots
 948
 949 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 950
 951 float weapon_pickupevalfunc(entity player, entity item)
 952 {
 953         // See if I have it already
 954         if(player.weapons & item.weapons)
 955         {
 956                 // If I can pick it up
 957                 if(!item.spawnshieldtime)
 958                         return 0;
 959                 return ammo_pickupevalfunc(player, item);
 960         }
 961
 962         // reduce weapon value if bot already got a good arsenal
 963         float c = 1;
 964         int weapons_value = 0;
 965         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
 966                 weapons_value += it.bot_pickupbasevalue;
 967         });
 968         c -= bound(0, weapons_value / 20000, 1) * 0.5;
 969
 970         return item.bot_pickupbasevalue * c;
 971 }
 972
 973 float ammo_pickupevalfunc(entity player, entity item)
 974 {
 975         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 976         entity wpn = NULL;
 977         float c = 0;
 978         float rating = 0;
 979
 980         // Detect needed ammo
 981         if(item.itemdef.instanceOfWeaponPickup)
 982         {
 983                 entity ammo = NULL;
 984                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
 985                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
 986                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
 987                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
 988                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
 989                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
 990
 991                 if(!ammo)
 992                         return 0;
 993                 wpn = item;
 994                 rating = ammo.m_botvalue;
 995         }
 996         else
 997         {
 998                 FOREACH(Weapons, it != WEP_Null, {
 999                         if(!(player.weapons & (it.m_wepset)))
1000                                 continue;
1001
1002                         switch(it.ammo_field)
1003                         {
1004                                 case ammo_shells:  need_shells  = true; break;
1005                                 case ammo_shells:  need_shells  = true; break;
1006                                 case ammo_nails:   need_nails   = true; break;
1007                                 case ammo_rockets: need_rockets = true; break;
1008                                 case ammo_cells:   need_cells   = true; break;
1009                                 case ammo_plasma:  need_plasma  = true; break;
1010                                 case ammo_fuel:    need_fuel    = true; break;
1011                         }
1012                 });
1013                 rating = item.bot_pickupbasevalue;
1014         }
1015
1016         if (need_shells)
1017         if (item.ammo_shells)
1018         if (player.ammo_shells < g_pickup_shells_max)
1019                 c = item.ammo_shells / player.ammo_shells;
1020         if (need_nails)
1021         if (item.ammo_nails)
1022         if (player.ammo_nails < g_pickup_nails_max)
1023                 c = item.ammo_nails / player.ammo_nails;
1024         if (need_rockets)
1025         if (item.ammo_rockets)
1026         if (player.ammo_rockets < g_pickup_rockets_max)
1027                 c = item.ammo_rockets / player.ammo_rockets;
1028         if (need_cells)
1029         if (item.ammo_cells)
1030         if (player.ammo_cells < g_pickup_cells_max)
1031                 c = item.ammo_cells / player.ammo_cells;
1032         if (need_plasma)
1033         if (item.ammo_plasma)
1034         if (player.ammo_plasma < g_pickup_plasma_max)
1035                 c = item.ammo_plasma / player.ammo_plasma;
1036         if (need_fuel)
1037         if (item.ammo_fuel)
1038         if (player.ammo_fuel < g_pickup_fuel_max)
1039                 c = item.ammo_fuel / player.ammo_fuel;
1040
1041         rating *= min(2, c);
1042         if(wpn)
1043                 rating += wpn.bot_pickupbasevalue * 0.1;
1044         return rating;
1045 }
1046
1047 .int item_group;
1048 .int item_group_count;
1049 float healtharmor_pickupevalfunc(entity player, entity item)
1050 {
1051         float c = 0;
1052         float rating = item.bot_pickupbasevalue;
1053
1054         float itemarmor = item.armorvalue;
1055         float itemhealth = item.health;
1056         if(item.item_group)
1057         {
1058                 itemarmor *= min(4, item.item_group_count);
1059                 itemhealth *= min(4, item.item_group_count);
1060         }
1061         if (itemarmor)
1062         if (player.armorvalue < item.max_armorvalue)
1063                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1064         if (itemhealth)
1065         if (player.health < item.max_health)
1066                 c = itemhealth / max(1, player.health);
1067
1068         rating *= min(2, c);
1069         return rating;
1070 }
1071
1072 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1073 {
1074         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1075                 RemoveItem(this);
1076 }
1077
1078 void item_use(entity this, entity actor, entity trigger)
1079 {
1080         // use the touch function to handle collection
1081         gettouch(this)(this, actor);
1082 }
1083
1084 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1085 {
1086         string itemname = def.m_name;
1087         Model itemmodel = def.m_model;
1088     Sound pickupsound = def.m_sound;
1089         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1090         float pickupbasevalue = def.m_botvalue;
1091         int itemflags = def.m_itemflags;
1092
1093         startitem_failed = false;
1094
1095         this.item_model_ent = itemmodel;
1096     this.item_pickupsound_ent = pickupsound;
1097
1098     if(def.m_iteminit)
1099         def.m_iteminit(this);
1100
1101         if(!this.respawntime) // both need to be set
1102         {
1103                 this.respawntime = defaultrespawntime;
1104                 this.respawntimejitter = defaultrespawntimejitter;
1105         }
1106
1107         if(!this.pickup_anyway && def.m_pickupanyway)
1108                 this.pickup_anyway = def.m_pickupanyway();
1109
1110         int itemid = def.m_itemid;
1111         this.items = itemid;
1112         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1113         this.weapon = weaponid;
1114
1115         if(!this.fade_end)
1116         {
1117                 this.fade_start = autocvar_g_items_mindist;
1118                 this.fade_end = autocvar_g_items_maxdist;
1119         }
1120
1121         if(weaponid)
1122                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1123
1124         this.flags = FL_ITEM | itemflags;
1125         IL_PUSH(g_items, this);
1126
1127         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1128         {
1129                 startitem_failed = true;
1130                 delete(this);
1131                 return;
1132         }
1133
1134         // is it a dropped weapon?
1135         if (this.classname == "droppedweapon")
1136         {
1137                 this.reset = SUB_Remove;
1138                 // it's a dropped weapon
1139                 set_movetype(this, MOVETYPE_TOSS);
1140
1141                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1142                 setthink(this, RemoveItem);
1143                 this.nextthink = time + 20;
1144
1145                 this.takedamage = DAMAGE_YES;
1146                 this.event_damage = Item_Damage;
1147
1148                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1149                 {
1150                         // if item is worthless after a timer, have it expire then
1151                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1152                 }
1153
1154                 // don't drop if in a NODROP zone (such as lava)
1155                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1156                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1157                 {
1158                         startitem_failed = true;
1159                         delete(this);
1160                         return;
1161                 }
1162         }
1163         else
1164         {
1165                 if(!have_pickup_item(this))
1166                 {
1167                         startitem_failed = true;
1168                         delete (this);
1169                         return;
1170                 }
1171
1172                 if(this.angles != '0 0 0')
1173                         this.SendFlags |= ISF_ANGLES;
1174
1175                 this.reset = Item_Reset;
1176                 // it's a level item
1177                 if(this.spawnflags & 1)
1178                         this.noalign = 1;
1179                 if (this.noalign > 0)
1180                         set_movetype(this, MOVETYPE_NONE);
1181                 else
1182                         set_movetype(this, MOVETYPE_TOSS);
1183                 // do item filtering according to game mode and other things
1184                 if (this.noalign <= 0)
1185                 {
1186                         // first nudge it off the floor a little bit to avoid math errors
1187                         setorigin(this, this.origin + '0 0 1');
1188                         // set item size before we spawn a spawnfunc_waypoint
1189                         setsize(this, def.m_mins, def.m_maxs);
1190                         this.SendFlags |= ISF_SIZE;
1191                         // note droptofloor returns false if stuck/or would fall too far
1192                         if (!this.noalign)
1193                                 droptofloor(this);
1194                         waypoint_spawnforitem(this);
1195                 }
1196
1197                 /*
1198                  * can't do it that way, as it would break maps
1199                  * TODO make a target_give like entity another way, that perhaps has
1200                  * the weapon name in a key
1201                 if(this.targetname)
1202                 {
1203                         // target_give not yet supported; maybe later
1204                         print("removed targeted ", this.classname, "\n");
1205                         startitem_failed = true;
1206                         remove (this);
1207                         return;
1208                 }
1209                 */
1210
1211                 if(this.targetname != "" && (this.spawnflags & 16))
1212                         this.use = item_use;
1213
1214                 if(autocvar_spawn_debug >= 2)
1215                 {
1216             // why not flags & fl_item?
1217                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1218                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1219                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1220                 error("Mapper sucks.");
1221             });
1222                         this.is_item = true;
1223                 }
1224
1225                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1226
1227                 precache_model(this.model);
1228                 precache_sound(this.item_pickupsound);
1229
1230                 if (   def.instanceOfPowerup
1231                         || def.instanceOfWeaponPickup
1232                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1233                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1234                         || (itemid & (IT_KEY1 | IT_KEY2))
1235                 ) this.target = "###item###"; // for finding the nearest item using find()
1236
1237                 Item_ItemsTime_SetTime(this, 0);
1238         }
1239
1240         this.bot_pickup = true;
1241         this.bot_pickupevalfunc = pickupevalfunc;
1242         this.bot_pickupbasevalue = pickupbasevalue;
1243         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1244         this.netname = itemname;
1245         settouch(this, Item_Touch);
1246         setmodel(this, MDL_Null); // precision set below
1247         //this.effects |= EF_LOWPRECISION;
1248
1249         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1250
1251         this.SendFlags |= ISF_SIZE;
1252
1253         if (!(this.spawnflags & 1024)) {
1254                 if(def.instanceOfPowerup)
1255                         this.ItemStatus |= ITS_ANIMATE1;
1256
1257                 if(this.armorvalue || this.health)
1258                         this.ItemStatus |= ITS_ANIMATE2;
1259         }
1260
1261         if(def.instanceOfWeaponPickup)
1262         {
1263                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1264                         this.colormap = 1024; // color shirt=0 pants=0 grey
1265                 else
1266                         this.gravity = 1;
1267                 if (!(this.spawnflags & 1024))
1268                         this.ItemStatus |= ITS_ANIMATE1;
1269                 this.SendFlags |= ISF_COLORMAP;
1270         }
1271
1272         this.state = 0;
1273         if(this.team) // broken, no idea why.
1274         {
1275                 if(!this.cnt)
1276                         this.cnt = 1; // item probability weight
1277
1278                 this.effects |= EF_NODRAW; // marker for item team search
1279                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1280         }
1281         else
1282                 Item_Reset(this);
1283
1284         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1285
1286         // call this hook after everything else has been done
1287         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1288         {
1289                 startitem_failed = true;
1290                 delete(this);
1291                 return;
1292         }
1293
1294         setItemGroup(this);
1295 }
1296
1297 void StartItem(entity this, GameItem def)
1298 {
1299     _StartItem(
1300         this,
1301         this.itemdef = def,
1302         def.m_respawntime(), // defaultrespawntime
1303         def.m_respawntimejitter() // defaultrespawntimejitter
1304         );
1305 }
1306
1307 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1308 int group_count = 1;
1309
1310 void setItemGroup(entity this)
1311 {
1312         if(!IS_SMALL(this.itemdef))
1313                 return;
1314
1315         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1316         {
1317                 if(!this.item_group)
1318                 {
1319                         if(!it.item_group)
1320                         {
1321                                 it.item_group = group_count;
1322                                 group_count++;
1323                         }
1324                         this.item_group = it.item_group;
1325                 }
1326                 else // spawning item is already part of a item_group X
1327                 {
1328                         if(!it.item_group)
1329                                 it.item_group = this.item_group;
1330                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1331                         {
1332                                 int grY = it.item_group;
1333                                 // move all items of item_group Y to item_group X
1334                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1335                                 {
1336                                         if(it.item_group == grY)
1337                                                 it.item_group = this.item_group;
1338                                 });
1339                         }
1340                 }
1341         });
1342 }
1343
1344 void setItemGroupCount()
1345 {
1346         for (int k = 1; k <= group_count; k++)
1347         {
1348                 int count = 0;
1349                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1350                 if (count)
1351                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1352         }
1353 }
1354
1355 spawnfunc(item_rockets)
1356 {
1357     StartItem(this, ITEM_Rockets);
1358 }
1359
1360 spawnfunc(item_bullets)
1361 {
1362         if(!weaponswapping)
1363         if(autocvar_sv_q3acompat_machineshotgunswap)
1364         if(this.classname != "droppedweapon")
1365         {
1366                 weaponswapping = true;
1367                 spawnfunc_item_shells(this);
1368                 weaponswapping = false;
1369                 return;
1370         }
1371
1372     StartItem(this, ITEM_Bullets);
1373 }
1374
1375 spawnfunc(item_cells)
1376 {
1377         StartItem(this, ITEM_Cells);
1378 }
1379
1380 spawnfunc(item_plasma)
1381 {
1382         StartItem(this, ITEM_Plasma);
1383 }
1384
1385 spawnfunc(item_shells)
1386 {
1387         if(!weaponswapping)
1388         if(autocvar_sv_q3acompat_machineshotgunswap)
1389         if(this.classname != "droppedweapon")
1390         {
1391                 weaponswapping = true;
1392                 spawnfunc_item_bullets(this);
1393                 weaponswapping = false;
1394                 return;
1395         }
1396
1397         StartItem(this, ITEM_Shells);
1398 }
1399
1400 spawnfunc(item_armor_small)
1401 {
1402         StartItem(this, ITEM_ArmorSmall);
1403 }
1404
1405 spawnfunc(item_armor_medium)
1406 {
1407         StartItem(this, ITEM_ArmorMedium);
1408 }
1409
1410 spawnfunc(item_armor_big)
1411 {
1412         StartItem(this, ITEM_ArmorBig);
1413 }
1414
1415 spawnfunc(item_armor_mega)
1416 {
1417         StartItem(this, ITEM_ArmorMega);
1418 }
1419
1420 spawnfunc(item_health_small)
1421 {
1422         StartItem(this, ITEM_HealthSmall);
1423 }
1424
1425 spawnfunc(item_health_medium)
1426 {
1427     StartItem(this, ITEM_HealthMedium);
1428 }
1429
1430 spawnfunc(item_health_big)
1431 {
1432         StartItem(this, ITEM_HealthBig);
1433 }
1434
1435 spawnfunc(item_health_mega)
1436 {
1437     StartItem(this, ITEM_HealthMega);
1438 }
1439
1440 // support old misnamed entities
1441 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1442 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1443 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1444 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1445 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1446 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1447 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1448
1449 spawnfunc(item_strength)
1450 {
1451         StartItem(this, ITEM_Strength);
1452 }
1453
1454 spawnfunc(item_invincible)
1455 {
1456         StartItem(this, ITEM_Shield);
1457 }
1458
1459 // compatibility:
1460 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1461
1462 void target_items_use(entity this, entity actor, entity trigger)
1463 {
1464         if(actor.classname == "droppedweapon")
1465         {
1466                 EXACTTRIGGER_TOUCH(this, trigger);
1467                 delete(actor);
1468                 return;
1469         }
1470
1471         if (!IS_PLAYER(actor))
1472                 return;
1473         if(IS_DEAD(actor))
1474                 return;
1475         if(trigger.solid == SOLID_TRIGGER)
1476         {
1477                 EXACTTRIGGER_TOUCH(this, trigger);
1478         }
1479
1480         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1481         {
1482                 delete(it);
1483         });
1484
1485         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1486                 centerprint(actor, this.message);
1487 }
1488
1489 spawnfunc(target_items)
1490 {
1491         int n, j;
1492         string s;
1493
1494         this.use = target_items_use;
1495         if(!this.strength_finished)
1496                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1497         if(!this.invincible_finished)
1498                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1499         if(!this.superweapons_finished)
1500                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1501
1502         n = tokenize_console(this.netname);
1503         if(argv(0) == "give")
1504         {
1505                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1506         }
1507         else
1508         {
1509                 for(j = 0; j < n; ++j)
1510                 {
1511                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1512                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1513                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1514                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1515                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1516                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1517                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1518                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1519                         else
1520                         {
1521                                 FOREACH(Buffs, it != BUFF_Null,
1522                                 {
1523                                         s = Buff_UndeprecateName(argv(j));
1524                                         if(s == it.m_name)
1525                                         {
1526                                                 this.buffs |= (it.m_itemid);
1527                                                 break;
1528                                         }
1529                                 });
1530                                 FOREACH(Weapons, it != WEP_Null, {
1531                                         s = W_UndeprecateName(argv(j));
1532                                         if(s == it.netname)
1533                                         {
1534                                                 this.weapons |= (it.m_wepset);
1535                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1536                                                         it.wr_init(it);
1537                                                 break;
1538                                         }
1539                                 });
1540                         }
1541                 }
1542
1543                 string itemprefix, valueprefix;
1544                 if(this.spawnflags == 0)
1545                 {
1546                         itemprefix = "";
1547                         valueprefix = "";
1548                 }
1549                 else if(this.spawnflags == 1)
1550                 {
1551                         itemprefix = "max ";
1552                         valueprefix = "max ";
1553                 }
1554                 else if(this.spawnflags == 2)
1555                 {
1556                         itemprefix = "min ";
1557                         valueprefix = "min ";
1558                 }
1559                 else if(this.spawnflags == 4)
1560                 {
1561                         itemprefix = "minus ";
1562                         valueprefix = "max ";
1563                 }
1564                 else
1565                 {
1566                         error("invalid spawnflags");
1567                         itemprefix = valueprefix = string_null;
1568                 }
1569
1570                 this.netname = "";
1571                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1572                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1573                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1574                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1575                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1576                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1577                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1578                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1579                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1580                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1581                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1582                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1583                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1584                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1585                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1586                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1587                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1588         }
1589         this.netname = strzone(this.netname);
1590         //print(this.netname, "\n");
1591
1592         n = tokenize_console(this.netname);
1593         for(j = 0; j < n; ++j)
1594         {
1595                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1596             it.wr_init(it);
1597             break;
1598                 });
1599         }
1600 }
1601
1602 spawnfunc(item_fuel)
1603 {
1604         StartItem(this, ITEM_JetpackFuel);
1605 }
1606
1607 spawnfunc(item_fuel_regen)
1608 {
1609         if(start_items & ITEM_JetpackRegen.m_itemid)
1610         {
1611                 spawnfunc_item_fuel(this);
1612                 return;
1613         }
1614         StartItem(this, ITEM_JetpackRegen);
1615 }
1616
1617 spawnfunc(item_jetpack)
1618 {
1619         if(start_items & ITEM_Jetpack.m_itemid)
1620         {
1621                 spawnfunc_item_fuel(this);
1622                 return;
1623         }
1624         StartItem(this, ITEM_Jetpack);
1625 }
1626
1627 float GiveWeapon(entity e, float wpn, float op, float val)
1628 {
1629         WepSet v0, v1;
1630         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1631         v0 = (e.weapons & s);
1632         switch(op)
1633         {
1634                 case OP_SET:
1635                         if(val > 0)
1636                                 e.weapons |= s;
1637                         else
1638                                 e.weapons &= ~s;
1639                         break;
1640                 case OP_MIN:
1641                 case OP_PLUS:
1642                         if(val > 0)
1643                                 e.weapons |= s;
1644                         break;
1645                 case OP_MAX:
1646                         if(val <= 0)
1647                                 e.weapons &= ~s;
1648                         break;
1649                 case OP_MINUS:
1650                         if(val > 0)
1651                                 e.weapons &= ~s;
1652                         break;
1653         }
1654         v1 = (e.weapons & s);
1655         return (v0 != v1);
1656 }
1657
1658 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1659 {
1660         bool had_buff = (e.buffs & thebuff.m_itemid);
1661         switch(op)
1662         {
1663                 case OP_SET:
1664                         if(val > 0)
1665                                 e.buffs |= thebuff.m_itemid;
1666                         else
1667                                 e.buffs &= ~thebuff.m_itemid;
1668                         break;
1669                 case OP_MIN:
1670                 case OP_PLUS:
1671                         if(val > 0)
1672                                 e.buffs |= thebuff.m_itemid;
1673                         break;
1674                 case OP_MAX:
1675                         if(val <= 0)
1676                                 e.buffs &= ~thebuff.m_itemid;
1677                         break;
1678                 case OP_MINUS:
1679                         if(val > 0)
1680                                 e.buffs &= ~thebuff.m_itemid;
1681                         break;
1682         }
1683         bool have_buff = (e.buffs & thebuff.m_itemid);
1684         return (had_buff != have_buff);
1685 }
1686
1687 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1688 {
1689         if(v1 == v0)
1690                 return;
1691         if(v1 <= v0 - t)
1692         {
1693                 if(snd_decr != NULL)
1694                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1695         }
1696         else if(v0 >= v0 + t)
1697         {
1698                 if(snd_incr != NULL)
1699                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1700         }
1701 }
1702
1703 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1704 {
1705         if(v0 < v1)
1706                 e.(rotfield) = max(e.(rotfield), time + rottime);
1707         else if(v0 > v1)
1708                 e.(regenfield) = max(e.(regenfield), time + regentime);
1709 }
1710 float GiveItems(entity e, float beginarg, float endarg)
1711 {
1712         float got, i, val, op;
1713         string cmd;
1714
1715         val = 999;
1716         op = OP_SET;
1717
1718         got = 0;
1719
1720         int _switchweapon = 0;
1721
1722         if(e.autoswitch)
1723         {
1724                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1725                 {
1726                         .entity weaponentity = weaponentities[slot];
1727                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1728                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1729                                 _switchweapon |= BIT(slot);
1730                 }
1731         }
1732
1733         e.strength_finished = max(0, e.strength_finished - time);
1734         e.invincible_finished = max(0, e.invincible_finished - time);
1735         e.superweapons_finished = max(0, e.superweapons_finished - time);
1736
1737         PREGIVE(e, items);
1738         PREGIVE_WEAPONS(e);
1739         PREGIVE(e, strength_finished);
1740         PREGIVE(e, invincible_finished);
1741         PREGIVE(e, superweapons_finished);
1742         PREGIVE(e, ammo_nails);
1743         PREGIVE(e, ammo_cells);
1744         PREGIVE(e, ammo_plasma);
1745         PREGIVE(e, ammo_shells);
1746         PREGIVE(e, ammo_rockets);
1747         PREGIVE(e, ammo_fuel);
1748         PREGIVE(e, armorvalue);
1749         PREGIVE(e, health);
1750
1751         for(i = beginarg; i < endarg; ++i)
1752         {
1753                 cmd = argv(i);
1754
1755                 if(cmd == "0" || stof(cmd))
1756                 {
1757                         val = stof(cmd);
1758                         continue;
1759                 }
1760                 switch(cmd)
1761                 {
1762                         case "no":
1763                                 op = OP_MAX;
1764                                 val = 0;
1765                                 continue;
1766                         case "max":
1767                                 op = OP_MAX;
1768                                 continue;
1769                         case "min":
1770                                 op = OP_MIN;
1771                                 continue;
1772                         case "plus":
1773                                 op = OP_PLUS;
1774                                 continue;
1775                         case "minus":
1776                                 op = OP_MINUS;
1777                                 continue;
1778                         case "ALL":
1779                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1780                                 got += GiveValue(e, strength_finished, op, val);
1781                                 got += GiveValue(e, invincible_finished, op, val);
1782                                 got += GiveValue(e, superweapons_finished, op, val);
1783                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1784                         case "all":
1785                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1786                                 got += GiveValue(e, health, op, val);
1787                                 got += GiveValue(e, armorvalue, op, val);
1788                         case "allweapons":
1789                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1790                         //case "allbuffs": // all buffs makes a player god, do not want!
1791                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1792                         case "allammo":
1793                                 got += GiveValue(e, ammo_cells, op, val);
1794                                 got += GiveValue(e, ammo_plasma, op, val);
1795                                 got += GiveValue(e, ammo_shells, op, val);
1796                                 got += GiveValue(e, ammo_nails, op, val);
1797                                 got += GiveValue(e, ammo_rockets, op, val);
1798                                 got += GiveValue(e, ammo_fuel, op, val);
1799                                 break;
1800                         case "unlimited_ammo":
1801                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1802                                 break;
1803                         case "unlimited_weapon_ammo":
1804                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1805                                 break;
1806                         case "unlimited_superweapons":
1807                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1808                                 break;
1809                         case "jetpack":
1810                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1811                                 break;
1812                         case "fuel_regen":
1813                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1814                                 break;
1815                         case "strength":
1816                                 got += GiveValue(e, strength_finished, op, val);
1817                                 break;
1818                         case "invincible":
1819                                 got += GiveValue(e, invincible_finished, op, val);
1820                                 break;
1821                         case "superweapons":
1822                                 got += GiveValue(e, superweapons_finished, op, val);
1823                                 break;
1824                         case "cells":
1825                                 got += GiveValue(e, ammo_cells, op, val);
1826                                 break;
1827                         case "plasma":
1828                                 got += GiveValue(e, ammo_plasma, op, val);
1829                                 break;
1830                         case "shells":
1831                                 got += GiveValue(e, ammo_shells, op, val);
1832                                 break;
1833                         case "nails":
1834                         case "bullets":
1835                                 got += GiveValue(e, ammo_nails, op, val);
1836                                 break;
1837                         case "rockets":
1838                                 got += GiveValue(e, ammo_rockets, op, val);
1839                                 break;
1840                         case "health":
1841                                 got += GiveValue(e, health, op, val);
1842                                 break;
1843                         case "armor":
1844                                 got += GiveValue(e, armorvalue, op, val);
1845                                 break;
1846                         case "fuel":
1847                                 got += GiveValue(e, ammo_fuel, op, val);
1848                                 break;
1849                         default:
1850                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1851                                 {
1852                                         got += GiveBuff(e, it, op, val);
1853                                         break;
1854                                 });
1855                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1856                     got += GiveWeapon(e, it.m_id, op, val);
1857                     break;
1858                                 });
1859                                 break;
1860                 }
1861                 val = 999;
1862                 op = OP_SET;
1863         }
1864
1865         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1866         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1867         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1868         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1869         FOREACH(Weapons, it != WEP_Null, {
1870                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1871                 if(!(save_weapons & (it.m_wepset)))
1872                         if(e.weapons & (it.m_wepset))
1873                                 it.wr_init(it);
1874         });
1875         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1876         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1877         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1878         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1879         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1880         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1881         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1882         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1883         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1884         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1885         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1886
1887         if(e.superweapons_finished <= 0)
1888                 if(e.weapons & WEPSET_SUPERWEAPONS)
1889                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1890
1891         if(e.strength_finished <= 0)
1892                 e.strength_finished = 0;
1893         else
1894                 e.strength_finished += time;
1895         if(e.invincible_finished <= 0)
1896                 e.invincible_finished = 0;
1897         else
1898                 e.invincible_finished += time;
1899         if(e.superweapons_finished <= 0)
1900                 e.superweapons_finished = 0;
1901         else
1902                 e.superweapons_finished += time;
1903
1904         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1905         {
1906                 .entity weaponentity = weaponentities[slot];
1907                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1908                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1909                         _switchweapon |= BIT(slot);
1910         }
1911
1912         if(_switchweapon)
1913         {
1914                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1915                 {
1916                         .entity weaponentity = weaponentities[slot];
1917                         if(_switchweapon & BIT(slot))
1918                                 W_SwitchWeapon_Force(e, w_getbestweapon(e, weaponentity), weaponentity);
1919                 }
1920         }
1921
1922         return got;
1923 }
1924 #endif