qcsrc/common/triggers/func/bobbing.qc

   1 #ifdef SVQC
   2 .float height;
   3 void func_bobbing_controller_think()
   4 {
   5         vector v;
   6         self.nextthink = time + 0.1;
   7
   8         if(self.owner.active != ACTIVE_ACTIVE)
   9         {
  10                 self.owner.velocity = '0 0 0';
  11                 return;
  12         }
  13
  14         // calculate sinewave using makevectors
  15         makevectors((self.nextthink * self.owner.cnt + self.owner.phase * 360) * '0 1 0');
  16         v = self.owner.destvec + self.owner.movedir * v_forward_y;
  17         if(self.owner.classname == "func_bobbing") // don't brake stuff if the func_bobbing was killtarget'ed
  18                 // * 10 so it will arrive in 0.1 sec
  19                 self.owner.velocity = (v - self.owner.SUB_ORIGIN) * 10;
  20 }
  21
  22 /*QUAKED spawnfunc_func_bobbing (0 .5 .8) ? X_AXIS Y_AXIS
  23 Brush model that moves back and forth on one axis (default Z).
  24 speed : how long one cycle takes in seconds (default 4)
  25 height : how far the cycle moves (default 32)
  26 phase : cycle timing adjustment (0-1 as a fraction of the cycle, default 0)
  27 noise : path/name of looping .wav file to play.
  28 dmg : Do this mutch dmg every .dmgtime intervall when blocked
  29 dmgtime : See above.
  30 */
  31 void spawnfunc_func_bobbing()
  32 {
  33         entity controller;
  34         if (self.noise != "")
  35         {
  36                 precache_sound(self.noise);
  37                 soundto(MSG_INIT, self, CH_TRIGGER_SINGLE, self.noise, VOL_BASE, ATTEN_IDLE);
  38         }
  39         if (!self.speed)
  40                 self.speed = 4;
  41         if (!self.height)
  42                 self.height = 32;
  43         // center of bobbing motion
  44         self.destvec = self.origin;
  45         // time scale to get degrees
  46         self.cnt = 360 / self.speed;
  47
  48         self.active = ACTIVE_ACTIVE;
  49
  50         // damage when blocked
  51         self.blocked = generic_plat_blocked;
  52         if(self.dmg && (self.message == ""))
  53                 self.message = " was squished";
  54     if(self.dmg && (self.message2 == ""))
  55                 self.message2 = "was squished by";
  56         if(self.dmg && (!self.dmgtime))
  57                 self.dmgtime = 0.25;
  58         self.dmgtime2 = time;
  59
  60         // how far to bob
  61         if (self.spawnflags & 1) // X
  62                 self.movedir = '1 0 0' * self.height;
  63         else if (self.spawnflags & 2) // Y
  64                 self.movedir = '0 1 0' * self.height;
  65         else // Z
  66                 self.movedir = '0 0 1' * self.height;
  67
  68         if (!InitMovingBrushTrigger())
  69                 return;
  70
  71         // wait for targets to spawn
  72         controller = spawn();
  73         controller.classname = "func_bobbing_controller";
  74         controller.owner = self;
  75         controller.nextthink = time + 1;
  76         controller.think = func_bobbing_controller_think;
  77         self.SUB_NEXTTHINK = self.SUB_LTIME + 999999999;
  78         self.SUB_THINK = SUB_NullThink;
  79
  80         // Savage: Reduce bandwith, critical on e.g. nexdm02
  81         self.effects |= EF_LOWPRECISION;
  82
  83         // TODO make a reset function for this one
  84 }
  85 #endif