qcsrc/common/triggers/func/breakable.qc

   1 #ifdef SVQC
   2
   3 #include "../../../server/g_subs.qh"
   4 #include "../../../server/g_damage.qh"
   5 #include "../../../server/bot/bot.qh"
   6 #include "../../../common/csqcmodel_settings.qh"
   7 #include "../../../lib/csqcmodel/sv_model.qh"
   8 #include "../../../server/weapons/common.qh"
   9
  10 .entity sprite;
  11
  12 .float dmg;
  13 .float dmg_edge;
  14 .float dmg_radius;
  15 .float dmg_force;
  16 .float debrismovetype;
  17 .float debrissolid;
  18 .vector debrisvelocity;
  19 .vector debrisvelocityjitter;
  20 .vector debrisavelocityjitter;
  21 .float debristime;
  22 .float debristimejitter;
  23 .float debrisfadetime;
  24 .float debrisdamageforcescale;
  25 .float debrisskin;
  26
  27 .string mdl_dead; // or "" to hide when broken
  28 .string debris; // space separated list of debris models
  29 // other fields:
  30 //   mdl = particle effect name
  31 //   count = particle effect multiplier
  32 //   targetname = target to trigger to unbreak the model
  33 //   target = targets to trigger when broken
  34 //   health = amount of damage it can take
  35 //   spawnflags:
  36 //     1 = start disabled (needs to be triggered to activate)
  37 //     2 = indicate damage
  38 //     4 = don't take direct damage (needs to be triggered to 'explode', then triggered again to restore)
  39 // notes:
  40 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  41 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  42 //   want that!
  43
  44 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
  45
  46 //
  47 // func_breakable
  48 // - basically func_assault_destructible for general gameplay use
  49 //
  50 void LaunchDebris (string debrisname, vector force)
  51 {SELFPARAM();
  52         entity dbr = spawn();
  53         setorigin(dbr, self.absmin
  54                    + '1 0 0' * random() * (self.absmax.x - self.absmin.x)
  55                    + '0 1 0' * random() * (self.absmax.y - self.absmin.y)
  56                    + '0 0 1' * random() * (self.absmax.z - self.absmin.z));
  57         _setmodel (dbr, debrisname );
  58         dbr.skin = self.debrisskin;
  59         dbr.colormap = self.colormap; // inherit team colors
  60         dbr.owner = self; // do not be affected by our own explosion
  61         dbr.movetype = self.debrismovetype;
  62         dbr.solid = self.debrissolid;
  63         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  64                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  65         dbr.velocity_x = self.debrisvelocity.x + self.debrisvelocityjitter.x * crandom();
  66         dbr.velocity_y = self.debrisvelocity.y + self.debrisvelocityjitter.y * crandom();
  67         dbr.velocity_z = self.debrisvelocity.z + self.debrisvelocityjitter.z * crandom();
  68         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  69         dbr.avelocity_x = random()*self.debrisavelocityjitter.x;
  70         dbr.avelocity_y = random()*self.debrisavelocityjitter.y;
  71         dbr.avelocity_z = random()*self.debrisavelocityjitter.z;
  72         dbr.damageforcescale = self.debrisdamageforcescale;
  73         if(dbr.damageforcescale)
  74                 dbr.takedamage = DAMAGE_YES;
  75         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  76 }
  77
  78 void func_breakable_colormod()
  79 {SELFPARAM();
  80         float h;
  81         if (!(self.spawnflags & 2))
  82                 return;
  83         h = self.health / self.max_health;
  84         if(h < 0.25)
  85                 self.colormod = '1 0 0';
  86         else if(h <= 0.75)
  87                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  88         else
  89                 self.colormod = '1 1 1';
  90
  91         CSQCMODEL_AUTOUPDATE(self);
  92 }
  93
  94 void func_breakable_look_destroyed()
  95 {SELFPARAM();
  96         float floorZ;
  97
  98         if(self.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
  99                 self.dropped_origin = self.origin;
 100
 101         if(self.mdl_dead == "")
 102                 self.effects |= EF_NODRAW;
 103         else {
 104                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
 105                         floorZ = self.absmin.z;
 106                         setorigin(self,((self.absmax+self.absmin)*.5));
 107                         self.origin_z = floorZ;
 108                 }
 109                 _setmodel(self, self.mdl_dead);
 110                 self.effects &= ~EF_NODRAW;
 111         }
 112
 113         CSQCMODEL_AUTOUPDATE(self);
 114
 115         self.solid = SOLID_NOT;
 116 }
 117
 118 void func_breakable_look_restore()
 119 {SELFPARAM();
 120         _setmodel(self, self.mdl);
 121         self.effects &= ~EF_NODRAW;
 122
 123         if(self.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 124                 setorigin(self, self.dropped_origin);
 125
 126         CSQCMODEL_AUTOUPDATE(self);
 127
 128         self.solid = SOLID_BSP;
 129 }
 130
 131 void func_breakable_behave_destroyed()
 132 {SELFPARAM();
 133         self.health = self.max_health;
 134         self.takedamage = DAMAGE_NO;
 135         self.bot_attack = false;
 136         self.event_damage = func_null;
 137         self.state = 1;
 138         if(self.spawnflags & 4)
 139                 self.use = func_null;
 140         func_breakable_colormod();
 141         if (self.noise1)
 142                 stopsound (self, CH_TRIGGER_SINGLE);
 143 }
 144
 145 void func_breakable_behave_restore()
 146 {SELFPARAM();
 147         self.health = self.max_health;
 148         if(self.sprite)
 149         {
 150                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 151                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 152         }
 153         if(!(self.spawnflags & 4))
 154         {
 155                 self.takedamage = DAMAGE_AIM;
 156                 self.bot_attack = true;
 157                 self.event_damage = func_breakable_damage;
 158         }
 159         self.state = 0;
 160         self.nextthink = 0; // cancel auto respawn
 161         func_breakable_colormod();
 162         if (self.noise1)
 163                 _sound (self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 164 }
 165
 166 void func_breakable_init_for_player(entity player)
 167 {SELFPARAM();
 168         if (self.noise1 && self.state == 0 && clienttype(player) == CLIENTTYPE_REAL)
 169         {
 170                 msg_entity = player;
 171                 soundto (MSG_ONE, self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 172         }
 173 }
 174
 175 void func_breakable_destroyed()
 176 {SELFPARAM();
 177         func_breakable_look_destroyed();
 178         func_breakable_behave_destroyed();
 179
 180         CSQCMODEL_AUTOUPDATE(self);
 181 }
 182
 183 void func_breakable_restore()
 184 {SELFPARAM();
 185         func_breakable_look_restore();
 186         func_breakable_behave_restore();
 187
 188         CSQCMODEL_AUTOUPDATE(self);
 189 }
 190
 191 vector debrisforce; // global, set before calling this
 192 void func_breakable_destroy()
 193 {SELFPARAM();
 194         float n, i;
 195         string oldmsg;
 196
 197         activator = self.owner;
 198         self.owner = world; // set by W_PrepareExplosionByDamage
 199
 200         // now throw around the debris
 201         n = tokenize_console(self.debris);
 202         for(i = 0; i < n; ++i)
 203                 LaunchDebris(argv(i), debrisforce);
 204
 205         func_breakable_destroyed();
 206
 207         if(self.noise)
 208                 _sound (self, CH_TRIGGER, self.noise, VOL_BASE, ATTEN_NORM);
 209
 210         if(self.dmg)
 211                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, world, self.dmg_force, DEATH_HURTTRIGGER.m_id, world);
 212
 213         if(self.cnt) // TODO
 214                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 215
 216         if(self.respawntime)
 217         {
 218                 self.think = func_breakable_restore;
 219                 self.nextthink = time + self.respawntime + crandom() * self.respawntimejitter;
 220         }
 221
 222         oldmsg = self.message;
 223         self.message = "";
 224         SUB_UseTargets();
 225         self.message = oldmsg;
 226 }
 227
 228 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 229 {SELFPARAM();
 230         if(self.state == 1)
 231                 return;
 232         if(self.spawnflags & DOOR_NOSPLASH)
 233                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 234                         return;
 235         if(self.team)
 236                 if(attacker.team == self.team)
 237                         return;
 238         self.pain_finished = time;
 239         self.health = self.health - damage;
 240         if(self.sprite)
 241         {
 242                 WaypointSprite_Ping(self.sprite);
 243                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 244         }
 245         func_breakable_colormod();
 246
 247         if(self.health <= 0)
 248         {
 249                 debrisforce = force;
 250                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 251         }
 252 }
 253
 254 void func_breakable_reset()
 255 {SELFPARAM();
 256         self.team = self.team_saved;
 257         func_breakable_look_restore();
 258         if(self.spawnflags & 1)
 259                 func_breakable_behave_destroyed();
 260         else
 261                 func_breakable_behave_restore();
 262
 263         CSQCMODEL_AUTOUPDATE(self);
 264 }
 265
 266 // destructible walls that can be used to trigger target_objective_decrease
 267 spawnfunc(func_breakable)
 268 {
 269         float n, i;
 270         if(!self.health)
 271                 self.health = 100;
 272         self.max_health = self.health;
 273
 274         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 275         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 276         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 277         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 278         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 279         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 280         if(!self.debristime) self.debristime = 3.5;
 281         if(!self.debristimejitter) self.debristime = 2.5;
 282
 283         if(self.mdl != "")
 284                 self.cnt = _particleeffectnum(self.mdl);
 285         if(self.count == 0)
 286                 self.count = 1;
 287
 288         if(self.message == "")
 289                 self.message = "got too close to an explosion";
 290         if(self.message2 == "")
 291                 self.message2 = "was pushed into an explosion by";
 292         if(!self.dmg_radius)
 293                 self.dmg_radius = 150;
 294         if(!self.dmg_force)
 295                 self.dmg_force = 200;
 296
 297         self.mdl = self.model;
 298         SetBrushEntityModel();
 299
 300         if(self.spawnflags & 4)
 301                 self.use = func_breakable_destroy;
 302         else
 303                 self.use = func_breakable_restore;
 304
 305         if(self.spawnflags & 4)
 306         {
 307                 self.takedamage = DAMAGE_NO;
 308                 self.event_damage = func_null;
 309                 self.bot_attack = false;
 310         }
 311
 312         // precache all the models
 313         if (self.mdl_dead)
 314                 precache_model(self.mdl_dead);
 315         n = tokenize_console(self.debris);
 316         for(i = 0; i < n; ++i)
 317                 precache_model(argv(i));
 318         if(self.noise)
 319                 precache_sound(self.noise);
 320         if(self.noise1)
 321                 precache_sound(self.noise1);
 322
 323         self.team_saved = self.team;
 324         self.dropped_origin = self.origin;
 325
 326         self.reset = func_breakable_reset;
 327         func_breakable_reset();
 328
 329         self.init_for_player_needed = 1;
 330         self.init_for_player = func_breakable_init_for_player;
 331
 332         CSQCMODEL_AUTOINIT(self);
 333 }
 334
 335 // for use in maps with a "model" key set
 336 spawnfunc(misc_breakablemodel) {
 337         spawnfunc_func_breakable(this);
 338 }
 339 #endif