qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "mapobjects/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 .bool item_simple; // probably not really needed, but better safe than sorry
  41 void Item_SetAlpha(entity this)
  42 {
  43         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  44
  45         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  46         {
  47                 this.alpha = 1;
  48                 this.colormod = '1 1 1';
  49                 this.glowmod = this.item_glowmod;
  50         }
  51         else
  52         {
  53                 this.alpha = autocvar_cl_ghost_items;
  54                 this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  55         }
  56
  57         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  58         {
  59                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  60                 this.alpha = autocvar_cl_weapon_stay_alpha;
  61         }
  62
  63         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  64 }
  65
  66 void ItemDraw(entity this)
  67 {
  68     if(this.gravity)
  69     {
  70         Movetype_Physics_MatchServer(this, false);
  71         if(IS_ONGROUND(this))
  72         { // For some reason avelocity gets set to '0 0 0' here ...
  73             this.oldorigin = this.origin;
  74             this.gravity = 0;
  75
  76             if(autocvar_cl_animate_items)
  77             { // ... so reset it if animations are requested.
  78                 if(this.ItemStatus & ITS_ANIMATE1)
  79                     this.avelocity = '0 180 0';
  80
  81                 if(this.ItemStatus & ITS_ANIMATE2)
  82                     this.avelocity = '0 -90 0';
  83             }
  84
  85             // delay is for blocking item's position for a while;
  86             // it's a workaround for dropped weapons that receive the position
  87             // another time right after they spawn overriding animation position
  88             this.onground_time = time + 0.5;
  89         }
  90     }
  91     else if (autocvar_cl_animate_items)
  92     {
  93         if(this.ItemStatus & ITS_ANIMATE1)
  94         {
  95                 if(!this.item_simple)
  96                 this.angles += this.avelocity * frametime;
  97             float fade_in = bound(0, time - this.onground_time, 1);
  98             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
  99         }
 100
 101         if(this.ItemStatus & ITS_ANIMATE2)
 102         {
 103                 if(!this.item_simple)
 104                 this.angles += this.avelocity * frametime;
 105             float fade_in = bound(0, time - this.onground_time, 1);
 106             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 107         }
 108     }
 109
 110     Item_SetAlpha(this);
 111 }
 112
 113 void Item_PreDraw(entity this)
 114 {
 115         if(warpzone_warpzones_exist)
 116         {
 117                 setpredraw(this, func_null); // no need to keep running this
 118                 return;
 119         }
 120         float alph;
 121         vector org = getpropertyvec(VF_ORIGIN);
 122         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 123                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 124         if(this.fade_start)
 125         {
 126                 if(vdist(org - this.origin, >, this.fade_end))
 127                         alph = 0; // save on some processing
 128                 else if(vdist(org - this.origin, <, this.fade_start))
 129                         alph = 1; // more processing saved
 130                 else
 131                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 132         }
 133         else
 134                 alph = 1;
 135         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 136         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 137                 this.alpha = alph;
 138         if(alph <= 0)
 139                 this.drawmask = 0;
 140         //else
 141                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 142 }
 143
 144 void ItemRemove(entity this)
 145 {
 146         strfree(this.mdl);
 147 }
 148
 149 HashMap ENT_CLIENT_ITEM_simple;
 150 STATIC_INIT(ENT_CLIENT_ITEM_simple)
 151 {
 152         HM_NEW(ENT_CLIENT_ITEM_simple);
 153 }
 154 SHUTDOWN(ENT_CLIENT_ITEM_simple)
 155 {
 156         HM_DELETE(ENT_CLIENT_ITEM_simple);
 157 }
 158
 159 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 160 {
 161     int sf = ReadByte();
 162
 163     if(sf & ISF_LOCATION)
 164     {
 165         this.origin = ReadVector();
 166         setorigin(this, this.origin);
 167         this.oldorigin = this.origin;
 168     }
 169
 170     if(sf & ISF_ANGLES)
 171     {
 172         this.angles_x = ReadAngle();
 173         this.angles_y = ReadAngle();
 174         this.angles_z = ReadAngle();
 175     }
 176
 177     if(sf & ISF_SIZE)
 178     {
 179         float use_bigsize = ReadByte();
 180         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 181     }
 182
 183     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 184     {
 185         this.ItemStatus = ReadByte();
 186
 187         Item_SetAlpha(this);
 188
 189         if(autocvar_cl_fullbright_items)
 190             if(this.ItemStatus & ITS_ALLOWFB)
 191                 this.effects |= EF_FULLBRIGHT;
 192
 193         if(this.ItemStatus & ITS_GLOW)
 194         {
 195             if(this.ItemStatus & ITS_AVAILABLE)
 196                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 197             else
 198                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 199         }
 200     }
 201
 202     if(sf & ISF_MODEL)
 203     {
 204         this.drawmask  = MASK_NORMAL;
 205                 set_movetype(this, MOVETYPE_TOSS);
 206                 if (isnew) IL_PUSH(g_drawables, this);
 207         this.draw       = ItemDraw;
 208         this.solid = SOLID_TRIGGER;
 209         //this.flags |= FL_ITEM;
 210
 211         bool use_bigsize = ReadByte();
 212
 213         this.fade_end = ReadShort();
 214         this.fade_start = ReadShort();
 215         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 216                 setpredraw(this, Item_PreDraw);
 217
 218                 strfree(this.mdl);
 219
 220         string _fn = ReadString();
 221         this.item_simple = false; // reset it!
 222
 223         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 224         {
 225             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 226             this.item_simple = true;
 227
 228                         #define extensions(x) \
 229                                 x(md3) \
 230                                 x(dpm) \
 231                                 x(iqm) \
 232                                 x(mdl) \
 233                                 /**/
 234                         #define tryext(ext) { \
 235                                 string s = strcat(_fn2, autocvar_cl_simpleitems_postfix, "." #ext); \
 236                                 string cached = HM_gets(ENT_CLIENT_ITEM_simple, s); \
 237                                 if (cached == "") { \
 238                                         HM_sets(ENT_CLIENT_ITEM_simple, s, cached = fexists(s) ? "1" : "0"); \
 239                                 } \
 240                                 if (cached != "0") { \
 241                                         strcpy(this.mdl, s); \
 242                                         break; \
 243                                 } \
 244                         }
 245                         do {
 246                                 extensions(tryext);
 247                                 this.item_simple = false;
 248                 LOG_TRACEF("Simple item requested for %s but no model exists for it", _fn);
 249                         } while (0);
 250                         #undef tryext
 251                         #undef extensions
 252         }
 253
 254         if(!this.item_simple)
 255             strcpy(this.mdl, _fn);
 256
 257         if(this.mdl == "")
 258             LOG_WARNF("this.mdl is unset for item %s", this.classname);
 259
 260         precache_model(this.mdl);
 261         _setmodel(this, this.mdl);
 262
 263         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 264     }
 265
 266     if(sf & ISF_COLORMAP)
 267     {
 268         this.colormap = ReadShort();
 269         this.item_glowmod_x = ReadByte() / 255.0;
 270         this.item_glowmod_y = ReadByte() / 255.0;
 271         this.item_glowmod_z = ReadByte() / 255.0;
 272     }
 273
 274     if(sf & ISF_DROP)
 275     {
 276         this.gravity = 1;
 277         this.pushable = true;
 278         //this.angles = '0 0 0';
 279         set_movetype(this, MOVETYPE_TOSS);
 280         this.velocity = ReadVector();
 281         setorigin(this, this.oldorigin);
 282
 283         if(!this.move_time)
 284         {
 285             this.move_time = time;
 286             this.spawntime = time;
 287         }
 288         else
 289             this.move_time = max(this.move_time, time);
 290     }
 291
 292     if(autocvar_cl_animate_items)
 293     {
 294         if(this.ItemStatus & ITS_ANIMATE1)
 295             this.avelocity = '0 180 0';
 296
 297         if(this.ItemStatus & ITS_ANIMATE2)
 298             this.avelocity = '0 -90 0';
 299     }
 300
 301     this.entremove = ItemRemove;
 302
 303     return true;
 304 }
 305
 306 #endif
 307
 308 #ifdef SVQC
 309 bool ItemSend(entity this, entity to, int sf)
 310 {
 311         if(this.gravity)
 312                 sf |= ISF_DROP;
 313         else
 314                 sf &= ~ISF_DROP;
 315
 316         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 317         WriteByte(MSG_ENTITY, sf);
 318
 319         //WriteByte(MSG_ENTITY, this.cnt);
 320         if(sf & ISF_LOCATION)
 321         {
 322                 WriteVector(MSG_ENTITY, this.origin);
 323         }
 324
 325         if(sf & ISF_ANGLES)
 326         {
 327                 WriteAngle(MSG_ENTITY, this.angles_x);
 328                 WriteAngle(MSG_ENTITY, this.angles_y);
 329                 WriteAngle(MSG_ENTITY, this.angles_z);
 330         }
 331
 332         if(sf & ISF_SIZE)
 333         {
 334                 Pickup p = this.itemdef;
 335                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 336         }
 337
 338         if(sf & ISF_STATUS)
 339                 WriteByte(MSG_ENTITY, this.ItemStatus);
 340
 341         if(sf & ISF_MODEL)
 342         {
 343                 Pickup p = this.itemdef;
 344                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 345                 WriteShort(MSG_ENTITY, this.fade_end);
 346                 WriteShort(MSG_ENTITY, this.fade_start);
 347
 348                 if(this.mdl == "")
 349                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 350
 351                 WriteString(MSG_ENTITY, this.mdl);
 352         }
 353
 354
 355         if(sf & ISF_COLORMAP)
 356         {
 357                 WriteShort(MSG_ENTITY, this.colormap);
 358                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 359         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 360         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 361         }
 362
 363         if(sf & ISF_DROP)
 364         {
 365                 WriteVector(MSG_ENTITY, this.velocity);
 366         }
 367
 368         return true;
 369 }
 370
 371 void ItemUpdate(entity this)
 372 {
 373         this.oldorigin = this.origin;
 374         this.SendFlags |= ISF_LOCATION;
 375 }
 376
 377 void UpdateItemAfterTeleport(entity this)
 378 {
 379         if(getSendEntity(this) == ItemSend)
 380                 ItemUpdate(this);
 381 }
 382
 383 bool have_pickup_item(entity this)
 384 {
 385         if(this.itemdef.instanceOfPowerup)
 386         {
 387                 if(autocvar_g_powerups > 0)
 388                         return true;
 389                 if(autocvar_g_powerups == 0)
 390                         return false;
 391         }
 392         else
 393         {
 394                 if(autocvar_g_pickup_items > 0)
 395                         return true;
 396                 if(autocvar_g_pickup_items == 0)
 397                         return false;
 398                 if(g_weaponarena)
 399                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 400                                 return false;
 401         }
 402         return true;
 403 }
 404
 405 void Item_Show (entity e, int mode)
 406 {
 407         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 408         e.ItemStatus &= ~ITS_STAYWEP;
 409         entity def = e.itemdef;
 410         if (mode > 0)
 411         {
 412                 // make the item look normal, and be touchable
 413                 e.model = e.mdl;
 414                 e.solid = SOLID_TRIGGER;
 415                 e.spawnshieldtime = 1;
 416                 e.ItemStatus |= ITS_AVAILABLE;
 417         }
 418         else if (mode < 0)
 419         {
 420                 // hide the item completely
 421                 e.model = string_null;
 422                 e.solid = SOLID_NOT;
 423                 e.spawnshieldtime = 1;
 424                 e.ItemStatus &= ~ITS_AVAILABLE;
 425         }
 426         else
 427         {
 428                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 429                         || e.team // weapon stay isn't supported for teamed weapons
 430                         ;
 431                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 432                 {
 433                         // make the item translucent and not touchable
 434                         e.model = e.mdl;
 435                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 436                         e.effects |= EF_STARDUST;
 437                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 438                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 439                 }
 440                 else
 441                 {
 442                         //setmodel(e, "null");
 443                         e.solid = SOLID_NOT;
 444                         e.colormod = '0 0 0';
 445                         //e.glowmod = e.colormod;
 446                         e.spawnshieldtime = 1;
 447                         e.ItemStatus &= ~ITS_AVAILABLE;
 448                 }
 449         }
 450
 451         if (def.m_glow)
 452                 e.ItemStatus |= ITS_GLOW;
 453
 454         if (autocvar_g_nodepthtestitems)
 455                 e.effects |= EF_NODEPTHTEST;
 456
 457
 458         if (autocvar_g_fullbrightitems)
 459                 e.ItemStatus |= ITS_ALLOWFB;
 460
 461         if (autocvar_sv_simple_items)
 462                 e.ItemStatus |= ITS_ALLOWSI;
 463
 464         // relink entity (because solid may have changed)
 465         setorigin(e, e.origin);
 466         e.SendFlags |= ISF_STATUS;
 467 }
 468
 469 void Item_Think(entity this)
 470 {
 471         this.nextthink = time;
 472         if(this.origin != this.oldorigin)
 473                 ItemUpdate(this);
 474 }
 475
 476 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 477 bool Item_ItemsTime_Allow(GameItem it);
 478 float Item_ItemsTime_UpdateTime(entity e, float t);
 479 void Item_ItemsTime_SetTime(entity e, float t);
 480 void Item_ItemsTime_SetTimesForAllPlayers();
 481
 482 void Item_Respawn (entity this)
 483 {
 484         Item_Show(this, 1);
 485         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 486         setorigin(this, this.origin);
 487
 488     if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
 489         {
 490                 float t = Item_ItemsTime_UpdateTime(this, 0);
 491                 Item_ItemsTime_SetTime(this, t);
 492                 Item_ItemsTime_SetTimesForAllPlayers();
 493         }
 494
 495         setthink(this, Item_Think);
 496         this.nextthink = time;
 497
 498         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 499         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 500 }
 501
 502 void Item_RespawnCountdown (entity this)
 503 {
 504         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 505         {
 506                 if(this.waypointsprite_attached)
 507                         WaypointSprite_Kill(this.waypointsprite_attached);
 508                 Item_Respawn(this);
 509         }
 510         else
 511         {
 512                 this.nextthink = time + 1;
 513                 this.item_respawncounter += 1;
 514                 if(this.item_respawncounter == 1)
 515                 {
 516                         do {
 517                                 {
 518                                         entity wi = Weapons_from(this.weapon);
 519                                         if (wi != WEP_Null) {
 520                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 521                                                 wp.wp_extra = wi.m_id;
 522                                                 break;
 523                                         }
 524                                 }
 525                                 {
 526                                         entity ii = this.itemdef;
 527                                         if (ii != NULL) {
 528                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 529                                                 wp.wp_extra = ii.m_id;
 530                                                 break;
 531                                         }
 532                                 }
 533                         } while (0);
 534                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 535             if(this.waypointsprite_attached)
 536             {
 537                 GameItem def = this.itemdef;
 538                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 539                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 540                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 541             }
 542                 }
 543
 544                 if(this.waypointsprite_attached)
 545                 {
 546                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 547                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 548                                 {
 549                                         msg_entity = it;
 550                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 551                                 }
 552                         });
 553
 554                         WaypointSprite_Ping(this.waypointsprite_attached);
 555                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 556                 }
 557         }
 558 }
 559
 560 void Item_RespawnThink(entity this)
 561 {
 562         this.nextthink = time;
 563         if(this.origin != this.oldorigin)
 564                 ItemUpdate(this);
 565
 566         if(time >= this.wait)
 567                 Item_Respawn(this);
 568 }
 569
 570 void Item_ScheduleRespawnIn(entity e, float t)
 571 {
 572         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 573         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 574         {
 575                 setthink(e, Item_RespawnCountdown);
 576                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 577                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 578                 e.item_respawncounter = 0;
 579                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 580                 {
 581                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 582                         Item_ItemsTime_SetTime(e, t);
 583                         Item_ItemsTime_SetTimesForAllPlayers();
 584                 }
 585         }
 586         else
 587         {
 588                 setthink(e, Item_RespawnThink);
 589                 e.nextthink = time;
 590                 e.scheduledrespawntime = time + t;
 591                 e.wait = time + t;
 592
 593                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 594                 {
 595                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 596                         Item_ItemsTime_SetTime(e, t);
 597                         Item_ItemsTime_SetTimesForAllPlayers();
 598                 }
 599         }
 600 }
 601
 602 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 603 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 604 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 605
 606 /// Adjust respawn time according to the number of players.
 607 float adjust_respawntime(float normal_respawntime) {
 608         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 609         float o = autocvar_g_pickup_respawntime_scaling_offset;
 610         float l = autocvar_g_pickup_respawntime_scaling_linear;
 611
 612         if (r == 0 && l == 1) {
 613                 return normal_respawntime;
 614         }
 615
 616         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 617         TeamBalance_GetTeamCounts(balance, NULL);
 618         int players = 0;
 619         for (int i = 1; i <= NUM_TEAMS; ++i)
 620         {
 621                 if (TeamBalance_IsTeamAllowed(balance, i))
 622                 {
 623                         players += TeamBalance_GetNumberOfPlayers(balance, i);
 624                 }
 625         }
 626         TeamBalance_Destroy(balance);
 627
 628         if (players >= 2) {
 629                 return normal_respawntime * (r / (players + o) + l);
 630         } else {
 631                 return normal_respawntime;
 632         }
 633 }
 634
 635 void Item_ScheduleRespawn(entity e)
 636 {
 637         if(e.respawntime > 0)
 638         {
 639                 Item_Show(e, 0);
 640
 641                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 642                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 643
 644                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 645                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 646                 Item_ScheduleRespawnIn(e, respawn_in);
 647         }
 648         else // if respawntime is -1, this item does not respawn
 649                 Item_Show(e, -1);
 650 }
 651
 652 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 653         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 654
 655 void Item_ScheduleInitialRespawn(entity e)
 656 {
 657         Item_Show(e, 0);
 658
 659         float spawn_in;
 660         if (autocvar_g_pickup_respawntime_initial_random == 0)
 661         {
 662                 // range: respawntime .. respawntime + respawntimejitter
 663                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 664         }
 665         else
 666         {
 667                 float rnd;
 668                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 669                 {
 670                         static float shared_random = 0;
 671                         // NOTE this code works only if items are scheduled at the same time (normal case)
 672                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 673                         if (!shared_random || floor(time) > shared_random)
 674                                 shared_random = floor(time) + random();
 675                         rnd = shared_random - floor(time);
 676                 }
 677                 else
 678                         rnd = random();
 679
 680                 // range:
 681                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 682                 // else: 0 .. ITEM_RESPAWN_TICKS
 683                 // this is to prevent powerups spawning unexpectedly without waypoints
 684                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 685         }
 686
 687         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 688 }
 689
 690 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 691         entity ammo_entity)
 692 {
 693         if (num_weapons == 0)
 694         {
 695                 return;
 696         }
 697         int num_potential_weapons = tokenize_console(weapon_names);
 698         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 699         {
 700                 RandomSelection_Init();
 701                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 702                         ++weapon_index)
 703                 {
 704                         string weapon = argv(weapon_index);
 705                         FOREACH(Weapons, it != WEP_Null,
 706                         {
 707                                 // Finding a weapon which player doesn't have.
 708                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
 709                                 {
 710                                         RandomSelection_AddEnt(it, 1, 1);
 711                                         break;
 712                                 }
 713                         });
 714                 }
 715                 if (RandomSelection_chosen_ent == NULL)
 716                 {
 717                         return;
 718                 }
 719                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
 720                 if (RandomSelection_chosen_ent.ammo_type == RES_NONE)
 721                 {
 722                         continue;
 723                 }
 724                 if (GetResource(receiver,
 725                         RandomSelection_chosen_ent.ammo_type) != 0)
 726                 {
 727                         continue;
 728                 }
 729                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 730                         GetResource(ammo_entity,
 731                         RandomSelection_chosen_ent.ammo_type));
 732         }
 733 }
 734
 735 bool Item_GiveAmmoTo(entity item, entity player, int res_type, float ammomax)
 736 {
 737         float amount = GetResource(item, res_type);
 738         if (amount == 0)
 739         {
 740                 return false;
 741         }
 742         float player_amount = GetResource(player, res_type);
 743         if (item.spawnshieldtime)
 744         {
 745                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 746                 {
 747                         return false;
 748                 }
 749                 if (amount < 0)
 750                         TakeResourceWithLimit(player, res_type, -amount, ammomax);
 751                 else
 752                         GiveResourceWithLimit(player, res_type, amount, ammomax);
 753                 return true;
 754         }
 755         if (g_weapon_stay != 2)
 756         {
 757                 return false;
 758         }
 759         if (amount < 0)
 760                 TakeResourceWithLimit(player, res_type, -amount, min(amount, ammomax));
 761         else
 762                 GiveResourceWithLimit(player, res_type, amount, min(amount, ammomax));
 763         return true;
 764 }
 765
 766 bool Item_GiveTo(entity item, entity player)
 767 {
 768         // if nothing happens to player, just return without taking the item
 769         int _switchweapon = 0;
 770         // in case the player has autoswitch enabled do the following:
 771         // if the player is using their best weapon before items are given, they
 772         // probably want to switch to an even better weapon after items are given
 773
 774         if(CS(player).autoswitch)
 775         {
 776                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 777                 {
 778                         .entity weaponentity = weaponentities[slot];
 779                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 780                         {
 781                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 782                                         _switchweapon |= BIT(slot);
 783
 784                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 785                                         _switchweapon |= BIT(slot);
 786                         }
 787                 }
 788         }
 789         bool pickedup = false;
 790         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_HEALTH, item.max_health));
 791         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_ARMOR, item.max_armorvalue));
 792         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_SHELLS, g_pickup_shells_max));
 793         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_BULLETS, g_pickup_nails_max));
 794         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_ROCKETS, g_pickup_rockets_max));
 795         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_CELLS, g_pickup_cells_max));
 796         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_PLASMA, g_pickup_plasma_max));
 797         pickedup = (pickedup || Item_GiveAmmoTo(item, player, RES_FUEL, g_pickup_fuel_max));
 798         if (item.itemdef.instanceOfWeaponPickup)
 799         {
 800                 WepSet w;
 801                 w = STAT(WEAPONS, item);
 802                 w &= ~STAT(WEAPONS, player);
 803
 804                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 805                 {
 806                         pickedup = true;
 807                         FOREACH(Weapons, it != WEP_Null, {
 808                                 if(w & (it.m_wepset))
 809                                 {
 810                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 811                                         {
 812                                                 .entity weaponentity = weaponentities[slot];
 813                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 814                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 815                                         }
 816                                         W_GiveWeapon(player, it.m_id);
 817                                 }
 818                         });
 819                 }
 820         }
 821
 822         if (item.itemdef.instanceOfPowerup)
 823         {
 824                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 825                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 826                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 827                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 828         }
 829
 830         int its;
 831         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 832         {
 833                 pickedup = true;
 834                 player.items |= its;
 835                 // TODO: we probably want to show a message in the console, but not this one!
 836                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 837         }
 838
 839         if (item.strength_finished)
 840         {
 841                 pickedup = true;
 842                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 843         }
 844         if (item.invincible_finished)
 845         {
 846                 pickedup = true;
 847                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 848         }
 849         if (item.superweapons_finished)
 850         {
 851                 pickedup = true;
 852                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 853         }
 854
 855         // always eat teamed entities
 856         if(item.team)
 857                 pickedup = true;
 858
 859         if (!pickedup)
 860                 return false;
 861
 862         // crude hack to enforce switching weapons
 863         if(g_cts && item.itemdef.instanceOfWeaponPickup && !CS(player).cvar_cl_cts_noautoswitch)
 864         {
 865                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 866                 {
 867                         .entity weaponentity = weaponentities[slot];
 868                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 869                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 870                 }
 871                 return true;
 872         }
 873
 874         if(_switchweapon)
 875         {
 876                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 877                 {
 878                         .entity weaponentity = weaponentities[slot];
 879                         if(_switchweapon & BIT(slot))
 880                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 881                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 882                 }
 883         }
 884
 885         return true;
 886 }
 887
 888 void Item_Touch(entity this, entity toucher)
 889 {
 890         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 891         if (Item_IsLoot(this))
 892         {
 893                 if (ITEM_TOUCH_NEEDKILL())
 894                 {
 895                         delete(this);
 896                         return;
 897                 }
 898         }
 899
 900         if(!(toucher.flags & FL_PICKUPITEMS)
 901         || STAT(FROZEN, toucher)
 902         || IS_DEAD(toucher)
 903         || (this.solid != SOLID_TRIGGER)
 904         || (this.owner == toucher)
 905         || (time < this.item_spawnshieldtime)
 906         ) { return; }
 907
 908         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 909         {
 910                 case MUT_ITEMTOUCH_RETURN: { return; }
 911                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 912         }
 913
 914         toucher = M_ARGV(1, entity);
 915
 916         if (Item_IsExpiring(this))
 917         {
 918                 this.strength_finished = max(0, this.strength_finished - time);
 919                 this.invincible_finished = max(0, this.invincible_finished - time);
 920                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 921         }
 922         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 923         if (!gave)
 924         {
 925                 if (Item_IsExpiring(this))
 926                 {
 927                         // undo what we did above
 928                         this.strength_finished += time;
 929                         this.invincible_finished += time;
 930                         this.superweapons_finished += time;
 931                 }
 932                 return;
 933         }
 934
 935 LABEL(pickup)
 936
 937         STAT(LAST_PICKUP, toucher) = time;
 938
 939         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 940         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 941
 942         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 943         if (wasfreed(this))
 944         {
 945                 return;
 946         }
 947
 948         if (Item_IsLoot(this))
 949         {
 950                 delete(this);
 951                 return;
 952         }
 953         if (!this.spawnshieldtime)
 954         {
 955                 return;
 956         }
 957         entity e;
 958         if (this.team)
 959         {
 960                 RandomSelection_Init();
 961                 IL_EACH(g_items, it.team == this.team,
 962                 {
 963                         if (it.itemdef) // is a registered item
 964                         {
 965                                 Item_Show(it, -1);
 966                                 it.scheduledrespawntime = 0;
 967                                 RandomSelection_AddEnt(it, it.cnt, 0);
 968                         }
 969                 });
 970                 e = RandomSelection_chosen_ent;
 971                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 972         }
 973         else
 974                 e = this;
 975         Item_ScheduleRespawn(e);
 976 }
 977
 978 void Item_Reset(entity this)
 979 {
 980         Item_Show(this, !this.state);
 981         setorigin(this, this.origin);
 982
 983         if (Item_IsLoot(this))
 984         {
 985                 return;
 986         }
 987         setthink(this, Item_Think);
 988         this.nextthink = time;
 989         if (this.waypointsprite_attached)
 990         {
 991                 WaypointSprite_Kill(this.waypointsprite_attached);
 992         }
 993         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 994         {
 995                 Item_ScheduleInitialRespawn(this);
 996         }
 997 }
 998
 999 void Item_FindTeam(entity this)
