qcsrc/common/triggers/func/vectormamamam.qc

   1 #include "vectormamamam.qh"
   2 #ifdef SVQC
   3 // reusing some fields havocbots declared
   4 .entity wp00, wp01, wp02, wp03;
   5
   6 .float targetfactor, target2factor, target3factor, target4factor;
   7 .vector targetnormal, target2normal, target3normal, target4normal;
   8
   9 vector func_vectormamamam_origin(entity o, float t)
  10 {
  11         vector v, p;
  12         float f;
  13         entity e;
  14
  15         f = o.spawnflags;
  16         v = '0 0 0';
  17
  18         e = o.wp00;
  19         if(e)
  20         {
  21                 p = e.origin + t * e.velocity;
  22                 if(f & 1)
  23                         v = v + (p * o.targetnormal) * o.targetnormal * o.targetfactor;
  24                 else
  25                         v = v + (p - (p * o.targetnormal) * o.targetnormal) * o.targetfactor;
  26         }
  27
  28         e = o.wp01;
  29         if(e)
  30         {
  31                 p = e.origin + t * e.velocity;
  32                 if(f & 2)
  33                         v = v + (p * o.target2normal) * o.target2normal * o.target2factor;
  34                 else
  35                         v = v + (p - (p * o.target2normal) * o.target2normal) * o.target2factor;
  36         }
  37
  38         e = o.wp02;
  39         if(e)
  40         {
  41                 p = e.origin + t * e.velocity;
  42                 if(f & 4)
  43                         v = v + (p * o.target3normal) * o.target3normal * o.target3factor;
  44                 else
  45                         v = v + (p - (p * o.target3normal) * o.target3normal) * o.target3factor;
  46         }
  47
  48         e = o.wp03;
  49         if(e)
  50         {
  51                 p = e.origin + t * e.velocity;
  52                 if(f & 8)
  53                         v = v + (p * o.target4normal) * o.target4normal * o.target4factor;
  54                 else
  55                         v = v + (p - (p * o.target4normal) * o.target4normal) * o.target4factor;
  56         }
  57
  58         return v;
  59 }
  60
  61 void func_vectormamamam_controller_think(entity this)
  62 {
  63         this.nextthink = time + 0.1;
  64
  65         if(this.owner.active != ACTIVE_ACTIVE)
  66         {
  67                 this.owner.velocity = '0 0 0';
  68                 return;
  69         }
  70
  71         if(this.owner.classname == "func_vectormamamam") // don't brake stuff if the func_vectormamamam was killtarget'ed
  72                 this.owner.velocity = (this.owner.destvec + func_vectormamamam_origin(this.owner, 0.1) - this.owner.origin) * 10;
  73 }
  74
  75 void func_vectormamamam_findtarget(entity this)
  76 {
  77         if(this.target != "")
  78                 this.wp00 = find(NULL, targetname, this.target);
  79
  80         if(this.target2 != "")
  81                 this.wp01 = find(NULL, targetname, this.target2);
  82
  83         if(this.target3 != "")
  84                 this.wp02 = find(NULL, targetname, this.target3);
  85
  86         if(this.target4 != "")
  87                 this.wp03 = find(NULL, targetname, this.target4);
  88
  89         if(!this.wp00 && !this.wp01 && !this.wp02 && !this.wp03)
  90                 objerror(this, "No reference entity found, so there is nothing to move. Aborting.");
  91
  92         this.destvec = this.origin - func_vectormamamam_origin(this, 0);
  93
  94         entity controller;
  95         controller = new(func_vectormamamam_controller);
  96         controller.owner = this;
  97         controller.nextthink = time + 1;
  98         setthink(controller, func_vectormamamam_controller_think);
  99 }
 100
 101 spawnfunc(func_vectormamamam)
 102 {
 103         if (this.noise != "")
 104         {
 105                 precache_sound(this.noise);
 106                 soundto(MSG_INIT, this, CH_TRIGGER_SINGLE, this.noise, VOL_BASE, ATTEN_IDLE);
 107         }
 108
 109         if(!this.targetfactor)
 110                 this.targetfactor = 1;
 111
 112         if(!this.target2factor)
 113                 this.target2factor = 1;
 114
 115         if(!this.target3factor)
 116                 this.target3factor = 1;
 117
 118         if(!this.target4factor)
 119                 this.target4factor = 1;
 120
 121         if(this.targetnormal)
 122                 this.targetnormal = normalize(this.targetnormal);
 123
 124         if(this.target2normal)
 125                 this.target2normal = normalize(this.target2normal);
 126
 127         if(this.target3normal)
 128                 this.target3normal = normalize(this.target3normal);
 129
 130         if(this.target4normal)
 131                 this.target4normal = normalize(this.target4normal);
 132
 133         setblocked(this, generic_plat_blocked);
 134         if(this.dmg && (this.message == ""))
 135                 this.message = " was squished";
 136     if(this.dmg && (this.message == ""))
 137                 this.message2 = "was squished by";
 138         if(this.dmg && (!this.dmgtime))
 139                 this.dmgtime = 0.25;
 140         this.dmgtime2 = time;
 141
 142         if(this.netname == "")
 143                 this.netname = "1 0 0 0 1";
 144
 145         if (!InitMovingBrushTrigger(this))
 146                 return;
 147
 148         // wait for targets to spawn
 149         this.SUB_NEXTTHINK = this.SUB_LTIME + 999999999;
 150         SUB_THINK(this, SUB_NullThink); // for PushMove
 151
 152         // Savage: Reduce bandwith, critical on e.g. nexdm02
 153         this.effects |= EF_LOWPRECISION;
 154
 155         this.active = ACTIVE_ACTIVE;
 156
 157         InitializeEntity(this, func_vectormamamam_findtarget, INITPRIO_FINDTARGET);
 158 }
 159 #endif