qcsrc/common/turrets/turret/fusionreactor.qc

   1 #ifndef TURRET_FUSIONREACTOR_H
   2 #define TURRET_FUSIONREACTOR_H
   3
   4 CLASS(FusionReactor, Turret)
   5 /* spawnflags */ ATTRIB(FusionReactor, spawnflags, int, TUR_FLAG_SUPPORT | TUR_FLAG_AMMOSOURCE);
   6 /* mins       */ ATTRIB(FusionReactor, mins, vector, '-34 -34 0');
   7 /* maxs       */ ATTRIB(FusionReactor, maxs, vector, '34 34 90');
   8 /* modelname  */ ATTRIB(FusionReactor, mdl, string, "base.md3");
   9 /* model      */ ATTRIB_STRZONE(FusionReactor, model, string, strcat("models/turrets/", this.mdl));
  10 /* head_model */ ATTRIB_STRZONE(FusionReactor, head_model, string, strcat("models/turrets/", "reactor.md3"));
  11 /* netname    */ ATTRIB(FusionReactor, netname, string, "fusionreactor");
  12 /* fullname   */ ATTRIB(FusionReactor, turret_name, string, _("Fusion Reactor"));
  13 ENDCLASS(FusionReactor)
  14 REGISTER_TURRET(FUSIONREACTOR, NEW(FusionReactor));
  15
  16 #endif
  17
  18 #ifdef IMPLEMENTATION
  19 #ifdef SVQC
  20 bool turret_fusionreactor_firecheck()
  21 {SELFPARAM();
  22     if (self.attack_finished_single[0] > time)
  23         return false;
  24
  25     if (IS_DEAD(self.enemy))
  26         return false;
  27
  28     if (self.enemy == world)
  29         return false;
  30
  31     if (self.ammo < self.shot_dmg)
  32         return false;
  33
  34     if (self.enemy.ammo >= self.enemy.ammo_max)
  35         return false;
  36
  37     if(vdist(self.enemy.origin - self.origin, >, self.target_range))
  38         return false;
  39
  40     if(self.team != self.enemy.team)
  41         return false;
  42
  43     if(!(self.enemy.ammo_flags & TFL_AMMO_ENERGY))
  44         return false;
  45
  46     return true;
  47 }
  48
  49 spawnfunc(turret_fusionreactor) { if (!turret_initialize(TUR_FUSIONREACTOR)) remove(self); }
  50
  51 METHOD(FusionReactor, tr_attack, void(FusionReactor this, entity it))
  52 {
  53     self.enemy.ammo = min(self.enemy.ammo + self.shot_dmg,self.enemy.ammo_max);
  54     vector fl_org = 0.5 * (self.enemy.absmin + self.enemy.absmax);
  55     te_smallflash(fl_org);
  56 }
  57 METHOD(FusionReactor, tr_think, void(FusionReactor thistur, entity it))
  58 {
  59     SELFPARAM();
  60     self.tur_head.avelocity = '0 250 0' * (self.ammo / self.ammo_max);
  61 }
  62 METHOD(FusionReactor, tr_setup, void(FusionReactor this, entity it))
  63 {
  64     it.ammo_flags                               = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE;
  65     it.target_select_flags      = TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_OWNTEAM | TFL_TARGETSELECT_RANGELIMITS;
  66     it.firecheck_flags          = TFL_FIRECHECK_AMMO_OWN | TFL_FIRECHECK_AMMO_OTHER | TFL_FIRECHECK_DISTANCES | TFL_FIRECHECK_DEAD;
  67     it.shoot_flags                      = TFL_SHOOT_HITALLVALID;
  68     it.aim_flags                                = TFL_AIM_NO;
  69     it.track_flags                      = TFL_TRACK_NO;
  70
  71     it.tur_head.scale = 0.75;
  72     it.tur_head.avelocity = '0 50 0';
  73
  74     it.turret_firecheckfunc = turret_fusionreactor_firecheck;
  75 }
  76
  77 #endif
  78 #endif