qcsrc/common/turrets/sv_turrets.qc

   1 #include "sv_turrets.qh"
   2 #ifdef SVQC
   3 #include <server/autocvars.qh>
   4
   5 // Generic aiming
   6 vector turret_aim_generic(entity this)
   7 {
   8
   9         vector pre_pos, prep;
  10         float distance, impact_time = 0, i, mintime;
  11
  12         turret_tag_fire_update(this);
  13
  14         if(this.aim_flags & TFL_AIM_SIMPLE)
  15                 return real_origin(this.enemy);
  16
  17         mintime = max(this.attack_finished_single[0] - time,0) + sys_frametime;
  18
  19         // Baseline
  20         pre_pos = real_origin(this.enemy);
  21
  22         // Lead?
  23         if (this.aim_flags & TFL_AIM_LEAD)
  24         {
  25                 if (this.aim_flags & TFL_AIM_SHOTTIMECOMPENSATE)           // Need to conpensate for shot traveltime
  26                 {
  27                         prep = pre_pos;
  28
  29                         distance = vlen(prep - this.tur_shotorg);
  30                         impact_time = distance / this.shot_speed;
  31
  32                         prep = pre_pos + (this.enemy.velocity * (impact_time + mintime));
  33
  34                         if(this.aim_flags & TFL_AIM_ZPREDICT)
  35                         if(!IS_ONGROUND(this.enemy))
  36                         if(this.enemy.move_movetype == MOVETYPE_WALK || this.enemy.move_movetype == MOVETYPE_TOSS || this.enemy.move_movetype == MOVETYPE_BOUNCE)
  37                         {
  38                                 float vz;
  39                                 prep_z = pre_pos_z;
  40                                 vz = this.enemy.velocity_z;
  41                                 for(i = 0; i < impact_time; i += sys_frametime)
  42                                 {
  43                                         vz = vz - (autocvar_sv_gravity * sys_frametime);
  44                                         prep_z = prep_z + vz * sys_frametime;
  45                                 }
  46                         }
  47                         pre_pos = prep;
  48                 }
  49                 else
  50                         pre_pos = pre_pos + this.enemy.velocity * mintime;
  51         }
  52
  53         if(this.aim_flags & TFL_AIM_SPLASH)
  54         {
  55                 //tracebox(pre_pos + '0 0 32',this.enemy.mins,this.enemy.maxs,pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
  56                 traceline(pre_pos + '0 0 32',pre_pos -'0 0 64',MOVE_WORLDONLY,this.enemy);
  57                 if(trace_fraction != 1.0)
  58                         pre_pos = trace_endpos;
  59         }
  60
  61         return pre_pos;
  62 }
  63
  64 float turret_targetscore_support(entity _turret,entity _target)
  65 {
  66         float score;            // Total score
  67         float s_score = 0, d_score;
  68
  69         if (_turret.enemy == _target) s_score = 1;
  70
  71         d_score = min(_turret.target_range_optimal,tvt_dist) / max(_turret.target_range_optimal,tvt_dist);
  72
  73         score = (d_score * _turret.target_select_rangebias) +
  74                         (s_score * _turret.target_select_samebias);
  75
  76         return score;
  77 }
  78
  79 /*
  80 * Generic bias aware score system.
  81 */
  82 float turret_targetscore_generic(entity _turret, entity _target)
  83 {
  84         float d_dist;      // Defendmode Distance
  85         float score;            // Total score
  86         float d_score;    // Distance score
  87         float a_score;    // Angular score
  88         float m_score = 0;  // missile score
  89         float p_score = 0;  // player score
  90         float ikr;                // ideal kill range
  91
  92         if (_turret.tur_defend)
  93         {
  94                 d_dist = vlen(real_origin(_target) - _turret.tur_defend.origin);
  95                 ikr = vlen(_turret.origin - _turret.tur_defend.origin);
  96                 d_score = 1 - d_dist / _turret.target_range;
  97         }
  98         else
  99         {
 100                 // Make a normlized value base on the targets distance from our optimal killzone
 101                 ikr = _turret.target_range_optimal;
 102                 d_score = min(ikr, tvt_dist) / max(ikr, tvt_dist);
 103         }
 104
 105         a_score = 1 - tvt_thadf / _turret.aim_maxrotate;
 106
 107         if ((_turret.target_select_missilebias > 0) && (_target.flags & FL_PROJECTILE))
 108                 m_score = 1;
 109
 110         if ((_turret.target_select_playerbias > 0) && IS_CLIENT(_target))
 111                 p_score = 1;
 112
 113         d_score = max(d_score, 0);
 114         a_score = max(a_score, 0);
 115         m_score = max(m_score, 0);
 116         p_score = max(p_score, 0);
 117
 118         score = (d_score * _turret.target_select_rangebias) +
 119                         (a_score * _turret.target_select_anglebias) +
 120                         (m_score * _turret.target_select_missilebias) +
 121                         (p_score * _turret.target_select_playerbias);
 122
 123         if(vdist((_turret.tur_shotorg - real_origin(_target)), >, _turret.target_range))
 124         {
 125                 //dprint("Wtf?\n");
 126                 score *= 0.001;
 127         }
 128
 129 #ifdef TURRET_DEBUG
 130         string sd,sa,sm,sp,ss;
 131         string sdt,sat,smt,spt;
 132
 133         sd = ftos(d_score);
 134         d_score *= _turret.target_select_rangebias;
 135         sdt = ftos(d_score);
 136
 137         //sv = ftos(v_score);
 138         //v_score *= _turret.target_select_samebias;
 139         //svt = ftos(v_score);
 140
 141         sa = ftos(a_score);
 142         a_score *= _turret.target_select_anglebias;
 143         sat = ftos(a_score);
 144
 145         sm = ftos(m_score);
 146         m_score *= _turret.target_select_missilebias;
 147         smt = ftos(m_score);
 148
 149         sp = ftos(p_score);
 150         p_score *= _turret.target_select_playerbias;
 151         spt = ftos(p_score);
 152
 153
 154         ss = ftos(score);
 155         bprint("^3Target scores^7 \[  ",_turret.netname, "  \] ^3for^7 \[  ", _target.netname,"  \]\n");
 156         bprint("^5Range:\[  ",sd,  "  \]^2+bias:\[  ",sdt,"  \]\n");
 157         bprint("^5Angle:\[  ",sa,  "  \]^2+bias:\[  ",sat,"  \]\n");
 158         bprint("^5Missile:\[  ",sm,"  \]^2+bias:\[  ",smt,"  \]\n");
 159         bprint("^5Player:\[  ",sp, "  \]^2+bias:\[  ",spt,"  \]\n");
 160         bprint("^3Total (w/bias):\[^1",ss,"\]\n");
 161
 162 #endif
 163
 164         return score;
 165 }
 166
 167 // Generic damage handling
 168 void turret_hide(entity this)
 169 {
 170         this.effects   |= EF_NODRAW;
 171         this.nextthink = time + this.respawntime - 0.2;
 172         setthink(this, turret_respawn);
 173 }
 174
 175 void turret_die(entity this)
 176 {
 177         this.deadflag             = DEAD_DEAD;
 178         this.tur_head.deadflag = this.deadflag;
 179
 180 // Unsolidify and hide real parts
 181         this.solid                       = SOLID_NOT;
 182         this.tur_head.solid      = this.solid;
 183
 184         this.event_damage                 = func_null;
 185         this.takedamage                  = DAMAGE_NO;
 186
 187         this.health                      = 0;
 188
 189 // Go boom
 190         //RadiusDamage (this,this, min(this.ammo,50),min(this.ammo,50) * 0.25,250,NULL,min(this.ammo,50)*5,DEATH_TURRET,NULL);
 191
 192         Turret tur = get_turretinfo(this.m_id);
 193         if(this.damage_flags & TFL_DMG_DEATH_NORESPAWN)
 194         {
 195                 tur.tr_death(tur, this);
 196
 197                 delete(this.tur_head);
 198                 delete(this);
 199         }
 200         else
 201         {
 202                 // Setup respawn
 203                 this.SendFlags    |= TNSF_STATUS;
 204                 this.nextthink   = time + 0.2;
 205                 setthink(this, turret_hide);
 206
 207                 tur.tr_death(tur, this);
 208         }
 209 }
 210
 211 void turret_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector vforce)
 212 {
 213         // Enough already!
 214         if(this.deadflag == DEAD_DEAD)
 215                 return;
 216
 217         // Inactive turrets take no damage. (hm..)
 218         if(!this.active)
 219                 return;
 220
 221         if(SAME_TEAM(this, attacker))
 222         {
 223                 if(autocvar_g_friendlyfire)
 224                         damage = damage * autocvar_g_friendlyfire;
 225                 else
 226                         return;
 227         }
 228
 229         this.health -= damage;
 230
 231         // thorw head slightly off aim when hit?
 232         if (this.damage_flags & TFL_DMG_HEADSHAKE)
 233         {
 234                 this.tur_head.angles_x = this.tur_head.angles_x + (-0.5 + random()) * damage;
 235                 this.tur_head.angles_y = this.tur_head.angles_y + (-0.5 + random()) * damage;
 236
 237                 this.SendFlags  |= TNSF_ANG;
 238         }
 239
 240         if (this.turret_flags & TUR_FLAG_MOVE)
 241                 this.velocity = this.velocity + vforce;
 242
 243         if (this.health <= 0)
 244         {
 245                 this.event_damage                 = func_null;
 246                 this.tur_head.event_damage = func_null;
 247                 this.takedamage                  = DAMAGE_NO;
 248                 this.nextthink = time;
 249                 setthink(this, turret_die);
 250         }
 251
 252         this.SendFlags  |= TNSF_STATUS;
 253 }
 254
 255 void turret_think(entity this);
 256 void turret_respawn(entity this)
 257 {
 258         // Make sure all parts belong to the same team since
 259         // this function doubles as "teamchange" function.
 260         this.tur_head.team      = this.team;
 261         this.effects                       &= ~EF_NODRAW;
 262         this.deadflag                           = DEAD_NO;
 263         this.effects                            = EF_LOWPRECISION;
 264         this.solid                                      = SOLID_BBOX;
 265         this.takedamage                         = DAMAGE_AIM;
 266         this.event_damage                       = turret_damage;
 267         this.avelocity                          = '0 0 0';
 268         this.tur_head.avelocity         = this.avelocity;
 269         this.tur_head.angles            = this.idle_aim;
 270         this.health                                     = this.max_health;
 271         this.enemy                                      = NULL;
 272         this.volly_counter                      = this.shot_volly;
 273         this.ammo                                       = this.ammo_max;
 274
 275         this.nextthink = time + this.ticrate;
 276         setthink(this, turret_think);
 277
 278         this.SendFlags = TNSF_FULL_UPDATE;
 279
 280         Turret tur = get_turretinfo(this.m_id);
 281         tur.tr_setup(tur, this);
 282 }
 283
 284
 285 // Main functions
 286 #define cvar_base "g_turrets_unit_"
 287 .float clientframe;
 288 void turrets_setframe(entity this, float _frame, float client_only)
 289 {
 290         if((client_only ? this.clientframe : this.frame ) != _frame)
 291         {
 292                 this.SendFlags |= TNSF_ANIM;
 293                 this.anim_start_time = time;
 294         }
 295
 296          if(client_only)
 297                 this.clientframe = _frame;
 298         else
 299                 this.frame = _frame;
 300
 301 }
 302
 303 bool turret_send(entity this, entity to, float sf)
 304 {
 305
 306         WriteHeader(MSG_ENTITY, ENT_CLIENT_TURRET);
 307         WriteByte(MSG_ENTITY, sf);
 308         if(sf & TNSF_SETUP)
 309         {
 310                 WriteByte(MSG_ENTITY, this.m_id);
 311
 312                 WriteCoord(MSG_ENTITY, this.origin_x);
 313                 WriteCoord(MSG_ENTITY, this.origin_y);
 314                 WriteCoord(MSG_ENTITY, this.origin_z);
 315
 316                 WriteAngle(MSG_ENTITY, this.angles_x);
 317                 WriteAngle(MSG_ENTITY, this.angles_y);
 318         }
 319
 320         if(sf & TNSF_ANG)
 321         {
 322                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_x));
 323                 WriteShort(MSG_ENTITY, rint(this.tur_head.angles_y));
 324         }
 325
 326         if(sf & TNSF_AVEL)
 327         {
 328                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_x));
 329                 WriteShort(MSG_ENTITY, rint(this.tur_head.avelocity_y));
 330         }
 331
 332         if(sf & TNSF_MOVE)
 333         {
 334                 WriteShort(MSG_ENTITY, rint(this.origin_x));
 335                 WriteShort(MSG_ENTITY, rint(this.origin_y));
 336                 WriteShort(MSG_ENTITY, rint(this.origin_z));
 337
 338                 WriteShort(MSG_ENTITY, rint(this.velocity_x));
 339                 WriteShort(MSG_ENTITY, rint(this.velocity_y));
 340                 WriteShort(MSG_ENTITY, rint(this.velocity_z));
 341
 342                 WriteShort(MSG_ENTITY, rint(this.angles_y));
 343         }
 344
 345         if(sf & TNSF_ANIM)
 346         {
 347                 WriteCoord(MSG_ENTITY, this.anim_start_time);
 348                 WriteByte(MSG_ENTITY, this.frame);
 349         }
 350
 351         if(sf & TNSF_STATUS)
 352         {
 353                 WriteByte(MSG_ENTITY, this.team);
 354
 355                 if(this.health <= 0)
 356                         WriteByte(MSG_ENTITY, 0);
 357                 else
 358                         WriteByte(MSG_ENTITY, ceil((this.health / this.max_health) * 255));
 359         }
 360
 361         return true;
 362 }
 363
 364 void load_unit_settings(entity ent, bool is_reload)
 365 {
 366         string unitname = ent.netname;
 367         string sbase;
 368
 369         if (ent == NULL)
 370                 return;
 371
 372         if(!ent.turret_scale_damage)    ent.turret_scale_damage = 1;
 373         if(!ent.turret_scale_range)             ent.turret_scale_range  = 1;
 374         if(!ent.turret_scale_refire)    ent.turret_scale_refire = 1;
 375         if(!ent.turret_scale_ammo)              ent.turret_scale_ammo   = 1;
 376         if(!ent.turret_scale_aim)               ent.turret_scale_aim     = 1;
 377         if(!ent.turret_scale_health)    ent.turret_scale_health = 1;
 378         if(!ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
 379
 380         sbase = strcat(cvar_base,unitname);
 381         if (is_reload)
 382         {
 383                 ent.enemy = NULL;
 384                 ent.tur_head.avelocity = '0 0 0';
 385
 386                 ent.tur_head.angles = '0 0 0';
 387         }
 388
 389         ent.health       = cvar(strcat(sbase,"_health")) * ent.turret_scale_health;
 390         ent.respawntime = cvar(strcat(sbase,"_respawntime")) * ent.turret_scale_respawn;
 391
 392         ent.shot_dmg             = cvar(strcat(sbase,"_shot_dmg")) * ent.turret_scale_damage;
 393         ent.shot_refire   = cvar(strcat(sbase,"_shot_refire")) * ent.turret_scale_refire;
 394         ent.shot_radius   = cvar(strcat(sbase,"_shot_radius")) * ent.turret_scale_damage;
 395         ent.shot_speed          = cvar(strcat(sbase,"_shot_speed"));
 396         ent.shot_spread   = cvar(strcat(sbase,"_shot_spread"));
 397         ent.shot_force          = cvar(strcat(sbase,"_shot_force")) * ent.turret_scale_damage;
 398         ent.shot_volly          = cvar(strcat(sbase,"_shot_volly"));
 399         ent.shot_volly_refire = cvar(strcat(sbase,"_shot_volly_refire")) * ent.turret_scale_refire;
 400
 401         ent.target_range                 = cvar(strcat(sbase,"_target_range")) * ent.turret_scale_range;
 402         ent.target_range_min     = cvar(strcat(sbase,"_target_range_min")) * ent.turret_scale_range;
 403         ent.target_range_optimal = cvar(strcat(sbase,"_target_range_optimal")) * ent.turret_scale_range;
 404         //ent.target_range_fire = cvar(strcat(sbase,"_target_range_fire")) * ent.turret_scale_range;
 405
 406         ent.target_select_rangebias = cvar(strcat(sbase,"_target_select_rangebias"));
 407         ent.target_select_samebias  = cvar(strcat(sbase,"_target_select_samebias"));
 408         ent.target_select_anglebias = cvar(strcat(sbase,"_target_select_anglebias"));
 409         ent.target_select_playerbias = cvar(strcat(sbase,"_target_select_playerbias"));
 410         //ent.target_select_fov = cvar(cvar_gets(sbase,"_target_select_fov"));
 411
 412         ent.ammo_max     = cvar(strcat(sbase,"_ammo_max")) * ent.turret_scale_ammo;
 413         ent.ammo_recharge = cvar(strcat(sbase,"_ammo_recharge")) * ent.turret_scale_ammo;
 414
 415         ent.aim_firetolerance_dist = cvar(strcat(sbase,"_aim_firetolerance_dist"));
 416         ent.aim_speed   = cvar(strcat(sbase,"_aim_speed")) * ent.turret_scale_aim;
 417         ent.aim_maxrotate  = cvar(strcat(sbase,"_aim_maxrot"));
 418         ent.aim_maxpitch = cvar(strcat(sbase,"_aim_maxpitch"));
 419
 420         ent.track_type          = cvar(strcat(sbase,"_track_type"));
 421         ent.track_accel_pitch = cvar(strcat(sbase,"_track_accel_pitch"));
 422         ent.track_accel_rotate  = cvar(strcat(sbase,"_track_accel_rot"));
 423         ent.track_blendrate  = cvar(strcat(sbase,"_track_blendrate"));
 424
 425         if(is_reload) {
 426                 Turret tur = get_turretinfo(ent.m_id);
 427                 tur.tr_setup(tur, ent);
 428         }
 429 }
 430
 431 void turret_projectile_explode(entity this)
 432 {
 433
 434         this.takedamage = DAMAGE_NO;
 435         this.event_damage = func_null;
 436 #ifdef TURRET_DEBUG
 437         float d;
 438         d = RadiusDamage (this, this.owner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.totalfrags, NULL);
 439         this.owner.tur_debug_dmg_t_h = this.owner.tur_debug_dmg_t_h + d;
 440         this.owner.tur_debug_dmg_t_f = this.owner.tur_debug_dmg_t_f + this.owner.shot_dmg;
 441 #else
 442         RadiusDamage (this, this.realowner, this.owner.shot_dmg, 0, this.owner.shot_radius, this, NULL, this.owner.shot_force, this.totalfrags, NULL);
 443 #endif
 444         delete(this);
 445 }
 446
 447 void turret_projectile_touch(entity this, entity toucher)
 448 {
 449         PROJECTILE_TOUCH(this, toucher);
 450         turret_projectile_explode(this);
 451 }
 452
 453 void turret_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector vforce)
 454 {
 455         this.velocity  += vforce;
 456         this.health     -= damage;
 457         //this.realowner = attacker; // Dont change realowner, it does not make much sense for turrets
 458         if(this.health <= 0)
 459                 W_PrepareExplosionByDamage(this, this.owner, turret_projectile_explode);
 460 }
 461
 462 entity turret_projectile(entity actor, Sound _snd, float _size, float _health, float _death, float _proj_type, float _cull, float _cli_anim)
 463 {
 464     TC(Sound, _snd);
 465         entity proj;
 466
 467         sound (actor, CH_WEAPON_A, _snd, VOL_BASE, ATTEN_NORM);
 468         proj                             = spawn ();
 469         setorigin(proj, actor.tur_shotorg);
 470         setsize(proj, '-0.5 -0.5 -0.5' * _size, '0.5 0.5 0.5' * _size);
 471         proj.owner                = actor;
 472         proj.realowner    = actor;
 473         proj.bot_dodge    = true;
 474         proj.bot_dodgerating = actor.shot_dmg;
 475         setthink(proj, turret_projectile_explode);
 476         settouch(proj, turret_projectile_touch);
 477         proj.nextthink    = time + 9;
 478         set_movetype(proj, MOVETYPE_FLYMISSILE);
 479         proj.velocity           = normalize(actor.tur_shotdir_updated + randomvec() * actor.shot_spread) * actor.shot_speed;
 480         proj.flags = FL_PROJECTILE;
 481         IL_PUSH(g_projectiles, proj);
 482         proj.enemy                = actor.enemy;
 483         proj.totalfrags  = _death;
 484         PROJECTILE_MAKETRIGGER(proj);
 485         if(_health)
 486         {
 487                 proj.health              = _health;
 488                 proj.takedamage  = DAMAGE_YES;
 489                 proj.event_damage  = turret_projectile_damage;
 490         }
 491         else
 492                 proj.flags |= FL_NOTARGET;
 493
 494         CSQCProjectile(proj, _cli_anim, _proj_type, _cull);
 495
 496         return proj;
 497 }
 498
 499 /**
 500 ** updates enemy distances, predicted impact point/time
 501 ** and updated aim<->predict impact distance.
 502 **/
 503 void turret_do_updates(entity t_turret)
 504 {
 505         vector enemy_pos = real_origin(t_turret.enemy);
 506
 507         turret_tag_fire_update(t_turret);
 508
 509         t_turret.tur_shotdir_updated = v_forward;
 510         t_turret.tur_dist_enemy = vlen(t_turret.tur_shotorg - enemy_pos);
 511         t_turret.tur_dist_aimpos = vlen(t_turret.tur_shotorg - t_turret.tur_aimpos);
 512
 513         /*if((t_turret.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (t_turret.enemy))
 514         {
 515                 oldpos = t_turret.enemy.origin;
 516                 setorigin(t_turret.enemy, t_turret.tur_aimpos);
 517                 tracebox(t_turret.tur_shotorg, '-1 -1 -1', '1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 518                 setorigin(t_turret.enemy, oldpos);
 519
 520                 if(trace_ent == t_turret.enemy)
 521                         t_turret.tur_dist_impact_to_aimpos = 0;
 522                 else
 523                         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos);
 524         }
 525         else*/
 526                 tracebox(t_turret.tur_shotorg, '-1 -1 -1','1 1 1', t_turret.tur_shotorg + (t_turret.tur_shotdir_updated * t_turret.tur_dist_aimpos), MOVE_NORMAL,t_turret);
 527
 528         t_turret.tur_dist_impact_to_aimpos = vlen(trace_endpos - t_turret.tur_aimpos) - (vlen(t_turret.enemy.maxs - t_turret.enemy.mins) * 0.5);
 529         t_turret.tur_impactent                   = trace_ent;
 530         t_turret.tur_impacttime                 = vlen(t_turret.tur_shotorg - trace_endpos) / t_turret.shot_speed;
 531 }
 532
 533 /**
 534 ** Handles head rotation according to
 535 ** the units .track_type and .track_flags
 536 **/
 537 .float turret_framecounter;
 538 void turret_track(entity this)
 539 {
 540         vector target_angle; // This is where we want to aim
 541         vector move_angle;   // This is where we can aim
 542         float f_tmp;
 543         vector v1, v2;
 544         v1 = this.tur_head.angles;
 545         v2 = this.tur_head.avelocity;
 546
 547         if (this.track_flags == TFL_TRACK_NO)
 548                 return;
 549
 550         if(!this.active)
 551                 target_angle = this.idle_aim - ('1 0 0' * this.aim_maxpitch);
 552         else if (this.enemy == NULL)
 553         {
 554                 if(time > this.lip)
 555                         target_angle = this.idle_aim + this.angles;
 556                 else
 557                         target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
 558         }
 559         else
 560         {
 561                 target_angle = vectoangles(normalize(this.tur_aimpos - this.tur_shotorg));
 562         }
 563
 564         this.tur_head.angles_x = anglemods(this.tur_head.angles_x);
 565         this.tur_head.angles_y = anglemods(this.tur_head.angles_y);
 566
 567         // Find the diffrence between where we currently aim and where we want to aim
 568         //move_angle = target_angle - (this.angles + this.tur_head.angles);
 569         //move_angle = shortangle_vxy(move_angle,(this.angles + this.tur_head.angles));
 570
 571         move_angle = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(this.angles), AnglesTransform_FromAngles(target_angle))) - this.tur_head.angles;
 572         move_angle = shortangle_vxy(move_angle, this.tur_head.angles);
 573
 574         switch(this.track_type)
 575         {
 576                 case TFL_TRACKTYPE_STEPMOTOR:
 577                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
 578                         if (this.track_flags & TFL_TRACK_PITCH)
 579                         {
 580                                 this.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
 581                                 if(this.tur_head.angles_x > this.aim_maxpitch)
 582                                         this.tur_head.angles_x = this.aim_maxpitch;
 583
 584                                 if(this.tur_head.angles_x  < -this.aim_maxpitch)
 585                                         this.tur_head.angles_x = this.aim_maxpitch;
 586                         }
 587
 588                         if (this.track_flags & TFL_TRACK_ROTATE)
 589                         {
 590                                 this.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
 591                                 if(this.tur_head.angles_y > this.aim_maxrotate)
 592                                         this.tur_head.angles_y = this.aim_maxrotate;
 593
 594                                 if(this.tur_head.angles_y  < -this.aim_maxrotate)
 595                                         this.tur_head.angles_y = this.aim_maxrotate;
 596                         }
 597
 598                         // CSQC
 599                         this.SendFlags  |= TNSF_ANG;
 600
 601                         return;
 602
 603                 case TFL_TRACKTYPE_FLUIDINERTIA:
 604                         f_tmp = this.aim_speed * this.ticrate; // dgr/sec -> dgr/tic
 605                         move_angle_x = bound(-this.aim_speed, move_angle_x * this.track_accel_pitch * f_tmp, this.aim_speed);
 606                         move_angle_y = bound(-this.aim_speed, move_angle_y * this.track_accel_rotate * f_tmp, this.aim_speed);
 607                         move_angle = (this.tur_head.avelocity * this.track_blendrate) + (move_angle * (1 - this.track_blendrate));
 608                         break;
 609
 610                 case TFL_TRACKTYPE_FLUIDPRECISE:
 611
 612                         move_angle_y = bound(-this.aim_speed, move_angle_y, this.aim_speed);
 613                         move_angle_x = bound(-this.aim_speed, move_angle_x, this.aim_speed);
 614
 615                         break;
 616         }
 617
 618         //  pitch
 619         if (this.track_flags & TFL_TRACK_PITCH)
 620         {
 621                 this.tur_head.avelocity_x = move_angle_x;
 622                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) > this.aim_maxpitch)
 623                 {
 624                         this.tur_head.avelocity_x = 0;
 625                         this.tur_head.angles_x = this.aim_maxpitch;
 626
 627                         this.SendFlags  |= TNSF_ANG;
 628                 }
 629
 630                 if((this.tur_head.angles_x + this.tur_head.avelocity_x * this.ticrate) < -this.aim_maxpitch)
 631                 {
 632                         this.tur_head.avelocity_x = 0;
 633                         this.tur_head.angles_x = -this.aim_maxpitch;
 634
 635                         this.SendFlags  |= TNSF_ANG;
 636                 }
 637         }
 638
 639         //  rot
 640         if (this.track_flags & TFL_TRACK_ROTATE)
 641         {
 642                 this.tur_head.avelocity_y = move_angle_y;
 643
 644                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) > this.aim_maxrotate)
 645                 {
 646                         this.tur_head.avelocity_y = 0;
 647                         this.tur_head.angles_y = this.aim_maxrotate;
 648
 649                         this.SendFlags  |= TNSF_ANG;
 650                 }
 651
 652                 if((this.tur_head.angles_y + this.tur_head.avelocity_y * this.ticrate) < -this.aim_maxrotate)
 653                 {
 654                         this.tur_head.avelocity_y = 0;
 655                         this.tur_head.angles_y = -this.aim_maxrotate;
 656
 657                         this.SendFlags  |= TNSF_ANG;
 658                 }
 659         }
 660
 661         this.SendFlags  |= TNSF_AVEL;
 662
 663         // Force a angle update every 10'th frame
 664         this.turret_framecounter += 1;
 665         if(this.turret_framecounter >= 10)
 666         {
 667                 this.SendFlags |= TNSF_ANG;
 668                 this.turret_framecounter = 0;
 669         }
 670 }
 671
 672 /*
 673  + TFL_TARGETSELECT_NO
 674  + TFL_TARGETSELECT_LOS
 675  + TFL_TARGETSELECT_PLAYERS
 676  + TFL_TARGETSELECT_MISSILES
 677  - TFL_TARGETSELECT_TRIGGERTARGET
 678  + TFL_TARGETSELECT_ANGLELIMITS
 679  + TFL_TARGETSELECT_RANGELIMITS
 680  + TFL_TARGETSELECT_TEAMCHECK
 681  - TFL_TARGETSELECT_NOBUILTIN
 682  + TFL_TARGETSELECT_OWNTEAM
 683 */
 684
 685 /**
 686 ** Evaluate a entity for target valitity based on validate_flags
 687 ** NOTE: the caller must check takedamage before calling this, to inline this check.
 688 **/
 689 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
 690 {
 691         vector v_tmp;
 692
 693         //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
 694         //      return -0.5;
 695
 696         if(!e_target)
 697                 return -2;
 698
 699         if(e_target.owner == e_turret)
 700                 return -0.5;
 701
 702         if(!checkpvs(e_target.origin, e_turret))
 703                 return -1;
 704
 705         if(e_target.alpha <= 0.3)
 706                 return -1;
 707
 708         if(MUTATOR_CALLHOOK(TurretValidateTarget, e_turret, e_target, validate_flags))
 709                 return M_ARGV(3, float);
 710
 711         if (validate_flags & TFL_TARGETSELECT_NO)
 712                 return -4;
 713
 714         // If only this was used more..
 715         if (e_target.flags & FL_NOTARGET)
 716                 return -5;
 717
 718         // Cant touch this
 719         if(IS_VEHICLE(e_target))
 720         {
 721                 if (e_target.vehicle_health <= 0)
 722                         return -6;
 723         }
 724         else if (e_target.health <= 0)
 725                 return -6;
 726         else if(STAT(FROZEN, e_target) > 0)
 727                 return -6;
 728
 729         // player
 730         if (IS_CLIENT(e_target))
 731         {
 732                 if(!(validate_flags & TFL_TARGETSELECT_PLAYERS))
 733                         return -7;
 734
 735                 if (IS_DEAD(e_target))
 736                         return -8;
 737         }
 738
 739         // enemy turrets
 740         if(validate_flags & TFL_TARGETSELECT_NOTURRETS)
 741         if(e_target.owner.tur_head == e_target)
 742         if(e_target.team != e_turret.team) // Dont break support units.
 743                 return -9;
 744
 745         // Missile
 746         if (e_target.flags & FL_PROJECTILE)
 747         if(!(validate_flags & TFL_TARGETSELECT_MISSILES))
 748                 return -10;
 749
 750         if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
 751         if(!(e_target.flags & FL_PROJECTILE))
 752                 return -10.5;
 753
 754         // Team check
 755         if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
 756         {
 757                 if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
 758                 {
 759                         if (e_target.team != e_turret.team)
 760                                 return -11;
 761
 762                         if (e_turret.team != e_target.owner.team)
 763                                 return -12;
 764                 }
 765                 else
 766                 {
 767                         if (e_target.team == e_turret.team)
 768                                 return -13;
 769
 770                         if (e_turret.team == e_target.owner.team)
 771                                 return -14;
 772                 }
 773         }
 774
 775         // Range limits?
 776         tvt_dist = vlen(e_turret.origin - real_origin(e_target));
 777         if (validate_flags & TFL_TARGETSELECT_RANGELIMITS)
 778         {
 779                 if (tvt_dist < e_turret.target_range_min)
 780                         return -15;
 781
 782                 if (tvt_dist > e_turret.target_range)
 783                         return -16;
 784         }
 785
 786         // Can we even aim this thing?
 787         tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target);
 788         tvt_tadv = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
 789         tvt_thadf = vlen(tvt_thadv);
 790         tvt_tadf = vlen(tvt_tadv);
 791
 792         /*
 793         if(validate_flags & TFL_TARGETSELECT_FOV)
 794         {
 795                 if(e_turret.target_select_fov < tvt_thadf)
 796                         return -21;
 797         }
 798         */
 799
 800         if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
 801         {
 802                 if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
 803                         return -17;
 804
 805                 if (fabs(tvt_tadv_y) > e_turret.aim_maxrotate)
 806                         return -18;
 807         }
 808
 809         // Line of sight?
 810         if (validate_flags & TFL_TARGETSELECT_LOS)
 811         {
 812                 v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
 813
 814                 traceline(e_turret.origin + '0 0 16', v_tmp, 0, e_turret);
 815
 816                 if(vdist(v_tmp - trace_endpos, >, e_turret.aim_firetolerance_dist))
 817                         return -19;
 818         }
 819
 820         if (e_target.classname == "grapplinghook")
 821                 return -20;
 822
 823         /*
 824         if (e_target.classname == "func_button")
 825                 return -21;
 826         */
 827
 828 #ifdef TURRET_DEBUG_TARGETSELECT
 829         LOG_TRACE("Target:",e_target.netname," is a valid target for ",e_turret.netname);
 830 #endif
 831
 832         return 1;
 833 }
 834
 835 entity turret_select_target(entity this)
 836 {
 837         entity e;               // target looper entity
 838         float  score;   // target looper entity score
 839         entity e_enemy;  // currently best scoreing target
 840         float  m_score;  // currently best scoreing target's score
 841
 842         m_score = 0;
 843         if(this.enemy && this.enemy.takedamage && turret_validate_target(this,this.enemy,this.target_validate_flags) > 0)
 844         {
 845                 e_enemy = this.enemy;
 846                 m_score = this.turret_score_target(this,e_enemy) * this.target_select_samebias;
 847         }
 848         else
 849                 e_enemy = this.enemy = NULL;
 850
 851         e = findradius(this.origin, this.target_range);
 852
 853         // Nothing to aim at?
 854         if (!e)
 855                 return NULL;
 856
 857         while (e)
 858         {
 859                 if(e.takedamage)
 860                 {
 861                         float f = turret_validate_target(this, e, this.target_select_flags);
 862                         //dprint("F is: ", ftos(f), "\n");
 863                         if ( f > 0)
 864                         {
 865                                 score = this.turret_score_target(this,e);
 866                                 if ((score > m_score) && (score > 0))
 867                                 {
 868                                         e_enemy = e;
 869                                         m_score = score;
 870                                 }
 871                         }
 872                 }
 873                 e = e.chain;
 874         }
 875
 876         return e_enemy;
 877 }
 878
 879
 880 /*
 881  + = implemented
 882  - = not implemented
 883
 884  + TFL_FIRECHECK_NO
 885  + TFL_FIRECHECK_WORLD
 886  + TFL_FIRECHECK_DEAD
 887  + TFL_FIRECHECK_DISTANCES
 888  - TFL_FIRECHECK_LOS
 889  + TFL_FIRECHECK_AIMDIST
 890  + TFL_FIRECHECK_REALDIST
 891  - TFL_FIRECHECK_ANGLEDIST
 892  - TFL_FIRECHECK_TEAMCECK
 893  + TFL_FIRECHECK_AFF
 894  + TFL_FIRECHECK_AMMO_OWN
 895  + TFL_FIRECHECK_AMMO_OTHER
 896  + TFL_FIRECHECK_REFIRE
 897 */
 898
 899 /**
 900 ** Preforms pre-fire checks based on the uints firecheck_flags
 901 **/
 902 bool turret_firecheck(entity this)
 903 {
 904         // This one just dont care =)
 905         if (this.firecheck_flags & TFL_FIRECHECK_NO)
 906                 return true;
 907
 908         if (this.enemy == NULL)
 909                 return false;
 910
 911         // Ready?
 912         if (this.firecheck_flags & TFL_FIRECHECK_REFIRE)
 913                 if (this.attack_finished_single[0] > time) return false;
 914
 915         // Special case: volly fire turret that has to fire a full volly if a shot was fired.
 916         if (this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 917                 if (this.volly_counter != this.shot_volly)
 918                         if(this.ammo >= this.shot_dmg)
 919                                 return true;
 920
 921         // Lack of zombies makes shooting dead things unnecessary :P
 922         if (this.firecheck_flags & TFL_FIRECHECK_DEAD)
 923                 if (IS_DEAD(this.enemy))
 924                         return false;
 925
 926         // Own ammo?
 927         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OWN)
 928                 if (this.ammo < this.shot_dmg)
 929                         return false;
 930
 931         // Other's ammo? (support-supply units)
 932         if (this.firecheck_flags & TFL_FIRECHECK_AMMO_OTHER)
 933                 if (this.enemy.ammo >= this.enemy.ammo_max)
 934                         return false;
 935
 936         // Target of opertunity?
 937         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
 938         {
 939                 this.enemy = this.tur_impactent;
 940                 return true;
 941         }
 942
 943         if (this.firecheck_flags & TFL_FIRECHECK_DISTANCES)
 944         {
 945                 // To close?
 946                 if (this.tur_dist_aimpos < this.target_range_min)
 947                         if(turret_validate_target(this, this.tur_impactent, this.target_validate_flags) > 0)
 948                                 return true; // Target of opertunity?
 949                         else
 950                                 return false;
 951         }
 952
 953         // Try to avoid FF?
 954         if (this.firecheck_flags & TFL_FIRECHECK_AFF)
 955                 if (this.tur_impactent.team == this.team)
 956                         return false;
 957
 958         // aim<->predicted impact
 959         if (this.firecheck_flags & TFL_FIRECHECK_AIMDIST)
 960                 if (this.tur_dist_impact_to_aimpos > this.aim_firetolerance_dist)
 961                         return false;
 962
 963         // Volly status
 964         if (this.shot_volly > 1)
 965                 if (this.volly_counter == this.shot_volly)
 966                         if (this.ammo < (this.shot_dmg * this.shot_volly))
 967                                 return false;
 968
 969         /*if(this.firecheck_flags & TFL_FIRECHECK_VERIFIED)
 970                 if(this.tur_impactent != this.enemy)
 971                         return false;*/
 972
 973         return true;
 974 }
 975
 976 bool turret_checkfire(entity this)
 977 {
 978         if(MUTATOR_CALLHOOK(Turret_CheckFire, this))
 979                 return M_ARGV(1, bool);
 980
 981         return this.turret_firecheckfunc(this);
 982 }
 983
 984 void turret_fire(entity this)
 985 {
 986         if (autocvar_g_turrets_nofire != 0)
 987                 return;
 988
 989         if(MUTATOR_CALLHOOK(TurretFire, this))
 990                 return;
 991
 992         Turret info = get_turretinfo(this.m_id);
 993         info.tr_attack(info, this);
 994
 995         this.attack_finished_single[0] = time + this.shot_refire;
 996         this.ammo -= this.shot_dmg;
 997         this.volly_counter = this.volly_counter - 1;
 998
 999         if (this.volly_counter <= 0)
1000         {
1001                 this.volly_counter = this.shot_volly;
1002
1003                 if (this.shoot_flags & TFL_SHOOT_CLEARTARGET)
1004                         this.enemy = NULL;
1005
1006                 if (this.shot_volly > 1)
1007                         this.attack_finished_single[0] = time + this.shot_volly_refire;
1008         }
1009
1010 #ifdef TURRET_DEBUG
1011         if (this.enemy) paint_target3(this.tur_aimpos, 64, this.tur_debug_rvec, this.tur_impacttime + 0.25);
1012 #endif
1013 }
1014
1015 void turret_think(entity this)
1016 {
1017         this.nextthink = time + this.ticrate;
1018
1019         MUTATOR_CALLHOOK(TurretThink, this);
1020
1021 #ifdef TURRET_DEBUG
1022         if (this.tur_debug_tmr1 < time)
1023         {
1024                 if (this.enemy) paint_target (this.enemy,128,this.tur_debug_rvec,0.9);
1025                 paint_target(this,256,this.tur_debug_rvec,0.9);
1026                 this.tur_debug_tmr1 = time + 1;
1027         }
1028 #endif
1029
1030         // Handle ammo
1031         if (!(this.spawnflags & TSF_NO_AMMO_REGEN))
1032         if (this.ammo < this.ammo_max)
1033                 this.ammo = min(this.ammo + this.ammo_recharge, this.ammo_max);
1034
1035         // Inactive turrets needs to run the think loop,
1036         // So they can handle animation and wake up if need be.
1037         if(!this.active)
1038         {
1039                 turret_track(this);
1040                 return;
1041         }
1042
1043         // This is typicaly used for zaping every target in range
1044         // turret_fusionreactor uses this to recharge friendlys.
1045         if (this.shoot_flags & TFL_SHOOT_HITALLVALID)
1046         {
1047                 // Do a this.turret_fire for every valid target.
1048                 entity e = findradius(this.origin,this.target_range);
1049                 while (e)
1050                 {
1051                         if(e.takedamage)
1052                         {
1053                                 if (turret_validate_target(this,e,this.target_validate_flags))
1054                                 {
1055                                         this.enemy = e;
1056
1057                                         turret_do_updates(this);
1058
1059                                         if (turret_checkfire(this))
1060                                                 turret_fire(this);
1061                                 }
1062                         }
1063
1064                         e = e.chain;
1065                 }
1066                 this.enemy = NULL;
1067         }
1068         else if(this.shoot_flags & TFL_SHOOT_CUSTOM)
1069         {
1070                 // This one is doing something.. oddball. assume its handles what needs to be handled.
1071
1072                 // Predict?
1073                 if(!(this.aim_flags & TFL_AIM_NO))
1074                         this.tur_aimpos = turret_aim_generic(this);
1075
1076                 // Turn & pitch?
1077                 if(!(this.track_flags & TFL_TRACK_NO))
1078                         turret_track(this);
1079
1080                 turret_do_updates(this);
1081
1082                 // Fire?
1083                 if (turret_checkfire(this))
1084                         turret_fire(this);
1085         }
1086         else
1087         {
1088                 // Special case for volly always. if it fired once it must compleate the volly.
1089                 if(this.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
1090                         if(this.volly_counter != this.shot_volly)
1091                         {
1092                                 // Predict or whatnot
1093                                 if(!(this.aim_flags & TFL_AIM_NO))
1094                                         this.tur_aimpos = turret_aim_generic(this);
1095
1096                                 // Turn & pitch
1097                                 if(!(this.track_flags & TFL_TRACK_NO))
1098                                         turret_track(this);
1099
1100                                 turret_do_updates(this);
1101
1102                                 // Fire!
1103                                 if (turret_checkfire(this))
1104                                         turret_fire(this);
1105
1106                                 Turret tur = get_turretinfo(this.m_id);
1107                                 tur.tr_think(tur, this);
1108
1109                                 return;
1110                         }
1111
1112                 // Check if we have a vailid enemy, and try to find one if we dont.
1113
1114                 // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
1115                 float do_target_scan = 0;
1116                 if((this.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
1117                         do_target_scan = 1;
1118
1119                 // Old target (if any) invalid?
1120                 if(this.target_validate_time < time)
1121                 if (turret_validate_target(this, this.enemy, this.target_validate_flags) <= 0)
1122                 {
1123                         this.enemy = NULL;
1124                         this.target_validate_time = time + 0.5;
1125                         do_target_scan = 1;
1126                 }
1127
1128                 // But never more often then g_turrets_targetscan_mindelay!
1129                 if (this.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
1130                         do_target_scan = 0;
1131
1132                 if(do_target_scan)
1133                 {
1134                         this.enemy = turret_select_target(this);
1135                         this.target_select_time = time;
1136                 }
1137
1138                 // No target, just go to idle, do any custom stuff and bail.
1139                 if (this.enemy == NULL)
1140                 {
1141                         // Turn & pitch
1142                         if(!(this.track_flags & TFL_TRACK_NO))
1143                                 turret_track(this);
1144
1145                         Turret tur = get_turretinfo(this.m_id);
1146                         tur.tr_think(tur, this);
1147
1148                         // And bail.
1149                         return;
1150                 }
1151                 else
1152                         this.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
1153
1154                 // Predict?
1155                 if(!(this.aim_flags & TFL_AIM_NO))
1156                         this.tur_aimpos = turret_aim_generic(this);
1157
1158                 // Turn & pitch?
1159                 if(!(this.track_flags & TFL_TRACK_NO))
1160                         turret_track(this);
1161
1162                 turret_do_updates(this);
1163
1164                 // Fire?
1165                 if (turret_checkfire(this))
1166                         turret_fire(this);
1167         }
1168
1169         Turret tur = get_turretinfo(this.m_id);
1170         tur.tr_think(tur, this);
1171 }
1172
1173 /*
1174         When .used a turret switch team to activator.team.
1175         If activator is NULL, the turret go inactive.
1176 */
1177 void turret_use(entity this, entity actor, entity trigger)
1178 {
1179         LOG_TRACE("Turret ",this.netname, " used by ", actor.classname);
1180
1181         this.team = actor.team;
1182
1183         if(this.team == 0)
1184                 this.active = ACTIVE_NOT;
1185         else
1186                 this.active = ACTIVE_ACTIVE;
1187
1188 }
1189
1190 void turret_link(entity this)
1191 {
1192         Net_LinkEntity(this, true, 0, turret_send);
1193         setthink(this, turret_think);
1194         this.nextthink = time;
1195         this.tur_head.effects = EF_NODRAW;
1196 }
1197
1198 void turrets_manager_think(entity this)
1199 {
1200         this.nextthink = time + 1;
1201
1202         if (autocvar_g_turrets_reloadcvars == 1)
1203         {
1204                 IL_EACH(g_turrets, true,
1205                 {
1206                         load_unit_settings(it, true);
1207                         Turret tur = get_turretinfo(it.m_id);
1208                         tur.tr_think(tur, it);
1209                 });
1210                 cvar_set("g_turrets_reloadcvars", "0");
1211         }
1212 }
1213
1214 void turret_initparams(entity tur)
1215 {
1216         #define TRY(x) (x) ? (x)
1217         tur.respawntime                 = max  (-1,              (TRY(tur.respawntime)               :  60                                         ));
1218         tur.shot_refire                 = bound(0.01,            (TRY(tur.shot_refire)               :  1                                          ), 9999);
1219         tur.shot_dmg                    = max  (1,               (TRY(tur.shot_dmg)                  :  tur.shot_refire * 50                       ));
1220         tur.shot_radius                 = max  (1,               (TRY(tur.shot_radius)               :  tur.shot_dmg * 0.5                         ));
1221         tur.shot_speed                  = max  (1,               (TRY(tur.shot_speed)                :  2500                                       ));
1222         tur.shot_spread                 = bound(0.0001,          (TRY(tur.shot_spread)               :  0.0125                                     ), 500);
1223         tur.shot_force                  = bound(0.001,           (TRY(tur.shot_force)                :  tur.shot_dmg * 0.5 + tur.shot_radius * 0.5 ), 5000);
1224         tur.shot_volly                  = bound(1,               (TRY(tur.shot_volly)                :  1                                          ), floor(tur.ammo_max / tur.shot_dmg));
1225         tur.shot_volly_refire           = bound(tur.shot_refire, (TRY(tur.shot_volly_refire)         :  tur.shot_refire * tur.shot_volly           ), 60);
1226         tur.target_range                = bound(0,               (TRY(tur.target_range)              :  tur.shot_speed * 0.5                       ), MAX_SHOT_DISTANCE);
1227         tur.target_range_min            = bound(0,               (TRY(tur.target_range_min)          :  tur.shot_radius * 2                        ), MAX_SHOT_DISTANCE);
1228         tur.target_range_optimal        = bound(0,               (TRY(tur.target_range_optimal)      :  tur.target_range * 0.5                     ), MAX_SHOT_DISTANCE);
1229         tur.aim_maxrotate               = bound(0,               (TRY(tur.aim_maxrotate)             :  90                                         ), 360);
1230         tur.aim_maxpitch                = bound(0,               (TRY(tur.aim_maxpitch)              :  20                                         ), 90);
1231         tur.aim_speed                   = bound(0.1,             (TRY(tur.aim_speed)                 :  36                                         ), 1000);
1232         tur.aim_firetolerance_dist      = bound(0.1,             (TRY(tur.aim_firetolerance_dist)    :  5 + (tur.shot_radius * 2)                  ), MAX_SHOT_DISTANCE);
1233         tur.target_select_rangebias     = bound(-10,             (TRY(tur.target_select_rangebias)   :  1                                          ), 10);
1234         tur.target_select_samebias      = bound(-10,             (TRY(tur.target_select_samebias)    :  1                                          ), 10);
1235         tur.target_select_anglebias     = bound(-10,             (TRY(tur.target_select_anglebias)   :  1                                          ), 10);
1236         tur.target_select_missilebias   = bound(-10,             (TRY(tur.target_select_missilebias) :  1                                          ), 10);
1237         tur.target_select_playerbias    = bound(-10,             (TRY(tur.target_select_playerbias)  :  1                                          ), 10);
1238         tur.ammo_max                    = max  (tur.shot_dmg,    (TRY(tur.ammo_max)                  :  tur.shot_dmg * 10                          ));
1239         tur.ammo_recharge               = max  (0,               (TRY(tur.ammo_recharge)             :  tur.shot_dmg * 0.5                         ));
1240         #undef TRY
1241 }
1242
1243 bool turret_initialize(entity this, Turret tur)
1244 {
1245         if(!autocvar_g_turrets)
1246                 return false;
1247
1248         if(tur.m_id == 0)
1249                 return false; // invalid turret
1250
1251         // if tur_head exists, we can assume this turret re-spawned
1252         if(!this.tur_head) {
1253                 tur.tr_precache(tur);
1254                 IL_PUSH(g_turrets, this);
1255         }
1256
1257         entity e = find(NULL, classname, "turret_manager");
1258         if(!e)
1259         {
1260                 e = new(turret_manager);
1261                 setthink(e, turrets_manager_think);
1262                 e.nextthink = time + 2;
1263         }
1264
1265         if(!(this.spawnflags & TSF_SUSPENDED))
1266                 droptofloor(this);
1267
1268         this.netname = tur.netname;
1269         load_unit_settings(this, 0);
1270
1271         if(!this.team || !teamplay)             { this.team = MAX_SHOT_DISTANCE; }
1272         if(!this.ticrate)                               { this.ticrate = ((this.turret_flags & TUR_FLAG_SUPPORT) ? 0.2 : 0.1); }
1273         if(!this.health)                                { this.health = 1000; }
1274         if(!this.shot_refire)                   { this.shot_refire = 1; }
1275         if(!this.tur_shotorg)                   { this.tur_shotorg = '50 0 50'; }
1276         if(!this.turret_flags)                  { this.turret_flags = TUR_FLAG_SPLASH | TUR_FLAG_MEDPROJ | TUR_FLAG_PLAYER; }
1277         if(!this.damage_flags)                  { this.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE; }
1278         if(!this.aim_flags)                             { this.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE; }
1279         if(!this.track_type)                    { this.track_type = TFL_TRACKTYPE_STEPMOTOR; }
1280         if(!this.track_flags)                   { this.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROTATE; }
1281         if(!this.ammo_flags)                    { this.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE; }
1282         if(!this.target_select_flags)   { this.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_ANGLELIMITS; }
1283         if(!this.firecheck_flags)               { this.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES | TFL_FIRECHECK_LOS
1284                                                                                                                    | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCHECK | TFL_FIRECHECK_AMMO_OWN | TFL_FIRECHECK_REFIRE; }
1285
1286         if(this.track_type != TFL_TRACKTYPE_STEPMOTOR)
1287         {
1288                 // Fluid / Ineria mode. Looks mutch nicer.
1289                 // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1290
1291                 this.aim_speed = bound(0.1, ((!this.aim_speed) ? 180 : this.aim_speed), 1000);
1292
1293                 if(!this.track_accel_pitch)             { this.track_accel_pitch = 0.5; }
1294                 if(!this.track_accel_rotate)    { this.track_accel_rotate = 0.5; }
1295                 if(!this.track_blendrate)               { this.track_blendrate = 0.35; }
1296         }
1297
1298         turret_initparams(this);
1299
1300         this.turret_flags = TUR_FLAG_ISTURRET | (tur.spawnflags);
1301
1302         if(this.turret_flags & TUR_FLAG_SPLASH)
1303                 this.aim_flags |= TFL_AIM_SPLASH;
1304
1305         if(this.turret_flags & TUR_FLAG_MISSILE)
1306                 this.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1307
1308         if(this.turret_flags & TUR_FLAG_PLAYER)
1309                 this.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1310
1311         if(this.spawnflags & TSL_NO_RESPAWN)
1312                 this.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1313
1314         if (this.turret_flags & TUR_FLAG_SUPPORT)
1315                 this.turret_score_target = turret_targetscore_support;
1316         else
1317                 this.turret_score_target = turret_targetscore_generic;
1318
1319         ++turret_count;
1320
1321         _setmodel(this, tur.model);
1322         setsize(this, tur.mins, tur.maxs);
1323
1324         this.m_id                                       = tur.m_id;
1325         this.classname                          = "turret_main";
1326         this.active                                     = ACTIVE_ACTIVE;
1327         this.effects                            = EF_NODRAW;
1328         this.netname                            = tur.turret_name;
1329         this.ticrate                            = bound(sys_frametime, this.ticrate, 60);
1330         this.max_health                         = this.health;
1331         this.target_validate_flags      = this.target_select_flags;
1332         this.ammo                                       = this.ammo_max;
1333         this.ammo_recharge                 *= this.ticrate;
1334         this.solid                                      = SOLID_BBOX;
1335         this.takedamage                         = DAMAGE_AIM;
1336         set_movetype(this, MOVETYPE_NOCLIP);
1337         this.view_ofs                           = '0 0 0';
1338         this.turret_firecheckfunc       = turret_firecheck;
1339         this.event_damage                       = turret_damage;
1340         this.use                                        = turret_use;
1341         this.bot_attack                         = true;
1342         this.nextthink                          = time + 1;
1343         this.nextthink                     += turret_count * sys_frametime;
1344
1345         this.tur_head = new(turret_head);
1346         _setmodel(this.tur_head, tur.head_model);
1347         setsize(this.tur_head, '0 0 0', '0 0 0');
1348         setorigin(this.tur_head, '0 0 0');
1349         setattachment(this.tur_head, this, "tag_head");
1350
1351         this.tur_head.netname           = this.tur_head.classname;
1352         this.tur_head.team                      = this.team;
1353         this.tur_head.owner                     = this;
1354         this.tur_head.takedamage        = DAMAGE_NO;
1355         this.tur_head.solid                     = SOLID_NOT;
1356         set_movetype(this.tur_head, this.move_movetype);
1357
1358         if(!this.tur_defend)
1359         if(this.target != "")
1360         {
1361                 this.tur_defend = find(NULL, targetname, this.target);
1362                 if (this.tur_defend == NULL)
1363                 {
1364                         this.target = "";
1365                         LOG_TRACE("Turret has invalid defendpoint!");
1366                 }
1367         }
1368
1369         if (this.tur_defend)
1370                 this.idle_aim = this.tur_head.angles + angleofs(this.tur_head, this.tur_defend);
1371         else
1372                 this.idle_aim = '0 0 0';
1373
1374 #ifdef TURRET_DEBUG
1375         this.tur_debug_start = this.nextthink;
1376         while(vdist(this.tur_debug_rvec, <, 2))
1377                 this.tur_debug_rvec = randomvec() * 4;
1378
1379         this.tur_debug_rvec_x = fabs(this.tur_debug_rvec_x);
1380         this.tur_debug_rvec_y = fabs(this.tur_debug_rvec_y);
1381         this.tur_debug_rvec_z = fabs(this.tur_debug_rvec_z);
1382 #endif
1383
1384         turret_link(this);
1385         turret_respawn(this);
1386         turret_tag_fire_update(this);
1387
1388         tur.tr_setup(tur, this);
1389
1390         if(MUTATOR_CALLHOOK(TurretSpawn, this))
1391                 return false;
1392
1393         return true;
1394 }
1395 #endif