qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include "../lib/warpzone/util_server.qh"
  26 #elif defined(CSQC)
  27         #include "physics/movetypes/movetypes.qh"
  28         #include <common/weapons/_all.qh>
  29         #include "../lib/csqcmodel/cl_model.qh"
  30         #include "../lib/csqcmodel/common.qh"
  31 #endif
  32
  33 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  34
  35 #ifdef CSQC
  36 bool autocvar_cl_ghost_items_vehicle = true;
  37 .vector item_glowmod;
  38 void Item_SetAlpha(entity this)
  39 {
  40         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  41
  42         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  43         {
  44                 this.alpha = 1;
  45                 this.colormod = '1 1 1';
  46                 this.glowmod = this.item_glowmod;
  47         }
  48         else
  49         {
  50                 if (autocvar_cl_ghost_items_color)
  51                 {
  52                         this.alpha = autocvar_cl_ghost_items;
  53                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  54                 }
  55                 else
  56                         this.alpha = -1;
  57         }
  58
  59         if(!veh_hud)
  60         if(this.ItemStatus & ITS_STAYWEP)
  61         {
  62                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  63                 this.alpha = autocvar_cl_weapon_stay_alpha;
  64         }
  65 }
  66
  67 void ItemDraw(entity this)
  68 {
  69     if(this.gravity)
  70     {
  71         Movetype_Physics_MatchServer(this, false);
  72         if(IS_ONGROUND(this))
  73         { // For some reason avelocity gets set to '0 0 0' here ...
  74             this.oldorigin = this.origin;
  75             this.gravity = 0;
  76
  77             if(autocvar_cl_animate_items)
  78             { // ... so reset it if animations are requested.
  79                 if(this.ItemStatus & ITS_ANIMATE1)
  80                     this.avelocity = '0 180 0';
  81
  82                 if(this.ItemStatus & ITS_ANIMATE2)
  83                     this.avelocity = '0 -90 0';
  84             }
  85
  86             // delay is for blocking item's position for a while;
  87             // it's a workaround for dropped weapons that receive the position
  88             // another time right after they spawn overriding animation position
  89             this.onground_time = time + 0.5;
  90         }
  91     }
  92     else if (autocvar_cl_animate_items)
  93     {
  94         if(this.ItemStatus & ITS_ANIMATE1)
  95         {
  96             this.angles += this.avelocity * frametime;
  97             float fade_in = bound(0, time - this.onground_time, 1);
  98             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
  99         }
 100
 101         if(this.ItemStatus & ITS_ANIMATE2)
 102         {
 103             this.angles += this.avelocity * frametime;
 104             float fade_in = bound(0, time - this.onground_time, 1);
 105             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 106         }
 107     }
 108
 109     Item_SetAlpha(this);
 110 }
 111
 112 void ItemDrawSimple(entity this)
 113 {
 114     if(this.gravity)
 115     {
 116         Movetype_Physics_MatchServer(this, false);
 117
 118         if(IS_ONGROUND(this))
 119             this.gravity = 0;
 120     }
 121
 122     Item_SetAlpha(this);
 123 }
 124
 125 void Item_PreDraw(entity this)
 126 {
 127         if(warpzone_warpzones_exist)
 128         {
 129                 // just incase warpzones were initialized last, reset these
 130                 //this.alpha = 1; // alpha is already set by the draw function
 131                 this.drawmask = MASK_NORMAL;
 132                 return;
 133         }
 134         float alph;
 135         vector org = getpropertyvec(VF_ORIGIN);
 136         if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 137                 alph = 0;
 138         else if(this.fade_start)
 139                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 140         else
 141                 alph = 1;
 142         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 143         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 144                 this.alpha = alph;
 145         if(alph <= 0)
 146                 this.drawmask = 0;
 147         else
 148                 this.drawmask = MASK_NORMAL;
 149 }
 150
 151 void ItemRemove(entity this)
 152 {
 153         if(this.mdl)
 154                 strunzone(this.mdl);
 155 }
 156
 157 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 158 {
 159     int sf = ReadByte();
 160
 161     if(sf & ISF_LOCATION)
 162     {
 163         this.origin_x = ReadCoord();
 164         this.origin_y = ReadCoord();
 165         this.origin_z = ReadCoord();
 166         setorigin(this, this.origin);
 167         this.oldorigin = this.origin;
 168     }
 169
 170     if(sf & ISF_ANGLES)
 171     {
 172         this.angles_x = ReadAngle();
 173         this.angles_y = ReadAngle();
 174         this.angles_z = ReadAngle();
 175     }
 176
 177     if(sf & ISF_SIZE)
 178     {
 179         float use_bigsize = ReadByte();
 180         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 181     }
 182
 183     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 184     {
 185         this.ItemStatus = ReadByte();
 186
 187         Item_SetAlpha(this);
 188
 189         if(autocvar_cl_fullbright_items)
 190             if(this.ItemStatus & ITS_ALLOWFB)
 191                 this.effects |= EF_FULLBRIGHT;
 192
 193         if(this.ItemStatus & ITS_GLOW)
 194         {
 195             if(this.ItemStatus & ITS_AVAILABLE)
 196                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 197             else
 198                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 199         }
 200     }
 201
 202     if(sf & ISF_MODEL)
 203     {
 204         this.drawmask  = MASK_NORMAL;
 205                 set_movetype(this, MOVETYPE_TOSS);
 206                 if (isnew) IL_PUSH(g_drawables, this);
 207         this.draw       = ItemDraw;
 208         this.solid = SOLID_TRIGGER;
 209         //this.flags |= FL_ITEM;
 210
 211         bool use_bigsize = ReadByte();
 212
 213         this.fade_end = ReadShort();
 214         this.fade_start = ReadShort();
 215         if(this.fade_start && !autocvar_cl_items_nofade)
 216                 setpredraw(this, Item_PreDraw);
 217
 218         if(this.mdl)
 219             strunzone(this.mdl);
 220
 221         this.mdl = "";
 222         string _fn = ReadString();
 223
 224         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 225         {
 226             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 227             this.draw = ItemDrawSimple;
 228
 229             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 230                 this.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 231             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 232                 this.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 233             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 234                 this.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 235             else if(fexists(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix)))
 236                 this.mdl = strzone(sprintf("%s%s.mdl", _fn2, autocvar_cl_simpleitems_postfix));
 237             else
 238             {
 239                 this.draw = ItemDraw;
 240                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 241             }
 242         }
 243
 244         if(this.draw != ItemDrawSimple)
 245             this.mdl = strzone(_fn);
 246
 247
 248         if(this.mdl == "")
 249             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 250
 251         precache_model(this.mdl);
 252         _setmodel(this, this.mdl);
 253
 254         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 255     }
 256
 257     if(sf & ISF_COLORMAP)
 258     {
 259         this.colormap = ReadShort();
 260         this.item_glowmod_x = ReadByte() / 255.0;
 261         this.item_glowmod_y = ReadByte() / 255.0;
 262         this.item_glowmod_z = ReadByte() / 255.0;
 263     }
 264
 265     if(sf & ISF_DROP)
 266     {
 267         this.gravity = 1;
 268         this.pushable = true;
 269         //this.angles = '0 0 0';
 270         set_movetype(this, MOVETYPE_TOSS);
 271         this.velocity_x = ReadCoord();
 272         this.velocity_y = ReadCoord();
 273         this.velocity_z = ReadCoord();
 274         setorigin(this, this.oldorigin);
 275
 276         if(!this.move_time)
 277         {
 278             this.move_time = time;
 279             this.spawntime = time;
 280         }
 281         else
 282             this.move_time = max(this.move_time, time);
 283     }
 284
 285     if(autocvar_cl_animate_items)
 286     {
 287         if(this.ItemStatus & ITS_ANIMATE1)
 288             this.avelocity = '0 180 0';
 289
 290         if(this.ItemStatus & ITS_ANIMATE2)
 291             this.avelocity = '0 -90 0';
 292     }
 293
 294     this.entremove = ItemRemove;
 295
 296     return true;
 297 }
 298
 299 #endif
 300
 301 #ifdef SVQC
 302 bool ItemSend(entity this, entity to, int sf)
 303 {
 304         if(this.gravity)
 305                 sf |= ISF_DROP;
 306         else
 307                 sf &= ~ISF_DROP;
 308
 309         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 310         WriteByte(MSG_ENTITY, sf);
 311
 312         //WriteByte(MSG_ENTITY, this.cnt);
 313         if(sf & ISF_LOCATION)
 314         {
 315                 WriteCoord(MSG_ENTITY, this.origin.x);
 316                 WriteCoord(MSG_ENTITY, this.origin.y);
 317                 WriteCoord(MSG_ENTITY, this.origin.z);
 318         }
 319
 320         if(sf & ISF_ANGLES)
 321         {
 322                 WriteAngle(MSG_ENTITY, this.angles_x);
 323                 WriteAngle(MSG_ENTITY, this.angles_y);
 324                 WriteAngle(MSG_ENTITY, this.angles_z);
 325         }
 326
 327         if(sf & ISF_SIZE)
 328         {
 329                 Pickup p = this.itemdef;
 330                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 331         }
 332
 333         if(sf & ISF_STATUS)
 334                 WriteByte(MSG_ENTITY, this.ItemStatus);
 335
 336         if(sf & ISF_MODEL)
 337         {
 338                 Pickup p = this.itemdef;
 339                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 340                 WriteShort(MSG_ENTITY, this.fade_end);
 341                 WriteShort(MSG_ENTITY, this.fade_start);
 342
 343                 if(this.mdl == "")
 344                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 345
 346                 WriteString(MSG_ENTITY, this.mdl);
 347         }
 348
 349
 350         if(sf & ISF_COLORMAP)
 351         {
 352                 WriteShort(MSG_ENTITY, this.colormap);
 353                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 354         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 355         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 356         }
 357
 358         if(sf & ISF_DROP)
 359         {
 360                 WriteCoord(MSG_ENTITY, this.velocity.x);
 361                 WriteCoord(MSG_ENTITY, this.velocity.y);
 362                 WriteCoord(MSG_ENTITY, this.velocity.z);
 363         }
 364
 365         return true;
 366 }
 367
 368 void ItemUpdate(entity this)
 369 {
 370         this.oldorigin = this.origin;
 371         this.SendFlags |= ISF_LOCATION;
 372 }
 373
 374 void UpdateItemAfterTeleport(entity this)
 375 {
 376         if(getSendEntity(this) == ItemSend)
 377                 ItemUpdate(this);
 378 }
 379
 380 bool have_pickup_item(entity this)
 381 {
 382         if(this.itemdef.instanceOfPowerup)
 383         {
 384                 if(autocvar_g_powerups > 0)
 385                         return true;
 386                 if(autocvar_g_powerups == 0)
 387                         return false;
 388         }
 389         else
 390         {
 391                 if(autocvar_g_pickup_items > 0)
 392                         return true;
 393                 if(autocvar_g_pickup_items == 0)
 394                         return false;
 395                 if(g_weaponarena)
 396                         if(this.weapons || (this.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 397                                 return false;
 398         }
 399         return true;
 400 }
 401
 402 /*
 403 float Item_Customize()
 404 {
 405         if(this.spawnshieldtime)
 406                 return true;
 407         if(this.weapons & ~other.weapons)
 408         {
 409                 this.colormod = '0 0 0';
 410                 this.glowmod = this.colormod;
 411                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 412                 return true;
 413         }
 414         else
 415         {
 416                 if(g_ghost_items)
 417                 {
 418                         this.colormod = stov(autocvar_g_ghost_items_color);
 419                         this.glowmod = this.colormod;
 420                         this.alpha = g_ghost_items;
 421                         return true;
 422                 }
 423                 else
 424                         return false;
 425         }
 426 }
 427 */
 428
 429 void Item_Show (entity e, float mode)
 430 {
 431         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 432         e.ItemStatus &= ~ITS_STAYWEP;
 433         entity def = e.itemdef;
 434         if (mode > 0)
 435         {
 436                 // make the item look normal, and be touchable
 437                 e.model = e.mdl;
 438                 e.solid = SOLID_TRIGGER;
 439                 e.spawnshieldtime = 1;
 440                 e.ItemStatus |= ITS_AVAILABLE;
 441         }
 442         else if (mode < 0)
 443         {
 444                 // hide the item completely
 445                 e.model = string_null;
 446                 e.solid = SOLID_NOT;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus &= ~ITS_AVAILABLE;
 449         }
 450         else {
 451         bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 452                 || e.team // weapon stay isn't supported for teamed weapons
 453                 ;
 454         if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 455         {
 456                 // make the item translucent and not touchable
 457                 e.model = e.mdl;
 458                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 459                 e.effects |= EF_STARDUST;
 460                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 461                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 462         }
 463         else
 464         {
 465                 //setmodel(e, "null");
 466                 e.solid = SOLID_NOT;
 467                 e.colormod = '0 0 0';
 468                 //e.glowmod = e.colormod;
 469                 e.spawnshieldtime = 1;
 470                 e.ItemStatus &= ~ITS_AVAILABLE;
 471         }}
 472
 473         if (def.m_glow)
 474                 e.ItemStatus |= ITS_GLOW;
 475
 476         if (autocvar_g_nodepthtestitems)
 477                 e.effects |= EF_NODEPTHTEST;
 478
 479
 480         if (autocvar_g_fullbrightitems)
 481                 e.ItemStatus |= ITS_ALLOWFB;
 482
 483         if (autocvar_sv_simple_items)
 484                 e.ItemStatus |= ITS_ALLOWSI;
 485
 486         // relink entity (because solid may have changed)
 487         setorigin(e, e.origin);
 488         e.SendFlags |= ISF_STATUS;
 489 }
 490
 491 void Item_Think(entity this)
 492 {
 493         this.nextthink = time;
 494         if(this.origin != this.oldorigin)
 495                 ItemUpdate(this);
 496 }
 497
 498 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 499 bool Item_ItemsTime_Allow(GameItem it);
 500 float Item_ItemsTime_UpdateTime(entity e, float t);
 501 void Item_ItemsTime_SetTime(entity e, float t);
 502 void Item_ItemsTime_SetTimesForAllPlayers();
 503
 504 void Item_Respawn (entity this)
 505 {
 506         Item_Show(this, 1);
 507         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 508         setorigin(this, this.origin);
 509
 510     if (Item_ItemsTime_Allow(this.itemdef) || this.weapons & WEPSET_SUPERWEAPONS)
 511         {
 512                 float t = Item_ItemsTime_UpdateTime(this, 0);
 513                 Item_ItemsTime_SetTime(this, t);
 514                 Item_ItemsTime_SetTimesForAllPlayers();
 515         }
 516
 517         setthink(this, Item_Think);
 518         this.nextthink = time;
 519
 520         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 521         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 522 }
 523
 524 void Item_RespawnCountdown (entity this)
 525 {
 526         if(this.count >= ITEM_RESPAWN_TICKS)
 527         {
 528                 if(this.waypointsprite_attached)
 529                         WaypointSprite_Kill(this.waypointsprite_attached);
 530                 Item_Respawn(this);
 531         }
 532         else
 533         {
 534                 this.nextthink = time + 1;
 535                 this.count += 1;
 536                 if(this.count == 1)
 537                 {
 538                         MUTATOR_CALLHOOK(Item_RespawnCountdown, string_null, '0 0 0');
 539                         do {
 540                                 {
 541                                         entity wi = Weapons_from(this.weapon);
 542                                         if (wi != WEP_Null) {
 543                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 544                                                 wp.wp_extra = wi.m_id;
 545                                                 break;
 546                                         }
 547                                 }
 548                                 {
 549                                         entity ii = this.itemdef;
 550                                         if (ii != NULL) {
 551                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 552                                                 wp.wp_extra = ii.m_id;
 553                                                 break;
 554                                         }
 555                                 }
 556                         } while (0);
 557             if(this.waypointsprite_attached)
 558             {
 559                 GameItem def = this.itemdef;
 560                 if (Item_ItemsTime_SpectatorOnly(def))
 561                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 562                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 563             }
 564                 }
 565
 566                 if(this.waypointsprite_attached)
 567                 {
 568                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 569                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 570                                 {
 571                                         msg_entity = it;
 572                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 573                                 }
 574                         });
 575
 576                         WaypointSprite_Ping(this.waypointsprite_attached);
 577                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 578                 }
 579         }
 580 }
 581
 582 void Item_RespawnThink(entity this)
 583 {
 584         this.nextthink = time;
 585         if(this.origin != this.oldorigin)
 586                 ItemUpdate(this);
 587
 588         if(time >= this.wait)
 589                 Item_Respawn(this);
 590 }
 591
 592 void Item_ScheduleRespawnIn(entity e, float t)
 593 {
 594         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 595         if ((Item_ItemsTime_Allow(e.itemdef) || e.weapons & WEPSET_SUPERWEAPONS) && (t - ITEM_RESPAWN_TICKS) > 0)
 596         {
 597                 setthink(e, Item_RespawnCountdown);
 598                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 599                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 600                 e.count = 0;
 601                 t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 602                 Item_ItemsTime_SetTime(e, t);
 603                 Item_ItemsTime_SetTimesForAllPlayers();
 604         }
 605         else
 606         {
 607                 setthink(e, Item_RespawnThink);
 608                 e.nextthink = time;
 609                 e.scheduledrespawntime = time + t;
 610                 e.wait = time + t;
 611         }
 612 }
 613
 614 void Item_ScheduleRespawn(entity e)
 615 {
 616         if(e.respawntime > 0)
 617         {
 618                 Item_Show(e, 0);
 619                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 620         }
 621         else // if respawntime is -1, this item does not respawn
 622                 Item_Show(e, -1);
 623 }
 624
 625 void Item_ScheduleInitialRespawn(entity e)
 626 {
 627         Item_Show(e, 0);
 628         Item_ScheduleRespawnIn(e, game_starttime - time + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 629 }
 630
 631 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 632 {
 633         if (!item.(ammotype))
 634                 return false;
 635
 636         if (item.spawnshieldtime)
 637         {
 638                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 639                 {
 640                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 641                         goto YEAH;
 642                 }
 643         }
 644         else if(g_weapon_stay == 2)
 645         {
 646                 float mi = min(item.(ammotype), ammomax);
 647                 if (player.(ammotype) < mi)
 648                 {
 649                         player.(ammotype) = mi;
 650                         goto YEAH;
 651                 }
 652         }
 653
 654         return false;
 655
 656 LABEL(YEAH)
 657         switch(mode)
 658         {
 659                 case ITEM_MODE_FUEL:
 660                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 661                         break;
 662                 case ITEM_MODE_HEALTH:
 663                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 664                         break;
 665                 case ITEM_MODE_ARMOR:
 666                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 667                         break;
 668                 default:
 669                         break;
 670         }
 671         return true;
 672 }
 673
 674 float Item_GiveTo(entity item, entity player)
 675 {
 676         float pickedup;
 677
 678         // if nothing happens to player, just return without taking the item
 679         pickedup = false;
 680         int _switchweapon = 0;
 681         // in case the player has autoswitch enabled do the following:
 682         // if the player is using their best weapon before items are given, they
 683         // probably want to switch to an even better weapon after items are given
 684
 685         if(player.autoswitch)
 686         {
 687                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 688                 {
 689                         .entity weaponentity = weaponentities[slot];
 690                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 691                         {
 692                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 693                                         _switchweapon |= BIT(slot);
 694
 695                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 696                                         _switchweapon |= BIT(slot);
 697                         }
 698                 }
 699         }
 700
 701         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 702         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 703         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 704         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 705         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 706         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 707         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 708         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 709
 710         if (item.itemdef.instanceOfWeaponPickup)
 711         {
 712                 WepSet w;
 713                 w = item.weapons;
 714                 w &= ~player.weapons;
 715
 716                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 717                 {
 718                         pickedup = true;
 719                         FOREACH(Weapons, it != WEP_Null, {
 720                                 if(w & (it.m_wepset))
 721                                 {
 722                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 723                                         {
 724                                                 .entity weaponentity = weaponentities[slot];
 725                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 726                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 727                                         }
 728                                         W_GiveWeapon(player, it.m_id);
 729                                 }
 730                         });
 731                 }
 732         }
 733
 734         if (item.itemdef.instanceOfPowerup)
 735         {
 736                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 737                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 738                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 739                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 740         }
 741
 742         int its;
 743         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 744         {
 745                 pickedup = true;
 746                 player.items |= its;
 747                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 748         }
 749
 750         if (item.strength_finished)
 751         {
 752                 pickedup = true;
 753                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 754         }
 755         if (item.invincible_finished)
 756         {
 757                 pickedup = true;
 758                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 759         }
 760         if (item.superweapons_finished)
 761         {
 762                 pickedup = true;
 763                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 764         }
 765
 766 LABEL(skip)
 767
 768         // always eat teamed entities
 769         if(item.team)
 770                 pickedup = true;
 771
 772         if (!pickedup)
 773                 return 0;
 774
 775         // crude hack to enforce switching weapons
 776         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 777         {
 778                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 779                 {
 780                         .entity weaponentity = weaponentities[slot];
 781                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 782                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 783                 }
 784                 return 1;
 785         }
 786
 787         if(_switchweapon)
 788         {
 789                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 790                 {
 791                         .entity weaponentity = weaponentities[slot];
 792                         if(_switchweapon & BIT(slot))
 793                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 794                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 795                 }
 796         }
 797
 798         return 1;
 799 }
 800
 801 void Item_Touch(entity this, entity toucher)
 802 {
 803
 804         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 805         if (this.classname == "droppedweapon")
 806         {
 807                 if (ITEM_TOUCH_NEEDKILL())
 808                 {
 809                         delete(this);
 810                         return;
 811                 }
 812         }
 813
 814         if(!(toucher.flags & FL_PICKUPITEMS)
 815         || STAT(FROZEN, toucher)
 816         || IS_DEAD(toucher)
 817         || (this.solid != SOLID_TRIGGER)
 818         || (this.owner == toucher)
 819         || (time < this.item_spawnshieldtime)
 820         ) { return; }
 821
 822         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 823         {
 824                 case MUT_ITEMTOUCH_RETURN: { return; }
 825                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 826         }
 827
 828         toucher = M_ARGV(1, entity);
 829
 830         if (this.classname == "droppedweapon")
 831         {
 832                 this.strength_finished = max(0, this.strength_finished - time);
 833                 this.invincible_finished = max(0, this.invincible_finished - time);
 834                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 835         }
 836         entity it = this.itemdef;
 837         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 838         if (!gave)
 839         {
 840                 if (this.classname == "droppedweapon")
 841                 {
 842                         // undo what we did above
 843                         this.strength_finished += time;
 844                         this.invincible_finished += time;
 845                         this.superweapons_finished += time;
 846                 }
 847                 return;
 848         }
 849
 850 LABEL(pickup)
 851
 852         toucher.last_pickup = time;
 853
 854         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 855         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 856
 857         if (this.classname == "droppedweapon")
 858                 delete (this);
 859         else if (this.spawnshieldtime)
 860         {
 861                 entity e;
 862                 if(this.team)
 863                 {
 864                         RandomSelection_Init();
 865                         IL_EACH(g_items, it.team == this.team,
 866                         {
 867                                 if(it.itemdef) // is a registered item
 868                                 {
 869                                         Item_Show(it, -1);
 870                                         RandomSelection_AddEnt(it, it.cnt, 0);
 871                                 }
 872                         });
 873                         e = RandomSelection_chosen_ent;
 874
 875                 }
 876                 else
 877                         e = this;
 878                 Item_ScheduleRespawn(e);
 879         }
 880 }
 881
 882 void Item_Reset(entity this)
 883 {
 884         Item_Show(this, !this.state);
 885         setorigin(this, this.origin);
 886
 887         if (this.classname != "droppedweapon")
 888         {
 889                 setthink(this, Item_Think);
 890                 this.nextthink = time;
 891
 892                 if (this.waypointsprite_attached)
 893                         WaypointSprite_Kill(this.waypointsprite_attached);
 894
 895                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 896                         Item_ScheduleInitialRespawn(this);
 897         }
 898 }
 899
 900 void Item_FindTeam(entity this)
 901 {
 902         entity e;
 903
 904         if(this.effects & EF_NODRAW)
 905         {
 906                 // marker for item team search
 907                 LOG_TRACE("Initializing item team ", ftos(this.team));
 908                 RandomSelection_Init();
 909                 IL_EACH(g_items, it.team == this.team,
 910                 {
 911                         if(it.itemdef) // is a registered item
 912                                 RandomSelection_AddEnt(it, it.cnt, 0);
 913                 });
 914
 915                 e = RandomSelection_chosen_ent;
 916                 e.state = 0;
 917                 Item_Show(e, 1);
 918
 919                 IL_EACH(g_items, it.team == this.team,
 920                 {
 921                         if(it.itemdef) // is a registered item
 922                         {
 923                                 if(it != e)
 924                                 {
 925                                         // make it non-spawned
 926                                         Item_Show(it, -1);
 927                                         it.state = 1; // state 1 = initially hidden item, apparently
 928                                 }
 929                                 it.effects &= ~EF_NODRAW;
 930                         }
 931                 });
 932
 933                 Item_Reset(this);
 934         }
 935 }
 936
 937 // Savage: used for item garbage-collection
 938 void RemoveItem(entity this)
 939 {
 940         if(wasfreed(this) || !this) { return; }
 941         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 942         delete(this);
 943 }
 944
 945 // pickup evaluation functions
 946 // these functions decide how desirable an item is to the bots
 947
 948 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 949
 950 float weapon_pickupevalfunc(entity player, entity item)
 951 {
 952         float c;
 953
 954         // See if I have it already
 955         if(item.weapons & ~player.weapons)
 956         {
 957                 // If I can pick it up
 958                 if(!item.spawnshieldtime)
 959                         c = 0;
 960                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
 961                 {
 962                         // Skilled bots will grab more
 963                         c = bound(0, skill / 10, 1) * 0.5;
 964                 }
 965                 else
 966                         c = 0;
 967         }
 968         else
 969                 c = 1;
 970
 971         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 972         if( bot_custom_weapon && c )
 973         {
 974                 // Find the highest position on any range
 975                 int position = -1;
 976                 for (int j = 0; j < WEP_LAST ; ++j){
 977                         if(
 978                                         bot_weapons_far[j] == item.weapon ||
 979                                         bot_weapons_mid[j] == item.weapon ||
 980                                         bot_weapons_close[j] == item.weapon
 981                           )
 982                         {
 983                                 position = j;
 984                                 break;
 985                         }
 986                 }
 987
 988                 // Rate it
 989                 if (position >= 0 )
 990                 {
 991                         position = WEP_LAST - position;
 992                         // item.bot_pickupbasevalue is overwritten here
 993                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 994                 }
 995         }
 996
 997         return item.bot_pickupbasevalue * c;
 998 }
 999
1000 float commodity_pickupevalfunc(entity player, entity item)
1001 {
1002         float c;
1003         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1004         c = 0;
1005
1006         // Detect needed ammo
1007         FOREACH(Weapons, it != WEP_Null, {
1008                 if(!(player.weapons & (it.m_wepset)))
1009                         continue;
1010
1011                 if(it.items & ITEM_Shells.m_itemid)
1012                         need_shells = true;
1013                 else if(it.items & ITEM_Bullets.m_itemid)
1014                         need_nails = true;
1015                 else if(it.items & ITEM_Rockets.m_itemid)
1016                         need_rockets = true;
1017                 else if(it.items & ITEM_Cells.m_itemid)
1018                         need_cells = true;
1019                 else if(it.items & ITEM_Plasma.m_itemid)
1020                         need_plasma = true;
1021                 else if(it.items & ITEM_JetpackFuel.m_itemid)
1022                         need_fuel = true;
1023         });
1024
1025         // TODO: figure out if the player even has the weapon this ammo is for?
1026         // may not affect strategy much though...
1027         // find out how much more ammo/armor/health the player can hold
1028         if (need_shells)
1029         if (item.ammo_shells)
1030         if (player.ammo_shells < g_pickup_shells_max)
1031                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
1032         if (need_nails)
1033         if (item.ammo_nails)
1034         if (player.ammo_nails < g_pickup_nails_max)
1035                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1036         if (need_rockets)
1037         if (item.ammo_rockets)
1038         if (player.ammo_rockets < g_pickup_rockets_max)
1039                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1040         if (need_cells)
1041         if (item.ammo_cells)
1042         if (player.ammo_cells < g_pickup_cells_max)
1043                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1044         if (need_plasma)
1045         if (item.ammo_plasma)
1046         if (player.ammo_plasma < g_pickup_plasma_max)
1047                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1048         if (need_fuel)
1049         if (item.ammo_fuel)
1050         if (player.ammo_fuel < g_pickup_fuel_max)
1051                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1052         if (item.armorvalue)
1053         if (player.armorvalue < item.max_armorvalue)
1054                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1055         if (item.health)
1056         if (player.health < item.max_health)
1057                 c = c + max(0, 1 - player.health / item.max_health);
1058
1059         return item.bot_pickupbasevalue * c;
1060 }
1061
1062 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1063 {
1064         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1065                 RemoveItem(this);
1066 }
1067
1068 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1069 {
1070         string itemname = def.m_name;
1071         Model itemmodel = def.m_model;
1072     Sound pickupsound = def.m_sound;
1073         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1074         float pickupbasevalue = def.m_botvalue;
1075         int itemflags = def.m_itemflags;
1076
1077         startitem_failed = false;
1078
1079         this.item_model_ent = itemmodel;
1080     this.item_pickupsound_ent = pickupsound;
1081
1082         if(!this.respawntime) // both need to be set
1083         {
1084                 this.respawntime = defaultrespawntime;
1085                 this.respawntimejitter = defaultrespawntimejitter;
1086         }
1087
1088         int itemid = def.m_itemid;
1089         this.items = itemid;
1090         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1091         this.weapon = weaponid;
1092
1093         if(!this.fade_end)
1094         {
1095                 this.fade_start = autocvar_g_items_mindist;
1096                 this.fade_end = autocvar_g_items_maxdist;
1097         }
1098
1099         if(weaponid)
1100                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1101
1102         this.flags = FL_ITEM | itemflags;
1103         IL_PUSH(g_items, this);
1104
1105         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1106         {
1107                 startitem_failed = true;
1108                 delete(this);
1109                 return;
1110         }
1111
1112         // is it a dropped weapon?
1113         if (this.classname == "droppedweapon")
1114         {
1115                 this.reset = SUB_Remove;
1116                 // it's a dropped weapon
1117                 set_movetype(this, MOVETYPE_TOSS);
1118
1119                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1120                 setthink(this, RemoveItem);
1121                 this.nextthink = time + 20;
1122
1123                 this.takedamage = DAMAGE_YES;
1124                 this.event_damage = Item_Damage;
1125
1126                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1127                 {
1128                         // if item is worthless after a timer, have it expire then
1129                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1130                 }
1131
1132                 // don't drop if in a NODROP zone (such as lava)
1133                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1134                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1135                 {
1136                         startitem_failed = true;
1137                         delete(this);
1138                         return;
1139                 }
1140         }
1141         else
1142         {
1143                 if(!have_pickup_item(this))
1144                 {
1145                         startitem_failed = true;
1146                         delete (this);
1147                         return;
1148                 }
1149
1150                 if(this.angles != '0 0 0')
1151                         this.SendFlags |= ISF_ANGLES;
1152
1153                 this.reset = Item_Reset;
1154                 // it's a level item
1155                 if(this.spawnflags & 1)
1156                         this.noalign = 1;
1157                 if (this.noalign > 0)
1158                         set_movetype(this, MOVETYPE_NONE);
1159                 else
1160                         set_movetype(this, MOVETYPE_TOSS);
1161                 // do item filtering according to game mode and other things
1162                 if (this.noalign <= 0)
1163                 {
1164                         // first nudge it off the floor a little bit to avoid math errors
1165                         setorigin(this, this.origin + '0 0 1');
1166                         // set item size before we spawn a spawnfunc_waypoint
1167                         setsize(this, def.m_mins, def.m_maxs);
1168                         this.SendFlags |= ISF_SIZE;
1169                         // note droptofloor returns false if stuck/or would fall too far
1170                         if (!this.noalign)
1171                                 droptofloor(this);
1172                         waypoint_spawnforitem(this);
1173                 }
1174
1175                 /*
1176                  * can't do it that way, as it would break maps
1177                  * TODO make a target_give like entity another way, that perhaps has
1178                  * the weapon name in a key
1179                 if(this.targetname)
1180                 {
1181                         // target_give not yet supported; maybe later
1182                         print("removed targeted ", this.classname, "\n");
1183                         startitem_failed = true;
1184                         remove (this);
1185                         return;
1186                 }
1187                 */
1188
1189                 if(autocvar_spawn_debug >= 2)
1190                 {
1191             // why not flags & fl_item?
1192                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1193                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1194                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1195                 error("Mapper sucks.");
1196             });
1197                         this.is_item = true;
1198                 }
1199
1200                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1201
1202                 precache_model(this.model);
1203                 precache_sound(this.item_pickupsound);
1204
1205                 if (   def.instanceOfPowerup
1206                         || def.instanceOfWeaponPickup
1207                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1208                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1209                         || (itemid & (IT_KEY1 | IT_KEY2))
1210                 ) this.target = "###item###"; // for finding the nearest item using find()
1211
1212                 Item_ItemsTime_SetTime(this, 0);
1213         }
1214
1215         this.bot_pickup = true;
1216         this.bot_pickupevalfunc = pickupevalfunc;
1217         this.bot_pickupbasevalue = pickupbasevalue;
1218         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1219         this.netname = itemname;
1220         settouch(this, Item_Touch);
1221         setmodel(this, MDL_Null); // precision set below
1222         //this.effects |= EF_LOWPRECISION;
1223
1224         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1225
1226         this.SendFlags |= ISF_SIZE;
1227
1228         if (!(this.spawnflags & 1024)) {
1229                 if(def.instanceOfPowerup)
1230                         this.ItemStatus |= ITS_ANIMATE1;
1231
1232                 if(this.armorvalue || this.health)
1233                         this.ItemStatus |= ITS_ANIMATE2;
1234         }
1235
1236         if(def.instanceOfWeaponPickup)
1237         {
1238                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1239                         this.colormap = 1024; // color shirt=0 pants=0 grey
1240                 else
1241                         this.gravity = 1;
1242                 if (!(this.spawnflags & 1024))
1243                         this.ItemStatus |= ITS_ANIMATE1;
1244                 this.SendFlags |= ISF_COLORMAP;
1245         }
1246
1247         this.state = 0;
1248         if(this.team) // broken, no idea why.
1249         {
1250                 if(!this.cnt)
1251                         this.cnt = 1; // item probability weight
1252
1253                 this.effects |= EF_NODRAW; // marker for item team search
1254                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1255         }
1256         else
1257                 Item_Reset(this);
1258
1259         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1260
1261         // call this hook after everything else has been done
1262         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1263         {
1264                 startitem_failed = true;
1265                 delete(this);
1266                 return;
1267         }
1268 }
1269
1270 void StartItem(entity this, GameItem def)
1271 {
1272     _StartItem(
1273         this,
1274         this.itemdef = def,
1275         def.m_respawntime(), // defaultrespawntime
1276         def.m_respawntimejitter() // defaultrespawntimejitter
1277         );
1278 }
1279
1280 spawnfunc(item_rockets)
1281 {
1282         if(!this.ammo_rockets)
1283                 this.ammo_rockets = g_pickup_rockets;
1284         if(!this.pickup_anyway)
1285                 this.pickup_anyway = g_pickup_ammo_anyway;
1286     StartItem(this, ITEM_Rockets);
1287 }
1288
1289 spawnfunc(item_bullets)
1290 {
1291         if(!weaponswapping)
1292         if(autocvar_sv_q3acompat_machineshotgunswap)
1293         if(this.classname != "droppedweapon")
1294         {
1295                 weaponswapping = true;
1296                 spawnfunc_item_shells(this);
1297                 weaponswapping = false;
1298                 return;
1299         }
1300
1301         if(!this.ammo_nails)
1302                 this.ammo_nails = g_pickup_nails;
1303         if(!this.pickup_anyway)
1304                 this.pickup_anyway = g_pickup_ammo_anyway;
1305     StartItem(this, ITEM_Bullets);
1306 }
1307
1308 spawnfunc(item_cells)
1309 {
1310         if(!this.ammo_cells)
1311                 this.ammo_cells = g_pickup_cells;
1312         if(!this.pickup_anyway)
1313                 this.pickup_anyway = g_pickup_ammo_anyway;
1314         StartItem(this, ITEM_Cells);
1315 }
1316
1317 spawnfunc(item_plasma)
1318 {
1319         if(!this.ammo_plasma)
1320                 this.ammo_plasma = g_pickup_plasma;
1321         if(!this.pickup_anyway)
1322                 this.pickup_anyway = g_pickup_ammo_anyway;
1323         StartItem(this, ITEM_Plasma);
1324 }
1325
1326 spawnfunc(item_shells)
1327 {
1328         if(!weaponswapping)
1329         if(autocvar_sv_q3acompat_machineshotgunswap)
1330         if(this.classname != "droppedweapon")
1331         {
1332                 weaponswapping = true;
1333                 spawnfunc_item_bullets(this);
1334                 weaponswapping = false;
1335                 return;
1336         }
1337
1338         if(!this.ammo_shells)
1339                 this.ammo_shells = g_pickup_shells;
1340         if(!this.pickup_anyway)
1341                 this.pickup_anyway = g_pickup_ammo_anyway;
1342         StartItem(this, ITEM_Shells);
1343 }
1344
1345 spawnfunc(item_armor_small)
1346 {
1347         if(!this.armorvalue)
1348                 this.armorvalue = g_pickup_armorsmall;
1349         if(!this.max_armorvalue)
1350                 this.max_armorvalue = g_pickup_armorsmall_max;
1351         if(!this.pickup_anyway)
1352                 this.pickup_anyway = g_pickup_armorsmall_anyway;
1353         StartItem(this, ITEM_ArmorSmall);
1354 }
1355
1356 spawnfunc(item_armor_medium)
1357 {
1358         if(!this.armorvalue)
1359                 this.armorvalue = g_pickup_armormedium;
1360         if(!this.max_armorvalue)
1361                 this.max_armorvalue = g_pickup_armormedium_max;
1362         if(!this.pickup_anyway)
1363                 this.pickup_anyway = g_pickup_armormedium_anyway;
1364         StartItem(this, ITEM_ArmorMedium);
1365 }
1366
1367 spawnfunc(item_armor_big)
1368 {
1369         if(!this.armorvalue)
1370                 this.armorvalue = g_pickup_armorbig;
1371         if(!this.max_armorvalue)
1372                 this.max_armorvalue = g_pickup_armorbig_max;
1373         if(!this.pickup_anyway)
1374                 this.pickup_anyway = g_pickup_armorbig_anyway;
1375         StartItem(this, ITEM_ArmorBig);
1376 }
1377
1378 spawnfunc(item_armor_mega)
1379 {
1380         if(!this.armorvalue)
1381                 this.armorvalue = g_pickup_armormega;
1382         if(!this.max_armorvalue)
1383                 this.max_armorvalue = g_pickup_armormega_max;
1384         if(!this.pickup_anyway)
1385                 this.pickup_anyway = g_pickup_armormega_anyway;
1386         StartItem(this, ITEM_ArmorMega);
1387 }
1388
1389 spawnfunc(item_health_small)
1390 {
1391         if(!this.max_health)
1392                 this.max_health = g_pickup_healthsmall_max;
1393         if(!this.health)
1394                 this.health = g_pickup_healthsmall;
1395         if(!this.pickup_anyway)
1396                 this.pickup_anyway = g_pickup_healthsmall_anyway;
1397         StartItem(this, ITEM_HealthSmall);
1398 }
1399
1400 spawnfunc(item_health_medium)
1401 {
1402         if(!this.max_health)
1403                 this.max_health = g_pickup_healthmedium_max;
1404         if(!this.health)
1405                 this.health = g_pickup_healthmedium;
1406         if(!this.pickup_anyway)
1407                 this.pickup_anyway = g_pickup_healthmedium_anyway;
1408     StartItem(this, ITEM_HealthMedium);
1409 }
1410
1411 spawnfunc(item_health_big)
1412 {
1413         if(!this.max_health)
1414                 this.max_health = g_pickup_healthbig_max;
1415         if(!this.health)
1416                 this.health = g_pickup_healthbig;
1417         if(!this.pickup_anyway)
1418                 this.pickup_anyway = g_pickup_healthbig_anyway;
1419         StartItem(this, ITEM_HealthBig);
1420 }
1421
1422 spawnfunc(item_health_mega)
1423 {
1424     if(!this.max_health)
1425         this.max_health = g_pickup_healthmega_max;
1426     if(!this.health)
1427         this.health = g_pickup_healthmega;
1428     if(!this.pickup_anyway)
1429         this.pickup_anyway = g_pickup_healthmega_anyway;
1430     StartItem(this, ITEM_HealthMega);
1431 }
1432
1433 // support old misnamed entities
1434 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1435 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1436 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1437 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1438 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1439 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1440 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1441
1442 spawnfunc(item_strength)
1443 {
1444                 if(!this.strength_finished)
1445                         this.strength_finished = autocvar_g_balance_powerup_strength_time;
1446                 StartItem(this, ITEM_Strength);
1447 }
1448
1449 spawnfunc(item_invincible)
1450 {
1451                 if(!this.invincible_finished)
1452                         this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1453                 StartItem(this, ITEM_Shield);
1454 }
1455
1456 // compatibility:
1457 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1458
1459 void target_items_use(entity this, entity actor, entity trigger)
1460 {
1461         if(actor.classname == "droppedweapon")
1462         {
1463                 EXACTTRIGGER_TOUCH(this, trigger);
1464                 delete(actor);
1465                 return;
1466         }
1467
1468         if (!IS_PLAYER(actor))
1469                 return;
1470         if(IS_DEAD(actor))
1471                 return;
1472         if(trigger.solid == SOLID_TRIGGER)
1473         {
1474                 EXACTTRIGGER_TOUCH(this, trigger);
1475         }
1476
1477         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1478         {
1479                 delete(it);
1480         });
1481
1482         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1483                 centerprint(actor, this.message);
1484 }
1485
1486 spawnfunc(target_items)
1487 {
1488         int n, j;
1489         string s;
1490
1491         this.use = target_items_use;
1492         if(!this.strength_finished)
1493                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1494         if(!this.invincible_finished)
1495                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1496         if(!this.superweapons_finished)
1497                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1498
1499         n = tokenize_console(this.netname);
1500         if(argv(0) == "give")
1501         {
1502                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1503         }
1504         else
1505         {
1506                 for(j = 0; j < n; ++j)
1507                 {
1508                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1509                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1510                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1511                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1512                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1513                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1514                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1515                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1516                         else
1517                         {
1518                                 FOREACH(Weapons, it != WEP_Null, {
1519                                         s = W_UndeprecateName(argv(j));
1520                                         if(s == it.netname)
1521                                         {
1522                                                 this.weapons |= (it.m_wepset);
1523                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1524                                                         it.wr_init(it);
1525                                                 break;
1526                                         }
1527                                 });
1528                         }
1529                 }
1530
1531                 string itemprefix, valueprefix;
1532                 if(this.spawnflags == 0)
1533                 {
1534                         itemprefix = "";
1535                         valueprefix = "";
1536                 }
1537                 else if(this.spawnflags == 1)
1538                 {
1539                         itemprefix = "max ";
1540                         valueprefix = "max ";
1541                 }
1542                 else if(this.spawnflags == 2)
1543                 {
1544                         itemprefix = "min ";
1545                         valueprefix = "min ";
1546                 }
1547                 else if(this.spawnflags == 4)
1548                 {
1549                         itemprefix = "minus ";
1550                         valueprefix = "max ";
1551                 }
1552                 else
1553                 {
1554                         error("invalid spawnflags");
1555                         itemprefix = valueprefix = string_null;
1556                 }
1557
1558                 this.netname = "";
1559                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1560                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1561                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1562                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1563                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1564                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1565                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1566                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1567                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1568                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1569                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1570                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1571                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1572                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1573                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1574                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1575         }
1576         this.netname = strzone(this.netname);
1577         //print(this.netname, "\n");
1578
1579         n = tokenize_console(this.netname);
1580         for(j = 0; j < n; ++j)
1581         {
1582                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1583             it.wr_init(it);
1584             break;
1585                 });
1586         }
1587 }
1588
1589 spawnfunc(item_fuel)
1590 {
1591         if(!this.ammo_fuel)
1592                 this.ammo_fuel = g_pickup_fuel;
1593         if(!this.pickup_anyway)
1594                 this.pickup_anyway = g_pickup_ammo_anyway;
1595         StartItem(this, ITEM_JetpackFuel);
1596 }
1597
1598 spawnfunc(item_fuel_regen)
1599 {
1600         if(start_items & ITEM_JetpackRegen.m_itemid)
1601         {
1602                 spawnfunc_item_fuel(this);
1603                 return;
1604         }
1605         StartItem(this, ITEM_JetpackRegen);
1606 }
1607
1608 spawnfunc(item_jetpack)
1609 {
1610         if(!this.ammo_fuel)
1611                 this.ammo_fuel = g_pickup_fuel_jetpack;
1612         if(start_items & ITEM_Jetpack.m_itemid)
1613         {
1614                 spawnfunc_item_fuel(this);
1615                 return;
1616         }
1617         StartItem(this, ITEM_Jetpack);
1618 }
1619
1620 float GiveWeapon(entity e, float wpn, float op, float val)
1621 {
1622         WepSet v0, v1;
1623         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1624         v0 = (e.weapons & s);
1625         switch(op)
1626         {
1627                 case OP_SET:
1628                         if(val > 0)
1629                                 e.weapons |= s;
1630                         else
1631                                 e.weapons &= ~s;
1632                         break;
1633                 case OP_MIN:
1634                 case OP_PLUS:
1635                         if(val > 0)
1636                                 e.weapons |= s;
1637                         break;
1638                 case OP_MAX:
1639                         if(val <= 0)
1640                                 e.weapons &= ~s;
1641                         break;
1642                 case OP_MINUS:
1643                         if(val > 0)
1644                                 e.weapons &= ~s;
1645                         break;
1646         }
1647         v1 = (e.weapons & s);
1648         return (v0 != v1);
1649 }
1650
1651 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1652 {
1653         if(v1 == v0)
1654                 return;
1655         if(v1 <= v0 - t)
1656         {
1657                 if(snd_decr != NULL)
1658                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1659         }
1660         else if(v0 >= v0 + t)
1661         {
1662                 if(snd_incr != NULL)
1663                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1664         }
1665 }
1666
1667 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1668 {
1669         if(v0 < v1)
1670                 e.(rotfield) = max(e.(rotfield), time + rottime);
1671         else if(v0 > v1)
1672                 e.(regenfield) = max(e.(regenfield), time + regentime);
1673 }
1674 float GiveItems(entity e, float beginarg, float endarg)
1675 {
1676         float got, i, val, op;
1677         string cmd;
1678
1679         val = 999;
1680         op = OP_SET;
1681
1682         got = 0;
1683
1684         int _switchweapon = 0;
1685
1686         if(e.autoswitch)
1687         {
1688                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1689                 {
1690                         .entity weaponentity = weaponentities[slot];
1691                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1692                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1693                                 _switchweapon |= BIT(slot);
1694                 }
1695         }
1696
1697         e.strength_finished = max(0, e.strength_finished - time);
1698         e.invincible_finished = max(0, e.invincible_finished - time);
1699         e.superweapons_finished = max(0, e.superweapons_finished - time);
1700
1701         PREGIVE(e, items);
1702         PREGIVE_WEAPONS(e);
1703         PREGIVE(e, strength_finished);
1704         PREGIVE(e, invincible_finished);
1705         PREGIVE(e, superweapons_finished);
1706         PREGIVE(e, ammo_nails);
1707         PREGIVE(e, ammo_cells);
1708         PREGIVE(e, ammo_plasma);
1709         PREGIVE(e, ammo_shells);
1710         PREGIVE(e, ammo_rockets);
1711         PREGIVE(e, ammo_fuel);
1712         PREGIVE(e, armorvalue);
1713         PREGIVE(e, health);
1714
1715         for(i = beginarg; i < endarg; ++i)
1716         {
1717                 cmd = argv(i);
1718
1719                 if(cmd == "0" || stof(cmd))
1720                 {
1721                         val = stof(cmd);
1722                         continue;
1723                 }
1724                 switch(cmd)
1725                 {
1726                         case "no":
1727                                 op = OP_MAX;
1728                                 val = 0;
1729                                 continue;
1730                         case "max":
1731                                 op = OP_MAX;
1732                                 continue;
1733                         case "min":
1734                                 op = OP_MIN;
1735                                 continue;
1736                         case "plus":
1737                                 op = OP_PLUS;
1738                                 continue;
1739                         case "minus":
1740                                 op = OP_MINUS;
1741                                 continue;
1742                         case "ALL":
1743                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1744                                 got += GiveValue(e, strength_finished, op, val);
1745                                 got += GiveValue(e, invincible_finished, op, val);
1746                                 got += GiveValue(e, superweapons_finished, op, val);
1747                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1748                         case "all":
1749                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1750                                 got += GiveValue(e, health, op, val);
1751                                 got += GiveValue(e, armorvalue, op, val);
1752                         case "allweapons":
1753                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1754                         case "allammo":
1755                                 got += GiveValue(e, ammo_cells, op, val);
1756                                 got += GiveValue(e, ammo_plasma, op, val);
1757                                 got += GiveValue(e, ammo_shells, op, val);
1758                                 got += GiveValue(e, ammo_nails, op, val);
1759                                 got += GiveValue(e, ammo_rockets, op, val);
1760                                 got += GiveValue(e, ammo_fuel, op, val);
1761                                 break;
1762                         case "unlimited_ammo":
1763                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1764                                 break;
1765                         case "unlimited_weapon_ammo":
1766                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1767                                 break;
1768                         case "unlimited_superweapons":
1769                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1770                                 break;
1771                         case "jetpack":
1772                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1773                                 break;
1774                         case "fuel_regen":
1775                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1776                                 break;
1777                         case "strength":
1778                                 got += GiveValue(e, strength_finished, op, val);
1779                                 break;
1780                         case "invincible":
1781                                 got += GiveValue(e, invincible_finished, op, val);
1782                                 break;
1783                         case "superweapons":
1784                                 got += GiveValue(e, superweapons_finished, op, val);
1785                                 break;
1786                         case "cells":
1787                                 got += GiveValue(e, ammo_cells, op, val);
1788                                 break;
1789                         case "plasma":
1790                                 got += GiveValue(e, ammo_plasma, op, val);
1791                                 break;
1792                         case "shells":
1793                                 got += GiveValue(e, ammo_shells, op, val);
1794                                 break;
1795                         case "nails":
1796                         case "bullets":
1797                                 got += GiveValue(e, ammo_nails, op, val);
1798                                 break;
1799                         case "rockets":
1800                                 got += GiveValue(e, ammo_rockets, op, val);
1801                                 break;
1802                         case "health":
1803                                 got += GiveValue(e, health, op, val);
1804                                 break;
1805                         case "armor":
1806                                 got += GiveValue(e, armorvalue, op, val);
1807                                 break;
1808                         case "fuel":
1809                                 got += GiveValue(e, ammo_fuel, op, val);
1810                                 break;
1811                         default:
1812                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1813                     got += GiveWeapon(e, it.m_id, op, val);
1814                     break;
1815                                 });
1816                                 break;
1817                 }
1818                 val = 999;
1819                 op = OP_SET;
1820         }
1821
1822         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1823         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1824         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1825         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1826         FOREACH(Weapons, it != WEP_Null, {
1827                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1828                 if(!(save_weapons & (it.m_wepset)))
1829                         if(e.weapons & (it.m_wepset))
1830                                 it.wr_init(it);
1831         });
1832         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1833         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1834         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1835         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1836         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1837         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1838         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1839         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1840         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1841         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1842         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1843
1844         if(e.superweapons_finished <= 0)
1845                 if(e.weapons & WEPSET_SUPERWEAPONS)
1846                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1847
1848         if(e.strength_finished <= 0)
1849                 e.strength_finished = 0;
1850         else
1851                 e.strength_finished += time;
1852         if(e.invincible_finished <= 0)
1853                 e.invincible_finished = 0;
1854         else
1855                 e.invincible_finished += time;
1856         if(e.superweapons_finished <= 0)
1857                 e.superweapons_finished = 0;
1858         else
1859                 e.superweapons_finished += time;
1860
1861         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1862         {
1863                 .entity weaponentity = weaponentities[slot];
1864                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1865                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1866                         _switchweapon |= BIT(slot);
1867         }
1868
1869         if(_switchweapon)
1870         {
1871                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1872                 {
1873                         .entity weaponentity = weaponentities[slot];
1874                         if(_switchweapon & BIT(slot))
1875                                 W_SwitchWeapon_Force(e, w_getbestweapon(e, weaponentity), weaponentity);
1876                 }
1877         }
1878
1879         return got;
1880 }
1881 #endif