1000 {
1001         entity e;
1002
1003         if(this.effects & EF_NODRAW)
1004         {
1005                 // marker for item team search
1006                 LOG_TRACE("Initializing item team ", ftos(this.team));
1007                 RandomSelection_Init();
1008                 IL_EACH(g_items, it.team == this.team,
1009                 {
1010                         if(it.itemdef) // is a registered item
1011                                 RandomSelection_AddEnt(it, it.cnt, 0);
1012                 });
1013
1014                 e = RandomSelection_chosen_ent;
1015                 e.state = 0;
1016                 Item_Show(e, 1);
1017
1018                 IL_EACH(g_items, it.team == this.team,
1019                 {
1020                         if(it.itemdef) // is a registered item
1021                         {
1022                                 if(it != e)
1023                                 {
1024                                         // make it non-spawned
1025                                         Item_Show(it, -1);
1026                                         it.state = 1; // state 1 = initially hidden item, apparently
1027                                 }
1028                                 it.effects &= ~EF_NODRAW;
1029                         }
1030                 });
1031
1032                 Item_Reset(this);
1033         }
1034 }
1035
1036 // Savage: used for item garbage-collection
1037 void RemoveItem(entity this)
1038 {
1039         if(wasfreed(this) || !this) { return; }
1040         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1041         delete(this);
1042 }
1043
1044 // pickup evaluation functions
1045 // these functions decide how desirable an item is to the bots
1046
1047 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1048
1049 float weapon_pickupevalfunc(entity player, entity item)
1050 {
1051         // See if I have it already
1052         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
1053         {
1054                 // If I can pick it up
1055                 if(!item.spawnshieldtime)
1056                         return 0;
1057                 return ammo_pickupevalfunc(player, item);
1058         }
1059
1060         // reduce weapon value if bot already got a good arsenal
1061         float c = 1;
1062         int weapons_value = 0;
1063         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
1064                 weapons_value += it.bot_pickupbasevalue;
1065         });
1066         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1067
1068         return item.bot_pickupbasevalue * c;
1069 }
1070
1071 float ammo_pickupevalfunc(entity player, entity item)
1072 {
1073         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1074         entity wpn = NULL;
1075         float c = 0;
1076         float rating = 0;
1077
1078         // Detect needed ammo
1079         if(item.itemdef.instanceOfWeaponPickup)
1080         {
1081                 entity ammo = NULL;
1082                 if(GetResource(item, RES_SHELLS))       { need_shells  = true; ammo = ITEM_Shells;      }
1083                 else if(GetResource(item, RES_BULLETS))   { need_nails   = true; ammo = ITEM_Bullets;     }
1084                 else if(GetResource(item, RES_ROCKETS)) { need_rockets = true; ammo = ITEM_Rockets;     }
1085                 else if(GetResource(item, RES_CELLS))   { need_cells   = true; ammo = ITEM_Cells;       }
1086                 else if(GetResource(item, RES_PLASMA))  { need_plasma  = true; ammo = ITEM_Plasma;      }
1087                 else if(GetResource(item, RES_FUEL))    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1088
1089                 if(!ammo)
1090                         return 0;
1091                 wpn = item;
1092                 rating = ammo.m_botvalue;
1093         }
1094         else
1095         {
1096                 FOREACH(Weapons, it != WEP_Null, {
1097                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
1098                                 continue;
1099
1100                         switch(it.ammo_type)
1101                         {
1102                                 case RES_SHELLS:  need_shells  = true; break;
1103                                 case RES_BULLETS: need_nails   = true; break;
1104                                 case RES_ROCKETS: need_rockets = true; break;
1105                                 case RES_CELLS:   need_cells   = true; break;
1106                                 case RES_PLASMA:  need_plasma  = true; break;
1107                                 case RES_FUEL:    need_fuel    = true; break;
1108                         }
1109                 });
1110                 rating = item.bot_pickupbasevalue;
1111         }
1112
1113         float noammorating = 0.5;
1114
1115         if ((need_shells) && GetResource(item, RES_SHELLS) && (GetResource(player, RES_SHELLS) < g_pickup_shells_max))
1116                 c = GetResource(item, RES_SHELLS) / max(noammorating, GetResource(player, RES_SHELLS));
1117
1118         if ((need_nails) && GetResource(item, RES_BULLETS) && (GetResource(player, RES_BULLETS) < g_pickup_nails_max))
1119                 c = GetResource(item, RES_BULLETS) / max(noammorating, GetResource(player, RES_BULLETS));
1120
1121         if ((need_rockets) && GetResource(item, RES_ROCKETS) && (GetResource(player, RES_ROCKETS) < g_pickup_rockets_max))
1122                 c = GetResource(item, RES_ROCKETS) / max(noammorating, GetResource(player, RES_ROCKETS));
1123
1124         if ((need_cells) && GetResource(item, RES_CELLS) && (GetResource(player, RES_CELLS) < g_pickup_cells_max))
1125                 c = GetResource(item, RES_CELLS) / max(noammorating, GetResource(player, RES_CELLS));
1126
1127         if ((need_plasma) && GetResource(item, RES_PLASMA) && (GetResource(player, RES_PLASMA) < g_pickup_plasma_max))
1128                 c = GetResource(item, RES_PLASMA) / max(noammorating, GetResource(player, RES_PLASMA));
1129
1130         if ((need_fuel) && GetResource(item, RES_FUEL) && (GetResource(player, RES_FUEL) < g_pickup_fuel_max))
1131                 c = GetResource(item, RES_FUEL) / max(noammorating, GetResource(player, RES_FUEL));
1132
1133         rating *= min(c, 2);
1134         if(wpn)
1135                 rating += wpn.bot_pickupbasevalue * 0.1;
1136         return rating;
1137 }
1138
1139 float healtharmor_pickupevalfunc(entity player, entity item)
1140 {
1141         float c = 0;
1142         float rating = item.bot_pickupbasevalue;
1143
1144         float itemarmor = GetResource(item, RES_ARMOR);
1145         float itemhealth = GetResource(item, RES_HEALTH);
1146
1147         if(item.item_group)
1148         {
1149                 itemarmor *= min(4, item.item_group_count);
1150                 itemhealth *= min(4, item.item_group_count);
1151         }
1152
1153         if (itemarmor && (GetResource(player, RES_ARMOR) < item.max_armorvalue))
1154                 c = itemarmor / max(1, GetResource(player, RES_ARMOR) * 2/3 + GetResource(player, RES_HEALTH) * 1/3);
1155
1156         if (itemhealth && (GetResource(player, RES_HEALTH) < item.max_health))
1157                 c = itemhealth / max(1, GetResource(player, RES_HEALTH));
1158
1159         rating *= min(2, c);
1160         return rating;
1161 }
1162
1163 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
1164 {
1165         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1166                 RemoveItem(this);
1167 }
1168
1169 void item_use(entity this, entity actor, entity trigger)
1170 {
1171         // use the touch function to handle collection
1172         gettouch(this)(this, actor);
1173 }
1174
1175 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1176 {
1177         string itemname = def.m_name;
1178         Model itemmodel = def.m_model;
1179     Sound pickupsound = def.m_sound;
1180         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1181         float pickupbasevalue = def.m_botvalue;
1182         int itemflags = def.m_itemflags;
1183
1184         startitem_failed = false;
1185
1186         this.item_model_ent = itemmodel;
1187     this.item_pickupsound_ent = pickupsound;
1188
1189     if(def.m_iteminit)
1190         def.m_iteminit(def, this);
1191
1192         if(!this.respawntime) // both need to be set
1193         {
1194                 this.respawntime = defaultrespawntime;
1195                 this.respawntimejitter = defaultrespawntimejitter;
1196         }
1197
1198         if(!this.pickup_anyway && def.m_pickupanyway)
1199                 this.pickup_anyway = def.m_pickupanyway();
1200
1201         int itemid = def.m_itemid;
1202         this.items = itemid;
1203         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1204         this.weapon = weaponid;
1205
1206         if(!this.fade_end)
1207         {
1208                 this.fade_start = autocvar_g_items_mindist;
1209                 this.fade_end = autocvar_g_items_maxdist;
1210         }
1211
1212         if(weaponid)
1213                 STAT(WEAPONS, this) = WepSet_FromWeapon(Weapons_from(weaponid));
1214
1215         this.flags = FL_ITEM | itemflags;
1216         IL_PUSH(g_items, this);
1217
1218         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1219         {
1220                 startitem_failed = true;
1221                 delete(this);
1222                 return;
1223         }
1224
1225         if (Item_IsLoot(this))
1226         {
1227                 this.reset = SUB_Remove;
1228                 set_movetype(this, MOVETYPE_TOSS);
1229
1230                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1231                 setthink(this, RemoveItem);
1232                 this.nextthink = time + 20;
1233
1234                 this.takedamage = DAMAGE_YES;
1235                 this.event_damage = Item_Damage;
1236
1237                 if (Item_IsExpiring(this))
1238                 {
1239                         // if item is worthless after a timer, have it expire then
1240                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1241                 }
1242
1243                 // don't drop if in a NODROP zone (such as lava)
1244                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1245                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1246                 {
1247                         startitem_failed = true;
1248                         delete(this);
1249                         return;
1250                 }
1251         }
1252         else
1253         {
1254                 if(!have_pickup_item(this))
1255                 {
1256                         startitem_failed = true;
1257                         delete(this);
1258                         return;
1259                 }
1260
1261                 if(this.angles != '0 0 0')
1262                         this.SendFlags |= ISF_ANGLES;
1263
1264                 this.reset = Item_Reset;
1265                 // it's a level item
1266                 if(this.spawnflags & 1)
1267                         this.noalign = 1;
1268                 if (this.noalign > 0)
1269                         set_movetype(this, MOVETYPE_NONE);
1270                 else
1271                         set_movetype(this, MOVETYPE_TOSS);
1272                 // do item filtering according to game mode and other things
1273                 if (this.noalign <= 0)
1274                 {
1275                         // first nudge it off the floor a little bit to avoid math errors
1276                         setorigin(this, this.origin + '0 0 1');
1277                         // set item size before we spawn a spawnfunc_waypoint
1278                         setsize(this, def.m_mins, def.m_maxs);
1279                         this.SendFlags |= ISF_SIZE;
1280                         // note droptofloor returns false if stuck/or would fall too far
1281                         if (!this.noalign)
1282                                 droptofloor(this);
1283                         waypoint_spawnforitem(this);
1284                 }
1285
1286                 /*
1287                  * can't do it that way, as it would break maps
1288                  * TODO make a target_give like entity another way, that perhaps has
1289                  * the weapon name in a key
1290                 if(this.targetname)
1291                 {
1292                         // target_give not yet supported; maybe later
1293                         print("removed targeted ", this.classname, "\n");
1294                         startitem_failed = true;
1295                         delete(this);
1296                         return;
1297                 }
1298                 */
1299
1300                 if(this.targetname != "" && (this.spawnflags & 16))
1301                         this.use = item_use;
1302
1303                 if(autocvar_spawn_debug >= 2)
1304                 {
1305             // why not flags & fl_item?
1306                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1307                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1308                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1309                 error("Mapper sucks.");
1310             });
1311                         this.is_item = true;
1312                 }
1313
1314                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1315
1316                 precache_model(this.model);
1317                 precache_sound(this.item_pickupsound);
1318
1319                 if (   def.instanceOfPowerup
1320                         || def.instanceOfWeaponPickup
1321                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1322                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1323                         || (itemid & (IT_KEY1 | IT_KEY2))
1324                 ) this.target = "###item###"; // for finding the nearest item using findnearest
1325
1326                 Item_ItemsTime_SetTime(this, 0);
1327         }
1328
1329         this.bot_pickup = true;
1330         this.bot_pickupevalfunc = pickupevalfunc;
1331         this.bot_pickupbasevalue = pickupbasevalue;
1332         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1333         this.netname = itemname;
1334         settouch(this, Item_Touch);
1335         setmodel(this, MDL_Null); // precision set below
1336         //this.effects |= EF_LOWPRECISION;
1337
1338         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1339
1340         this.SendFlags |= ISF_SIZE;
1341
1342         if (!(this.spawnflags & 1024)) {
1343                 if(def.instanceOfPowerup)
1344                         this.ItemStatus |= ITS_ANIMATE1;
1345
1346                 if(GetResource(this, RES_ARMOR) || GetResource(this, RES_HEALTH))
1347                         this.ItemStatus |= ITS_ANIMATE2;
1348         }
1349
1350         if(def.instanceOfWeaponPickup)
1351         {
1352                 if (!Item_IsLoot(this)) // if dropped, colormap is already set up nicely
1353                         this.colormap = 1024; // color shirt=0 pants=0 grey
1354                 else
1355                         this.gravity = 1;
1356                 if (!(this.spawnflags & 1024))
1357                         this.ItemStatus |= ITS_ANIMATE1;
1358                 this.SendFlags |= ISF_COLORMAP;
1359         }
1360
1361         this.state = 0;
1362         if(this.team) // broken, no idea why.
1363         {
1364                 if(!this.cnt)
1365                         this.cnt = 1; // item probability weight
1366
1367                 this.effects |= EF_NODRAW; // marker for item team search
1368                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1369         }
1370         else
1371                 Item_Reset(this);
1372
1373         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1374
1375         // call this hook after everything else has been done
1376         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1377         {
1378                 startitem_failed = true;
1379                 delete(this);
1380                 return;
1381         }
1382
1383         setItemGroup(this);
1384 }
1385
1386 void StartItem(entity this, GameItem def)
1387 {
1388     def = def.m_spawnfunc_hookreplace(def, this);
1389     if (def.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
1390     {
1391         delete(this);
1392         return;
1393     }
1394     this.classname = def.m_canonical_spawnfunc;
1395     _StartItem(
1396         this,
1397         this.itemdef = def,
1398         def.m_respawntime(), // defaultrespawntime
1399         def.m_respawntimejitter() // defaultrespawntimejitter
1400         );
1401 }
1402
1403 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1404 int group_count = 1;
1405
1406 void setItemGroup(entity this)
1407 {
1408         if(!IS_SMALL(this.itemdef) || Item_IsLoot(this))
1409                 return;
1410
1411         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1412         {
1413                 if(!this.item_group)
1414                 {
1415                         if(!it.item_group)
1416                         {
1417                                 it.item_group = group_count;
1418                                 group_count++;
1419                         }
1420                         this.item_group = it.item_group;
1421                 }
1422                 else // spawning item is already part of a item_group X
1423                 {
1424                         if(!it.item_group)
1425                                 it.item_group = this.item_group;
1426                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1427                         {
1428                                 int grY = it.item_group;
1429                                 // move all items of item_group Y to item_group X
1430                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1431                                 {
1432                                         if(it.item_group == grY)
1433                                                 it.item_group = this.item_group;
1434                                 });
1435                         }
1436                 }
1437         });
1438 }
1439
1440 void setItemGroupCount()
1441 {
1442         for (int k = 1; k <= group_count; k++)
1443         {
1444                 int count = 0;
1445                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1446                 if (count)
1447                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1448         }
1449 }
1450
1451 void target_items_use(entity this, entity actor, entity trigger)
1452 {
1453         if(Item_IsLoot(actor))
1454         {
1455                 EXACTTRIGGER_TOUCH(this, trigger);
1456                 delete(actor);
1457                 return;
1458         }
1459
1460         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1461                 return;
1462
1463         if(trigger.solid == SOLID_TRIGGER)
1464         {
1465                 EXACTTRIGGER_TOUCH(this, trigger);
1466         }
1467
1468         IL_EACH(g_items, it.enemy == actor && Item_IsLoot(it),
1469         {
1470                 delete(it);
1471         });
1472
1473         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1474                 centerprint(actor, this.message);
1475 }
1476
1477 spawnfunc(target_items)
1478 {
1479         int n;
1480         string s;
1481
1482         this.use = target_items_use;
1483         if(!this.strength_finished)
1484                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1485         if(!this.invincible_finished)
1486                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1487         if(!this.superweapons_finished)
1488                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1489
1490         n = tokenize_console(this.netname);
1491         if(argv(0) == "give")
1492         {
1493                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1494         }
1495         else
1496         {
1497                 for(int j = 0; j < n; ++j)
1498                 {
1499                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1500                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1501                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1502                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1503                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1504                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1505                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1506                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1507                         else
1508                         {
1509                                 FOREACH(Buffs, it != BUFF_Null,
1510                                 {
1511                                         s = Buff_UndeprecateName(argv(j));
1512                                         if(s == it.m_name)
1513                                         {
1514                                                 STAT(BUFFS, this) |= (it.m_itemid);
1515                                                 break;
1516                                         }
1517                                 });
1518                                 FOREACH(Weapons, it != WEP_Null, {
1519                                         s = W_UndeprecateName(argv(j));
1520                                         if(s == it.netname)
1521                                         {
1522                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1523                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1524                                                         it.wr_init(it);
1525                                                 break;
1526                                         }
1527                                 });
1528                         }
1529                 }
1530
1531                 string itemprefix, valueprefix;
1532                 if(this.spawnflags == 0)
1533                 {
1534                         itemprefix = "";
1535                         valueprefix = "";
1536                 }
1537                 else if(this.spawnflags == 1)
1538                 {
1539                         itemprefix = "max ";
1540                         valueprefix = "max ";
1541                 }
1542                 else if(this.spawnflags == 2)
1543                 {
1544                         itemprefix = "min ";
1545                         valueprefix = "min ";
1546                 }
1547                 else if(this.spawnflags == 4)
1548                 {
1549                         itemprefix = "minus ";
1550                         valueprefix = "max ";
1551                 }
1552                 else
1553                 {
1554                         error("invalid spawnflags");
1555                         itemprefix = valueprefix = string_null;
1556                 }
1557
1558                 this.netname = "";
1559                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1560                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1561                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1562                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1563                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1564                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1565                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1566                 if(GetResource(this, RES_SHELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_SHELLS)), "shells");
1567                 if(GetResource(this, RES_BULLETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_BULLETS)), "nails");
1568                 if(GetResource(this, RES_ROCKETS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_ROCKETS)), "rockets");
1569                 if(GetResource(this, RES_CELLS) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_CELLS)), "cells");
1570                 if(GetResource(this, RES_PLASMA) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_PLASMA)), "plasma");
1571                 if(GetResource(this, RES_FUEL) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_FUEL)), "fuel");
1572                 if(GetResource(this, RES_HEALTH) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_HEALTH)), "health");
1573                 if(GetResource(this, RES_ARMOR) != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, GetResource(this, RES_ARMOR)), "armor");
1574                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(BUFFS, this) & (it.m_itemid)), it.m_name));
1575                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1576         }
1577         this.netname = strzone(this.netname);
1578         //print(this.netname, "\n");
1579
1580         n = tokenize_console(this.netname);
1581         for(int j = 0; j < n; ++j)
1582         {
1583                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1584             it.wr_init(it);
1585             break;
1586                 });
1587         }
1588 }
1589
1590 float GiveWeapon(entity e, float wpn, float op, float val)
1591 {
1592         WepSet v0, v1;
1593         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1594         v0 = (STAT(WEAPONS, e) & s);
1595         switch(op)
1596         {
1597                 case OP_SET:
1598                         if(val > 0)
1599                                 STAT(WEAPONS, e) |= s;
1600                         else
1601                                 STAT(WEAPONS, e) &= ~s;
1602                         break;
1603                 case OP_MIN:
1604                 case OP_PLUS:
1605                         if(val > 0)
1606                                 STAT(WEAPONS, e) |= s;
1607                         break;
1608                 case OP_MAX:
1609                         if(val <= 0)
1610                                 STAT(WEAPONS, e) &= ~s;
1611                         break;
1612                 case OP_MINUS:
1613                         if(val > 0)
1614                                 STAT(WEAPONS, e) &= ~s;
1615                         break;
1616         }
1617         v1 = (STAT(WEAPONS, e) & s);
1618         return (v0 != v1);
1619 }
1620
1621 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1622 {
1623         bool had_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1624         switch(op)
1625         {
1626                 case OP_SET:
1627                         if(val > 0)
1628                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1629                         else
1630                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1631                         break;
1632                 case OP_MIN:
1633                 case OP_PLUS:
1634                         if(val > 0)
1635                                 STAT(BUFFS, e) |= thebuff.m_itemid;
1636                         break;
1637                 case OP_MAX:
1638                         if(val <= 0)
1639                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1640                         break;
1641                 case OP_MINUS:
1642                         if(val > 0)
1643                                 STAT(BUFFS, e) &= ~thebuff.m_itemid;
1644                         break;
1645         }
1646         bool have_buff = (STAT(BUFFS, e) & thebuff.m_itemid);
1647         return (had_buff != have_buff);
1648 }
1649
1650 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1651 {
1652         if(v1 == v0)
1653                 return;
1654         if(v1 <= v0 - t)
1655         {
1656                 if(snd_decr != NULL)
1657                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1658         }
1659         else if(v0 >= v0 + t)
1660         {
1661                 if(snd_incr != NULL)
1662                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1663         }
1664 }
1665
1666 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1667 {
1668         if(v0 < v1)
1669                 e.(rotfield) = max(e.(rotfield), time + rottime);
1670         else if(v0 > v1)
1671                 e.(regenfield) = max(e.(regenfield), time + regentime);
1672 }
1673 bool GiveResourceValue(entity e, int res_type, int op, int val)
1674 {
1675         int v0 = GetResource(e, res_type);
1676         switch (op)
1677         {
1678                 // min 100 cells = at least 100 cells
1679                 case OP_SET: SetResource(e, res_type, val); break;
1680                 case OP_MIN: SetResource(e, res_type, max(v0, val)); break;
1681                 case OP_MAX: SetResource(e, res_type, min(v0, val)); break;
1682                 case OP_PLUS: SetResource(e, res_type, v0 + val); break;
1683                 case OP_MINUS: SetResource(e, res_type, v0 - val); break;
1684         }
1685         int v1 = GetResource(e, res_type);
1686         return v0 != v1;
1687 }
1688
1689 float GiveItems(entity e, float beginarg, float endarg)
1690 {
1691         float got, i, val, op;
1692         string cmd;
1693
1694         val = 999;
1695         op = OP_SET;
1696
1697         got = 0;
1698
1699         int _switchweapon = 0;
1700
1701         if(CS(e).autoswitch)
1702         {
1703                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1704                 {
1705                         .entity weaponentity = weaponentities[slot];
1706                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1707                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1708                                 _switchweapon |= BIT(slot);
1709                 }
1710         }
1711
1712         e.strength_finished = max(0, e.strength_finished - time);
1713         e.invincible_finished = max(0, e.invincible_finished - time);
1714         e.superweapons_finished = max(0, e.superweapons_finished - time);
1715
1716         PREGIVE(e, items);
1717         PREGIVE_WEAPONS(e);
1718         PREGIVE(e, strength_finished);
1719         PREGIVE(e, invincible_finished);
1720         PREGIVE(e, superweapons_finished);
1721         PREGIVE_RESOURCE(e, RES_BULLETS);
1722         PREGIVE_RESOURCE(e, RES_CELLS);
1723         PREGIVE_RESOURCE(e, RES_PLASMA);
1724         PREGIVE_RESOURCE(e, RES_SHELLS);
1725         PREGIVE_RESOURCE(e, RES_ROCKETS);
1726         PREGIVE_RESOURCE(e, RES_FUEL);
1727         PREGIVE_RESOURCE(e, RES_ARMOR);
1728         PREGIVE_RESOURCE(e, RES_HEALTH);
1729
1730         for(i = beginarg; i < endarg; ++i)
1731         {
1732                 cmd = argv(i);
1733
1734                 if(cmd == "0" || stof(cmd))
1735                 {
1736                         val = stof(cmd);
1737                         continue;
1738                 }
1739                 switch(cmd)
1740                 {
1741                         case "no":
1742                                 op = OP_MAX;
1743                                 val = 0;
1744                                 continue;
1745                         case "max":
1746                                 op = OP_MAX;
1747                                 continue;
1748                         case "min":
1749                                 op = OP_MIN;
1750                                 continue;
1751                         case "plus":
1752                                 op = OP_PLUS;
1753                                 continue;
1754                         case "minus":
1755                                 op = OP_MINUS;
1756                                 continue;
1757                         case "ALL":
1758                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1759                                 got += GiveValue(e, strength_finished, op, val);
1760                                 got += GiveValue(e, invincible_finished, op, val);
1761                                 got += GiveValue(e, superweapons_finished, op, val);
1762                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1763                         case "all":
1764                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1765                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1766                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1767                         case "allweapons":
1768                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1769                         //case "allbuffs": // all buffs makes a player god, do not want!
1770                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1771                         case "allammo":
1772                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1773                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1774                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1775                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1776                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1777                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1778                                 break;
1779                         case "unlimited_ammo":
1780                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1781                                 break;
1782                         case "unlimited_weapon_ammo":
1783                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1784                                 break;
1785                         case "unlimited_superweapons":
1786                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1787                                 break;
1788                         case "jetpack":
1789                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1790                                 break;
1791                         case "fuel_regen":
1792                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1793                                 break;
1794                         case "strength":
1795                                 got += GiveValue(e, strength_finished, op, val);
1796                                 break;
1797                         case "invincible":
1798                                 got += GiveValue(e, invincible_finished, op, val);
1799                                 break;
1800                         case "superweapons":
1801                                 got += GiveValue(e, superweapons_finished, op, val);
1802                                 break;
1803                         case "cells":
1804                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1805                                 break;
1806                         case "plasma":
1807                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1808                                 break;
1809                         case "shells":
1810                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1811                                 break;
1812                         case "nails":
1813                         case "bullets":
1814                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1815                                 break;
1816                         case "rockets":
1817                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1818                                 break;
1819                         case "health":
1820                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1821                                 break;
1822                         case "armor":
1823                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1824                                 break;
1825                         case "fuel":
1826                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1827                                 break;
1828                         default:
1829                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1830                                 {
1831                                         got += GiveBuff(e, it, op, val);
1832                                         break;
1833                                 });
1834                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1835                     got += GiveWeapon(e, it.m_id, op, val);
1836                     break;
1837                                 });
1838                                 break;
1839                 }
1840                 val = 999;
1841                 op = OP_SET;
1842         }
1843
1844         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1845         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1846         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1847         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1848         FOREACH(Weapons, it != WEP_Null, {
1849                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1850                 if(!(save_weapons & (it.m_wepset)))
1851                         if(STAT(WEAPONS, e) & (it.m_wepset))
1852                                 it.wr_init(it);
1853         });
1854         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1855         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1856         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1857         POSTGIVE_RESOURCE(e, RES_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1858         POSTGIVE_RESOURCE(e, RES_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1859         POSTGIVE_RESOURCE(e, RES_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1860         POSTGIVE_RESOURCE(e, RES_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1861         POSTGIVE_RESOURCE(e, RES_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1862         POSTGIVE_RES_ROT(e, RES_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1863         POSTGIVE_RES_ROT(e, RES_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1864         POSTGIVE_RES_ROT(e, RES_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1865
1866         if(e.superweapons_finished <= 0)
1867                 if(STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS)
1868                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1869
1870         if(e.strength_finished <= 0)
1871                 e.strength_finished = 0;
1872         else
1873                 e.strength_finished += time;
1874         if(e.invincible_finished <= 0)
1875                 e.invincible_finished = 0;
1876         else
1877                 e.invincible_finished += time;
1878         if(e.superweapons_finished <= 0)
1879                 e.superweapons_finished = 0;
1880         else
1881                 e.superweapons_finished += time;
1882
1883         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1884         {
1885                 .entity weaponentity = weaponentities[slot];
1886                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1887                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1888                         _switchweapon |= BIT(slot);
1889         }
1890
1891         if(_switchweapon)
1892         {
1893                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1894                 {
1895                         .entity weaponentity = weaponentities[slot];
1896                         if(_switchweapon & BIT(slot))
1897                         {
1898                                 Weapon wep = w_getbestweapon(e, weaponentity);
1899                                 if(wep != e.(weaponentity).m_switchweapon)
1900                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1901                         }
1902                 }
1903         }
1904
1905         return got;
1906 }
1907 #endif