qcsrc/common/util.qc

   1 string wordwrap_buffer;
   2
   3 void wordwrap_buffer_put(string s)
   4 {
   5         wordwrap_buffer = strcat(wordwrap_buffer, s);
   6 }
   7
   8 string wordwrap(string s, float l)
   9 {
  10         string r;
  11         wordwrap_buffer = "";
  12         wordwrap_cb(s, l, wordwrap_buffer_put);
  13         r = wordwrap_buffer;
  14         wordwrap_buffer = "";
  15         return r;
  16 }
  17
  18 #ifndef MENUQC
  19 #ifndef CSQC
  20 void wordwrap_buffer_sprint(string s)
  21 {
  22         wordwrap_buffer = strcat(wordwrap_buffer, s);
  23         if(s == "\n")
  24         {
  25                 sprint(self, wordwrap_buffer);
  26                 wordwrap_buffer = "";
  27         }
  28 }
  29
  30 void wordwrap_sprint(string s, float l)
  31 {
  32         wordwrap_buffer = "";
  33         wordwrap_cb(s, l, wordwrap_buffer_sprint);
  34         if(wordwrap_buffer != "")
  35                 sprint(self, strcat(wordwrap_buffer, "\n"));
  36         wordwrap_buffer = "";
  37         return;
  38 }
  39 #endif
  40 #endif
  41
  42 string unescape(string in)
  43 {
  44         float i, len;
  45         string str, s;
  46
  47         // but it doesn't seem to be necessary in my tests at least
  48         in = strzone(in);
  49
  50         len = strlen(in);
  51         str = "";
  52         for(i = 0; i < len; ++i)
  53         {
  54                 s = substring(in, i, 1);
  55                 if(s == "\\")
  56                 {
  57                         s = substring(in, i+1, 1);
  58                         if(s == "n")
  59                                 str = strcat(str, "\n");
  60                         else if(s == "\\")
  61                                 str = strcat(str, "\\");
  62                         else
  63                                 str = strcat(str, substring(in, i, 2));
  64                         ++i;
  65                 } else
  66                         str = strcat(str, s);
  67         }
  68
  69         strunzone(in);
  70         return str;
  71 }
  72
  73 void wordwrap_cb(string s, float l, void(string) callback)
  74 {
  75         string c;
  76         float lleft, i, j, wlen;
  77
  78         s = strzone(s);
  79         lleft = l;
  80         for (i = 0;i < strlen(s);++i)
  81         {
  82                 if (substring(s, i, 2) == "\\n")
  83                 {
  84                         callback("\n");
  85                         lleft = l;
  86                         ++i;
  87                 }
  88                 else if (substring(s, i, 1) == "\n")
  89                 {
  90                         callback("\n");
  91                         lleft = l;
  92                 }
  93                 else if (substring(s, i, 1) == " ")
  94                 {
  95                         if (lleft > 0)
  96                         {
  97                                 callback(" ");
  98                                 lleft = lleft - 1;
  99                         }
 100                 }
 101                 else
 102                 {
 103                         for (j = i+1;j < strlen(s);++j)
 104                                 //    ^^ this skips over the first character of a word, which
 105                                 //       is ALWAYS part of the word
 106                                 //       this is safe since if i+1 == strlen(s), i will become
 107                                 //       strlen(s)-1 at the end of this block and the function
 108                                 //       will terminate. A space can't be the first character we
 109                                 //       read here, and neither can a \n be the start, since these
 110                                 //       two cases have been handled above.
 111                         {
 112                                 c = substring(s, j, 1);
 113                                 if (c == " ")
 114                                         break;
 115                                 if (c == "\\")
 116                                         break;
 117                                 if (c == "\n")
 118                                         break;
 119                                 // we need to keep this tempstring alive even if substring is
 120                                 // called repeatedly, so call strcat even though we're not
 121                                 // doing anything
 122                                 callback("");
 123                         }
 124                         wlen = j - i;
 125                         if (lleft < wlen)
 126                         {
 127                                 callback("\n");
 128                                 lleft = l;
 129                         }
 130                         callback(substring(s, i, wlen));
 131                         lleft = lleft - wlen;
 132                         i = j - 1;
 133                 }
 134         }
 135         strunzone(s);
 136 }
 137
 138 float dist_point_line(vector p, vector l0, vector ldir)
 139 {
 140         ldir = normalize(ldir);
 141
 142         // remove the component in line direction
 143         p = p - (p * ldir) * ldir;
 144
 145         // vlen of the remaining vector
 146         return vlen(p);
 147 }
 148
 149 void depthfirst(entity start, .entity up, .entity downleft, .entity right, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
 150 {
 151         entity e;
 152         e = start;
 153         funcPre(pass, e);
 154         while(e.downleft)
 155         {
 156                 e = e.downleft;
 157                 funcPre(pass, e);
 158         }
 159         funcPost(pass, e);
 160         while(e != start)
 161         {
 162                 if(e.right)
 163                 {
 164                         e = e.right;
 165                         funcPre(pass, e);
 166                         while(e.downleft)
 167                         {
 168                                 e = e.downleft;
 169                                 funcPre(pass, e);
 170                         }
 171                 }
 172                 else
 173                         e = e.up;
 174                 funcPost(pass, e);
 175         }
 176 }
 177
 178 float median(float a, float b, float c)
 179 {
 180         if(a < c)
 181                 return bound(a, b, c);
 182         return bound(c, b, a);
 183 }
 184
 185 // converts a number to a string with the indicated number of decimals
 186 // works for up to 10 decimals!
 187 string ftos_decimals(float number, float decimals)
 188 {
 189         // we have sprintf...
 190         return sprintf("%.*f", decimals, number);
 191 }
 192
 193 float time;
 194 vector colormapPaletteColor(float c, float isPants)
 195 {
 196         switch(c)
 197         {
 198                 case  0: return '0.800000 0.800000 0.800000';
 199                 case  1: return '0.600000 0.400000 0.000000';
 200                 case  2: return '0.000000 1.000000 0.501961';
 201                 case  3: return '0.000000 1.000000 0.000000';
 202                 case  4: return '1.000000 0.000000 0.000000';
 203                 case  5: return '0.000000 0.658824 1.000000';
 204                 case  6: return '0.000000 1.000000 1.000000';
 205                 case  7: return '0.501961 1.000000 0.000000';
 206                 case  8: return '0.501961 0.000000 1.000000';
 207                 case  9: return '1.000000 0.000000 1.000000';
 208                 case 10: return '1.000000 0.000000 0.501961';
 209                 case 11: return '0.600000 0.600000 0.600000';
 210                 case 12: return '1.000000 1.000000 0.000000';
 211                 case 13: return '0.000000 0.313725 1.000000';
 212                 case 14: return '1.000000 0.501961 0.000000';
 213                 case 15:
 214                         if(isPants)
 215                                 return
 216                                           '1 0 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 0.0000000000))
 217                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 2.0943951024))
 218                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 2.7182818285 + 4.1887902048));
 219                         else
 220                                 return
 221                                           '1 0 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 5.2359877560))
 222                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 3.1415926536))
 223                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 3.1415926536 + 1.0471975512));
 224                 default: return '0.000 0.000 0.000';
 225         }
 226 }
 227
 228 // unzone the string, and return it as tempstring. Safe to be called on string_null
 229 string fstrunzone(string s)
 230 {
 231         string sc;
 232         if not(s)
 233                 return s;
 234         sc = strcat(s, "");
 235         strunzone(s);
 236         return sc;
 237 }
 238
 239 float fexists(string f)
 240 {
 241     float fh;
 242     fh = fopen(f, FILE_READ);
 243     if (fh < 0)
 244         return FALSE;
 245     fclose(fh);
 246     return TRUE;
 247 }
 248
 249 // Databases (hash tables)
 250 #define DB_BUCKETS 8192
 251 void db_save(float db, string pFilename)
 252 {
 253         float fh, i, n;
 254         fh = fopen(pFilename, FILE_WRITE);
 255         if(fh < 0)
 256         {
 257                 print(strcat("^1Can't write DB to ", pFilename));
 258                 return;
 259         }
 260         n = buf_getsize(db);
 261         fputs(fh, strcat(ftos(DB_BUCKETS), "\n"));
 262         for(i = 0; i < n; ++i)
 263                 fputs(fh, strcat(bufstr_get(db, i), "\n"));
 264         fclose(fh);
 265 }
 266
 267 float db_create()
 268 {
 269         return buf_create();
 270 }
 271
 272 float db_load(string pFilename)
 273 {
 274         float db, fh, i, j, n;
 275         string l;
 276         db = buf_create();
 277         if(db < 0)
 278                 return -1;
 279         fh = fopen(pFilename, FILE_READ);
 280         if(fh < 0)
 281                 return db;
 282         l = fgets(fh);
 283         if(stof(l) == DB_BUCKETS)
 284         {
 285                 i = 0;
 286                 while((l = fgets(fh)))
 287                 {
 288                         if(l != "")
 289                                 bufstr_set(db, i, l);
 290                         ++i;
 291                 }
 292         }
 293         else
 294         {
 295                 // different count of buckets, or a dump?
 296                 // need to reorganize the database then (SLOW)
 297                 //
 298                 // note: we also parse the first line (l) in case the DB file is
 299                 // missing the bucket count
 300                 do
 301                 {
 302                         n = tokenizebyseparator(l, "\\");
 303                         for(j = 2; j < n; j += 2)
 304                                 db_put(db, argv(j-1), uri_unescape(argv(j)));
 305                 }
 306                 while((l = fgets(fh)));
 307         }
 308         fclose(fh);
 309         return db;
 310 }
 311
 312 void db_dump(float db, string pFilename)
 313 {
 314         float fh, i, j, n, m;
 315         fh = fopen(pFilename, FILE_WRITE);
 316         if(fh < 0)
 317                 error(strcat("Can't dump DB to ", pFilename));
 318         n = buf_getsize(db);
 319         fputs(fh, "0\n");
 320         for(i = 0; i < n; ++i)
 321         {
 322                 m = tokenizebyseparator(bufstr_get(db, i), "\\");
 323                 for(j = 2; j < m; j += 2)
 324                         fputs(fh, strcat("\\", argv(j-1), "\\", argv(j), "\n"));
 325         }
 326         fclose(fh);
 327 }
 328
 329 void db_close(float db)
 330 {
 331         buf_del(db);
 332 }
 333
 334 string db_get(float db, string pKey)
 335 {
 336         float h;
 337         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 338         return uri_unescape(infoget(bufstr_get(db, h), pKey));
 339 }
 340
 341 void db_put(float db, string pKey, string pValue)
 342 {
 343         float h;
 344         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 345         bufstr_set(db, h, infoadd(bufstr_get(db, h), pKey, uri_escape(pValue)));
 346 }
 347
 348 void db_test()
 349 {
 350         float db, i;
 351         print("LOAD...\n");
 352         db = db_load("foo.db");
 353         print("LOADED. FILL...\n");
 354         for(i = 0; i < DB_BUCKETS; ++i)
 355                 db_put(db, ftos(random()), "X");
 356         print("FILLED. SAVE...\n");
 357         db_save(db, "foo.db");
 358         print("SAVED. CLOSE...\n");
 359         db_close(db);
 360         print("CLOSED.\n");
 361 }
 362
 363 // Multiline text file buffers
 364 float buf_load(string pFilename)
 365 {
 366         float buf, fh, i;
 367         string l;
 368         buf = buf_create();
 369         if(buf < 0)
 370                 return -1;
 371         fh = fopen(pFilename, FILE_READ);
 372         if(fh < 0)
 373         {
 374                 buf_del(buf);
 375                 return -1;
 376         }
 377         i = 0;
 378         while((l = fgets(fh)))
 379         {
 380                 bufstr_set(buf, i, l);
 381                 ++i;
 382         }
 383         fclose(fh);
 384         return buf;
 385 }
 386
 387 void buf_save(float buf, string pFilename)
 388 {
 389         float fh, i, n;
 390         fh = fopen(pFilename, FILE_WRITE);
 391         if(fh < 0)
 392                 error(strcat("Can't write buf to ", pFilename));
 393         n = buf_getsize(buf);
 394         for(i = 0; i < n; ++i)
 395                 fputs(fh, strcat(bufstr_get(buf, i), "\n"));
 396         fclose(fh);
 397 }
 398
 399 string GametypeNameFromType(float g)
 400 {
 401         if      (g == GAME_DEATHMATCH) return "dm";
 402         else if (g == GAME_TEAM_DEATHMATCH) return "tdm";
 403         else if (g == GAME_DOMINATION) return "dom";
 404         else if (g == GAME_CTF) return "ctf";
 405         else if (g == GAME_RUNEMATCH) return "rune";
 406         else if (g == GAME_LMS) return "lms";
 407         else if (g == GAME_ARENA) return "arena";
 408         else if (g == GAME_CA) return "ca";
 409         else if (g == GAME_KEYHUNT) return "kh";
 410         else if (g == GAME_ONSLAUGHT) return "ons";
 411         else if (g == GAME_ASSAULT) return "as";
 412         else if (g == GAME_RACE) return "rc";
 413         else if (g == GAME_NEXBALL) return "nexball";
 414         else if (g == GAME_CTS) return "cts";
 415         else if (g == GAME_FREEZETAG) return "freezetag";
 416         else if (g == GAME_KEEPAWAY) return "ka";
 417         return "dm";
 418 }
 419
 420 string mmsss(float tenths)
 421 {
 422         float minutes;
 423         string s;
 424         tenths = floor(tenths + 0.5);
 425         minutes = floor(tenths / 600);
 426         tenths -= minutes * 600;
 427         s = ftos(1000 + tenths);
 428         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 1));
 429 }
 430
 431 string mmssss(float hundredths)
 432 {
 433         float minutes;
 434         string s;
 435         hundredths = floor(hundredths + 0.5);
 436         minutes = floor(hundredths / 6000);
 437         hundredths -= minutes * 6000;
 438         s = ftos(10000 + hundredths);
 439         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 2));
 440 }
 441
 442 string ScoreString(float pFlags, float pValue)
 443 {
 444         string valstr;
 445         float l;
 446
 447         pValue = floor(pValue + 0.5); // round
 448
 449         if((pValue == 0) && (pFlags & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME)))
 450                 valstr = "";
 451         else if(pFlags & SFL_RANK)
 452         {
 453                 valstr = ftos(pValue);
 454                 l = strlen(valstr);
 455                 if((l >= 2) && (substring(valstr, l - 2, 1) == "1"))
 456                         valstr = strcat(valstr, "th");
 457                 else if(substring(valstr, l - 1, 1) == "1")
 458                         valstr = strcat(valstr, "st");
 459                 else if(substring(valstr, l - 1, 1) == "2")
 460                         valstr = strcat(valstr, "nd");
 461                 else if(substring(valstr, l - 1, 1) == "3")
 462                         valstr = strcat(valstr, "rd");
 463                 else
 464                         valstr = strcat(valstr, "th");
 465         }
 466         else if(pFlags & SFL_TIME)
 467                 valstr = TIME_ENCODED_TOSTRING(pValue);
 468         else
 469                 valstr = ftos(pValue);
 470
 471         return valstr;
 472 }
 473
 474 vector cross(vector a, vector b)
 475 {
 476         return
 477                 '1 0 0' * (a_y * b_z - a_z * b_y)
 478         +       '0 1 0' * (a_z * b_x - a_x * b_z)
 479         +       '0 0 1' * (a_x * b_y - a_y * b_x);
 480 }
 481
 482 // compressed vector format:
 483 // like MD3, just even shorter
 484 //   4 bit pitch (16 angles), 0 is -90, 8 is 0, 16 would be 90
 485 //   5 bit yaw (32 angles), 0=0, 8=90, 16=180, 24=270
 486 //   7 bit length (logarithmic encoding), 1/8 .. about 7844
 487 //     length = 2^(length_encoded/8) / 8
 488 // if pitch is 90, yaw does nothing and therefore indicates the sign (yaw is then either 11111 or 11110); 11111 is pointing DOWN
 489 // thus, valid values are from 0000.11110.0000000 to 1111.11111.1111111
 490 // the special value 0 indicates the zero vector
 491
 492 float lengthLogTable[128];
 493
 494 float invertLengthLog(float x)
 495 {
 496         float l, r, m, lerr, rerr;
 497
 498         if(x >= lengthLogTable[127])
 499                 return 127;
 500         if(x <= lengthLogTable[0])
 501                 return 0;
 502
 503         l = 0;
 504         r = 127;
 505
 506         while(r - l > 1)
 507         {
 508                 m = floor((l + r) / 2);
 509                 if(lengthLogTable[m] < x)
 510                         l = m;
 511                 else
 512                         r = m;
 513         }
 514
 515         // now: r is >=, l is <
 516         lerr = (x - lengthLogTable[l]);
 517         rerr = (lengthLogTable[r] - x);
 518         if(lerr < rerr)
 519                 return l;
 520         return r;
 521 }
 522
 523 vector decompressShortVector(float data)
 524 {
 525         vector out;
 526         float pitch, yaw, len;
 527         if(data == 0)
 528                 return '0 0 0';
 529         pitch = (data & 0xF000) / 0x1000;
 530         yaw =   (data & 0x0F80) / 0x80;
 531         len =   (data & 0x007F);
 532
 533         //print("\ndecompress: pitch ", ftos(pitch)); print("yaw ", ftos(yaw)); print("len ", ftos(len), "\n");
 534
 535         if(pitch == 0)
 536         {
 537                 out_x = 0;
 538                 out_y = 0;
 539                 if(yaw == 31)
 540                         out_z = -1;
 541                 else
 542                         out_z = +1;
 543         }
 544         else
 545         {
 546                 yaw   = .19634954084936207740 * yaw;
 547                 pitch = .19634954084936207740 * pitch - 1.57079632679489661922;
 548                 out_x = cos(yaw) *  cos(pitch);
 549                 out_y = sin(yaw) *  cos(pitch);
 550                 out_z =            -sin(pitch);
 551         }
 552
 553         //print("decompressed: ", vtos(out), "\n");
 554
 555         return out * lengthLogTable[len];
 556 }
 557
 558 float compressShortVector(vector vec)
 559 {
 560         vector ang;
 561         float pitch, yaw, len;
 562         if(vlen(vec) == 0)
 563                 return 0;
 564         //print("compress: ", vtos(vec), "\n");
 565         ang = vectoangles(vec);
 566         ang_x = -ang_x;
 567         if(ang_x < -90)
 568                 ang_x += 360;
 569         if(ang_x < -90 && ang_x > +90)
 570                 error("BOGUS vectoangles");
 571         //print("angles: ", vtos(ang), "\n");
 572
 573         pitch = floor(0.5 + (ang_x + 90) * 16 / 180) & 15; // -90..90 to 0..14
 574         if(pitch == 0)
 575         {
 576                 if(vec_z < 0)
 577                         yaw = 31;
 578                 else
 579                         yaw = 30;
 580         }
 581         else
 582                 yaw = floor(0.5 + ang_y * 32 / 360)          & 31; // 0..360 to 0..32
 583         len = invertLengthLog(vlen(vec));
 584
 585         //print("compressed: pitch ", ftos(pitch)); print("yaw ", ftos(yaw)); print("len ", ftos(len), "\n");
 586
 587         return (pitch * 0x1000) + (yaw * 0x80) + len;
 588 }
 589
 590 void compressShortVector_init()
 591 {
 592         float l, f, i;
 593         l = 1;
 594         f = pow(2, 1/8);
 595         for(i = 0; i < 128; ++i)
 596         {
 597                 lengthLogTable[i] = l;
 598                 l *= f;
 599         }
 600
 601         if(cvar("developer"))
 602         {
 603                 print("Verifying vector compression table...\n");
 604                 for(i = 0x0F00; i < 0xFFFF; ++i)
 605                         if(i != compressShortVector(decompressShortVector(i)))
 606                         {
 607                                 print("BROKEN vector compression: ", ftos(i));
 608                                 print(" -> ", vtos(decompressShortVector(i)));
 609                                 print(" -> ", ftos(compressShortVector(decompressShortVector(i))));
 610                                 print("\n");
 611                                 error("b0rk");
 612                         }
 613                 print("Done.\n");
 614         }
 615 }
 616
 617 #ifndef MENUQC
 618 float CheckWireframeBox(entity forent, vector v0, vector dvx, vector dvy, vector dvz)
 619 {
 620         traceline(v0, v0 + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 621         traceline(v0, v0 + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 622         traceline(v0, v0 + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 623         traceline(v0 + dvx, v0 + dvx + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 624         traceline(v0 + dvx, v0 + dvx + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 625         traceline(v0 + dvy, v0 + dvy + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 626         traceline(v0 + dvy, v0 + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 627         traceline(v0 + dvz, v0 + dvz + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 628         traceline(v0 + dvz, v0 + dvz + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 629         traceline(v0 + dvx + dvy, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 630         traceline(v0 + dvx + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 631         traceline(v0 + dvy + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 632         return 1;
 633 }
 634 #endif
 635
 636 string fixPriorityList(string order, float from, float to, float subtract, float complete)
 637 {
 638         string neworder;
 639         float i, n, w;
 640
 641         n = tokenize_console(order);
 642         neworder = "";
 643         for(i = 0; i < n; ++i)
 644         {
 645                 w = stof(argv(i));
 646                 if(w == floor(w))
 647                 {
 648                         if(w >= from && w <= to)
 649                                 neworder = strcat(neworder, ftos(w), " ");
 650                         else
 651                         {
 652                                 w -= subtract;
 653                                 if(w >= from && w <= to)
 654                                         neworder = strcat(neworder, ftos(w), " ");
 655                         }
 656                 }
 657         }
 658
 659         if(complete)
 660         {
 661                 n = tokenize_console(neworder);
 662                 for(w = to; w >= from; --w)
 663                 {
 664                         for(i = 0; i < n; ++i)
 665                                 if(stof(argv(i)) == w)
 666                                         break;
 667                         if(i == n) // not found
 668                                 neworder = strcat(neworder, ftos(w), " ");
 669                 }
 670         }
 671
 672         return substring(neworder, 0, strlen(neworder) - 1);
 673 }
 674
 675 string mapPriorityList(string order, string(string) mapfunc)
 676 {
 677         string neworder;
 678         float i, n;
 679
 680         n = tokenize_console(order);
 681         neworder = "";
 682         for(i = 0; i < n; ++i)
 683                 neworder = strcat(neworder, mapfunc(argv(i)), " ");
 684
 685         return substring(neworder, 0, strlen(neworder) - 1);
 686 }
 687
 688 string swapInPriorityList(string order, float i, float j)
 689 {
 690         string s;
 691         float w, n;
 692
 693         n = tokenize_console(order);
 694
 695         if(i >= 0 && i < n && j >= 0 && j < n && i != j)
 696         {
 697                 s = "";
 698                 for(w = 0; w < n; ++w)
 699                 {
 700                         if(w == i)
 701                                 s = strcat(s, argv(j), " ");
 702                         else if(w == j)
 703                                 s = strcat(s, argv(i), " ");
 704                         else
 705                                 s = strcat(s, argv(w), " ");
 706                 }
 707                 return substring(s, 0, strlen(s) - 1);
 708         }
 709
 710         return order;
 711 }
 712
 713 float cvar_value_issafe(string s)
 714 {
 715         if(strstrofs(s, "\"", 0) >= 0)
 716                 return 0;
 717         if(strstrofs(s, "\\", 0) >= 0)
 718                 return 0;
 719         if(strstrofs(s, ";", 0) >= 0)
 720                 return 0;
 721         if(strstrofs(s, "$", 0) >= 0)
 722                 return 0;
 723         if(strstrofs(s, "\r", 0) >= 0)
 724                 return 0;
 725         if(strstrofs(s, "\n", 0) >= 0)
 726                 return 0;
 727         return 1;
 728 }
 729
 730 #ifndef MENUQC
 731 void get_mi_min_max(float mode)
 732 {
 733         vector mi, ma;
 734
 735         if(mi_shortname)
 736                 strunzone(mi_shortname);
 737         mi_shortname = mapname;
 738         if(!strcasecmp(substring(mi_shortname, 0, 5), "maps/"))
 739                 mi_shortname = substring(mi_shortname, 5, strlen(mi_shortname) - 5);
 740         if(!strcasecmp(substring(mi_shortname, strlen(mi_shortname) - 4, 4), ".bsp"))
 741                 mi_shortname = substring(mi_shortname, 0, strlen(mi_shortname) - 4);
 742         mi_shortname = strzone(mi_shortname);
 743
 744 #ifdef CSQC
 745         mi = world.mins;
 746         ma = world.maxs;
 747 #else
 748         mi = world.absmin;
 749         ma = world.absmax;
 750 #endif
 751
 752         mi_min = mi;
 753         mi_max = ma;
 754         MapInfo_Get_ByName(mi_shortname, 0, 0);
 755         if(MapInfo_Map_mins_x < MapInfo_Map_maxs_x)
 756         {
 757                 mi_min = MapInfo_Map_mins;
 758                 mi_max = MapInfo_Map_maxs;
 759         }
 760         else
 761         {
 762                 // not specified
 763                 if(mode)
 764                 {
 765                         // be clever
 766                         tracebox('1 0 0' * mi_x,
 767                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 768                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 769                                          '1 0 0' * ma_x,
 770                                          MOVE_WORLDONLY,
 771                                          world);
 772                         if(!trace_startsolid)
 773                                 mi_min_x = trace_endpos_x;
 774
 775                         tracebox('0 1 0' * mi_y,
 776                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 777                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 778                                          '0 1 0' * ma_y,
 779                                          MOVE_WORLDONLY,
 780                                          world);
 781                         if(!trace_startsolid)
 782                                 mi_min_y = trace_endpos_y;
 783
 784                         tracebox('0 0 1' * mi_z,
 785                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 786                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 787                                          '0 0 1' * ma_z,
 788                                          MOVE_WORLDONLY,
 789                                          world);
 790                         if(!trace_startsolid)
 791                                 mi_min_z = trace_endpos_z;
 792
 793                         tracebox('1 0 0' * ma_x,
 794                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 795                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 796                                          '1 0 0' * mi_x,
 797                                          MOVE_WORLDONLY,
 798                                          world);
 799                         if(!trace_startsolid)
 800                                 mi_max_x = trace_endpos_x;
 801
 802                         tracebox('0 1 0' * ma_y,
 803                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 804                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 805                                          '0 1 0' * mi_y,
 806                                          MOVE_WORLDONLY,
 807                                          world);
 808                         if(!trace_startsolid)
 809                                 mi_max_y = trace_endpos_y;
 810
 811                         tracebox('0 0 1' * ma_z,
 812                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 813                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 814                                          '0 0 1' * mi_z,
 815                                          MOVE_WORLDONLY,
 816                                          world);
 817                         if(!trace_startsolid)
 818                                 mi_max_z = trace_endpos_z;
 819                 }
 820         }
 821 }
 822
 823 void get_mi_min_max_texcoords(float mode)
 824 {
 825         vector extend;
 826
 827         get_mi_min_max(mode);
 828
 829         mi_picmin = mi_min;
 830         mi_picmax = mi_max;
 831
 832         // extend mi_picmax to get a square aspect ratio
 833         // center the map in that area
 834         extend = mi_picmax - mi_picmin;
 835         if(extend_y > extend_x)
 836         {
 837                 mi_picmin_x -= (extend_y - extend_x) * 0.5;
 838                 mi_picmax_x += (extend_y - extend_x) * 0.5;
 839         }
 840         else
 841         {
 842                 mi_picmin_y -= (extend_x - extend_y) * 0.5;
 843                 mi_picmax_y += (extend_x - extend_y) * 0.5;
 844         }
 845
 846         // add another some percent
 847         extend = (mi_picmax - mi_picmin) * (1 / 64.0);
 848         mi_picmin -= extend;
 849         mi_picmax += extend;
 850
 851         // calculate the texcoords
 852         mi_pictexcoord0 = mi_pictexcoord1 = mi_pictexcoord2 = mi_pictexcoord3 = '0 0 0';
 853         // first the two corners of the origin
 854         mi_pictexcoord0_x = (mi_min_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 855         mi_pictexcoord0_y = (mi_min_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 856         mi_pictexcoord2_x = (mi_max_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 857         mi_pictexcoord2_y = (mi_max_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 858         // then the other corners
 859         mi_pictexcoord1_x = mi_pictexcoord0_x;
 860         mi_pictexcoord1_y = mi_pictexcoord2_y;
 861         mi_pictexcoord3_x = mi_pictexcoord2_x;
 862         mi_pictexcoord3_y = mi_pictexcoord0_y;
 863 }
 864 #endif
 865
 866 #ifdef CSQC
 867 void cvar_settemp(string pKey, string pValue)
 868 {
 869         error("cvar_settemp called from CSQC - use cvar_clientsettemp instead!");
 870 }
 871 void cvar_settemp_restore()
 872 {
 873         error("cvar_settemp_restore called from CSQC - use cvar_clientsettemp instead!");
 874 }
 875 #else
 876 void cvar_settemp(string pKey, string pValue)
 877 {
 878         float i;
 879         string settemp_var;
 880         if(cvar_string(pKey) == pValue)
 881                 return;
 882         i = cvar("settemp_idx");
 883         cvar_set("settemp_idx", ftos(i+1));
 884         settemp_var = strcat("_settemp_x", ftos(i));
 885 #ifdef MENUQC
 886         registercvar(settemp_var, "", 0);
 887 #else
 888         registercvar(settemp_var, "");
 889 #endif
 890         cvar_set("settemp_list", strcat("1 ", pKey, " ", settemp_var, " ", cvar_string("settemp_list")));
 891         cvar_set(settemp_var, cvar_string(pKey));
 892         cvar_set(pKey, pValue);
 893 }
 894
 895 void cvar_settemp_restore()
 896 {
 897         // undo what cvar_settemp did
 898         float n, i;
 899         n = tokenize_console(cvar_string("settemp_list"));
 900         for(i = 0; i < n - 3; i += 3)
 901                 cvar_set(argv(i + 1), cvar_string(argv(i + 2)));
 902         cvar_set("settemp_list", "0");
 903 }
 904 #endif
 905
 906 float almost_equals(float a, float b)
 907 {
 908         float eps;
 909         eps = (max(a, -a) + max(b, -b)) * 0.001;
 910         if(a - b < eps && b - a < eps)
 911                 return TRUE;
 912         return FALSE;
 913 }
 914
 915 float almost_in_bounds(float a, float b, float c)
 916 {
 917         float eps;
 918         eps = (max(a, -a) + max(c, -c)) * 0.001;
 919         return b == median(a - eps, b, c + eps);
 920 }
 921
 922 float power2of(float e)
 923 {
 924         return pow(2, e);
 925 }
 926 float log2of(float x)
 927 {
 928         // NOTE: generated code
 929         if(x > 2048)
 930                 if(x > 131072)
 931                         if(x > 1048576)
 932                                 if(x > 4194304)
 933                                         return 23;
 934                                 else
 935                                         if(x > 2097152)
 936                                                 return 22;
 937                                         else
 938                                                 return 21;
 939                         else
 940                                 if(x > 524288)
 941                                         return 20;
 942                                 else
 943                                         if(x > 262144)
 944                                                 return 19;
 945                                         else
 946                                                 return 18;
 947                 else
 948                         if(x > 16384)
 949                                 if(x > 65536)
 950                                         return 17;
 951                                 else
 952                                         if(x > 32768)
 953                                                 return 16;
 954                                         else
 955                                                 return 15;
 956                         else
 957                                 if(x > 8192)
 958                                         return 14;
 959                                 else
 960                                         if(x > 4096)
 961                                                 return 13;
 962                                         else
 963                                                 return 12;
 964         else
 965                 if(x > 32)
 966                         if(x > 256)
 967                                 if(x > 1024)
 968                                         return 11;
 969                                 else
 970                                         if(x > 512)
 971                                                 return 10;
 972                                         else
 973                                                 return 9;
 974                         else
 975                                 if(x > 128)
 976                                         return 8;
 977                                 else
 978                                         if(x > 64)
 979                                                 return 7;
 980                                         else
 981                                                 return 6;
 982                 else
 983                         if(x > 4)
 984                                 if(x > 16)
 985                                         return 5;
 986                                 else
 987                                         if(x > 8)
 988                                                 return 4;
 989                                         else
 990                                                 return 3;
 991                         else
 992                                 if(x > 2)
 993                                         return 2;
 994                                 else
 995                                         if(x > 1)
 996                                                 return 1;
 997                                         else
 998                                                 return 0;
 999 }
1000
1001 float rgb_mi_ma_to_hue(vector rgb, float mi, float ma)
1002 {
1003         if(mi == ma)
1004                 return 0;
1005         else if(ma == rgb_x)
1006         {
1007                 if(rgb_y >= rgb_z)
1008                         return (rgb_y - rgb_z) / (ma - mi);
1009                 else
1010                         return (rgb_y - rgb_z) / (ma - mi) + 6;
1011         }
1012         else if(ma == rgb_y)
1013                 return (rgb_z - rgb_x) / (ma - mi) + 2;
1014         else // if(ma == rgb_z)
1015                 return (rgb_x - rgb_y) / (ma - mi) + 4;
1016 }
1017
1018 vector hue_mi_ma_to_rgb(float hue, float mi, float ma)
1019 {
1020         vector rgb;
1021
1022         hue -= 6 * floor(hue / 6);
1023
1024         //else if(ma == rgb_x)
1025         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1026         if(hue <= 1)
1027         {
1028                 rgb_x = ma;
1029                 rgb_y = hue * (ma - mi) + mi;
1030                 rgb_z = mi;
1031         }
1032         //else if(ma == rgb_y)
1033         //      hue = 60 * (rgb_z - rgb_x) / (ma - mi) + 120;
1034         else if(hue <= 2)
1035         {
1036                 rgb_x = (2 - hue) * (ma - mi) + mi;
1037                 rgb_y = ma;
1038                 rgb_z = mi;
1039         }
1040         else if(hue <= 3)
1041         {
1042                 rgb_x = mi;
1043                 rgb_y = ma;
1044                 rgb_z = (hue - 2) * (ma - mi) + mi;
1045         }
1046         //else // if(ma == rgb_z)
1047         //      hue = 60 * (rgb_x - rgb_y) / (ma - mi) + 240;
1048         else if(hue <= 4)
1049         {
1050                 rgb_x = mi;
1051                 rgb_y = (4 - hue) * (ma - mi) + mi;
1052                 rgb_z = ma;
1053         }
1054         else if(hue <= 5)
1055         {
1056                 rgb_x = (hue - 4) * (ma - mi) + mi;
1057                 rgb_y = mi;
1058                 rgb_z = ma;
1059         }
1060         //else if(ma == rgb_x)
1061         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1062         else // if(hue <= 6)
1063         {
1064                 rgb_x = ma;
1065                 rgb_y = mi;
1066                 rgb_z = (6 - hue) * (ma - mi) + mi;
1067         }
1068
1069         return rgb;
1070 }
1071
1072 vector rgb_to_hsv(vector rgb)
1073 {
1074         float mi, ma;
1075         vector hsv;
1076
1077         mi = min(rgb_x, rgb_y, rgb_z);
1078         ma = max(rgb_x, rgb_y, rgb_z);
1079
1080         hsv_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1081         hsv_z = ma;
1082
1083         if(ma == 0)
1084                 hsv_y = 0;
1085         else
1086                 hsv_y = 1 - mi/ma;
1087
1088         return hsv;
1089 }
1090
1091 vector hsv_to_rgb(vector hsv)
1092 {
1093         return hue_mi_ma_to_rgb(hsv_x, hsv_z * (1 - hsv_y), hsv_z);
1094 }
1095
1096 vector rgb_to_hsl(vector rgb)
1097 {
1098         float mi, ma;
1099         vector hsl;
1100
1101         mi = min(rgb_x, rgb_y, rgb_z);
1102         ma = max(rgb_x, rgb_y, rgb_z);
1103
1104         hsl_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1105
1106         hsl_z = 0.5 * (mi + ma);
1107         if(mi == ma)
1108                 hsl_y = 0;
1109         else if(hsl_z <= 0.5)
1110                 hsl_y = (ma - mi) / (2*hsl_z);
1111         else // if(hsl_z > 0.5)
1112                 hsl_y = (ma - mi) / (2 - 2*hsl_z);
1113
1114         return hsl;
1115 }
1116
1117 vector hsl_to_rgb(vector hsl)
1118 {
1119         float mi, ma, maminusmi;
1120
1121         if(hsl_z <= 0.5)
1122                 maminusmi = hsl_y * 2 * hsl_z;
1123         else
1124                 maminusmi = hsl_y * (2 - 2 * hsl_z);
1125
1126         // hsl_z     = 0.5 * mi + 0.5 * ma
1127         // maminusmi =     - mi +       ma
1128         mi = hsl_z - 0.5 * maminusmi;
1129         ma = hsl_z + 0.5 * maminusmi;
1130
1131         return hue_mi_ma_to_rgb(hsl_x, mi, ma);
1132 }
1133
1134 string rgb_to_hexcolor(vector rgb)
1135 {
1136         return
1137                 strcat(
1138                         "^x",
1139                         DEC_TO_HEXDIGIT(floor(rgb_x * 15 + 0.5)),
1140                         DEC_TO_HEXDIGIT(floor(rgb_y * 15 + 0.5)),
1141                         DEC_TO_HEXDIGIT(floor(rgb_z * 15 + 0.5))
1142                 );
1143 }
1144
1145 // requires that m2>m1 in all coordinates, and that m4>m3
1146 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;}
1147
1148 // requires the same, but is a stronger condition
1149 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;}
1150
1151 #ifndef MENUQC
1152 #endif
1153
1154 float textLengthUpToWidth(string theText, float maxWidth, vector theSize, textLengthUpToWidth_widthFunction_t w)
1155 {
1156         // STOP.
1157         // The following function is SLOW.
1158         // For your safety and for the protection of those around you...
1159         // DO NOT CALL THIS AT HOME.
1160         // No really, don't.
1161         if(w(theText, theSize) <= maxWidth)
1162                 return strlen(theText); // yeah!
1163
1164         // binary search for right place to cut string
1165         float ch;
1166         float left, right, middle; // this always works
1167         left = 0;
1168         right = strlen(theText); // this always fails
1169         do
1170         {
1171                 middle = floor((left + right) / 2);
1172                 if(w(substring(theText, 0, middle), theSize) <= maxWidth)
1173                         left = middle;
1174                 else
1175                         right = middle;
1176         }
1177         while(left < right - 1);
1178
1179         if(w("^7", theSize) == 0) // detect color codes support in the width function
1180         {
1181                 // NOTE: when color codes are involved, this binary search is,
1182                 // mathematically, BROKEN. However, it is obviously guaranteed to
1183                 // terminate, as the range still halves each time - but nevertheless, it is
1184                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1185                 // range, and "right" is outside).
1186
1187                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1188                 // and decrease left on the basis of the chars detected of the truncated tag
1189                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1190                 // (sometimes too much but with a correct result)
1191                 // it fixes also ^[0-9]
1192                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1193                         left-=1;
1194
1195                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1196                         left-=2;
1197                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1198                         {
1199                                 ch = str2chr(theText, left-1);
1200                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1201                                         left-=3;
1202                         }
1203                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1204                         {
1205                                 ch = str2chr(theText, left-2);
1206                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1207                                 {
1208                                         ch = str2chr(theText, left-1);
1209                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1210                                                 left-=4;
1211                                 }
1212                         }
1213         }
1214
1215         return left;
1216 }
1217
1218 float textLengthUpToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t w)
1219 {
1220         // STOP.
1221         // The following function is SLOW.
1222         // For your safety and for the protection of those around you...
1223         // DO NOT CALL THIS AT HOME.
1224         // No really, don't.
1225         if(w(theText) <= maxWidth)
1226                 return strlen(theText); // yeah!
1227
1228         // binary search for right place to cut string
1229         float ch;
1230         float left, right, middle; // this always works
1231         left = 0;
1232         right = strlen(theText); // this always fails
1233         do
1234         {
1235                 middle = floor((left + right) / 2);
1236                 if(w(substring(theText, 0, middle)) <= maxWidth)
1237                         left = middle;
1238                 else
1239                         right = middle;
1240         }
1241         while(left < right - 1);
1242
1243         if(w("^7") == 0) // detect color codes support in the width function
1244         {
1245                 // NOTE: when color codes are involved, this binary search is,
1246                 // mathematically, BROKEN. However, it is obviously guaranteed to
1247                 // terminate, as the range still halves each time - but nevertheless, it is
1248                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1249                 // range, and "right" is outside).
1250
1251                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1252                 // and decrease left on the basis of the chars detected of the truncated tag
1253                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1254                 // (sometimes too much but with a correct result)
1255                 // it fixes also ^[0-9]
1256                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1257                         left-=1;
1258
1259                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1260                         left-=2;
1261                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1262                         {
1263                                 ch = str2chr(theText, left-1);
1264                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1265                                         left-=3;
1266                         }
1267                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1268                         {
1269                                 ch = str2chr(theText, left-2);
1270                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1271                                 {
1272                                         ch = str2chr(theText, left-1);
1273                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1274                                                 left-=4;
1275                                 }
1276                         }
1277         }
1278
1279         return left;
1280 }
1281
1282 string find_last_color_code(string s)
1283 {
1284         float start, len, i, carets;
1285         start = strstrofs(s, "^", 0);
1286         if (start == -1) // no caret found
1287                 return "";
1288         len = strlen(s)-1;
1289         for(i = len; i >= start; --i)
1290         {
1291                 if(substring(s, i, 1) != "^")
1292                         continue;
1293
1294                 carets = 1;
1295                 while (i-carets >= start && substring(s, i-carets, 1) == "^")
1296                         ++carets;
1297
1298                 // check if carets aren't all escaped
1299                 if (carets == 1 || mod(carets, 2) == 1) // first check is just an optimization
1300                 {
1301                         if(i+1 <= len)
1302                         if(strstrofs("0123456789", substring(s, i+1, 1), 0) >= 0)
1303                                 return substring(s, i, 2);
1304
1305                         if(i+4 <= len)
1306                         if(substring(s, i+1, 1) == "x")
1307                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+2, 1), 0) >= 0)
1308                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+3, 1), 0) >= 0)
1309                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+4, 1), 0) >= 0)
1310                                 return substring(s, i, 5);
1311                 }
1312                 i -= carets; // this also skips one char before the carets
1313         }
1314
1315         return "";
1316 }
1317
1318 string getWrappedLine(float w, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1319 {
1320         float cantake;
1321         float take;
1322         string s;
1323
1324         s = getWrappedLine_remaining;
1325
1326         if(w <= 0)
1327         {
1328                 getWrappedLine_remaining = string_null;
1329                 return s; // the line has no size ANYWAY, nothing would be displayed.
1330         }
1331
1332         cantake = textLengthUpToWidth(s, w, theFontSize, tw);
1333         if(cantake > 0 && cantake < strlen(s))
1334         {
1335                 take = cantake - 1;
1336                 while(take > 0 && substring(s, take, 1) != " ")
1337                         --take;
1338                 if(take == 0)
1339                 {
1340                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1341                         if(getWrappedLine_remaining == "")
1342                                 getWrappedLine_remaining = string_null;
1343                         else if (tw("^7", theFontSize) == 0)
1344                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
1345                         return substring(s, 0, cantake);
1346                 }
1347                 else
1348                 {
1349                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1350                         if(getWrappedLine_remaining == "")
1351                                 getWrappedLine_remaining = string_null;
1352                         else if (tw("^7", theFontSize) == 0)
1353                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
1354                         return substring(s, 0, take);
1355                 }
1356         }
1357         else
1358         {
1359                 getWrappedLine_remaining = string_null;
1360                 return s;
1361         }
1362 }
1363
1364 string getWrappedLineLen(float w, textLengthUpToLength_lenFunction_t tw)
1365 {
1366         float cantake;
1367         float take;
1368         string s;
1369
1370         s = getWrappedLine_remaining;
1371
1372         if(w <= 0)
1373         {
1374                 getWrappedLine_remaining = string_null;
1375                 return s; // the line has no size ANYWAY, nothing would be displayed.
1376         }
1377
1378         cantake = textLengthUpToLength(s, w, tw);
1379         if(cantake > 0 && cantake < strlen(s))
1380         {
1381                 take = cantake - 1;
1382                 while(take > 0 && substring(s, take, 1) != " ")
1383                         --take;
1384                 if(take == 0)
1385                 {
1386                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1387                         if(getWrappedLine_remaining == "")
1388                                 getWrappedLine_remaining = string_null;
1389                         else if (tw("^7") == 0)
1390                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
1391                         return substring(s, 0, cantake);
1392                 }
1393                 else
1394                 {
1395                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1396                         if(getWrappedLine_remaining == "")
1397                                 getWrappedLine_remaining = string_null;
1398                         else if (tw("^7") == 0)
1399                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
1400                         return substring(s, 0, take);
1401                 }
1402         }
1403         else
1404         {
1405                 getWrappedLine_remaining = string_null;
1406                 return s;
1407         }
1408 }
1409
1410 string textShortenToWidth(string theText, float maxWidth, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1411 {
1412         if(tw(theText, theFontSize) <= maxWidth)
1413                 return theText;
1414         else
1415                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - tw("...", theFontSize), theFontSize, tw)), "...");
1416 }
1417
1418 string textShortenToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t tw)
1419 {
1420         if(tw(theText) <= maxWidth)
1421                 return theText;
1422         else
1423                 return strcat(substring(theText, 0, textLengthUpToLength(theText, maxWidth - tw("..."), tw)), "...");
1424 }
1425
1426 float isGametypeInFilter(float gt, float tp, float ts, string pattern)
1427 {
1428         string subpattern, subpattern2, subpattern3, subpattern4;
1429         subpattern = strcat(",", GametypeNameFromType(gt), ",");
1430         if(tp)
1431                 subpattern2 = ",teams,";
1432         else
1433                 subpattern2 = ",noteams,";
1434         if(ts)
1435                 subpattern3 = ",teamspawns,";
1436         else
1437                 subpattern3 = ",noteamspawns,";
1438         if(gt == GAME_RACE || gt == GAME_CTS)
1439                 subpattern4 = ",race,";
1440         else
1441                 subpattern4 = string_null;
1442
1443         if(substring(pattern, 0, 1) == "-")
1444         {
1445                 pattern = substring(pattern, 1, strlen(pattern) - 1);
1446                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
1447                         return 0;
1448                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
1449                         return 0;
1450                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) >= 0)
1451                         return 0;
1452                 if(subpattern4 && strstrofs(strcat(",", pattern, ","), subpattern4, 0) >= 0)
1453                         return 0;
1454         }
1455         else
1456         {
1457                 if(substring(pattern, 0, 1) == "+")
1458                         pattern = substring(pattern, 1, strlen(pattern) - 1);
1459                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
1460                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
1461                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) < 0)
1462                 if((!subpattern4) || strstrofs(strcat(",", pattern, ","), subpattern4, 0) < 0)
1463                         return 0;
1464         }
1465         return 1;
1466 }
1467
1468 void shuffle(float n, swapfunc_t swap, entity pass)
1469 {
1470         float i, j;
1471         for(i = 1; i < n; ++i)
1472         {
1473                 // swap i-th item at a random position from 0 to i
1474                 // proof for even distribution:
1475                 //   n = 1: obvious
1476                 //   n -> n+1:
1477                 //     item n+1 gets at any position with chance 1/(n+1)
1478                 //     all others will get their 1/n chance reduced by factor n/(n+1)
1479                 //     to be on place n+1, their chance will be 1/(n+1)
1480                 //     1/n * n/(n+1) = 1/(n+1)
1481                 //     q.e.d.
1482                 j = floor(random() * (i + 1));
1483                 if(j != i)
1484                         swap(j, i, pass);
1485         }
1486 }
1487
1488 string substring_range(string s, float b, float e)
1489 {
1490         return substring(s, b, e - b);
1491 }
1492
1493 string swapwords(string str, float i, float j)
1494 {
1495         float n;
1496         string s1, s2, s3, s4, s5;
1497         float si, ei, sj, ej, s0, en;
1498         n = tokenizebyseparator(str, " "); // must match g_maplist processing in ShuffleMaplist and "shuffle"
1499         si = argv_start_index(i);
1500         sj = argv_start_index(j);
1501         ei = argv_end_index(i);
1502         ej = argv_end_index(j);
1503         s0 = argv_start_index(0);
1504         en = argv_end_index(n-1);
1505         s1 = substring_range(str, s0, si);
1506         s2 = substring_range(str, si, ei);
1507         s3 = substring_range(str, ei, sj);
1508         s4 = substring_range(str, sj, ej);
1509         s5 = substring_range(str, ej, en);
1510         return strcat(s1, s4, s3, s2, s5);
1511 }
1512
1513 string _shufflewords_str;
1514 void _shufflewords_swapfunc(float i, float j, entity pass)
1515 {
1516         _shufflewords_str = swapwords(_shufflewords_str, i, j);
1517 }
1518 string shufflewords(string str)
1519 {
1520         float n;
1521         _shufflewords_str = str;
1522         n = tokenizebyseparator(str, " ");
1523         shuffle(n, _shufflewords_swapfunc, world);
1524         str = _shufflewords_str;
1525         _shufflewords_str = string_null;
1526         return str;
1527 }
1528
1529 vector solve_quadratic(float a, float b, float c) // ax^2 + bx + c = 0
1530 {
1531         vector v;
1532         float D;
1533         v = '0 0 0';
1534         if(a == 0)
1535         {
1536                 if(b != 0)
1537                 {
1538                         v_x = v_y = -c / b;
1539                         v_z = 1;
1540                 }
1541                 else
1542                 {
1543                         if(c == 0)
1544                         {
1545                                 // actually, every number solves the equation!
1546                                 v_z = 1;
1547                         }
1548                 }
1549         }
1550         else
1551         {
1552                 D = b*b - 4*a*c;
1553                 if(D >= 0)
1554                 {
1555                         D = sqrt(D);
1556                         if(a > 0) // put the smaller solution first
1557                         {
1558                                 v_x = ((-b)-D) / (2*a);
1559                                 v_y = ((-b)+D) / (2*a);
1560                         }
1561                         else
1562                         {
1563                                 v_x = (-b+D) / (2*a);
1564                                 v_y = (-b-D) / (2*a);
1565                         }
1566                         v_z = 1;
1567                 }
1568                 else
1569                 {
1570                         // complex solutions!
1571                         D = sqrt(-D);
1572                         v_x = -b / (2*a);
1573                         if(a > 0)
1574                                 v_y =  D / (2*a);
1575                         else
1576                                 v_y = -D / (2*a);
1577                         v_z = 0;
1578                 }
1579         }
1580         return v;
1581 }
1582
1583 void check_unacceptable_compiler_bugs()
1584 {
1585         if(cvar("_allow_unacceptable_compiler_bugs"))
1586                 return;
1587         tokenize_console("foo bar");
1588         if(strcat(argv(0), substring("foo bar", 4, 7 - argv_start_index(1))) == "barbar")
1589                 error("fteqcc bug introduced with revision 3178 detected. Please upgrade fteqcc to a later revision, downgrade fteqcc to revision 3177, or pester Spike until he fixes it. You can set _allow_unacceptable_compiler_bugs 1 to skip this check, but expect stuff to be horribly broken then.");
1590 }
1591
1592 float compressShotOrigin(vector v)
1593 {
1594         float x, y, z;
1595         x = rint(v_x * 2);
1596         y = rint(v_y * 4) + 128;
1597         z = rint(v_z * 4) + 128;
1598         if(x > 255 || x < 0)
1599         {
1600                 print("shot origin ", vtos(v), " x out of bounds\n");
1601                 x = bound(0, x, 255);
1602         }
1603         if(y > 255 || y < 0)
1604         {
1605                 print("shot origin ", vtos(v), " y out of bounds\n");
1606                 y = bound(0, y, 255);
1607         }
1608         if(z > 255 || z < 0)
1609         {
1610                 print("shot origin ", vtos(v), " z out of bounds\n");
1611                 z = bound(0, z, 255);
1612         }
1613         return x * 0x10000 + y * 0x100 + z;
1614 }
1615 vector decompressShotOrigin(float f)
1616 {
1617         vector v;
1618         v_x = ((f & 0xFF0000) / 0x10000) / 2;
1619         v_y = ((f & 0xFF00) / 0x100 - 128) / 4;
1620         v_z = ((f & 0xFF) - 128) / 4;
1621         return v;
1622 }
1623
1624 void heapsort(float n, swapfunc_t swap, comparefunc_t cmp, entity pass)
1625 {
1626         float start, end, root, child;
1627
1628         // heapify
1629         start = floor((n - 2) / 2);
1630         while(start >= 0)
1631         {
1632                 // siftdown(start, count-1);
1633                 root = start;
1634                 while(root * 2 + 1 <= n-1)
1635                 {
1636                         child = root * 2 + 1;
1637                         if(child < n-1)
1638                                 if(cmp(child, child+1, pass) < 0)
1639                                         ++child;
1640                         if(cmp(root, child, pass) < 0)
1641                         {
1642                                 swap(root, child, pass);
1643                                 root = child;
1644                         }
1645                         else
1646                                 break;
1647                 }
1648                 // end of siftdown
1649                 --start;
1650         }
1651
1652         // extract
1653         end = n - 1;
1654         while(end > 0)
1655         {
1656                 swap(0, end, pass);
1657                 --end;
1658                 // siftdown(0, end);
1659                 root = 0;
1660                 while(root * 2 + 1 <= end)
1661                 {
1662                         child = root * 2 + 1;
1663                         if(child < end && cmp(child, child+1, pass) < 0)
1664                                 ++child;
1665                         if(cmp(root, child, pass) < 0)
1666                         {
1667                                 swap(root, child, pass);
1668                                 root = child;
1669                         }
1670                         else
1671                                 break;
1672                 }
1673                 // end of siftdown
1674         }
1675 }
1676
1677 void RandomSelection_Init()
1678 {
1679         RandomSelection_totalweight = 0;
1680         RandomSelection_chosen_ent = world;
1681         RandomSelection_chosen_float = 0;
1682         RandomSelection_chosen_string = string_null;
1683         RandomSelection_best_priority = -1;
1684 }
1685 void RandomSelection_Add(entity e, float f, string s, float weight, float priority)
1686 {
1687         if(priority > RandomSelection_best_priority)
1688         {
1689                 RandomSelection_best_priority = priority;
1690                 RandomSelection_chosen_ent = e;
1691                 RandomSelection_chosen_float = f;
1692                 RandomSelection_chosen_string = s;
1693                 RandomSelection_totalweight = weight;
1694         }
1695         else if(priority == RandomSelection_best_priority)
1696         {
1697                 RandomSelection_totalweight += weight;
1698                 if(random() * RandomSelection_totalweight <= weight)
1699                 {
1700                         RandomSelection_chosen_ent = e;
1701                         RandomSelection_chosen_float = f;
1702                         RandomSelection_chosen_string = s;
1703                 }
1704         }
1705 }
1706
1707 vector healtharmor_maxdamage(float h, float a, float armorblock)
1708 {
1709         // NOTE: we'll always choose the SMALLER value...
1710         float healthdamage, armordamage, armorideal;
1711         vector v;
1712         healthdamage = (h - 1) / (1 - armorblock); // damage we can take if we could use more health
1713         armordamage = a + (h - 1); // damage we can take if we could use more armor
1714         armorideal = healthdamage * armorblock;
1715         v_y = armorideal;
1716         if(armordamage < healthdamage)
1717         {
1718                 v_x = armordamage;
1719                 v_z = 1;
1720         }
1721         else
1722         {
1723                 v_x = healthdamage;
1724                 v_z = 0;
1725         }
1726         return v;
1727 }
1728
1729 vector healtharmor_applydamage(float a, float armorblock, float damage)
1730 {
1731         vector v;
1732         v_y = bound(0, damage * armorblock, a); // save
1733         v_x = bound(0, damage - v_y, damage); // take
1734         v_z = 0;
1735         return v;
1736 }
1737
1738 string getcurrentmod()
1739 {
1740         float n;
1741         string m;
1742         m = cvar_string("fs_gamedir");
1743         n = tokenize_console(m);
1744         if(n == 0)
1745                 return "data";
1746         else
1747                 return argv(n - 1);
1748 }
1749
1750 #ifndef MENUQC
1751 #ifdef CSQC
1752 float ReadInt24_t()
1753 {
1754         float v;
1755         v = ReadShort() * 256; // note: this is signed
1756         v += ReadByte(); // note: this is unsigned
1757         return v;
1758 }
1759 #else
1760 void WriteInt24_t(float dest, float val)
1761 {
1762         float v;
1763         WriteShort(dest, (v = floor(val / 256)));
1764         WriteByte(dest, val - v * 256); // 0..255
1765 }
1766 #endif
1767 #endif
1768
1769 float float2range11(float f)
1770 {
1771         // continuous function mapping all reals into -1..1
1772         return f / (fabs(f) + 1);
1773 }
1774
1775 float float2range01(float f)
1776 {
1777         // continuous function mapping all reals into 0..1
1778         return 0.5 + 0.5 * float2range11(f);
1779 }
1780
1781 // from the GNU Scientific Library
1782 float gsl_ran_gaussian_lastvalue;
1783 float gsl_ran_gaussian_lastvalue_set;
1784 float gsl_ran_gaussian(float sigma)
1785 {
1786         float a, b;
1787         if(gsl_ran_gaussian_lastvalue_set)
1788         {
1789                 gsl_ran_gaussian_lastvalue_set = 0;
1790                 return sigma * gsl_ran_gaussian_lastvalue;
1791         }
1792         else
1793         {
1794                 a = random() * 2 * M_PI;
1795                 b = sqrt(-2 * log(random()));
1796                 gsl_ran_gaussian_lastvalue = cos(a) * b;
1797                 gsl_ran_gaussian_lastvalue_set = 1;
1798                 return sigma * sin(a) * b;
1799         }
1800 }
1801
1802 string car(string s)
1803 {
1804         float o;
1805         o = strstrofs(s, " ", 0);
1806         if(o < 0)
1807                 return s;
1808         return substring(s, 0, o);
1809 }
1810 string cdr(string s)
1811 {
1812         float o;
1813         o = strstrofs(s, " ", 0);
1814         if(o < 0)
1815                 return string_null;
1816         return substring(s, o + 1, strlen(s) - (o + 1));
1817 }
1818 float matchacl(string acl, string str)
1819 {
1820         string t, s;
1821         float r, d;
1822         r = 0;
1823         while(acl)
1824         {
1825                 t = car(acl); acl = cdr(acl);
1826                 d = 1;
1827                 if(substring(t, 0, 1) == "-")
1828                 {
1829                         d = -1;
1830                         t = substring(t, 1, strlen(t) - 1);
1831                 }
1832                 else if(substring(t, 0, 1) == "+")
1833                         t = substring(t, 1, strlen(t) - 1);
1834                 if(substring(t, -1, 1) == "*")
1835                 {
1836                         t = substring(t, 0, strlen(t) - 1);
1837                         s = substring(s, 0, strlen(t));
1838                 }
1839                 else
1840                         s = str;
1841
1842                 if(s == t)
1843                 {
1844                         r = d;
1845                 }
1846         }
1847         return r;
1848 }
1849 float startsWith(string haystack, string needle)
1850 {
1851         return substring(haystack, 0, strlen(needle)) == needle;
1852 }
1853 float startsWithNocase(string haystack, string needle)
1854 {
1855         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
1856 }
1857
1858 string get_model_datafilename(string m, float sk, string fil)
1859 {
1860         if(m)
1861                 m = strcat(m, "_");
1862         else
1863                 m = "models/player/*_";
1864         if(sk >= 0)
1865                 m = strcat(m, ftos(sk));
1866         else
1867                 m = strcat(m, "*");
1868         return strcat(m, ".", fil);
1869 }
1870
1871 float get_model_parameters(string m, float sk)
1872 {
1873         string fn, s, c;
1874         float fh;
1875
1876         get_model_parameters_modelname = string_null;
1877         get_model_parameters_modelskin = -1;
1878         get_model_parameters_name = string_null;
1879         get_model_parameters_species = -1;
1880         get_model_parameters_sex = string_null;
1881         get_model_parameters_weight = -1;
1882         get_model_parameters_age = -1;
1883         get_model_parameters_desc = string_null;
1884
1885         if not(m)
1886                 return 1;
1887         if(sk < 0)
1888         {
1889                 if(substring(m, -4, -1) != ".txt")
1890                         return 0;
1891                 if(substring(m, -6, 1) != "_")
1892                         return 0;
1893                 sk = stof(substring(m, -5, 1));
1894                 m = substring(m, 0, -7);
1895         }
1896
1897         fn = get_model_datafilename(m, sk, "txt");
1898         fh = fopen(fn, FILE_READ);
1899         if(fh < 0)
1900         {
1901                 sk = 0;
1902                 fn = get_model_datafilename(m, sk, "txt");
1903                 fh = fopen(fn, FILE_READ);
1904                 if(fh < 0)
1905                         return 0;
1906         }
1907
1908         get_model_parameters_modelname = m;
1909         get_model_parameters_modelskin = sk;
1910         while((s = fgets(fh)))
1911         {
1912                 if(s == "")
1913                         break; // next lines will be description
1914                 c = car(s);
1915                 s = cdr(s);
1916                 if(c == "name")
1917                         get_model_parameters_name = s;
1918                 if(c == "species")
1919                         switch(s)
1920                         {
1921                                 case "human":       get_model_parameters_species = SPECIES_HUMAN;       break;
1922                                 case "alien":       get_model_parameters_species = SPECIES_ALIEN;       break;
1923                                 case "robot_shiny": get_model_parameters_species = SPECIES_ROBOT_SHINY; break;
1924                                 case "robot_rusty": get_model_parameters_species = SPECIES_ROBOT_RUSTY; break;
1925                                 case "robot_solid": get_model_parameters_species = SPECIES_ROBOT_SOLID; break;
1926                                 case "animal":      get_model_parameters_species = SPECIES_ANIMAL;      break;
1927                                 case "reserved":    get_model_parameters_species = SPECIES_RESERVED;    break;
1928                         }
1929                 if(c == "sex")
1930                         get_model_parameters_sex = s;
1931                 if(c == "weight")
1932                         get_model_parameters_weight = stof(s);
1933                 if(c == "age")
1934                         get_model_parameters_age = stof(s);
1935         }
1936
1937         while((s = fgets(fh)))
1938         {
1939                 if(get_model_parameters_desc)
1940                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
1941                 if(s != "")
1942                         get_model_parameters_desc = strcat(get_model_parameters_desc, s);
1943         }
1944
1945         fclose(fh);
1946
1947         return 1;
1948 }
1949
1950 vector vec2(vector v)
1951 {
1952         v_z = 0;
1953         return v;
1954 }
1955
1956 #ifndef MENUQC
1957 vector NearestPointOnBox(entity box, vector org)
1958 {
1959         vector m1, m2, nearest;
1960
1961         m1 = box.mins + box.origin;
1962         m2 = box.maxs + box.origin;
1963
1964         nearest_x = bound(m1_x, org_x, m2_x);
1965         nearest_y = bound(m1_y, org_y, m2_y);
1966         nearest_z = bound(m1_z, org_z, m2_z);
1967
1968         return nearest;
1969 }
1970 #endif
1971
1972 float vercmp_recursive(string v1, string v2)
1973 {
1974         float dot1, dot2;
1975         string s1, s2;
1976         float r;
1977
1978         dot1 = strstrofs(v1, ".", 0);
1979         dot2 = strstrofs(v2, ".", 0);
1980         if(dot1 == -1)
1981                 s1 = v1;
1982         else
1983                 s1 = substring(v1, 0, dot1);
1984         if(dot2 == -1)
1985                 s2 = v2;
1986         else
1987                 s2 = substring(v2, 0, dot2);
1988
1989         r = stof(s1) - stof(s2);
1990         if(r != 0)
1991                 return r;
1992
1993         r = strcasecmp(s1, s2);
1994         if(r != 0)
1995                 return r;
1996
1997         if(dot1 == -1)
1998                 if(dot2 == -1)
1999                         return 0;
2000                 else
2001                         return -1;
2002         else
2003                 if(dot2 == -1)
2004                         return 1;
2005                 else
2006                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2007 }
2008
2009 float vercmp(string v1, string v2)
2010 {
2011         if(strcasecmp(v1, v2) == 0) // early out check
2012                 return 0;
2013
2014         // "git" beats all
2015         if(v1 == "git")
2016                 return 1;
2017         if(v2 == "git")
2018                 return -1;
2019
2020         return vercmp_recursive(v1, v2);
2021 }
2022
2023 float u8_strsize(string s)
2024 {
2025         float l, i, c;
2026         l = 0;
2027         for(i = 0; ; ++i)
2028         {
2029                 c = str2chr(s, i);
2030                 if(c <= 0)
2031                         break;
2032                 ++l;
2033                 if(c >= 0x80)
2034                         ++l;
2035                 if(c >= 0x800)
2036                         ++l;
2037                 if(c >= 0x10000)
2038                         ++l;
2039         }
2040         return l;
2041 }
2042
2043 // translation helpers
2044 string language_filename(string s)
2045 {
2046         string fn;
2047         float fh;
2048         fn = prvm_language;
2049         if(fn == "" || fn == "dump")
2050                 return s;
2051         fn = strcat(s, ".", fn);
2052         if((fh = fopen(fn, FILE_READ)) >= 0)
2053         {
2054                 fclose(fh);
2055                 return fn;
2056         }
2057         return s;
2058 }
2059 string CTX(string s)
2060 {
2061         float p = strstrofs(s, "^", 0);
2062         if(p < 0)
2063                 return s;
2064         return substring(s, p+1, -1);
2065 }
2066
2067 // x-encoding (encoding as zero length invisible string)
2068 const string XENCODE_2  = "xX";
2069 const string XENCODE_22 = "0123456789abcdefABCDEF";
2070 string xencode(float f)
2071 {
2072         float a, b, c, d;
2073         d = mod(f, 22); f = floor(f / 22);
2074         c = mod(f, 22); f = floor(f / 22);
2075         b = mod(f, 22); f = floor(f / 22);
2076         a = mod(f,  2); // f = floor(f /  2);
2077         return strcat(
2078                 "^",
2079                 substring(XENCODE_2,  a, 1),
2080                 substring(XENCODE_22, b, 1),
2081                 substring(XENCODE_22, c, 1),
2082                 substring(XENCODE_22, d, 1)
2083         );
2084 }
2085 float xdecode(string s)
2086 {
2087         float a, b, c, d;
2088         if(substring(s, 0, 1) != "^")
2089                 return -1;
2090         if(strlen(s) < 5)
2091                 return -1;
2092         a = strstrofs(XENCODE_2,  substring(s, 1, 1), 0);
2093         b = strstrofs(XENCODE_22, substring(s, 2, 1), 0);
2094         c = strstrofs(XENCODE_22, substring(s, 3, 1), 0);
2095         d = strstrofs(XENCODE_22, substring(s, 4, 1), 0);
2096         if(a < 0 || b < 0 || c < 0 || d < 0)
2097                 return -1;
2098         return ((a * 22 + b) * 22 + c) * 22 + d;
2099 }
2100
2101 float lowestbit(float f)
2102 {
2103         f &~= f * 2;
2104         f &~= f * 4;
2105         f &~= f * 16;
2106         f &~= f * 256;
2107         f &~= f * 65536;
2108         return f;
2109 }
2110
2111 string strlimitedlen(string input, string truncation, float strip_colors, float limit)
2112 {
2113         if(strlen((strip_colors ? strdecolorize(input) : input)) <= limit)
2114                 return input;
2115         else
2116                 return strcat(substring(input, 0, (strlen(input) - strlen(truncation))), truncation);
2117 }