qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 alph = 0;
 139         else if(this.fade_start)
 140                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 141         else
 142                 alph = 1;
 143         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 144         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 145                 this.alpha = alph;
 146         if(alph <= 0)
 147                 this.drawmask = 0;
 148         //else
 149                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 150 }
 151
 152 void ItemRemove(entity this)
 153 {
 154         if(this.mdl)
 155                 strunzone(this.mdl);
 156 }
 157
 158 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 159 {
 160     int sf = ReadByte();
 161
 162     if(sf & ISF_LOCATION)
 163     {
 164         this.origin_x = ReadCoord();
 165         this.origin_y = ReadCoord();
 166         this.origin_z = ReadCoord();
 167         setorigin(this, this.origin);
 168         this.oldorigin = this.origin;
 169     }
 170
 171     if(sf & ISF_ANGLES)
 172     {
 173         this.angles_x = ReadAngle();
 174         this.angles_y = ReadAngle();
 175         this.angles_z = ReadAngle();
 176     }
 177
 178     if(sf & ISF_SIZE)
 179     {
 180         float use_bigsize = ReadByte();
 181         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 182     }
 183
 184     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 185     {
 186         this.ItemStatus = ReadByte();
 187
 188         Item_SetAlpha(this);
 189
 190         if(autocvar_cl_fullbright_items)
 191             if(this.ItemStatus & ITS_ALLOWFB)
 192                 this.effects |= EF_FULLBRIGHT;
 193
 194         if(this.ItemStatus & ITS_GLOW)
 195         {
 196             if(this.ItemStatus & ITS_AVAILABLE)
 197                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 198             else
 199                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 200         }
 201     }
 202
 203     if(sf & ISF_MODEL)
 204     {
 205         this.drawmask  = MASK_NORMAL;
 206                 set_movetype(this, MOVETYPE_TOSS);
 207                 if (isnew) IL_PUSH(g_drawables, this);
 208         this.draw       = ItemDraw;
 209         this.solid = SOLID_TRIGGER;
 210         //this.flags |= FL_ITEM;
 211
 212         bool use_bigsize = ReadByte();
 213
 214         this.fade_end = ReadShort();
 215         this.fade_start = ReadShort();
 216         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 217                 setpredraw(this, Item_PreDraw);
 218
 219         if(this.mdl)
 220             strunzone(this.mdl);
 221
 222         this.mdl = "";
 223         string _fn = ReadString();
 224
 225         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 226         {
 227             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 228             this.draw = ItemDrawSimple;
 229
 230             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 231                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 232             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 233                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 234             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 235                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 236             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 237                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 238             else
 239             {
 240                 this.draw = ItemDraw;
 241                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 242             }
 243         }
 244
 245         if(this.draw != ItemDrawSimple)
 246             this.mdl = strzone(_fn);
 247
 248
 249         if(this.mdl == "")
 250             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 251
 252         precache_model(this.mdl);
 253         _setmodel(this, this.mdl);
 254
 255         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 256     }
 257
 258     if(sf & ISF_COLORMAP)
 259     {
 260         this.colormap = ReadShort();
 261         this.item_glowmod_x = ReadByte() / 255.0;
 262         this.item_glowmod_y = ReadByte() / 255.0;
 263         this.item_glowmod_z = ReadByte() / 255.0;
 264     }
 265
 266     if(sf & ISF_DROP)
 267     {
 268         this.gravity = 1;
 269         this.pushable = true;
 270         //this.angles = '0 0 0';
 271         set_movetype(this, MOVETYPE_TOSS);
 272         this.velocity_x = ReadCoord();
 273         this.velocity_y = ReadCoord();
 274         this.velocity_z = ReadCoord();
 275         setorigin(this, this.oldorigin);
 276
 277         if(!this.move_time)
 278         {
 279             this.move_time = time;
 280             this.spawntime = time;
 281         }
 282         else
 283             this.move_time = max(this.move_time, time);
 284     }
 285
 286     if(autocvar_cl_animate_items)
 287     {
 288         if(this.ItemStatus & ITS_ANIMATE1)
 289             this.avelocity = '0 180 0';
 290
 291         if(this.ItemStatus & ITS_ANIMATE2)
 292             this.avelocity = '0 -90 0';
 293     }
 294
 295     this.entremove = ItemRemove;
 296
 297     return true;
 298 }
 299
 300 #endif
 301
 302 #ifdef SVQC
 303 bool ItemSend(entity this, entity to, int sf)
 304 {
 305         if(this.gravity)
 306                 sf |= ISF_DROP;
 307         else
 308                 sf &= ~ISF_DROP;
 309
 310         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 311         WriteByte(MSG_ENTITY, sf);
 312
 313         //WriteByte(MSG_ENTITY, this.cnt);
 314         if(sf & ISF_LOCATION)
 315         {
 316                 WriteCoord(MSG_ENTITY, this.origin.x);
 317                 WriteCoord(MSG_ENTITY, this.origin.y);
 318                 WriteCoord(MSG_ENTITY, this.origin.z);
 319         }
 320
 321         if(sf & ISF_ANGLES)
 322         {
 323                 WriteAngle(MSG_ENTITY, this.angles_x);
 324                 WriteAngle(MSG_ENTITY, this.angles_y);
 325                 WriteAngle(MSG_ENTITY, this.angles_z);
 326         }
 327
 328         if(sf & ISF_SIZE)
 329         {
 330                 Pickup p = this.itemdef;
 331                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 332         }
 333
 334         if(sf & ISF_STATUS)
 335                 WriteByte(MSG_ENTITY, this.ItemStatus);
 336
 337         if(sf & ISF_MODEL)
 338         {
 339                 Pickup p = this.itemdef;
 340                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 341                 WriteShort(MSG_ENTITY, this.fade_end);
 342                 WriteShort(MSG_ENTITY, this.fade_start);
 343
 344                 if(this.mdl == "")
 345                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 346
 347                 WriteString(MSG_ENTITY, this.mdl);
 348         }
 349
 350
 351         if(sf & ISF_COLORMAP)
 352         {
 353                 WriteShort(MSG_ENTITY, this.colormap);
 354                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 355         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 356         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 357         }
 358
 359         if(sf & ISF_DROP)
 360         {
 361                 WriteCoord(MSG_ENTITY, this.velocity.x);
 362                 WriteCoord(MSG_ENTITY, this.velocity.y);
 363                 WriteCoord(MSG_ENTITY, this.velocity.z);
 364         }
 365
 366         return true;
 367 }
 368
 369 void ItemUpdate(entity this)
 370 {
 371         this.oldorigin = this.origin;
 372         this.SendFlags |= ISF_LOCATION;
 373 }
 374
 375 void UpdateItemAfterTeleport(entity this)
 376 {
 377         if(getSendEntity(this) == ItemSend)
 378                 ItemUpdate(this);
 379 }
 380
 381 bool have_pickup_item(entity this)
 382 {
 383         if(this.itemdef.instanceOfPowerup)
 384         {
 385                 if(autocvar_g_powerups > 0)
 386                         return true;
 387                 if(autocvar_g_powerups == 0)
 388                         return false;
 389         }
 390         else
 391         {
 392                 if(autocvar_g_pickup_items > 0)
 393                         return true;
 394                 if(autocvar_g_pickup_items == 0)
 395                         return false;
 396                 if(g_weaponarena)
 397                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 398                                 return false;
 399         }
 400         return true;
 401 }
 402
 403 /*
 404 float Item_Customize()
 405 {
 406         if(this.spawnshieldtime)
 407                 return true;
 408         if(this.weapons & ~other.weapons)
 409         {
 410                 this.colormod = '0 0 0';
 411                 this.glowmod = this.colormod;
 412                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 413                 return true;
 414         }
 415         else
 416         {
 417                 if(g_ghost_items)
 418                 {
 419                         this.colormod = stov(autocvar_g_ghost_items_color);
 420                         this.glowmod = this.colormod;
 421                         this.alpha = g_ghost_items;
 422                         return true;
 423                 }
 424                 else
 425                         return false;
 426         }
 427 }
 428 */
 429
 430 void Item_Show (entity e, float mode)
 431 {
 432         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 433         e.ItemStatus &= ~ITS_STAYWEP;
 434         entity def = e.itemdef;
 435         if (mode > 0)
 436         {
 437                 // make the item look normal, and be touchable
 438                 e.model = e.mdl;
 439                 e.solid = SOLID_TRIGGER;
 440                 e.spawnshieldtime = 1;
 441                 e.ItemStatus |= ITS_AVAILABLE;
 442         }
 443         else if (mode < 0)
 444         {
 445                 // hide the item completely
 446                 e.model = string_null;
 447                 e.solid = SOLID_NOT;
 448                 e.spawnshieldtime = 1;
 449                 e.ItemStatus &= ~ITS_AVAILABLE;
 450         }
 451         else
 452         {
 453                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 454                         || e.team // weapon stay isn't supported for teamed weapons
 455                         ;
 456                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 457                 {
 458                         // make the item translucent and not touchable
 459                         e.model = e.mdl;
 460                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 461                         e.effects |= EF_STARDUST;
 462                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 463                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 464                 }
 465                 else
 466                 {
 467                         //setmodel(e, "null");
 468                         e.solid = SOLID_NOT;
 469                         e.colormod = '0 0 0';
 470                         //e.glowmod = e.colormod;
 471                         e.spawnshieldtime = 1;
 472                         e.ItemStatus &= ~ITS_AVAILABLE;
 473                 }
 474         }
 475
 476         if (def.m_glow)
 477                 e.ItemStatus |= ITS_GLOW;
 478
 479         if (autocvar_g_nodepthtestitems)
 480                 e.effects |= EF_NODEPTHTEST;
 481
 482
 483         if (autocvar_g_fullbrightitems)
 484                 e.ItemStatus |= ITS_ALLOWFB;
 485
 486         if (autocvar_sv_simple_items)
 487                 e.ItemStatus |= ITS_ALLOWSI;
 488
 489         // relink entity (because solid may have changed)
 490         setorigin(e, e.origin);
 491         e.SendFlags |= ISF_STATUS;
 492 }
 493
 494 void Item_Think(entity this)
 495 {
 496         this.nextthink = time;
 497         if(this.origin != this.oldorigin)
 498                 ItemUpdate(this);
 499 }
 500
 501 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 502 bool Item_ItemsTime_Allow(GameItem it);
 503 float Item_ItemsTime_UpdateTime(entity e, float t);
 504 void Item_ItemsTime_SetTime(entity e, float t);
 505 void Item_ItemsTime_SetTimesForAllPlayers();
 506
 507 void Item_Respawn (entity this)
 508 {
 509         Item_Show(this, 1);
 510         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 511         setorigin(this, this.origin);
 512
 513     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 514         {
 515                 float t = Item_ItemsTime_UpdateTime(this, 0);
 516                 Item_ItemsTime_SetTime(this, t);
 517                 Item_ItemsTime_SetTimesForAllPlayers();
 518         }
 519
 520         setthink(this, Item_Think);
 521         this.nextthink = time;
 522
 523         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 524         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 525 }
 526
 527 void Item_RespawnCountdown (entity this)
 528 {
 529         if(this.count >= ITEM_RESPAWN_TICKS)
 530         {
 531                 if(this.waypointsprite_attached)
 532                         WaypointSprite_Kill(this.waypointsprite_attached);
 533                 Item_Respawn(this);
 534         }
 535         else
 536         {
 537                 this.nextthink = time + 1;
 538                 this.count += 1;
 539                 if(this.count == 1)
 540                 {
 541                         do {
 542                                 {
 543                                         entity wi = Weapons_from(this.weapon);
 544                                         if (wi != WEP_Null) {
 545                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 546                                                 wp.wp_extra = wi.m_id;
 547                                                 break;
 548                                         }
 549                                 }
 550                                 {
 551                                         entity ii = this.itemdef;
 552                                         if (ii != NULL) {
 553                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 554                                                 wp.wp_extra = ii.m_id;
 555                                                 break;
 556                                         }
 557                                 }
 558                         } while (0);
 559                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 560             if(this.waypointsprite_attached)
 561             {
 562                 GameItem def = this.itemdef;
 563                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 564                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 565                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 566             }
 567                 }
 568
 569                 if(this.waypointsprite_attached)
 570                 {
 571                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 572                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 573                                 {
 574                                         msg_entity = it;
 575                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 576                                 }
 577                         });
 578
 579                         WaypointSprite_Ping(this.waypointsprite_attached);
 580                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 581                 }
 582         }
 583 }
 584
 585 void Item_RespawnThink(entity this)
 586 {
 587         this.nextthink = time;
 588         if(this.origin != this.oldorigin)
 589                 ItemUpdate(this);
 590
 591         if(time >= this.wait)
 592                 Item_Respawn(this);
 593 }
 594
 595 void Item_ScheduleRespawnIn(entity e, float t)
 596 {
 597         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 598         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 599         {
 600                 setthink(e, Item_RespawnCountdown);
 601                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 602                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 603                 e.count = 0;
 604                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 605                 {
 606                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 607                         Item_ItemsTime_SetTime(e, t);
 608                         Item_ItemsTime_SetTimesForAllPlayers();
 609                 }
 610         }
 611         else
 612         {
 613                 setthink(e, Item_RespawnThink);
 614                 e.nextthink = time;
 615                 e.scheduledrespawntime = time + t;
 616                 e.wait = time + t;
 617
 618                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 619                 {
 620                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 621                         Item_ItemsTime_SetTime(e, t);
 622                         Item_ItemsTime_SetTimesForAllPlayers();
 623                 }
 624         }
 625 }
 626
 627 void Item_ScheduleRespawn(entity e)
 628 {
 629         if(e.respawntime > 0)
 630         {
 631                 Item_Show(e, 0);
 632                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 633         }
 634         else // if respawntime is -1, this item does not respawn
 635                 Item_Show(e, -1);
 636 }
 637
 638 void Item_ScheduleInitialRespawn(entity e)
 639 {
 640         Item_Show(e, 0);
 641         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 642 }
 643
 644 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 645 {
 646         if (!item.(ammotype))
 647                 return false;
 648
 649         if (item.spawnshieldtime)
 650         {
 651                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 652                 {
 653                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 654                         goto YEAH;
 655                 }
 656         }
 657         else if(g_weapon_stay == 2)
 658         {
 659                 float mi = min(item.(ammotype), ammomax);
 660                 if (player.(ammotype) < mi)
 661                 {
 662                         player.(ammotype) = mi;
 663                         goto YEAH;
 664                 }
 665         }
 666
 667         return false;
 668
 669 LABEL(YEAH)
 670         switch(mode)
 671         {
 672                 case ITEM_MODE_FUEL:
 673                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 674                         break;
 675                 case ITEM_MODE_HEALTH:
 676                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 677                         break;
 678                 case ITEM_MODE_ARMOR:
 679                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 680                         break;
 681                 default:
 682                         break;
 683         }
 684         return true;
 685 }
 686
 687 float Item_GiveTo(entity item, entity player)
 688 {
 689         float pickedup;
 690
 691         // if nothing happens to player, just return without taking the item
 692         pickedup = false;
 693         int _switchweapon = 0;
 694         // in case the player has autoswitch enabled do the following:
 695         // if the player is using their best weapon before items are given, they
 696         // probably want to switch to an even better weapon after items are given
 697
 698         if(player.autoswitch)
 699         {
 700                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 701                 {
 702                         .entity weaponentity = weaponentities[slot];
 703                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 704                         {
 705                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 706                                         _switchweapon |= BIT(slot);
 707
 708                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 709                                         _switchweapon |= BIT(slot);
 710                         }
 711                 }
 712         }
 713
 714         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 715         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 716         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 717         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 718         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 719         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 720         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 721         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 722
 723         if (item.itemdef.instanceOfWeaponPickup)
 724         {
 725                 WepSet w;
 726                 w = item.weapons;
 727                 w &= ~player.weapons;
 728
 729                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 730                 {
 731                         pickedup = true;
 732                         FOREACH(Weapons, it != WEP_Null, {
 733                                 if(w & (it.m_wepset))
 734                                 {
 735                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 736                                         {
 737                                                 .entity weaponentity = weaponentities[slot];
 738                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 739                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 740                                         }
 741                                         W_GiveWeapon(player, it.m_id);
 742                                 }
 743                         });
 744                 }
 745         }
 746
 747         if (item.itemdef.instanceOfPowerup)
 748         {
 749                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 750                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 751                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 752                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 753         }
 754
 755         int its;
 756         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 757         {
 758                 pickedup = true;
 759                 player.items |= its;
 760                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 761         }
 762
 763         if (item.strength_finished)
 764         {
 765                 pickedup = true;
 766                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 767         }
 768         if (item.invincible_finished)
 769         {
 770                 pickedup = true;
 771                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 772         }
 773         if (item.superweapons_finished)
 774         {
 775                 pickedup = true;
 776                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 777         }
 778
 779 LABEL(skip)
 780
 781         // always eat teamed entities
 782         if(item.team)
 783                 pickedup = true;
 784
 785         if (!pickedup)
 786                 return 0;
 787
 788         // crude hack to enforce switching weapons
 789         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 790         {
 791                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 792                 {
 793                         .entity weaponentity = weaponentities[slot];
 794                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 795                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 796                 }
 797                 return 1;
 798         }
 799
 800         if(_switchweapon)
 801         {
 802                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 803                 {
 804                         .entity weaponentity = weaponentities[slot];
 805                         if(_switchweapon & BIT(slot))
 806                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 807                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 808                 }
 809         }
 810
 811         return 1;
 812 }
 813
 814 void Item_Touch(entity this, entity toucher)
 815 {
 816
 817         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 818         if (this.classname == "droppedweapon")
 819         {
 820                 if (ITEM_TOUCH_NEEDKILL())
 821                 {
 822                         delete(this);
 823                         return;
 824                 }
 825         }
 826
 827         if(!(toucher.flags & FL_PICKUPITEMS)
 828         || STAT(FROZEN, toucher)
 829         || IS_DEAD(toucher)
 830         || (this.solid != SOLID_TRIGGER)
 831         || (this.owner == toucher)
 832         || (time < this.item_spawnshieldtime)
 833         ) { return; }
 834
 835         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 836         {
 837                 case MUT_ITEMTOUCH_RETURN: { return; }
 838                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 839         }
 840
 841         toucher = M_ARGV(1, entity);
 842
 843         if (this.classname == "droppedweapon")
 844         {
 845                 this.strength_finished = max(0, this.strength_finished - time);
 846                 this.invincible_finished = max(0, this.invincible_finished - time);
 847                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 848         }
 849         entity it = this.itemdef;
 850         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 851         if (!gave)
 852         {
 853                 if (this.classname == "droppedweapon")
 854                 {
 855                         // undo what we did above
 856                         this.strength_finished += time;
 857                         this.invincible_finished += time;
 858                         this.superweapons_finished += time;
 859                 }
 860                 return;
 861         }
 862
 863 LABEL(pickup)
 864
 865         toucher.last_pickup = time;
 866
 867         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 868         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 869
 870         if (this.classname == "droppedweapon")
 871                 delete (this);
 872         else if (this.spawnshieldtime)
 873         {
 874                 entity e;
 875                 if(this.team)
 876                 {
 877                         RandomSelection_Init();
 878                         IL_EACH(g_items, it.team == this.team,
 879                         {
 880                                 if(it.itemdef) // is a registered item
 881                                 {
 882                                         Item_Show(it, -1);
 883                                         RandomSelection_AddEnt(it, it.cnt, 0);
 884                                 }
 885                         });
 886                         e = RandomSelection_chosen_ent;
 887                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 888                 }
 889                 else
 890                         e = this;
 891                 Item_ScheduleRespawn(e);
 892         }
 893 }
 894
 895 void Item_Reset(entity this)
 896 {
 897         Item_Show(this, !this.state);
 898         setorigin(this, this.origin);
 899
 900         if (this.classname != "droppedweapon")
 901         {
 902                 setthink(this, Item_Think);
 903                 this.nextthink = time;
 904
 905                 if (this.waypointsprite_attached)
 906                         WaypointSprite_Kill(this.waypointsprite_attached);
 907
 908                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 909                         Item_ScheduleInitialRespawn(this);
 910         }
 911 }
 912
 913 void Item_FindTeam(entity this)
 914 {
 915         entity e;
 916
 917         if(this.effects & EF_NODRAW)
 918         {
 919                 // marker for item team search
 920                 LOG_TRACE("Initializing item team ", ftos(this.team));
 921                 RandomSelection_Init();
 922                 IL_EACH(g_items, it.team == this.team,
 923                 {
 924                         if(it.itemdef) // is a registered item
 925                                 RandomSelection_AddEnt(it, it.cnt, 0);
 926                 });
 927
 928                 e = RandomSelection_chosen_ent;
 929                 e.state = 0;
 930                 Item_Show(e, 1);
 931
 932                 IL_EACH(g_items, it.team == this.team,
 933                 {
 934                         if(it.itemdef) // is a registered item
 935                         {
 936                                 if(it != e)
 937                                 {
 938                                         // make it non-spawned
 939                                         Item_Show(it, -1);
 940                                         it.state = 1; // state 1 = initially hidden item, apparently
 941                                 }
 942                                 it.effects &= ~EF_NODRAW;
 943                         }
 944                 });
 945
 946                 Item_Reset(this);
 947         }
 948 }
 949
 950 // Savage: used for item garbage-collection
 951 void RemoveItem(entity this)
 952 {
 953         if(wasfreed(this) || !this) { return; }
 954         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 955         delete(this);
 956 }
 957
 958 // pickup evaluation functions
 959 // these functions decide how desirable an item is to the bots
 960
 961 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 962
 963 float weapon_pickupevalfunc(entity player, entity item)
 964 {
 965         // See if I have it already
 966         if(player.weapons & item.weapons)
 967         {
 968                 // If I can pick it up
 969                 if(!item.spawnshieldtime)
 970                         return 0;
 971                 return ammo_pickupevalfunc(player, item);
 972         }
 973
 974         // reduce weapon value if bot already got a good arsenal
 975         float c = 1;
 976         int weapons_value = 0;
 977         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
 978                 weapons_value += it.bot_pickupbasevalue;
 979         });
 980         c -= bound(0, weapons_value / 20000, 1) * 0.5;
 981
 982         return item.bot_pickupbasevalue * c;
 983 }
 984
 985 float ammo_pickupevalfunc(entity player, entity item)
 986 {
 987         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
 988         entity wpn = NULL;
 989         float c = 0;
 990         float rating = 0;
 991
 992         // Detect needed ammo
 993         if(item.itemdef.instanceOfWeaponPickup)
 994         {
 995                 entity ammo = NULL;
 996                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
 997                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
 998                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
 999                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1000                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1001                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1002
1003                 if(!ammo)
1004                         return 0;
1005                 wpn = item;
1006                 rating = ammo.m_botvalue;
1007         }
1008         else
1009         {
1010                 FOREACH(Weapons, it != WEP_Null, {
1011                         if(!(player.weapons & (it.m_wepset)))
1012                                 continue;
1013
1014                         switch(it.ammo_field)
1015                         {
1016                                 case ammo_shells:  need_shells  = true; break;
1017                                 case ammo_nails:   need_nails   = true; break;
1018                                 case ammo_rockets: need_rockets = true; break;
1019                                 case ammo_cells:   need_cells   = true; break;
1020                                 case ammo_plasma:  need_plasma  = true; break;
1021                                 case ammo_fuel:    need_fuel    = true; break;
1022                         }
1023                 });
1024                 rating = item.bot_pickupbasevalue;
1025         }
1026
1027         float noammorating = 0.5;
1028
1029         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1030                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1031
1032         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1033                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1034
1035         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1036                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1037
1038         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1039                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1040
1041         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1042                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1043
1044         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1045                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1046
1047         rating *= min(c, 2);
1048         if(wpn)
1049                 rating += wpn.bot_pickupbasevalue * 0.1;
1050         return rating;
1051 }
1052
1053 .int item_group;
1054 .int item_group_count;
1055 float healtharmor_pickupevalfunc(entity player, entity item)
1056 {
1057         float c = 0;
1058         float rating = item.bot_pickupbasevalue;
1059
1060         float itemarmor = item.armorvalue;
1061         float itemhealth = item.health;
1062
1063         if(item.item_group)
1064         {
1065                 itemarmor *= min(4, item.item_group_count);
1066                 itemhealth *= min(4, item.item_group_count);
1067         }
1068
1069         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1070                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1071
1072         if (itemhealth && (player.health < item.max_health))
1073                 c = itemhealth / max(1, player.health);
1074
1075         rating *= min(2, c);
1076         return rating;
1077 }
1078
1079 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1080 {
1081         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1082                 RemoveItem(this);
1083 }
1084
1085 void item_use(entity this, entity actor, entity trigger)
1086 {
1087         // use the touch function to handle collection
1088         gettouch(this)(this, actor);
1089 }
1090
1091 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1092 {
1093         string itemname = def.m_name;
1094         Model itemmodel = def.m_model;
1095     Sound pickupsound = def.m_sound;
1096         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1097         float pickupbasevalue = def.m_botvalue;
1098         int itemflags = def.m_itemflags;
1099
1100         startitem_failed = false;
1101
1102         this.item_model_ent = itemmodel;
1103     this.item_pickupsound_ent = pickupsound;
1104
1105     if(def.m_iteminit)
1106         def.m_iteminit(this);
1107
1108         if(!this.respawntime) // both need to be set
1109         {
1110                 this.respawntime = defaultrespawntime;
1111                 this.respawntimejitter = defaultrespawntimejitter;
1112         }
1113
1114         if(!this.pickup_anyway && def.m_pickupanyway)
1115                 this.pickup_anyway = def.m_pickupanyway();
1116
1117         int itemid = def.m_itemid;
1118         this.items = itemid;
1119         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1120         this.weapon = weaponid;
1121
1122         if(!this.fade_end)
1123         {
1124                 this.fade_start = autocvar_g_items_mindist;
1125                 this.fade_end = autocvar_g_items_maxdist;
1126         }
1127
1128         if(weaponid)
1129                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1130
1131         this.flags = FL_ITEM | itemflags;
1132         IL_PUSH(g_items, this);
1133
1134         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1135         {
1136                 startitem_failed = true;
1137                 delete(this);
1138                 return;
1139         }
1140
1141         // is it a dropped weapon?
1142         if (this.classname == "droppedweapon")
1143         {
1144                 this.reset = SUB_Remove;
1145                 // it's a dropped weapon
1146                 set_movetype(this, MOVETYPE_TOSS);
1147
1148                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1149                 setthink(this, RemoveItem);
1150                 this.nextthink = time + 20;
1151
1152                 this.takedamage = DAMAGE_YES;
1153                 this.event_damage = Item_Damage;
1154
1155                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1156                 {
1157                         // if item is worthless after a timer, have it expire then
1158                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1159                 }
1160
1161                 // don't drop if in a NODROP zone (such as lava)
1162                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1163                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1164                 {
1165                         startitem_failed = true;
1166                         delete(this);
1167                         return;
1168                 }
1169         }
1170         else
1171         {
1172                 if(!have_pickup_item(this))
1173                 {
1174                         startitem_failed = true;
1175                         delete (this);
1176                         return;
1177                 }
1178
1179                 if(this.angles != '0 0 0')
1180                         this.SendFlags |= ISF_ANGLES;
1181
1182                 this.reset = Item_Reset;
1183                 // it's a level item
1184                 if(this.spawnflags & 1)
1185                         this.noalign = 1;
1186                 if (this.noalign > 0)
1187                         set_movetype(this, MOVETYPE_NONE);
1188                 else
1189                         set_movetype(this, MOVETYPE_TOSS);
1190                 // do item filtering according to game mode and other things
1191                 if (this.noalign <= 0)
1192                 {
1193                         // first nudge it off the floor a little bit to avoid math errors
1194                         setorigin(this, this.origin + '0 0 1');
1195                         // set item size before we spawn a spawnfunc_waypoint
1196                         setsize(this, def.m_mins, def.m_maxs);
1197                         this.SendFlags |= ISF_SIZE;
1198                         // note droptofloor returns false if stuck/or would fall too far
1199                         if (!this.noalign)
1200                                 droptofloor(this);
1201                         waypoint_spawnforitem(this);
1202                 }
1203
1204                 /*
1205                  * can't do it that way, as it would break maps
1206                  * TODO make a target_give like entity another way, that perhaps has
1207                  * the weapon name in a key
1208                 if(this.targetname)
1209                 {
1210                         // target_give not yet supported; maybe later
1211                         print("removed targeted ", this.classname, "\n");
1212                         startitem_failed = true;
1213                         remove (this);
1214                         return;
1215                 }
1216                 */
1217
1218                 if(this.targetname != "" && (this.spawnflags & 16))
1219                         this.use = item_use;
1220
1221                 if(autocvar_spawn_debug >= 2)
1222                 {
1223             // why not flags & fl_item?
1224                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1225                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1226                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1227                 error("Mapper sucks.");
1228             });
1229                         this.is_item = true;
1230                 }
1231
1232                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1233
1234                 precache_model(this.model);
1235                 precache_sound(this.item_pickupsound);
1236
1237                 if (   def.instanceOfPowerup
1238                         || def.instanceOfWeaponPickup
1239                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1240                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1241                         || (itemid & (IT_KEY1 | IT_KEY2))
1242                 ) this.target = "###item###"; // for finding the nearest item using find()
1243
1244                 Item_ItemsTime_SetTime(this, 0);
1245         }
1246
1247         this.bot_pickup = true;
1248         this.bot_pickupevalfunc = pickupevalfunc;
1249         this.bot_pickupbasevalue = pickupbasevalue;
1250         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1251         this.netname = itemname;
1252         settouch(this, Item_Touch);
1253         setmodel(this, MDL_Null); // precision set below
1254         //this.effects |= EF_LOWPRECISION;
1255
1256         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1257
1258         this.SendFlags |= ISF_SIZE;
1259
1260         if (!(this.spawnflags & 1024)) {
1261                 if(def.instanceOfPowerup)
1262                         this.ItemStatus |= ITS_ANIMATE1;
1263
1264                 if(this.armorvalue || this.health)
1265                         this.ItemStatus |= ITS_ANIMATE2;
1266         }
1267
1268         if(def.instanceOfWeaponPickup)
1269         {
1270                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1271                         this.colormap = 1024; // color shirt=0 pants=0 grey
1272                 else
1273                         this.gravity = 1;
1274                 if (!(this.spawnflags & 1024))
1275                         this.ItemStatus |= ITS_ANIMATE1;
1276                 this.SendFlags |= ISF_COLORMAP;
1277         }
1278
1279         this.state = 0;
1280         if(this.team) // broken, no idea why.
1281         {
1282                 if(!this.cnt)
1283                         this.cnt = 1; // item probability weight
1284
1285                 this.effects |= EF_NODRAW; // marker for item team search
1286                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1287         }
1288         else
1289                 Item_Reset(this);
1290
1291         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1292
1293         // call this hook after everything else has been done
1294         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1295         {
1296                 startitem_failed = true;
1297                 delete(this);
1298                 return;
1299         }
1300
1301         setItemGroup(this);
1302 }
1303
1304 void StartItem(entity this, GameItem def)
1305 {
1306     _StartItem(
1307         this,
1308         this.itemdef = def,
1309         def.m_respawntime(), // defaultrespawntime
1310         def.m_respawntimejitter() // defaultrespawntimejitter
1311         );
1312 }
1313
1314 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1315 int group_count = 1;
1316
1317 void setItemGroup(entity this)
1318 {
1319         if(!IS_SMALL(this.itemdef))
1320                 return;
1321
1322         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1323         {
1324                 if(!this.item_group)
1325                 {
1326                         if(!it.item_group)
1327                         {
1328                                 it.item_group = group_count;
1329                                 group_count++;
1330                         }
1331                         this.item_group = it.item_group;
1332                 }
1333                 else // spawning item is already part of a item_group X
1334                 {
1335                         if(!it.item_group)
1336                                 it.item_group = this.item_group;
1337                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1338                         {
1339                                 int grY = it.item_group;
1340                                 // move all items of item_group Y to item_group X
1341                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1342                                 {
1343                                         if(it.item_group == grY)
1344                                                 it.item_group = this.item_group;
1345                                 });
1346                         }
1347                 }
1348         });
1349 }
1350
1351 void setItemGroupCount()
1352 {
1353         for (int k = 1; k <= group_count; k++)
1354         {
1355                 int count = 0;
1356                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1357                 if (count)
1358                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1359         }
1360 }
1361
1362 spawnfunc(item_rockets)
1363 {
1364     StartItem(this, ITEM_Rockets);
1365 }
1366
1367 spawnfunc(item_bullets)
1368 {
1369         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1370            (this.classname != "droppedweapon"))
1371         {
1372                 weaponswapping = true;
1373                 spawnfunc_item_shells(this);
1374                 weaponswapping = false;
1375                 return;
1376         }
1377
1378     StartItem(this, ITEM_Bullets);
1379 }
1380
1381 spawnfunc(item_cells)
1382 {
1383         StartItem(this, ITEM_Cells);
1384 }
1385
1386 spawnfunc(item_plasma)
1387 {
1388         StartItem(this, ITEM_Plasma);
1389 }
1390
1391 spawnfunc(item_shells)
1392 {
1393         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1394            (this.classname != "droppedweapon"))
1395         {
1396                 weaponswapping = true;
1397                 spawnfunc_item_bullets(this);
1398                 weaponswapping = false;
1399                 return;
1400         }
1401
1402         StartItem(this, ITEM_Shells);
1403 }
1404
1405 spawnfunc(item_armor_small)
1406 {
1407         StartItem(this, ITEM_ArmorSmall);
1408 }
1409
1410 spawnfunc(item_armor_medium)
1411 {
1412         StartItem(this, ITEM_ArmorMedium);
1413 }
1414
1415 spawnfunc(item_armor_big)
1416 {
1417         StartItem(this, ITEM_ArmorBig);
1418 }
1419
1420 spawnfunc(item_armor_mega)
1421 {
1422         StartItem(this, ITEM_ArmorMega);
1423 }
1424
1425 spawnfunc(item_health_small)
1426 {
1427         StartItem(this, ITEM_HealthSmall);
1428 }
1429
1430 spawnfunc(item_health_medium)
1431 {
1432     StartItem(this, ITEM_HealthMedium);
1433 }
1434
1435 spawnfunc(item_health_big)
1436 {
1437         StartItem(this, ITEM_HealthBig);
1438 }
1439
1440 spawnfunc(item_health_mega)
1441 {
1442     StartItem(this, ITEM_HealthMega);
1443 }
1444
1445 // support old misnamed entities
1446 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1447 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1448 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1449 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1450 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1451 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1452 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1453
1454 spawnfunc(item_strength)
1455 {
1456         StartItem(this, ITEM_Strength);
1457 }
1458
1459 spawnfunc(item_invincible)
1460 {
1461         StartItem(this, ITEM_Shield);
1462 }
1463
1464 // compatibility:
1465 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1466
1467 void target_items_use(entity this, entity actor, entity trigger)
1468 {
1469         if(actor.classname == "droppedweapon")
1470         {
1471                 EXACTTRIGGER_TOUCH(this, trigger);
1472                 delete(actor);
1473                 return;
1474         }
1475
1476         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1477                 return;
1478
1479         if(trigger.solid == SOLID_TRIGGER)
1480         {
1481                 EXACTTRIGGER_TOUCH(this, trigger);
1482         }
1483
1484         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1485         {
1486                 delete(it);
1487         });
1488
1489         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1490                 centerprint(actor, this.message);
1491 }
1492
1493 spawnfunc(target_items)
1494 {
1495         int n;
1496         string s;
1497
1498         this.use = target_items_use;
1499         if(!this.strength_finished)
1500                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1501         if(!this.invincible_finished)
1502                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1503         if(!this.superweapons_finished)
1504                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1505
1506         n = tokenize_console(this.netname);
1507         if(argv(0) == "give")
1508         {
1509                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1510         }
1511         else
1512         {
1513                 for(int j = 0; j < n; ++j)
1514                 {
1515                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1516                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1517                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1518                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1519                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1520                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1521                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1522                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1523                         else
1524                         {
1525                                 FOREACH(Buffs, it != BUFF_Null,
1526                                 {
1527                                         s = Buff_UndeprecateName(argv(j));
1528                                         if(s == it.m_name)
1529                                         {
1530                                                 this.buffs |= (it.m_itemid);
1531                                                 break;
1532                                         }
1533                                 });
1534                                 FOREACH(Weapons, it != WEP_Null, {
1535                                         s = W_UndeprecateName(argv(j));
1536                                         if(s == it.netname)
1537                                         {
1538                                                 this.weapons |= (it.m_wepset);
1539                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1540                                                         it.wr_init(it);
1541                                                 break;
1542                                         }
1543                                 });
1544                         }
1545                 }
1546
1547                 string itemprefix, valueprefix;
1548                 if(this.spawnflags == 0)
1549                 {
1550                         itemprefix = "";
1551                         valueprefix = "";
1552                 }
1553                 else if(this.spawnflags == 1)
1554                 {
1555                         itemprefix = "max ";
1556                         valueprefix = "max ";
1557                 }
1558                 else if(this.spawnflags == 2)
1559                 {
1560                         itemprefix = "min ";
1561                         valueprefix = "min ";
1562                 }
1563                 else if(this.spawnflags == 4)
1564                 {
1565                         itemprefix = "minus ";
1566                         valueprefix = "max ";
1567                 }
1568                 else
1569                 {
1570                         error("invalid spawnflags");
1571                         itemprefix = valueprefix = string_null;
1572                 }
1573
1574                 this.netname = "";
1575                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1576                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1577                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1578                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1579                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1580                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1581                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1582                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1583                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1584                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1585                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1586                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1587                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1588                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1589                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1590                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1591                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1592         }
1593         this.netname = strzone(this.netname);
1594         //print(this.netname, "\n");
1595
1596         n = tokenize_console(this.netname);
1597         for(int j = 0; j < n; ++j)
1598         {
1599                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1600             it.wr_init(it);
1601             break;
1602                 });
1603         }
1604 }
1605
1606 spawnfunc(item_fuel)
1607 {
1608         StartItem(this, ITEM_JetpackFuel);
1609 }
1610
1611 spawnfunc(item_fuel_regen)
1612 {
1613         if(start_items & ITEM_JetpackRegen.m_itemid)
1614         {
1615                 spawnfunc_item_fuel(this);
1616                 return;
1617         }
1618         StartItem(this, ITEM_JetpackRegen);
1619 }
1620
1621 spawnfunc(item_jetpack)
1622 {
1623         if(start_items & ITEM_Jetpack.m_itemid)
1624         {
1625                 spawnfunc_item_fuel(this);
1626                 return;
1627         }
1628         StartItem(this, ITEM_Jetpack);
1629 }
1630
1631 float GiveWeapon(entity e, float wpn, float op, float val)
1632 {
1633         WepSet v0, v1;
1634         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1635         v0 = (e.weapons & s);
1636         switch(op)
1637         {
1638                 case OP_SET:
1639                         if(val > 0)
1640                                 e.weapons |= s;
1641                         else
1642                                 e.weapons &= ~s;
1643                         break;
1644                 case OP_MIN:
1645                 case OP_PLUS:
1646                         if(val > 0)
1647                                 e.weapons |= s;
1648                         break;
1649                 case OP_MAX:
1650                         if(val <= 0)
1651                                 e.weapons &= ~s;
1652                         break;
1653                 case OP_MINUS:
1654                         if(val > 0)
1655                                 e.weapons &= ~s;
1656                         break;
1657         }
1658         v1 = (e.weapons & s);
1659         return (v0 != v1);
1660 }
1661
1662 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1663 {
1664         bool had_buff = (e.buffs & thebuff.m_itemid);
1665         switch(op)
1666         {
1667                 case OP_SET:
1668                         if(val > 0)
1669                                 e.buffs |= thebuff.m_itemid;
1670                         else
1671                                 e.buffs &= ~thebuff.m_itemid;
1672                         break;
1673                 case OP_MIN:
1674                 case OP_PLUS:
1675                         if(val > 0)
1676                                 e.buffs |= thebuff.m_itemid;
1677                         break;
1678                 case OP_MAX:
1679                         if(val <= 0)
1680                                 e.buffs &= ~thebuff.m_itemid;
1681                         break;
1682                 case OP_MINUS:
1683                         if(val > 0)
1684                                 e.buffs &= ~thebuff.m_itemid;
1685                         break;
1686         }
1687         bool have_buff = (e.buffs & thebuff.m_itemid);
1688         return (had_buff != have_buff);
1689 }
1690
1691 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1692 {
1693         if(v1 == v0)
1694                 return;
1695         if(v1 <= v0 - t)
1696         {
1697                 if(snd_decr != NULL)
1698                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1699         }
1700         else if(v0 >= v0 + t)
1701         {
1702                 if(snd_incr != NULL)
1703                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1704         }
1705 }
1706
1707 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1708 {
1709         if(v0 < v1)
1710                 e.(rotfield) = max(e.(rotfield), time + rottime);
1711         else if(v0 > v1)
1712                 e.(regenfield) = max(e.(regenfield), time + regentime);
1713 }
1714 float GiveItems(entity e, float beginarg, float endarg)
1715 {
1716         float got, i, val, op;
1717         string cmd;
1718
1719         val = 999;
1720         op = OP_SET;
1721
1722         got = 0;
1723
1724         int _switchweapon = 0;
1725
1726         if(e.autoswitch)
1727         {
1728                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1729                 {
1730                         .entity weaponentity = weaponentities[slot];
1731                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1732                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1733                                 _switchweapon |= BIT(slot);
1734                 }
1735         }
1736
1737         e.strength_finished = max(0, e.strength_finished - time);
1738         e.invincible_finished = max(0, e.invincible_finished - time);
1739         e.superweapons_finished = max(0, e.superweapons_finished - time);
1740
1741         PREGIVE(e, items);
1742         PREGIVE_WEAPONS(e);
1743         PREGIVE(e, strength_finished);
1744         PREGIVE(e, invincible_finished);
1745         PREGIVE(e, superweapons_finished);
1746         PREGIVE(e, ammo_nails);
1747         PREGIVE(e, ammo_cells);
1748         PREGIVE(e, ammo_plasma);
1749         PREGIVE(e, ammo_shells);
1750         PREGIVE(e, ammo_rockets);
1751         PREGIVE(e, ammo_fuel);
1752         PREGIVE(e, armorvalue);
1753         PREGIVE(e, health);
1754
1755         for(i = beginarg; i < endarg; ++i)
1756         {
1757                 cmd = argv(i);
1758
1759                 if(cmd == "0" || stof(cmd))
1760                 {
1761                         val = stof(cmd);
1762                         continue;
1763                 }
1764                 switch(cmd)
1765                 {
1766                         case "no":
1767                                 op = OP_MAX;
1768                                 val = 0;
1769                                 continue;
1770                         case "max":
1771                                 op = OP_MAX;
1772                                 continue;
1773                         case "min":
1774                                 op = OP_MIN;
1775                                 continue;
1776                         case "plus":
1777                                 op = OP_PLUS;
1778                                 continue;
1779                         case "minus":
1780                                 op = OP_MINUS;
1781                                 continue;
1782                         case "ALL":
1783                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1784                                 got += GiveValue(e, strength_finished, op, val);
1785                                 got += GiveValue(e, invincible_finished, op, val);
1786                                 got += GiveValue(e, superweapons_finished, op, val);
1787                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1788                         case "all":
1789                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1790                                 got += GiveValue(e, health, op, val);
1791                                 got += GiveValue(e, armorvalue, op, val);
1792                         case "allweapons":
1793                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1794                         //case "allbuffs": // all buffs makes a player god, do not want!
1795                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1796                         case "allammo":
1797                                 got += GiveValue(e, ammo_cells, op, val);
1798                                 got += GiveValue(e, ammo_plasma, op, val);
1799                                 got += GiveValue(e, ammo_shells, op, val);
1800                                 got += GiveValue(e, ammo_nails, op, val);
1801                                 got += GiveValue(e, ammo_rockets, op, val);
1802                                 got += GiveValue(e, ammo_fuel, op, val);
1803                                 break;
1804                         case "unlimited_ammo":
1805                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1806                                 break;
1807                         case "unlimited_weapon_ammo":
1808                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1809                                 break;
1810                         case "unlimited_superweapons":
1811                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1812                                 break;
1813                         case "jetpack":
1814                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1815                                 break;
1816                         case "fuel_regen":
1817                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1818                                 break;
1819                         case "strength":
1820                                 got += GiveValue(e, strength_finished, op, val);
1821                                 break;
1822                         case "invincible":
1823                                 got += GiveValue(e, invincible_finished, op, val);
1824                                 break;
1825                         case "superweapons":
1826                                 got += GiveValue(e, superweapons_finished, op, val);
1827                                 break;
1828                         case "cells":
1829                                 got += GiveValue(e, ammo_cells, op, val);
1830                                 break;
1831                         case "plasma":
1832                                 got += GiveValue(e, ammo_plasma, op, val);
1833                                 break;
1834                         case "shells":
1835                                 got += GiveValue(e, ammo_shells, op, val);
1836                                 break;
1837                         case "nails":
1838                         case "bullets":
1839                                 got += GiveValue(e, ammo_nails, op, val);
1840                                 break;
1841                         case "rockets":
1842                                 got += GiveValue(e, ammo_rockets, op, val);
1843                                 break;
1844                         case "health":
1845                                 got += GiveValue(e, health, op, val);
1846                                 break;
1847                         case "armor":
1848                                 got += GiveValue(e, armorvalue, op, val);
1849                                 break;
1850                         case "fuel":
1851                                 got += GiveValue(e, ammo_fuel, op, val);
1852                                 break;
1853                         default:
1854                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1855                                 {
1856                                         got += GiveBuff(e, it, op, val);
1857                                         break;
1858                                 });
1859                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1860                     got += GiveWeapon(e, it.m_id, op, val);
1861                     break;
1862                                 });
1863                                 break;
1864                 }
1865                 val = 999;
1866                 op = OP_SET;
1867         }
1868
1869         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1870         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1871         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1872         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1873         FOREACH(Weapons, it != WEP_Null, {
1874                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1875                 if(!(save_weapons & (it.m_wepset)))
1876                         if(e.weapons & (it.m_wepset))
1877                                 it.wr_init(it);
1878         });
1879         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1880         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1881         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1882         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1883         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1884         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1885         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1886         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1887         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1888         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1889         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1890
1891         if(e.superweapons_finished <= 0)
1892                 if(e.weapons & WEPSET_SUPERWEAPONS)
1893                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1894
1895         if(e.strength_finished <= 0)
1896                 e.strength_finished = 0;
1897         else
1898                 e.strength_finished += time;
1899         if(e.invincible_finished <= 0)
1900                 e.invincible_finished = 0;
1901         else
1902                 e.invincible_finished += time;
1903         if(e.superweapons_finished <= 0)
1904                 e.superweapons_finished = 0;
1905         else
1906                 e.superweapons_finished += time;
1907
1908         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1909         {
1910                 .entity weaponentity = weaponentities[slot];
1911                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1912                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1913                         _switchweapon |= BIT(slot);
1914         }
1915
1916         if(_switchweapon)
1917         {
1918                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1919                 {
1920                         .entity weaponentity = weaponentities[slot];
1921                         if(_switchweapon & BIT(slot))
1922                         {
1923                                 Weapon wep = w_getbestweapon(e, weaponentity);
1924                                 if(wep != e.(weaponentity).m_switchweapon)
1925                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1926                         }
1927                 }
1928         }
1929
1930         return got;
1931 }
1932 #endif