qcsrc/common/util.qc

   1 #include "util.qh"
   2
   3 #if defined(CSQC)
   4     #include "../client/defs.qh"
   5     #include "constants.qh"
   6         #include "../client/mutators/events.qh"
   7     #include "mapinfo.qh"
   8     #include "notifications.qh"
   9     #include <common/deathtypes/all.qh>
  10 #elif defined(MENUQC)
  11 #elif defined(SVQC)
  12     #include "constants.qh"
  13     #include "../server/autocvars.qh"
  14     #include "../server/defs.qh"
  15         #include "../server/mutators/events.qh"
  16     #include "notifications.qh"
  17     #include <common/deathtypes/all.qh>
  18     #include "mapinfo.qh"
  19 #endif
  20
  21 #ifndef MENUQC
  22 /*
  23 * Get "real" origin, in worldspace, even if ent is attached to something else.
  24 */
  25 vector real_origin(entity ent)
  26 {
  27         entity e;
  28         vector v = ((ent.absmin + ent.absmax) * 0.5);
  29
  30         e = ent.tag_entity;
  31         while(e)
  32         {
  33                 v = v + ((e.absmin + e.absmax) * 0.5);
  34                 e = e.tag_entity;
  35         }
  36
  37         return v;
  38 }
  39 #endif
  40
  41 string wordwrap_buffer;
  42
  43 void wordwrap_buffer_put(string s)
  44 {
  45         wordwrap_buffer = strcat(wordwrap_buffer, s);
  46 }
  47
  48 string wordwrap(string s, float l)
  49 {
  50         string r;
  51         wordwrap_buffer = "";
  52         wordwrap_cb(s, l, wordwrap_buffer_put);
  53         r = wordwrap_buffer;
  54         wordwrap_buffer = "";
  55         return r;
  56 }
  57
  58 #ifndef MENUQC
  59 #ifndef CSQC
  60 void wordwrap_buffer_sprint(string s)
  61 {SELFPARAM();
  62         wordwrap_buffer = strcat(wordwrap_buffer, s);
  63         if(s == "\n")
  64         {
  65                 sprint(self, wordwrap_buffer);
  66                 wordwrap_buffer = "";
  67         }
  68 }
  69
  70 void wordwrap_sprint(string s, float l)
  71 {SELFPARAM();
  72         wordwrap_buffer = "";
  73         wordwrap_cb(s, l, wordwrap_buffer_sprint);
  74         if(wordwrap_buffer != "")
  75                 sprint(self, strcat(wordwrap_buffer, "\n"));
  76         wordwrap_buffer = "";
  77         return;
  78 }
  79 #endif
  80 #endif
  81
  82 #ifndef SVQC
  83 string draw_UseSkinFor(string pic)
  84 {
  85         if(substring(pic, 0, 1) == "/")
  86                 return substring(pic, 1, strlen(pic)-1);
  87         else
  88                 return strcat(draw_currentSkin, "/", pic);
  89 }
  90 #endif
  91
  92 void wordwrap_cb(string s, float l, void(string) callback)
  93 {
  94         string c;
  95         float lleft, i, j, wlen;
  96
  97         s = strzone(s);
  98         lleft = l;
  99         for (i = 0;i < strlen(s);++i)
 100         {
 101                 if (substring(s, i, 2) == "\\n")
 102                 {
 103                         callback("\n");
 104                         lleft = l;
 105                         ++i;
 106                 }
 107                 else if (substring(s, i, 1) == "\n")
 108                 {
 109                         callback("\n");
 110                         lleft = l;
 111                 }
 112                 else if (substring(s, i, 1) == " ")
 113                 {
 114                         if (lleft > 0)
 115                         {
 116                                 callback(" ");
 117                                 lleft = lleft - 1;
 118                         }
 119                 }
 120                 else
 121                 {
 122                         for (j = i+1;j < strlen(s);++j)
 123                                 //    ^^ this skips over the first character of a word, which
 124                                 //       is ALWAYS part of the word
 125                                 //       this is safe since if i+1 == strlen(s), i will become
 126                                 //       strlen(s)-1 at the end of this block and the function
 127                                 //       will terminate. A space can't be the first character we
 128                                 //       read here, and neither can a \n be the start, since these
 129                                 //       two cases have been handled above.
 130                         {
 131                                 c = substring(s, j, 1);
 132                                 if (c == " ")
 133                                         break;
 134                                 if (c == "\\")
 135                                         break;
 136                                 if (c == "\n")
 137                                         break;
 138                                 // we need to keep this tempstring alive even if substring is
 139                                 // called repeatedly, so call strcat even though we're not
 140                                 // doing anything
 141                                 callback("");
 142                         }
 143                         wlen = j - i;
 144                         if (lleft < wlen)
 145                         {
 146                                 callback("\n");
 147                                 lleft = l;
 148                         }
 149                         callback(substring(s, i, wlen));
 150                         lleft = lleft - wlen;
 151                         i = j - 1;
 152                 }
 153         }
 154         strunzone(s);
 155 }
 156
 157 void depthfirst(entity start, .entity up, .entity downleft, .entity right, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
 158 {
 159         entity e;
 160         e = start;
 161         funcPre(pass, e);
 162         while (e.(downleft))
 163         {
 164                 e = e.(downleft);
 165                 funcPre(pass, e);
 166         }
 167         funcPost(pass, e);
 168         while(e != start)
 169         {
 170                 if (e.(right))
 171                 {
 172                         e = e.(right);
 173                         funcPre(pass, e);
 174                         while (e.(downleft))
 175                         {
 176                                 e = e.(downleft);
 177                                 funcPre(pass, e);
 178                         }
 179                 }
 180                 else
 181                         e = e.(up);
 182                 funcPost(pass, e);
 183         }
 184 }
 185
 186 string ScoreString(int pFlags, float pValue)
 187 {
 188         string valstr;
 189         float l;
 190
 191         pValue = floor(pValue + 0.5); // round
 192
 193         if((pValue == 0) && (pFlags & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME)))
 194                 valstr = "";
 195         else if(pFlags & SFL_RANK)
 196         {
 197                 valstr = ftos(pValue);
 198                 l = strlen(valstr);
 199                 if((l >= 2) && (substring(valstr, l - 2, 1) == "1"))
 200                         valstr = strcat(valstr, "th");
 201                 else if(substring(valstr, l - 1, 1) == "1")
 202                         valstr = strcat(valstr, "st");
 203                 else if(substring(valstr, l - 1, 1) == "2")
 204                         valstr = strcat(valstr, "nd");
 205                 else if(substring(valstr, l - 1, 1) == "3")
 206                         valstr = strcat(valstr, "rd");
 207                 else
 208                         valstr = strcat(valstr, "th");
 209         }
 210         else if(pFlags & SFL_TIME)
 211                 valstr = TIME_ENCODED_TOSTRING(pValue);
 212         else
 213                 valstr = ftos(pValue);
 214
 215         return valstr;
 216 }
 217
 218 // compressed vector format:
 219 // like MD3, just even shorter
 220 //   4 bit pitch (16 angles), 0 is -90, 8 is 0, 16 would be 90
 221 //   5 bit yaw (32 angles), 0=0, 8=90, 16=180, 24=270
 222 //   7 bit length (logarithmic encoding), 1/8 .. about 7844
 223 //     length = 2^(length_encoded/8) / 8
 224 // if pitch is 90, yaw does nothing and therefore indicates the sign (yaw is then either 11111 or 11110); 11111 is pointing DOWN
 225 // thus, valid values are from 0000.11110.0000000 to 1111.11111.1111111
 226 // the special value 0 indicates the zero vector
 227
 228 float lengthLogTable[128];
 229
 230 float invertLengthLog(float x)
 231 {
 232         int l, r, m;
 233
 234         if(x >= lengthLogTable[127])
 235                 return 127;
 236         if(x <= lengthLogTable[0])
 237                 return 0;
 238
 239         l = 0;
 240         r = 127;
 241
 242         while(r - l > 1)
 243         {
 244                 m = floor((l + r) / 2);
 245                 if(lengthLogTable[m] < x)
 246                         l = m;
 247                 else
 248                         r = m;
 249         }
 250
 251         // now: r is >=, l is <
 252         float lerr = (x - lengthLogTable[l]);
 253         float rerr = (lengthLogTable[r] - x);
 254         if(lerr < rerr)
 255                 return l;
 256         return r;
 257 }
 258
 259 vector decompressShortVector(int data)
 260 {
 261         vector out;
 262         if(data == 0)
 263                 return '0 0 0';
 264         float p = (data & 0xF000) / 0x1000;
 265         float y = (data & 0x0F80) / 0x80;
 266         int len = (data & 0x007F);
 267
 268         //print("\ndecompress: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
 269
 270         if(p == 0)
 271         {
 272                 out.x = 0;
 273                 out.y = 0;
 274                 if(y == 31)
 275                         out.z = -1;
 276                 else
 277                         out.z = +1;
 278         }
 279         else
 280         {
 281                 y   = .19634954084936207740 * y;
 282                 p = .19634954084936207740 * p - 1.57079632679489661922;
 283                 out.x = cos(y) *  cos(p);
 284                 out.y = sin(y) *  cos(p);
 285                 out.z =          -sin(p);
 286         }
 287
 288         //print("decompressed: ", vtos(out), "\n");
 289
 290         return out * lengthLogTable[len];
 291 }
 292
 293 float compressShortVector(vector vec)
 294 {
 295         vector ang;
 296         float p, y, len;
 297         if(vlen(vec) == 0)
 298                 return 0;
 299         //print("compress: ", vtos(vec), "\n");
 300         ang = vectoangles(vec);
 301         ang.x = -ang.x;
 302         if(ang.x < -90)
 303                 ang.x += 360;
 304         if(ang.x < -90 && ang.x > +90)
 305                 error("BOGUS vectoangles");
 306         //print("angles: ", vtos(ang), "\n");
 307
 308         p = floor(0.5 + (ang.x + 90) * 16 / 180) & 15; // -90..90 to 0..14
 309         if(p == 0)
 310         {
 311                 if(vec.z < 0)
 312                         y = 31;
 313                 else
 314                         y = 30;
 315         }
 316         else
 317                 y = floor(0.5 + ang.y * 32 / 360)          & 31; // 0..360 to 0..32
 318         len = invertLengthLog(vlen(vec));
 319
 320         //print("compressed: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
 321
 322         return (p * 0x1000) + (y * 0x80) + len;
 323 }
 324
 325 void compressShortVector_init()
 326 {
 327         float l = 1;
 328         float f = pow(2, 1/8);
 329         int i;
 330         for(i = 0; i < 128; ++i)
 331         {
 332                 lengthLogTable[i] = l;
 333                 l *= f;
 334         }
 335
 336         if(cvar("developer"))
 337         {
 338                 LOG_INFO("Verifying vector compression table...\n");
 339                 for(i = 0x0F00; i < 0xFFFF; ++i)
 340                         if(i != compressShortVector(decompressShortVector(i)))
 341                         {
 342                                 LOG_INFO("BROKEN vector compression: ", ftos(i));
 343                                 LOG_INFO(" -> ", vtos(decompressShortVector(i)));
 344                                 LOG_INFO(" -> ", ftos(compressShortVector(decompressShortVector(i))));
 345                                 LOG_INFO("\n");
 346                                 error("b0rk");
 347                         }
 348                 LOG_INFO("Done.\n");
 349         }
 350 }
 351
 352 #ifndef MENUQC
 353 float CheckWireframeBox(entity forent, vector v0, vector dvx, vector dvy, vector dvz)
 354 {
 355         traceline(v0, v0 + dvx, true, forent); if(trace_fraction < 1) return 0;
 356         traceline(v0, v0 + dvy, true, forent); if(trace_fraction < 1) return 0;
 357         traceline(v0, v0 + dvz, true, forent); if(trace_fraction < 1) return 0;
 358         traceline(v0 + dvx, v0 + dvx + dvy, true, forent); if(trace_fraction < 1) return 0;
 359         traceline(v0 + dvx, v0 + dvx + dvz, true, forent); if(trace_fraction < 1) return 0;
 360         traceline(v0 + dvy, v0 + dvy + dvx, true, forent); if(trace_fraction < 1) return 0;
 361         traceline(v0 + dvy, v0 + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
 362         traceline(v0 + dvz, v0 + dvz + dvx, true, forent); if(trace_fraction < 1) return 0;
 363         traceline(v0 + dvz, v0 + dvz + dvy, true, forent); if(trace_fraction < 1) return 0;
 364         traceline(v0 + dvx + dvy, v0 + dvx + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
 365         traceline(v0 + dvx + dvz, v0 + dvx + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
 366         traceline(v0 + dvy + dvz, v0 + dvx + dvy + dvz, true, forent); if(trace_fraction < 1) return 0;
 367         return 1;
 368 }
 369 #endif
 370
 371 string fixPriorityList(string order, float from, float to, float subtract, float complete)
 372 {
 373         string neworder;
 374         float i, n, w;
 375
 376         n = tokenize_console(order);
 377         neworder = "";
 378         for(i = 0; i < n; ++i)
 379         {
 380                 w = stof(argv(i));
 381                 if(w == floor(w))
 382                 {
 383                         if(w >= from && w <= to)
 384                                 neworder = strcat(neworder, ftos(w), " ");
 385                         else
 386                         {
 387                                 w -= subtract;
 388                                 if(w >= from && w <= to)
 389                                         neworder = strcat(neworder, ftos(w), " ");
 390                         }
 391                 }
 392         }
 393
 394         if(complete)
 395         {
 396                 n = tokenize_console(neworder);
 397                 for(w = to; w >= from; --w)
 398                 {
 399                         for(i = 0; i < n; ++i)
 400                                 if(stof(argv(i)) == w)
 401                                         break;
 402                         if(i == n) // not found
 403                                 neworder = strcat(neworder, ftos(w), " ");
 404                 }
 405         }
 406
 407         return substring(neworder, 0, strlen(neworder) - 1);
 408 }
 409
 410 string mapPriorityList(string order, string(string) mapfunc)
 411 {
 412         string neworder;
 413         float i, n;
 414
 415         n = tokenize_console(order);
 416         neworder = "";
 417         for(i = 0; i < n; ++i)
 418                 neworder = strcat(neworder, mapfunc(argv(i)), " ");
 419
 420         return substring(neworder, 0, strlen(neworder) - 1);
 421 }
 422
 423 string swapInPriorityList(string order, float i, float j)
 424 {
 425         string s;
 426         float w, n;
 427
 428         n = tokenize_console(order);
 429
 430         if(i >= 0 && i < n && j >= 0 && j < n && i != j)
 431         {
 432                 s = "";
 433                 for(w = 0; w < n; ++w)
 434                 {
 435                         if(w == i)
 436                                 s = strcat(s, argv(j), " ");
 437                         else if(w == j)
 438                                 s = strcat(s, argv(i), " ");
 439                         else
 440                                 s = strcat(s, argv(w), " ");
 441                 }
 442                 return substring(s, 0, strlen(s) - 1);
 443         }
 444
 445         return order;
 446 }
 447
 448 #ifndef MENUQC
 449 void get_mi_min_max(float mode)
 450 {
 451         vector mi, ma;
 452
 453         if(mi_shortname)
 454                 strunzone(mi_shortname);
 455         mi_shortname = mapname;
 456         if(!strcasecmp(substring(mi_shortname, 0, 5), "maps/"))
 457                 mi_shortname = substring(mi_shortname, 5, strlen(mi_shortname) - 5);
 458         if(!strcasecmp(substring(mi_shortname, strlen(mi_shortname) - 4, 4), ".bsp"))
 459                 mi_shortname = substring(mi_shortname, 0, strlen(mi_shortname) - 4);
 460         mi_shortname = strzone(mi_shortname);
 461
 462 #ifdef CSQC
 463         mi = world.mins;
 464         ma = world.maxs;
 465 #else
 466         mi = world.absmin;
 467         ma = world.absmax;
 468 #endif
 469
 470         mi_min = mi;
 471         mi_max = ma;
 472         MapInfo_Get_ByName(mi_shortname, 0, 0);
 473         if(MapInfo_Map_mins.x < MapInfo_Map_maxs.x)
 474         {
 475                 mi_min = MapInfo_Map_mins;
 476                 mi_max = MapInfo_Map_maxs;
 477         }
 478         else
 479         {
 480                 // not specified
 481                 if(mode)
 482                 {
 483                         // be clever
 484                         tracebox('1 0 0' * mi.x,
 485                                          '0 1 0' * mi.y + '0 0 1' * mi.z,
 486                                          '0 1 0' * ma.y + '0 0 1' * ma.z,
 487                                          '1 0 0' * ma.x,
 488                                          MOVE_WORLDONLY,
 489                                          world);
 490                         if(!trace_startsolid)
 491                                 mi_min.x = trace_endpos.x;
 492
 493                         tracebox('0 1 0' * mi.y,
 494                                          '1 0 0' * mi.x + '0 0 1' * mi.z,
 495                                          '1 0 0' * ma.x + '0 0 1' * ma.z,
 496                                          '0 1 0' * ma.y,
 497                                          MOVE_WORLDONLY,
 498                                          world);
 499                         if(!trace_startsolid)
 500                                 mi_min.y = trace_endpos.y;
 501
 502                         tracebox('0 0 1' * mi.z,
 503                                          '1 0 0' * mi.x + '0 1 0' * mi.y,
 504                                          '1 0 0' * ma.x + '0 1 0' * ma.y,
 505                                          '0 0 1' * ma.z,
 506                                          MOVE_WORLDONLY,
 507                                          world);
 508                         if(!trace_startsolid)
 509                                 mi_min.z = trace_endpos.z;
 510
 511                         tracebox('1 0 0' * ma.x,
 512                                          '0 1 0' * mi.y + '0 0 1' * mi.z,
 513                                          '0 1 0' * ma.y + '0 0 1' * ma.z,
 514                                          '1 0 0' * mi.x,
 515                                          MOVE_WORLDONLY,
 516                                          world);
 517                         if(!trace_startsolid)
 518                                 mi_max.x = trace_endpos.x;
 519
 520                         tracebox('0 1 0' * ma.y,
 521                                          '1 0 0' * mi.x + '0 0 1' * mi.z,
 522                                          '1 0 0' * ma.x + '0 0 1' * ma.z,
 523                                          '0 1 0' * mi.y,
 524                                          MOVE_WORLDONLY,
 525                                          world);
 526                         if(!trace_startsolid)
 527                                 mi_max.y = trace_endpos.y;
 528
 529                         tracebox('0 0 1' * ma.z,
 530                                          '1 0 0' * mi.x + '0 1 0' * mi.y,
 531                                          '1 0 0' * ma.x + '0 1 0' * ma.y,
 532                                          '0 0 1' * mi.z,
 533                                          MOVE_WORLDONLY,
 534                                          world);
 535                         if(!trace_startsolid)
 536                                 mi_max.z = trace_endpos.z;
 537                 }
 538         }
 539 }
 540
 541 void get_mi_min_max_texcoords(float mode)
 542 {
 543         vector extend;
 544
 545         get_mi_min_max(mode);
 546
 547         mi_picmin = mi_min;
 548         mi_picmax = mi_max;
 549
 550         // extend mi_picmax to get a square aspect ratio
 551         // center the map in that area
 552         extend = mi_picmax - mi_picmin;
 553         if(extend.y > extend.x)
 554         {
 555                 mi_picmin.x -= (extend.y - extend.x) * 0.5;
 556                 mi_picmax.x += (extend.y - extend.x) * 0.5;
 557         }
 558         else
 559         {
 560                 mi_picmin.y -= (extend.x - extend.y) * 0.5;
 561                 mi_picmax.y += (extend.x - extend.y) * 0.5;
 562         }
 563
 564         // add another some percent
 565         extend = (mi_picmax - mi_picmin) * (1 / 64.0);
 566         mi_picmin -= extend;
 567         mi_picmax += extend;
 568
 569         // calculate the texcoords
 570         mi_pictexcoord0 = mi_pictexcoord1 = mi_pictexcoord2 = mi_pictexcoord3 = '0 0 0';
 571         // first the two corners of the origin
 572         mi_pictexcoord0_x = (mi_min.x - mi_picmin.x) / (mi_picmax.x - mi_picmin.x);
 573         mi_pictexcoord0_y = (mi_min.y - mi_picmin.y) / (mi_picmax.y - mi_picmin.y);
 574         mi_pictexcoord2_x = (mi_max.x - mi_picmin.x) / (mi_picmax.x - mi_picmin.x);
 575         mi_pictexcoord2_y = (mi_max.y - mi_picmin.y) / (mi_picmax.y - mi_picmin.y);
 576         // then the other corners
 577         mi_pictexcoord1_x = mi_pictexcoord0_x;
 578         mi_pictexcoord1_y = mi_pictexcoord2_y;
 579         mi_pictexcoord3_x = mi_pictexcoord2_x;
 580         mi_pictexcoord3_y = mi_pictexcoord0_y;
 581 }
 582 #endif
 583
 584 float cvar_settemp(string tmp_cvar, string tmp_value)
 585 {
 586         float created_saved_value;
 587
 588         created_saved_value = 0;
 589
 590         if (!(tmp_cvar || tmp_value))
 591         {
 592                 LOG_TRACE("Error: Invalid usage of cvar_settemp(string, string); !\n");
 593                 return 0;
 594         }
 595
 596         if(!cvar_type(tmp_cvar))
 597         {
 598                 LOG_INFOF("Error: cvar %s doesn't exist!\n", tmp_cvar);
 599                 return 0;
 600         }
 601
 602         FOREACH_ENTITY_CLASS("saved_cvar_value", it.netname == tmp_cvar,
 603         {
 604                 created_saved_value = -1; // skip creation
 605                 break; // no need to continue
 606         });
 607
 608         if(created_saved_value != -1)
 609         {
 610                 // creating a new entity to keep track of this cvar
 611                 entity e = new(saved_cvar_value);
 612                 make_pure(e);
 613                 e.netname = strzone(tmp_cvar);
 614                 e.message = strzone(cvar_string(tmp_cvar));
 615                 created_saved_value = 1;
 616         }
 617
 618         // update the cvar to the value given
 619         cvar_set(tmp_cvar, tmp_value);
 620
 621         return created_saved_value;
 622 }
 623
 624 int cvar_settemp_restore()
 625 {
 626         int j = 0;
 627         FOREACH_ENTITY_CLASS("saved_cvar_value", true,
 628         {
 629                 if(cvar_type(it.netname))
 630                 {
 631                         cvar_set(it.netname, it.message);
 632                         strunzone(it.netname);
 633                         strunzone(it.message);
 634                         remove(it);
 635                         ++j;
 636                 }
 637                 else
 638                         LOG_INFOF("Error: cvar %s doesn't exist anymore! It can still be restored once it's manually recreated.\n", it.netname);
 639         });
 640
 641         return j;
 642 }
 643
 644 float textLengthUpToWidth(string theText, float maxWidth, vector theSize, textLengthUpToWidth_widthFunction_t w)
 645 {
 646         // STOP.
 647         // The following function is SLOW.
 648         // For your safety and for the protection of those around you...
 649         // DO NOT CALL THIS AT HOME.
 650         // No really, don't.
 651         if(w(theText, theSize) <= maxWidth)
 652                 return strlen(theText); // yeah!
 653
 654         // binary search for right place to cut string
 655         float ch;
 656         float left, right, middle; // this always works
 657         left = 0;
 658         right = strlen(theText); // this always fails
 659         do
 660         {
 661                 middle = floor((left + right) / 2);
 662                 if(w(substring(theText, 0, middle), theSize) <= maxWidth)
 663                         left = middle;
 664                 else
 665                         right = middle;
 666         }
 667         while(left < right - 1);
 668
 669         if(w("^7", theSize) == 0) // detect color codes support in the width function
 670         {
 671                 // NOTE: when color codes are involved, this binary search is,
 672                 // mathematically, BROKEN. However, it is obviously guaranteed to
 673                 // terminate, as the range still halves each time - but nevertheless, it is
 674                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
 675                 // range, and "right" is outside).
 676
 677                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
 678                 // and decrease left on the basis of the chars detected of the truncated tag
 679                 // Even if the ^xrgb tag is not complete/correct, left is decreased
 680                 // (sometimes too much but with a correct result)
 681                 // it fixes also ^[0-9]
 682                 while(left >= 1 && substring(theText, left-1, 1) == "^")
 683                         left-=1;
 684
 685                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
 686                         left-=2;
 687                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
 688                         {
 689                                 ch = str2chr(theText, left-1);
 690                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
 691                                         left-=3;
 692                         }
 693                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
 694                         {
 695                                 ch = str2chr(theText, left-2);
 696                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
 697                                 {
 698                                         ch = str2chr(theText, left-1);
 699                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
 700                                                 left-=4;
 701                                 }
 702                         }
 703         }
 704
 705         return left;
 706 }
 707
 708 float textLengthUpToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t w)
 709 {
 710         // STOP.
 711         // The following function is SLOW.
 712         // For your safety and for the protection of those around you...
 713         // DO NOT CALL THIS AT HOME.
 714         // No really, don't.
 715         if(w(theText) <= maxWidth)
 716                 return strlen(theText); // yeah!
 717
 718         // binary search for right place to cut string
 719         float ch;
 720         float left, right, middle; // this always works
 721         left = 0;
 722         right = strlen(theText); // this always fails
 723         do
 724         {
 725                 middle = floor((left + right) / 2);
 726                 if(w(substring(theText, 0, middle)) <= maxWidth)
 727                         left = middle;
 728                 else
 729                         right = middle;
 730         }
 731         while(left < right - 1);
 732
 733         if(w("^7") == 0) // detect color codes support in the width function
 734         {
 735                 // NOTE: when color codes are involved, this binary search is,
 736                 // mathematically, BROKEN. However, it is obviously guaranteed to
 737                 // terminate, as the range still halves each time - but nevertheless, it is
 738                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
 739                 // range, and "right" is outside).
 740
 741                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
 742                 // and decrease left on the basis of the chars detected of the truncated tag
 743                 // Even if the ^xrgb tag is not complete/correct, left is decreased
 744                 // (sometimes too much but with a correct result)
 745                 // it fixes also ^[0-9]
 746                 while(left >= 1 && substring(theText, left-1, 1) == "^")
 747                         left-=1;
 748
 749                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
 750                         left-=2;
 751                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
 752                         {
 753                                 ch = str2chr(theText, left-1);
 754                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
 755                                         left-=3;
 756                         }
 757                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
 758                         {
 759                                 ch = str2chr(theText, left-2);
 760                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
 761                                 {
 762                                         ch = str2chr(theText, left-1);
 763                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
 764                                                 left-=4;
 765                                 }
 766                         }
 767         }
 768
 769         return left;
 770 }
 771
 772 string find_last_color_code(string s)
 773 {
 774         int start = strstrofs(s, "^", 0);
 775         if (start == -1) // no caret found
 776                 return "";
 777         int len = strlen(s)-1;
 778         int i;
 779         for(i = len; i >= start; --i)
 780         {
 781                 if(substring(s, i, 1) != "^")
 782                         continue;
 783
 784                 int carets = 1;
 785                 while (i-carets >= start && substring(s, i-carets, 1) == "^")
 786                         ++carets;
 787
 788                 // check if carets aren't all escaped
 789                 if (carets & 1)
 790                 {
 791                         if(i+1 <= len)
 792                         if(strstrofs("0123456789", substring(s, i+1, 1), 0) >= 0)
 793                                 return substring(s, i, 2);
 794
 795                         if(i+4 <= len)
 796                         if(substring(s, i+1, 1) == "x")
 797                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+2, 1), 0) >= 0)
 798                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+3, 1), 0) >= 0)
 799                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+4, 1), 0) >= 0)
 800                                 return substring(s, i, 5);
 801                 }
 802                 i -= carets; // this also skips one char before the carets
 803         }
 804
 805         return "";
 806 }
 807
 808 string getWrappedLine(float w, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
 809 {
 810         float cantake;
 811         float take;
 812         string s;
 813
 814         s = getWrappedLine_remaining;
 815
 816         if(w <= 0)
 817         {
 818                 getWrappedLine_remaining = string_null;
 819                 return s; // the line has no size ANYWAY, nothing would be displayed.
 820         }
 821
 822         cantake = textLengthUpToWidth(s, w, theFontSize, tw);
 823         if(cantake > 0 && cantake < strlen(s))
 824         {
 825                 take = cantake - 1;
 826                 while(take > 0 && substring(s, take, 1) != " ")
 827                         --take;
 828                 if(take == 0)
 829                 {
 830                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
 831                         if(getWrappedLine_remaining == "")
 832                                 getWrappedLine_remaining = string_null;
 833                         else if (tw("^7", theFontSize) == 0)
 834                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
 835                         return substring(s, 0, cantake);
 836                 }
 837                 else
 838                 {
 839                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
 840                         if(getWrappedLine_remaining == "")
 841                                 getWrappedLine_remaining = string_null;
 842                         else if (tw("^7", theFontSize) == 0)
 843                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
 844                         return substring(s, 0, take);
 845                 }
 846         }
 847         else
 848         {
 849                 getWrappedLine_remaining = string_null;
 850                 return s;
 851         }
 852 }
 853
 854 string getWrappedLineLen(float w, textLengthUpToLength_lenFunction_t tw)
 855 {
 856         float cantake;
 857         float take;
 858         string s;
 859
 860         s = getWrappedLine_remaining;
 861
 862         if(w <= 0)
 863         {
 864                 getWrappedLine_remaining = string_null;
 865                 return s; // the line has no size ANYWAY, nothing would be displayed.
 866         }
 867
 868         cantake = textLengthUpToLength(s, w, tw);
 869         if(cantake > 0 && cantake < strlen(s))
 870         {
 871                 take = cantake - 1;
 872                 while(take > 0 && substring(s, take, 1) != " ")
 873                         --take;
 874                 if(take == 0)
 875                 {
 876                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
 877                         if(getWrappedLine_remaining == "")
 878                                 getWrappedLine_remaining = string_null;
 879                         else if (tw("^7") == 0)
 880                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
 881                         return substring(s, 0, cantake);
 882                 }
 883                 else
 884                 {
 885                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
 886                         if(getWrappedLine_remaining == "")
 887                                 getWrappedLine_remaining = string_null;
 888                         else if (tw("^7") == 0)
 889                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
 890                         return substring(s, 0, take);
 891                 }
 892         }
 893         else
 894         {
 895                 getWrappedLine_remaining = string_null;
 896                 return s;
 897         }
 898 }
 899
 900 string textShortenToWidth(string theText, float maxWidth, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
 901 {
 902         if(tw(theText, theFontSize) <= maxWidth)
 903                 return theText;
 904         else
 905                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - tw("...", theFontSize), theFontSize, tw)), "...");
 906 }
 907
 908 string textShortenToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t tw)
 909 {
 910         if(tw(theText) <= maxWidth)
 911                 return theText;
 912         else
 913                 return strcat(substring(theText, 0, textLengthUpToLength(theText, maxWidth - tw("..."), tw)), "...");
 914 }
 915
 916 float isGametypeInFilter(float gt, float tp, float ts, string pattern)
 917 {
 918         string subpattern, subpattern2, subpattern3, subpattern4;
 919         subpattern = strcat(",", MapInfo_Type_ToString(gt), ",");
 920         if(tp)
 921                 subpattern2 = ",teams,";
 922         else
 923                 subpattern2 = ",noteams,";
 924         if(ts)
 925                 subpattern3 = ",teamspawns,";
 926         else
 927                 subpattern3 = ",noteamspawns,";
 928         if(gt == MAPINFO_TYPE_RACE || gt == MAPINFO_TYPE_CTS)
 929                 subpattern4 = ",race,";
 930         else
 931                 subpattern4 = string_null;
 932
 933         if(substring(pattern, 0, 1) == "-")
 934         {
 935                 pattern = substring(pattern, 1, strlen(pattern) - 1);
 936                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
 937                         return 0;
 938                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
 939                         return 0;
 940                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) >= 0)
 941                         return 0;
 942                 if(subpattern4 && strstrofs(strcat(",", pattern, ","), subpattern4, 0) >= 0)
 943                         return 0;
 944         }
 945         else
 946         {
 947                 if(substring(pattern, 0, 1) == "+")
 948                         pattern = substring(pattern, 1, strlen(pattern) - 1);
 949                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
 950                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
 951                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) < 0)
 952                 {
 953                         if (!subpattern4)
 954                                 return 0;
 955                         if(strstrofs(strcat(",", pattern, ","), subpattern4, 0) < 0)
 956                                 return 0;
 957                 }
 958         }
 959         return 1;
 960 }
 961
 962 vector solve_shotdirection(vector myorg, vector myvel, vector eorg, vector evel, float spd, float newton_style)
 963 {
 964         vector ret;
 965
 966         // make origin and speed relative
 967         eorg -= myorg;
 968         if(newton_style)
 969                 evel -= myvel;
 970
 971         // now solve for ret, ret normalized:
 972         //   eorg + t * evel == t * ret * spd
 973         // or, rather, solve for t:
 974         //   |eorg + t * evel| == t * spd
 975         //   eorg^2 + t^2 * evel^2 + 2 * t * (eorg * evel) == t^2 * spd^2
 976         //   t^2 * (evel^2 - spd^2) + t * (2 * (eorg * evel)) + eorg^2 == 0
 977         vector solution = solve_quadratic(evel * evel - spd * spd, 2 * (eorg * evel), eorg * eorg);
 978         // p = 2 * (eorg * evel) / (evel * evel - spd * spd)
 979         // q = (eorg * eorg) / (evel * evel - spd * spd)
 980         if(!solution.z) // no real solution
 981         {
 982                 // happens if D < 0
 983                 // (eorg * evel)^2 < (evel^2 - spd^2) * eorg^2
 984                 // (eorg * evel)^2 / eorg^2 < evel^2 - spd^2
 985                 // spd^2 < ((evel^2 * eorg^2) - (eorg * evel)^2) / eorg^2
 986                 // spd^2 < evel^2 * (1 - cos^2 angle(evel, eorg))
 987                 // spd^2 < evel^2 * sin^2 angle(evel, eorg)
 988                 // spd < |evel| * sin angle(evel, eorg)
 989                 return '0 0 0';
 990         }
 991         else if(solution.x > 0)
 992         {
 993                 // both solutions > 0: take the smaller one
 994                 // happens if p < 0 and q > 0
 995                 ret = normalize(eorg + solution.x * evel);
 996         }
 997         else if(solution.y > 0)
 998         {
 999                 // one solution > 0: take the larger one
1000                 // happens if q < 0 or q == 0 and p < 0
1001                 ret = normalize(eorg + solution.y * evel);
1002         }
1003         else
1004         {
1005                 // no solution > 0: reject
1006                 // happens if p > 0 and q >= 0
1007                 // 2 * (eorg * evel) / (evel * evel - spd * spd) > 0
1008                 // (eorg * eorg) / (evel * evel - spd * spd) >= 0
1009                 //
1010                 // |evel| >= spd
1011                 // eorg * evel > 0
1012                 //
1013                 // "Enemy is moving away from me at more than spd"
1014                 return '0 0 0';
1015         }
1016
1017         // NOTE: we always got a solution if spd > |evel|
1018
1019         if(newton_style == 2)
1020                 ret = normalize(ret * spd + myvel);
1021
1022         return ret;
1023 }
1024
1025 vector get_shotvelocity(vector myvel, vector mydir, float spd, float newton_style, float mi, float ma)
1026 {
1027         if(!newton_style)
1028                 return spd * mydir;
1029
1030         if(newton_style == 2)
1031         {
1032                 // true Newtonian projectiles with automatic aim adjustment
1033                 //
1034                 // solve: |outspeed * mydir - myvel| = spd
1035                 // outspeed^2 - 2 * outspeed * (mydir * myvel) + myvel^2 - spd^2 = 0
1036                 // outspeed = (mydir * myvel) +- sqrt((mydir * myvel)^2 - myvel^2 + spd^2)
1037                 // PLUS SIGN!
1038                 // not defined?
1039                 // then...
1040                 // myvel^2 - (mydir * myvel)^2 > spd^2
1041                 // velocity without mydir component > spd
1042                 // fire at smallest possible spd that works?
1043                 // |(mydir * myvel) * myvel - myvel| = spd
1044
1045                 vector solution = solve_quadratic(1, -2 * (mydir * myvel), myvel * myvel - spd * spd);
1046
1047                 float outspeed;
1048                 if(solution.z)
1049                         outspeed = solution.y; // the larger one
1050                 else
1051                 {
1052                         //outspeed = 0; // slowest possible shot
1053                         outspeed = solution.x; // the real part (that is, the average!)
1054                         //dprint("impossible shot, adjusting\n");
1055                 }
1056
1057                 outspeed = bound(spd * mi, outspeed, spd * ma);
1058                 return mydir * outspeed;
1059         }
1060
1061         // real Newtonian
1062         return myvel + spd * mydir;
1063 }
1064
1065 float compressShotOrigin(vector v)
1066 {
1067         float x, y, z;
1068         x = rint(v.x * 2);
1069         y = rint(v.y * 4) + 128;
1070         z = rint(v.z * 4) + 128;
1071         if(x > 255 || x < 0)
1072         {
1073                 LOG_INFO("shot origin ", vtos(v), " x out of bounds\n");
1074                 x = bound(0, x, 255);
1075         }
1076         if(y > 255 || y < 0)
1077         {
1078                 LOG_INFO("shot origin ", vtos(v), " y out of bounds\n");
1079                 y = bound(0, y, 255);
1080         }
1081         if(z > 255 || z < 0)
1082         {
1083                 LOG_INFO("shot origin ", vtos(v), " z out of bounds\n");
1084                 z = bound(0, z, 255);
1085         }
1086         return x * 0x10000 + y * 0x100 + z;
1087 }
1088 vector decompressShotOrigin(int f)
1089 {
1090         vector v;
1091         v.x = ((f & 0xFF0000) / 0x10000) / 2;
1092         v.y = ((f & 0xFF00) / 0x100 - 128) / 4;
1093         v.z = ((f & 0xFF) - 128) / 4;
1094         return v;
1095 }
1096
1097 #ifndef MENUQC
1098 vector healtharmor_maxdamage(float h, float a, float armorblock, int deathtype)
1099 {
1100         // NOTE: we'll always choose the SMALLER value...
1101         float healthdamage, armordamage, armorideal;
1102         if (DEATH_IS(deathtype, DEATH_DROWN))  // Why should armor help here...
1103                 armorblock = 0;
1104         vector v;
1105         healthdamage = (h - 1) / (1 - armorblock); // damage we can take if we could use more health
1106         armordamage = a + (h - 1); // damage we can take if we could use more armor
1107         armorideal = healthdamage * armorblock;
1108         v.y = armorideal;
1109         if(armordamage < healthdamage)
1110         {
1111                 v.x = armordamage;
1112                 v.z = 1;
1113         }
1114         else
1115         {
1116                 v.x = healthdamage;
1117                 v.z = 0;
1118         }
1119         return v;
1120 }
1121
1122 vector healtharmor_applydamage(float a, float armorblock, int deathtype, float damage)
1123 {
1124         vector v;
1125         if (DEATH_IS(deathtype, DEATH_DROWN))  // Why should armor help here...
1126                 armorblock = 0;
1127         v.y = bound(0, damage * armorblock, a); // save
1128         v.x = bound(0, damage - v.y, damage); // take
1129         v.z = 0;
1130         return v;
1131 }
1132 #endif
1133
1134 string getcurrentmod()
1135 {
1136         float n;
1137         string m;
1138         m = cvar_string("fs_gamedir");
1139         n = tokenize_console(m);
1140         if(n == 0)
1141                 return "data";
1142         else
1143                 return argv(n - 1);
1144 }
1145
1146 float matchacl(string acl, string str)
1147 {
1148         string t, s;
1149         float r, d;
1150         r = 0;
1151         while(acl)
1152         {
1153                 t = car(acl); acl = cdr(acl);
1154
1155                 d = 1;
1156                 if(substring(t, 0, 1) == "-")
1157                 {
1158                         d = -1;
1159                         t = substring(t, 1, strlen(t) - 1);
1160                 }
1161                 else if(substring(t, 0, 1) == "+")
1162                         t = substring(t, 1, strlen(t) - 1);
1163
1164                 if(substring(t, -1, 1) == "*")
1165                 {
1166                         t = substring(t, 0, strlen(t) - 1);
1167                         s = substring(str, 0, strlen(t));
1168                 }
1169                 else
1170                         s = str;
1171
1172                 if(s == t)
1173                 {
1174                         r = d;
1175                 }
1176         }
1177         return r;
1178 }
1179
1180 string get_model_datafilename(string m, float sk, string fil)
1181 {
1182         if(m)
1183                 m = strcat(m, "_");
1184         else
1185                 m = "models/player/*_";
1186         if(sk >= 0)
1187                 m = strcat(m, ftos(sk));
1188         else
1189                 m = strcat(m, "*");
1190         return strcat(m, ".", fil);
1191 }
1192
1193 float get_model_parameters(string m, float sk)
1194 {
1195         get_model_parameters_modelname = string_null;
1196         get_model_parameters_modelskin = -1;
1197         get_model_parameters_name = string_null;
1198         get_model_parameters_species = -1;
1199         get_model_parameters_sex = string_null;
1200         get_model_parameters_weight = -1;
1201         get_model_parameters_age = -1;
1202         get_model_parameters_desc = string_null;
1203         get_model_parameters_bone_upperbody = string_null;
1204         get_model_parameters_bone_weapon = string_null;
1205         for(int i = 0; i < MAX_AIM_BONES; ++i)
1206         {
1207                 get_model_parameters_bone_aim[i] = string_null;
1208                 get_model_parameters_bone_aimweight[i] = 0;
1209         }
1210         get_model_parameters_fixbone = 0;
1211
1212 #ifndef MENUQC
1213         MUTATOR_CALLHOOK(ClearModelParams);
1214 #endif
1215
1216         if (!m)
1217                 return 1;
1218
1219         if(substring(m, -9, 5) == "_lod1" || substring(m, -9, 5) == "_lod2")
1220                 m = strcat(substring(m, 0, -10), substring(m, -4, -1));
1221
1222         if(sk < 0)
1223         {
1224                 if(substring(m, -4, -1) != ".txt")
1225                         return 0;
1226                 if(substring(m, -6, 1) != "_")
1227                         return 0;
1228                 sk = stof(substring(m, -5, 1));
1229                 m = substring(m, 0, -7);
1230         }
1231
1232         string fn = get_model_datafilename(m, sk, "txt");
1233         int fh = fopen(fn, FILE_READ);
1234         if(fh < 0)
1235         {
1236                 sk = 0;
1237                 fn = get_model_datafilename(m, sk, "txt");
1238                 fh = fopen(fn, FILE_READ);
1239                 if(fh < 0)
1240                         return 0;
1241         }
1242
1243         get_model_parameters_modelname = m;
1244         get_model_parameters_modelskin = sk;
1245         string s, c;
1246         while((s = fgets(fh)))
1247         {
1248                 if(s == "")
1249                         break; // next lines will be description
1250                 c = car(s);
1251                 s = cdr(s);
1252                 if(c == "name")
1253                         get_model_parameters_name = s;
1254                 if(c == "species")
1255                         switch(s)
1256                         {
1257                                 case "human":       get_model_parameters_species = SPECIES_HUMAN;       break;
1258                                 case "alien":       get_model_parameters_species = SPECIES_ALIEN;       break;
1259                                 case "robot_shiny": get_model_parameters_species = SPECIES_ROBOT_SHINY; break;
1260                                 case "robot_rusty": get_model_parameters_species = SPECIES_ROBOT_RUSTY; break;
1261                                 case "robot_solid": get_model_parameters_species = SPECIES_ROBOT_SOLID; break;
1262                                 case "animal":      get_model_parameters_species = SPECIES_ANIMAL;      break;
1263                                 case "reserved":    get_model_parameters_species = SPECIES_RESERVED;    break;
1264                         }
1265                 if(c == "sex")
1266                         get_model_parameters_sex = s;
1267                 if(c == "weight")
1268                         get_model_parameters_weight = stof(s);
1269                 if(c == "age")
1270                         get_model_parameters_age = stof(s);
1271                 if(c == "description")
1272                         get_model_parameters_description = s;
1273                 if(c == "bone_upperbody")
1274                         get_model_parameters_bone_upperbody = s;
1275                 if(c == "bone_weapon")
1276                         get_model_parameters_bone_weapon = s;
1277         #ifndef MENUQC
1278                 MUTATOR_CALLHOOK(GetModelParams, c, s);
1279         #endif
1280                 for(int i = 0; i < MAX_AIM_BONES; ++i)
1281                         if(c == strcat("bone_aim", ftos(i)))
1282                         {
1283                                 get_model_parameters_bone_aimweight[i] = stof(car(s));
1284                                 get_model_parameters_bone_aim[i] = cdr(s);
1285                         }
1286                 if(c == "fixbone")
1287                         get_model_parameters_fixbone = stof(s);
1288         }
1289
1290         while((s = fgets(fh)))
1291         {
1292                 if(get_model_parameters_desc)
1293                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
1294                 if(s != "")
1295                         get_model_parameters_desc = strcat(get_model_parameters_desc, s);
1296         }
1297
1298         fclose(fh);
1299
1300         return 1;
1301 }
1302
1303 // x-encoding (encoding as zero length invisible string)
1304 const string XENCODE_2  = "xX";
1305 const string XENCODE_22 = "0123456789abcdefABCDEF";
1306 string xencode(int f)
1307 {
1308         float a, b, c, d;
1309         d = f % 22; f = floor(f / 22);
1310         c = f % 22; f = floor(f / 22);
1311         b = f % 22; f = floor(f / 22);
1312         a = f %  2; // f = floor(f /  2);
1313         return strcat(
1314                 "^",
1315                 substring(XENCODE_2,  a, 1),
1316                 substring(XENCODE_22, b, 1),
1317                 substring(XENCODE_22, c, 1),
1318                 substring(XENCODE_22, d, 1)
1319         );
1320 }
1321 float xdecode(string s)
1322 {
1323         float a, b, c, d;
1324         if(substring(s, 0, 1) != "^")
1325                 return -1;
1326         if(strlen(s) < 5)
1327                 return -1;
1328         a = strstrofs(XENCODE_2,  substring(s, 1, 1), 0);
1329         b = strstrofs(XENCODE_22, substring(s, 2, 1), 0);
1330         c = strstrofs(XENCODE_22, substring(s, 3, 1), 0);
1331         d = strstrofs(XENCODE_22, substring(s, 4, 1), 0);
1332         if(a < 0 || b < 0 || c < 0 || d < 0)
1333                 return -1;
1334         return ((a * 22 + b) * 22 + c) * 22 + d;
1335 }
1336
1337 /*
1338 string strlimitedlen(string input, string truncation, float strip_colors, float limit)
1339 {
1340         if(strlen((strip_colors ? strdecolorize(input) : input)) <= limit)
1341                 return input;
1342         else
1343                 return strcat(substring(input, 0, (strlen(input) - strlen(truncation))), truncation);
1344 }*/
1345
1346 float shutdown_running;
1347 #ifdef SVQC
1348 void SV_Shutdown()
1349 #endif
1350 #ifdef CSQC
1351 void CSQC_Shutdown()
1352 #endif
1353 #ifdef MENUQC
1354 void m_shutdown()
1355 #endif
1356 {
1357         if(shutdown_running)
1358         {
1359                 LOG_INFO("Recursive shutdown detected! Only restoring cvars...\n");
1360         }
1361         else
1362         {
1363                 shutdown_running = 1;
1364                 Shutdown();
1365                 shutdownhooks();
1366         }
1367         cvar_settemp_restore(); // this must be done LAST, but in any case
1368 }
1369
1370 #ifndef MENUQC
1371 .float skeleton_bones_index;
1372 void Skeleton_SetBones(entity e)
1373 {
1374         // set skeleton_bones to the total number of bones on the model
1375         if(e.skeleton_bones_index == e.modelindex)
1376                 return; // same model, nothing to update
1377
1378         float skelindex;
1379         skelindex = skel_create(e.modelindex);
1380         e.skeleton_bones = skel_get_numbones(skelindex);
1381         skel_delete(skelindex);
1382         e.skeleton_bones_index = e.modelindex;
1383 }
1384 #endif
1385
1386 string to_execute_next_frame;
1387 void execute_next_frame()
1388 {
1389         if(to_execute_next_frame)
1390         {
1391                 localcmd("\n", to_execute_next_frame, "\n");
1392                 strunzone(to_execute_next_frame);
1393                 to_execute_next_frame = string_null;
1394         }
1395 }
1396 void queue_to_execute_next_frame(string s)
1397 {
1398         if(to_execute_next_frame)
1399         {
1400                 s = strcat(s, "\n", to_execute_next_frame);
1401                 strunzone(to_execute_next_frame);
1402         }
1403         to_execute_next_frame = strzone(s);
1404 }
1405
1406 .float FindConnectedComponent_processing;
1407 void FindConnectedComponent(entity e, .entity fld, findNextEntityNearFunction_t nxt, isConnectedFunction_t iscon, entity pass)
1408 {
1409         entity queue_start, queue_end;
1410
1411         // we build a queue of to-be-processed entities.
1412         // queue_start is the next entity to be checked for neighbors
1413         // queue_end is the last entity added
1414
1415         if(e.FindConnectedComponent_processing)
1416                 error("recursion or broken cleanup");
1417
1418         // start with a 1-element queue
1419         queue_start = queue_end = e;
1420         queue_end.(fld) = world;
1421         queue_end.FindConnectedComponent_processing = 1;
1422
1423         // for each queued item:
1424         for (; queue_start; queue_start = queue_start.(fld))
1425         {
1426                 // find all neighbors of queue_start
1427                 entity t;
1428                 for(t = world; (t = nxt(t, queue_start, pass)); )
1429                 {
1430                         if(t.FindConnectedComponent_processing)
1431                                 continue;
1432                         if(iscon(t, queue_start, pass))
1433                         {
1434                                 // it is connected? ADD IT. It will look for neighbors soon too.
1435                                 queue_end.(fld) = t;
1436                                 queue_end = t;
1437                                 queue_end.(fld) = world;
1438                                 queue_end.FindConnectedComponent_processing = 1;
1439                         }
1440                 }
1441         }
1442
1443         // unmark
1444         for (queue_start = e; queue_start; queue_start = queue_start.(fld))
1445                 queue_start.FindConnectedComponent_processing = 0;
1446 }
1447
1448 #ifndef MENUQC
1449 vector animfixfps(entity e, vector a, vector b)
1450 {
1451         // multi-frame anim: keep as-is
1452         if(a.y == 1)
1453         {
1454                 float dur = frameduration(e.modelindex, a.x);
1455                 if (dur <= 0 && b.y)
1456                 {
1457                         a = b;
1458                         dur = frameduration(e.modelindex, a.x);
1459                 }
1460                 if (dur > 0)
1461                         a.z = 1.0 / dur;
1462         }
1463         return a;
1464 }
1465 #endif
1466
1467 #ifdef SVQC
1468 void dedicated_print(string input) // print(), but only print if the server is not local
1469 {
1470         if(server_is_dedicated) { LOG_INFO(input); }
1471 }
1472 #endif
1473
1474 #ifndef MENUQC
1475 float Announcer_PickNumber(float type, float num)
1476 {
1477         switch(type)
1478         {
1479                 case CNT_GAMESTART:
1480                 {
1481                         switch(num)
1482                         {
1483                                 case 10: return ANNCE_NUM_GAMESTART_10;
1484                                 case 9:  return ANNCE_NUM_GAMESTART_9;
1485                                 case 8:  return ANNCE_NUM_GAMESTART_8;
1486                                 case 7:  return ANNCE_NUM_GAMESTART_7;
1487                                 case 6:  return ANNCE_NUM_GAMESTART_6;
1488                                 case 5:  return ANNCE_NUM_GAMESTART_5;
1489                                 case 4:  return ANNCE_NUM_GAMESTART_4;
1490                                 case 3:  return ANNCE_NUM_GAMESTART_3;
1491                                 case 2:  return ANNCE_NUM_GAMESTART_2;
1492                                 case 1:  return ANNCE_NUM_GAMESTART_1;
1493                         }
1494                         break;
1495                 }
1496                 case CNT_IDLE:
1497                 {
1498                         switch(num)
1499                         {
1500                                 case 10: return ANNCE_NUM_IDLE_10;
1501                                 case 9:  return ANNCE_NUM_IDLE_9;
1502                                 case 8:  return ANNCE_NUM_IDLE_8;
1503                                 case 7:  return ANNCE_NUM_IDLE_7;
1504                                 case 6:  return ANNCE_NUM_IDLE_6;
1505                                 case 5:  return ANNCE_NUM_IDLE_5;
1506                                 case 4:  return ANNCE_NUM_IDLE_4;
1507                                 case 3:  return ANNCE_NUM_IDLE_3;
1508                                 case 2:  return ANNCE_NUM_IDLE_2;
1509                                 case 1:  return ANNCE_NUM_IDLE_1;
1510                         }
1511                         break;
1512                 }
1513                 case CNT_KILL:
1514                 {
1515                         switch(num)
1516                         {
1517                                 case 10: return ANNCE_NUM_KILL_10;
1518                                 case 9:  return ANNCE_NUM_KILL_9;
1519                                 case 8:  return ANNCE_NUM_KILL_8;
1520                                 case 7:  return ANNCE_NUM_KILL_7;
1521                                 case 6:  return ANNCE_NUM_KILL_6;
1522                                 case 5:  return ANNCE_NUM_KILL_5;
1523                                 case 4:  return ANNCE_NUM_KILL_4;
1524                                 case 3:  return ANNCE_NUM_KILL_3;
1525                                 case 2:  return ANNCE_NUM_KILL_2;
1526                                 case 1:  return ANNCE_NUM_KILL_1;
1527                         }
1528                         break;
1529                 }
1530                 case CNT_RESPAWN:
1531                 {
1532                         switch(num)
1533                         {
1534                                 case 10: return ANNCE_NUM_RESPAWN_10;
1535                                 case 9:  return ANNCE_NUM_RESPAWN_9;
1536                                 case 8:  return ANNCE_NUM_RESPAWN_8;
1537                                 case 7:  return ANNCE_NUM_RESPAWN_7;
1538                                 case 6:  return ANNCE_NUM_RESPAWN_6;
1539                                 case 5:  return ANNCE_NUM_RESPAWN_5;
1540                                 case 4:  return ANNCE_NUM_RESPAWN_4;
1541                                 case 3:  return ANNCE_NUM_RESPAWN_3;
1542                                 case 2:  return ANNCE_NUM_RESPAWN_2;
1543                                 case 1:  return ANNCE_NUM_RESPAWN_1;
1544                         }
1545                         break;
1546                 }
1547                 case CNT_ROUNDSTART:
1548                 {
1549                         switch(num)
1550                         {
1551                                 case 10: return ANNCE_NUM_ROUNDSTART_10;
1552                                 case 9:  return ANNCE_NUM_ROUNDSTART_9;
1553                                 case 8:  return ANNCE_NUM_ROUNDSTART_8;
1554                                 case 7:  return ANNCE_NUM_ROUNDSTART_7;
1555                                 case 6:  return ANNCE_NUM_ROUNDSTART_6;
1556                                 case 5:  return ANNCE_NUM_ROUNDSTART_5;
1557                                 case 4:  return ANNCE_NUM_ROUNDSTART_4;
1558                                 case 3:  return ANNCE_NUM_ROUNDSTART_3;
1559                                 case 2:  return ANNCE_NUM_ROUNDSTART_2;
1560                                 case 1:  return ANNCE_NUM_ROUNDSTART_1;
1561                         }
1562                         break;
1563                 }
1564                 default:
1565                 {
1566                         switch(num)
1567                         {
1568                                 case 10: return ANNCE_NUM_10;
1569                                 case 9:  return ANNCE_NUM_9;
1570                                 case 8:  return ANNCE_NUM_8;
1571                                 case 7:  return ANNCE_NUM_7;
1572                                 case 6:  return ANNCE_NUM_6;
1573                                 case 5:  return ANNCE_NUM_5;
1574                                 case 4:  return ANNCE_NUM_4;
1575                                 case 3:  return ANNCE_NUM_3;
1576                                 case 2:  return ANNCE_NUM_2;
1577                                 case 1:  return ANNCE_NUM_1;
1578                         }
1579                         break;
1580                 }
1581         }
1582         return NOTIF_ABORT; // abort sending if none of these numbers were right
1583 }
1584 #endif
1585
1586 #ifndef MENUQC
1587 int Mod_Q1BSP_SuperContentsFromNativeContents(int nativecontents)
1588 {
1589         switch(nativecontents)
1590         {
1591                 case CONTENT_EMPTY:
1592                         return 0;
1593                 case CONTENT_SOLID:
1594                         return DPCONTENTS_SOLID | DPCONTENTS_OPAQUE;
1595                 case CONTENT_WATER:
1596                         return DPCONTENTS_WATER;
1597                 case CONTENT_SLIME:
1598                         return DPCONTENTS_SLIME;
1599                 case CONTENT_LAVA:
1600                         return DPCONTENTS_LAVA | DPCONTENTS_NODROP;
1601                 case CONTENT_SKY:
1602                         return DPCONTENTS_SKY | DPCONTENTS_NODROP | DPCONTENTS_OPAQUE; // to match behaviour of Q3 maps, let sky count as opaque
1603         }
1604         return 0;
1605 }
1606
1607 int Mod_Q1BSP_NativeContentsFromSuperContents(int supercontents)
1608 {
1609         if(supercontents & (DPCONTENTS_SOLID | DPCONTENTS_BODY))
1610                 return CONTENT_SOLID;
1611         if(supercontents & DPCONTENTS_SKY)
1612                 return CONTENT_SKY;
1613         if(supercontents & DPCONTENTS_LAVA)
1614                 return CONTENT_LAVA;
1615         if(supercontents & DPCONTENTS_SLIME)
1616                 return CONTENT_SLIME;
1617         if(supercontents & DPCONTENTS_WATER)
1618                 return CONTENT_WATER;
1619         return CONTENT_EMPTY;
1620 }
1621 #endif