qcsrc/common/util.qc

   1 string wordwrap_buffer;
   2
   3 void wordwrap_buffer_put(string s)
   4 {
   5         wordwrap_buffer = strcat(wordwrap_buffer, s);
   6 }
   7
   8 string wordwrap(string s, float l)
   9 {
  10         string r;
  11         wordwrap_buffer = "";
  12         wordwrap_cb(s, l, wordwrap_buffer_put);
  13         r = wordwrap_buffer;
  14         wordwrap_buffer = "";
  15         return r;
  16 }
  17
  18 #ifndef MENUQC
  19 #ifndef CSQC
  20 void wordwrap_buffer_sprint(string s)
  21 {
  22         wordwrap_buffer = strcat(wordwrap_buffer, s);
  23         if(s == "\n")
  24         {
  25                 sprint(self, wordwrap_buffer);
  26                 wordwrap_buffer = "";
  27         }
  28 }
  29
  30 void wordwrap_sprint(string s, float l)
  31 {
  32         wordwrap_buffer = "";
  33         wordwrap_cb(s, l, wordwrap_buffer_sprint);
  34         if(wordwrap_buffer != "")
  35                 sprint(self, strcat(wordwrap_buffer, "\n"));
  36         wordwrap_buffer = "";
  37         return;
  38 }
  39 #endif
  40 #endif
  41
  42 #ifndef SVQC
  43 string draw_UseSkinFor(string pic)
  44 {
  45         if(substring(pic, 0, 1) == "/")
  46                 return substring(pic, 1, strlen(pic)-1);
  47         else
  48                 return strcat(draw_currentSkin, "/", pic);
  49 }
  50 #endif
  51
  52 string unescape(string in)
  53 {
  54         float i, len;
  55         string str, s;
  56
  57         // but it doesn't seem to be necessary in my tests at least
  58         in = strzone(in);
  59
  60         len = strlen(in);
  61         str = "";
  62         for(i = 0; i < len; ++i)
  63         {
  64                 s = substring(in, i, 1);
  65                 if(s == "\\")
  66                 {
  67                         s = substring(in, i+1, 1);
  68                         if(s == "n")
  69                                 str = strcat(str, "\n");
  70                         else if(s == "\\")
  71                                 str = strcat(str, "\\");
  72                         else
  73                                 str = strcat(str, substring(in, i, 2));
  74                         ++i;
  75                 } else
  76                         str = strcat(str, s);
  77         }
  78
  79         strunzone(in);
  80         return str;
  81 }
  82
  83 void wordwrap_cb(string s, float l, void(string) callback)
  84 {
  85         string c;
  86         float lleft, i, j, wlen;
  87
  88         s = strzone(s);
  89         lleft = l;
  90         for (i = 0;i < strlen(s);++i)
  91         {
  92                 if (substring(s, i, 2) == "\\n")
  93                 {
  94                         callback("\n");
  95                         lleft = l;
  96                         ++i;
  97                 }
  98                 else if (substring(s, i, 1) == "\n")
  99                 {
 100                         callback("\n");
 101                         lleft = l;
 102                 }
 103                 else if (substring(s, i, 1) == " ")
 104                 {
 105                         if (lleft > 0)
 106                         {
 107                                 callback(" ");
 108                                 lleft = lleft - 1;
 109                         }
 110                 }
 111                 else
 112                 {
 113                         for (j = i+1;j < strlen(s);++j)
 114                                 //    ^^ this skips over the first character of a word, which
 115                                 //       is ALWAYS part of the word
 116                                 //       this is safe since if i+1 == strlen(s), i will become
 117                                 //       strlen(s)-1 at the end of this block and the function
 118                                 //       will terminate. A space can't be the first character we
 119                                 //       read here, and neither can a \n be the start, since these
 120                                 //       two cases have been handled above.
 121                         {
 122                                 c = substring(s, j, 1);
 123                                 if (c == " ")
 124                                         break;
 125                                 if (c == "\\")
 126                                         break;
 127                                 if (c == "\n")
 128                                         break;
 129                                 // we need to keep this tempstring alive even if substring is
 130                                 // called repeatedly, so call strcat even though we're not
 131                                 // doing anything
 132                                 callback("");
 133                         }
 134                         wlen = j - i;
 135                         if (lleft < wlen)
 136                         {
 137                                 callback("\n");
 138                                 lleft = l;
 139                         }
 140                         callback(substring(s, i, wlen));
 141                         lleft = lleft - wlen;
 142                         i = j - 1;
 143                 }
 144         }
 145         strunzone(s);
 146 }
 147
 148 float dist_point_line(vector p, vector l0, vector ldir)
 149 {
 150         ldir = normalize(ldir);
 151
 152         // remove the component in line direction
 153         p = p - (p * ldir) * ldir;
 154
 155         // vlen of the remaining vector
 156         return vlen(p);
 157 }
 158
 159 void depthfirst(entity start, .entity up, .entity downleft, .entity right, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
 160 {
 161         entity e;
 162         e = start;
 163         funcPre(pass, e);
 164         while(e.downleft)
 165         {
 166                 e = e.downleft;
 167                 funcPre(pass, e);
 168         }
 169         funcPost(pass, e);
 170         while(e != start)
 171         {
 172                 if(e.right)
 173                 {
 174                         e = e.right;
 175                         funcPre(pass, e);
 176                         while(e.downleft)
 177                         {
 178                                 e = e.downleft;
 179                                 funcPre(pass, e);
 180                         }
 181                 }
 182                 else
 183                         e = e.up;
 184                 funcPost(pass, e);
 185         }
 186 }
 187
 188 float median(float a, float b, float c)
 189 {
 190         if(a < c)
 191                 return bound(a, b, c);
 192         return bound(c, b, a);
 193 }
 194
 195 // converts a number to a string with the indicated number of decimals
 196 // works for up to 10 decimals!
 197 string ftos_decimals(float number, float decimals)
 198 {
 199         // inhibit stupid negative zero
 200         if(number == 0)
 201                 number = 0;
 202         // we have sprintf...
 203         return sprintf("%.*f", decimals, number);
 204 }
 205
 206 float time;
 207 vector colormapPaletteColor(float c, float isPants)
 208 {
 209         switch(c)
 210         {
 211                 case  0: return '1.000000 1.000000 1.000000';
 212                 case  1: return '1.000000 0.333333 0.000000';
 213                 case  2: return '0.000000 1.000000 0.501961';
 214                 case  3: return '0.000000 1.000000 0.000000';
 215                 case  4: return '1.000000 0.000000 0.000000';
 216                 case  5: return '0.000000 0.666667 1.000000';
 217                 case  6: return '0.000000 1.000000 1.000000';
 218                 case  7: return '0.501961 1.000000 0.000000';
 219                 case  8: return '0.501961 0.000000 1.000000';
 220                 case  9: return '1.000000 0.000000 1.000000';
 221                 case 10: return '1.000000 0.000000 0.501961';
 222                 case 11: return '0.000000 0.000000 1.000000';
 223                 case 12: return '1.000000 1.000000 0.000000';
 224                 case 13: return '0.000000 0.333333 1.000000';
 225                 case 14: return '1.000000 0.666667 0.000000';
 226                 case 15:
 227                         if(isPants)
 228                                 return
 229                                           '1 0 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 0.0000000000))
 230                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 2.0943951024))
 231                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 2.7182818285 + 4.1887902048));
 232                         else
 233                                 return
 234                                           '1 0 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 5.2359877560))
 235                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 3.1415926536))
 236                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 3.1415926536 + 1.0471975512));
 237                 default: return '0.000 0.000 0.000';
 238         }
 239 }
 240
 241 // unzone the string, and return it as tempstring. Safe to be called on string_null
 242 string fstrunzone(string s)
 243 {
 244         string sc;
 245         if not(s)
 246                 return s;
 247         sc = strcat(s, "");
 248         strunzone(s);
 249         return sc;
 250 }
 251
 252 float fexists(string f)
 253 {
 254     float fh;
 255     fh = fopen(f, FILE_READ);
 256     if (fh < 0)
 257         return FALSE;
 258     fclose(fh);
 259     return TRUE;
 260 }
 261
 262 // Databases (hash tables)
 263 #define DB_BUCKETS 8192
 264 void db_save(float db, string pFilename)
 265 {
 266         float fh, i, n;
 267         fh = fopen(pFilename, FILE_WRITE);
 268         if(fh < 0)
 269         {
 270                 print(strcat("^1Can't write DB to ", pFilename));
 271                 return;
 272         }
 273         n = buf_getsize(db);
 274         fputs(fh, strcat(ftos(DB_BUCKETS), "\n"));
 275         for(i = 0; i < n; ++i)
 276                 fputs(fh, strcat(bufstr_get(db, i), "\n"));
 277         fclose(fh);
 278 }
 279
 280 float db_create()
 281 {
 282         return buf_create();
 283 }
 284
 285 float db_load(string pFilename)
 286 {
 287         float db, fh, i, j, n;
 288         string l;
 289         db = buf_create();
 290         if(db < 0)
 291                 return -1;
 292         fh = fopen(pFilename, FILE_READ);
 293         if(fh < 0)
 294                 return db;
 295         l = fgets(fh);
 296         if(stof(l) == DB_BUCKETS)
 297         {
 298                 i = 0;
 299                 while((l = fgets(fh)))
 300                 {
 301                         if(l != "")
 302                                 bufstr_set(db, i, l);
 303                         ++i;
 304                 }
 305         }
 306         else
 307         {
 308                 // different count of buckets, or a dump?
 309                 // need to reorganize the database then (SLOW)
 310                 //
 311                 // note: we also parse the first line (l) in case the DB file is
 312                 // missing the bucket count
 313                 do
 314                 {
 315                         n = tokenizebyseparator(l, "\\");
 316                         for(j = 2; j < n; j += 2)
 317                                 db_put(db, argv(j-1), uri_unescape(argv(j)));
 318                 }
 319                 while((l = fgets(fh)));
 320         }
 321         fclose(fh);
 322         return db;
 323 }
 324
 325 void db_dump(float db, string pFilename)
 326 {
 327         float fh, i, j, n, m;
 328         fh = fopen(pFilename, FILE_WRITE);
 329         if(fh < 0)
 330                 error(strcat("Can't dump DB to ", pFilename));
 331         n = buf_getsize(db);
 332         fputs(fh, "0\n");
 333         for(i = 0; i < n; ++i)
 334         {
 335                 m = tokenizebyseparator(bufstr_get(db, i), "\\");
 336                 for(j = 2; j < m; j += 2)
 337                         fputs(fh, strcat("\\", argv(j-1), "\\", argv(j), "\n"));
 338         }
 339         fclose(fh);
 340 }
 341
 342 void db_close(float db)
 343 {
 344         buf_del(db);
 345 }
 346
 347 string db_get(float db, string pKey)
 348 {
 349         float h;
 350         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 351         return uri_unescape(infoget(bufstr_get(db, h), pKey));
 352 }
 353
 354 void db_put(float db, string pKey, string pValue)
 355 {
 356         float h;
 357         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 358         bufstr_set(db, h, infoadd(bufstr_get(db, h), pKey, uri_escape(pValue)));
 359 }
 360
 361 void db_test()
 362 {
 363         float db, i;
 364         print("LOAD...\n");
 365         db = db_load("foo.db");
 366         print("LOADED. FILL...\n");
 367         for(i = 0; i < DB_BUCKETS; ++i)
 368                 db_put(db, ftos(random()), "X");
 369         print("FILLED. SAVE...\n");
 370         db_save(db, "foo.db");
 371         print("SAVED. CLOSE...\n");
 372         db_close(db);
 373         print("CLOSED.\n");
 374 }
 375
 376 // Multiline text file buffers
 377 float buf_load(string pFilename)
 378 {
 379         float buf, fh, i;
 380         string l;
 381         buf = buf_create();
 382         if(buf < 0)
 383                 return -1;
 384         fh = fopen(pFilename, FILE_READ);
 385         if(fh < 0)
 386         {
 387                 buf_del(buf);
 388                 return -1;
 389         }
 390         i = 0;
 391         while((l = fgets(fh)))
 392         {
 393                 bufstr_set(buf, i, l);
 394                 ++i;
 395         }
 396         fclose(fh);
 397         return buf;
 398 }
 399
 400 void buf_save(float buf, string pFilename)
 401 {
 402         float fh, i, n;
 403         fh = fopen(pFilename, FILE_WRITE);
 404         if(fh < 0)
 405                 error(strcat("Can't write buf to ", pFilename));
 406         n = buf_getsize(buf);
 407         for(i = 0; i < n; ++i)
 408                 fputs(fh, strcat(bufstr_get(buf, i), "\n"));
 409         fclose(fh);
 410 }
 411
 412 string mmsss(float tenths)
 413 {
 414         float minutes;
 415         string s;
 416         tenths = floor(tenths + 0.5);
 417         minutes = floor(tenths / 600);
 418         tenths -= minutes * 600;
 419         s = ftos(1000 + tenths);
 420         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 1));
 421 }
 422
 423 string mmssss(float hundredths)
 424 {
 425         float minutes;
 426         string s;
 427         hundredths = floor(hundredths + 0.5);
 428         minutes = floor(hundredths / 6000);
 429         hundredths -= minutes * 6000;
 430         s = ftos(10000 + hundredths);
 431         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 2));
 432 }
 433
 434 string ScoreString(float pFlags, float pValue)
 435 {
 436         string valstr;
 437         float l;
 438
 439         pValue = floor(pValue + 0.5); // round
 440
 441         if((pValue == 0) && (pFlags & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME)))
 442                 valstr = "";
 443         else if(pFlags & SFL_RANK)
 444         {
 445                 valstr = ftos(pValue);
 446                 l = strlen(valstr);
 447                 if((l >= 2) && (substring(valstr, l - 2, 1) == "1"))
 448                         valstr = strcat(valstr, "th");
 449                 else if(substring(valstr, l - 1, 1) == "1")
 450                         valstr = strcat(valstr, "st");
 451                 else if(substring(valstr, l - 1, 1) == "2")
 452                         valstr = strcat(valstr, "nd");
 453                 else if(substring(valstr, l - 1, 1) == "3")
 454                         valstr = strcat(valstr, "rd");
 455                 else
 456                         valstr = strcat(valstr, "th");
 457         }
 458         else if(pFlags & SFL_TIME)
 459                 valstr = TIME_ENCODED_TOSTRING(pValue);
 460         else
 461                 valstr = ftos(pValue);
 462
 463         return valstr;
 464 }
 465
 466 vector cross(vector a, vector b)
 467 {
 468         return
 469                 '1 0 0' * (a_y * b_z - a_z * b_y)
 470         +       '0 1 0' * (a_z * b_x - a_x * b_z)
 471         +       '0 0 1' * (a_x * b_y - a_y * b_x);
 472 }
 473
 474 // compressed vector format:
 475 // like MD3, just even shorter
 476 //   4 bit pitch (16 angles), 0 is -90, 8 is 0, 16 would be 90
 477 //   5 bit yaw (32 angles), 0=0, 8=90, 16=180, 24=270
 478 //   7 bit length (logarithmic encoding), 1/8 .. about 7844
 479 //     length = 2^(length_encoded/8) / 8
 480 // if pitch is 90, yaw does nothing and therefore indicates the sign (yaw is then either 11111 or 11110); 11111 is pointing DOWN
 481 // thus, valid values are from 0000.11110.0000000 to 1111.11111.1111111
 482 // the special value 0 indicates the zero vector
 483
 484 float lengthLogTable[128];
 485
 486 float invertLengthLog(float x)
 487 {
 488         float l, r, m, lerr, rerr;
 489
 490         if(x >= lengthLogTable[127])
 491                 return 127;
 492         if(x <= lengthLogTable[0])
 493                 return 0;
 494
 495         l = 0;
 496         r = 127;
 497
 498         while(r - l > 1)
 499         {
 500                 m = floor((l + r) / 2);
 501                 if(lengthLogTable[m] < x)
 502                         l = m;
 503                 else
 504                         r = m;
 505         }
 506
 507         // now: r is >=, l is <
 508         lerr = (x - lengthLogTable[l]);
 509         rerr = (lengthLogTable[r] - x);
 510         if(lerr < rerr)
 511                 return l;
 512         return r;
 513 }
 514
 515 vector decompressShortVector(float data)
 516 {
 517         vector out;
 518         float p, y, len;
 519         if(data == 0)
 520                 return '0 0 0';
 521         p   = (data & 0xF000) / 0x1000;
 522         y   = (data & 0x0F80) / 0x80;
 523         len = (data & 0x007F);
 524
 525         //print("\ndecompress: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
 526
 527         if(p == 0)
 528         {
 529                 out_x = 0;
 530                 out_y = 0;
 531                 if(y == 31)
 532                         out_z = -1;
 533                 else
 534                         out_z = +1;
 535         }
 536         else
 537         {
 538                 y   = .19634954084936207740 * y;
 539                 p = .19634954084936207740 * p - 1.57079632679489661922;
 540                 out_x = cos(y) *  cos(p);
 541                 out_y = sin(y) *  cos(p);
 542                 out_z =          -sin(p);
 543         }
 544
 545         //print("decompressed: ", vtos(out), "\n");
 546
 547         return out * lengthLogTable[len];
 548 }
 549
 550 float compressShortVector(vector vec)
 551 {
 552         vector ang;
 553         float p, y, len;
 554         if(vlen(vec) == 0)
 555                 return 0;
 556         //print("compress: ", vtos(vec), "\n");
 557         ang = vectoangles(vec);
 558         ang_x = -ang_x;
 559         if(ang_x < -90)
 560                 ang_x += 360;
 561         if(ang_x < -90 && ang_x > +90)
 562                 error("BOGUS vectoangles");
 563         //print("angles: ", vtos(ang), "\n");
 564
 565         p = floor(0.5 + (ang_x + 90) * 16 / 180) & 15; // -90..90 to 0..14
 566         if(p == 0)
 567         {
 568                 if(vec_z < 0)
 569                         y = 31;
 570                 else
 571                         y = 30;
 572         }
 573         else
 574                 y = floor(0.5 + ang_y * 32 / 360)          & 31; // 0..360 to 0..32
 575         len = invertLengthLog(vlen(vec));
 576
 577         //print("compressed: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
 578
 579         return (p * 0x1000) + (y * 0x80) + len;
 580 }
 581
 582 void compressShortVector_init()
 583 {
 584         float l, f, i;
 585         l = 1;
 586         f = pow(2, 1/8);
 587         for(i = 0; i < 128; ++i)
 588         {
 589                 lengthLogTable[i] = l;
 590                 l *= f;
 591         }
 592
 593         if(cvar("developer"))
 594         {
 595                 print("Verifying vector compression table...\n");
 596                 for(i = 0x0F00; i < 0xFFFF; ++i)
 597                         if(i != compressShortVector(decompressShortVector(i)))
 598                         {
 599                                 print("BROKEN vector compression: ", ftos(i));
 600                                 print(" -> ", vtos(decompressShortVector(i)));
 601                                 print(" -> ", ftos(compressShortVector(decompressShortVector(i))));
 602                                 print("\n");
 603                                 error("b0rk");
 604                         }
 605                 print("Done.\n");
 606         }
 607 }
 608
 609 #ifndef MENUQC
 610 float CheckWireframeBox(entity forent, vector v0, vector dvx, vector dvy, vector dvz)
 611 {
 612         traceline(v0, v0 + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 613         traceline(v0, v0 + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 614         traceline(v0, v0 + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 615         traceline(v0 + dvx, v0 + dvx + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 616         traceline(v0 + dvx, v0 + dvx + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 617         traceline(v0 + dvy, v0 + dvy + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 618         traceline(v0 + dvy, v0 + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 619         traceline(v0 + dvz, v0 + dvz + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 620         traceline(v0 + dvz, v0 + dvz + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 621         traceline(v0 + dvx + dvy, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 622         traceline(v0 + dvx + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 623         traceline(v0 + dvy + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 624         return 1;
 625 }
 626 #endif
 627
 628 string fixPriorityList(string order, float from, float to, float subtract, float complete)
 629 {
 630         string neworder;
 631         float i, n, w;
 632
 633         n = tokenize_console(order);
 634         neworder = "";
 635         for(i = 0; i < n; ++i)
 636         {
 637                 w = stof(argv(i));
 638                 if(w == floor(w))
 639                 {
 640                         if(w >= from && w <= to)
 641                                 neworder = strcat(neworder, ftos(w), " ");
 642                         else
 643                         {
 644                                 w -= subtract;
 645                                 if(w >= from && w <= to)
 646                                         neworder = strcat(neworder, ftos(w), " ");
 647                         }
 648                 }
 649         }
 650
 651         if(complete)
 652         {
 653                 n = tokenize_console(neworder);
 654                 for(w = to; w >= from; --w)
 655                 {
 656                         for(i = 0; i < n; ++i)
 657                                 if(stof(argv(i)) == w)
 658                                         break;
 659                         if(i == n) // not found
 660                                 neworder = strcat(neworder, ftos(w), " ");
 661                 }
 662         }
 663
 664         return substring(neworder, 0, strlen(neworder) - 1);
 665 }
 666
 667 string mapPriorityList(string order, string(string) mapfunc)
 668 {
 669         string neworder;
 670         float i, n;
 671
 672         n = tokenize_console(order);
 673         neworder = "";
 674         for(i = 0; i < n; ++i)
 675                 neworder = strcat(neworder, mapfunc(argv(i)), " ");
 676
 677         return substring(neworder, 0, strlen(neworder) - 1);
 678 }
 679
 680 string swapInPriorityList(string order, float i, float j)
 681 {
 682         string s;
 683         float w, n;
 684
 685         n = tokenize_console(order);
 686
 687         if(i >= 0 && i < n && j >= 0 && j < n && i != j)
 688         {
 689                 s = "";
 690                 for(w = 0; w < n; ++w)
 691                 {
 692                         if(w == i)
 693                                 s = strcat(s, argv(j), " ");
 694                         else if(w == j)
 695                                 s = strcat(s, argv(i), " ");
 696                         else
 697                                 s = strcat(s, argv(w), " ");
 698                 }
 699                 return substring(s, 0, strlen(s) - 1);
 700         }
 701
 702         return order;
 703 }
 704
 705 float cvar_value_issafe(string s)
 706 {
 707         if(strstrofs(s, "\"", 0) >= 0)
 708                 return 0;
 709         if(strstrofs(s, "\\", 0) >= 0)
 710                 return 0;
 711         if(strstrofs(s, ";", 0) >= 0)
 712                 return 0;
 713         if(strstrofs(s, "$", 0) >= 0)
 714                 return 0;
 715         if(strstrofs(s, "\r", 0) >= 0)
 716                 return 0;
 717         if(strstrofs(s, "\n", 0) >= 0)
 718                 return 0;
 719         return 1;
 720 }
 721
 722 #ifndef MENUQC
 723 void get_mi_min_max(float mode)
 724 {
 725         vector mi, ma;
 726
 727         if(mi_shortname)
 728                 strunzone(mi_shortname);
 729         mi_shortname = mapname;
 730         if(!strcasecmp(substring(mi_shortname, 0, 5), "maps/"))
 731                 mi_shortname = substring(mi_shortname, 5, strlen(mi_shortname) - 5);
 732         if(!strcasecmp(substring(mi_shortname, strlen(mi_shortname) - 4, 4), ".bsp"))
 733                 mi_shortname = substring(mi_shortname, 0, strlen(mi_shortname) - 4);
 734         mi_shortname = strzone(mi_shortname);
 735
 736 #ifdef CSQC
 737         mi = world.mins;
 738         ma = world.maxs;
 739 #else
 740         mi = world.absmin;
 741         ma = world.absmax;
 742 #endif
 743
 744         mi_min = mi;
 745         mi_max = ma;
 746         MapInfo_Get_ByName(mi_shortname, 0, 0);
 747         if(MapInfo_Map_mins_x < MapInfo_Map_maxs_x)
 748         {
 749                 mi_min = MapInfo_Map_mins;
 750                 mi_max = MapInfo_Map_maxs;
 751         }
 752         else
 753         {
 754                 // not specified
 755                 if(mode)
 756                 {
 757                         // be clever
 758                         tracebox('1 0 0' * mi_x,
 759                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 760                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 761                                          '1 0 0' * ma_x,
 762                                          MOVE_WORLDONLY,
 763                                          world);
 764                         if(!trace_startsolid)
 765                                 mi_min_x = trace_endpos_x;
 766
 767                         tracebox('0 1 0' * mi_y,
 768                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 769                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 770                                          '0 1 0' * ma_y,
 771                                          MOVE_WORLDONLY,
 772                                          world);
 773                         if(!trace_startsolid)
 774                                 mi_min_y = trace_endpos_y;
 775
 776                         tracebox('0 0 1' * mi_z,
 777                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 778                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 779                                          '0 0 1' * ma_z,
 780                                          MOVE_WORLDONLY,
 781                                          world);
 782                         if(!trace_startsolid)
 783                                 mi_min_z = trace_endpos_z;
 784
 785                         tracebox('1 0 0' * ma_x,
 786                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 787                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 788                                          '1 0 0' * mi_x,
 789                                          MOVE_WORLDONLY,
 790                                          world);
 791                         if(!trace_startsolid)
 792                                 mi_max_x = trace_endpos_x;
 793
 794                         tracebox('0 1 0' * ma_y,
 795                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 796                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 797                                          '0 1 0' * mi_y,
 798                                          MOVE_WORLDONLY,
 799                                          world);
 800                         if(!trace_startsolid)
 801                                 mi_max_y = trace_endpos_y;
 802
 803                         tracebox('0 0 1' * ma_z,
 804                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 805                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 806                                          '0 0 1' * mi_z,
 807                                          MOVE_WORLDONLY,
 808                                          world);
 809                         if(!trace_startsolid)
 810                                 mi_max_z = trace_endpos_z;
 811                 }
 812         }
 813 }
 814
 815 void get_mi_min_max_texcoords(float mode)
 816 {
 817         vector extend;
 818
 819         get_mi_min_max(mode);
 820
 821         mi_picmin = mi_min;
 822         mi_picmax = mi_max;
 823
 824         // extend mi_picmax to get a square aspect ratio
 825         // center the map in that area
 826         extend = mi_picmax - mi_picmin;
 827         if(extend_y > extend_x)
 828         {
 829                 mi_picmin_x -= (extend_y - extend_x) * 0.5;
 830                 mi_picmax_x += (extend_y - extend_x) * 0.5;
 831         }
 832         else
 833         {
 834                 mi_picmin_y -= (extend_x - extend_y) * 0.5;
 835                 mi_picmax_y += (extend_x - extend_y) * 0.5;
 836         }
 837
 838         // add another some percent
 839         extend = (mi_picmax - mi_picmin) * (1 / 64.0);
 840         mi_picmin -= extend;
 841         mi_picmax += extend;
 842
 843         // calculate the texcoords
 844         mi_pictexcoord0 = mi_pictexcoord1 = mi_pictexcoord2 = mi_pictexcoord3 = '0 0 0';
 845         // first the two corners of the origin
 846         mi_pictexcoord0_x = (mi_min_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 847         mi_pictexcoord0_y = (mi_min_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 848         mi_pictexcoord2_x = (mi_max_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 849         mi_pictexcoord2_y = (mi_max_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 850         // then the other corners
 851         mi_pictexcoord1_x = mi_pictexcoord0_x;
 852         mi_pictexcoord1_y = mi_pictexcoord2_y;
 853         mi_pictexcoord3_x = mi_pictexcoord2_x;
 854         mi_pictexcoord3_y = mi_pictexcoord0_y;
 855 }
 856 #endif
 857
 858 float cvar_settemp(string tmp_cvar, string tmp_value)
 859 {
 860         float created_saved_value;
 861         entity e;
 862
 863         if not(tmp_cvar || tmp_value)
 864         {
 865                 dprint("Error: Invalid usage of cvar_settemp(string, string); !\n");
 866                 return FALSE;
 867         }
 868
 869         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
 870                 if(e.netname == tmp_cvar)
 871                         goto saved; // skip creation
 872
 873         // creating a new entity to keep track of this cvar
 874         e = spawn();
 875         e.classname = "saved_cvar_value";
 876         e.netname = strzone(tmp_cvar);
 877         e.message = strzone(cvar_string(tmp_cvar));
 878         created_saved_value = TRUE;
 879
 880         // an entity for this cvar already exists
 881         :saved
 882
 883         // update the cvar to the value given
 884         cvar_set(tmp_cvar, tmp_value);
 885
 886         return created_saved_value;
 887 }
 888
 889 float cvar_settemp_restore()
 890 {
 891         float i;
 892         entity e;
 893         while((e = find(world, classname, "saved_cvar_value")))
 894         {
 895                 cvar_set(e.netname, e.message);
 896                 remove(e);
 897         }
 898
 899         return i;
 900 }
 901
 902 float almost_equals(float a, float b)
 903 {
 904         float eps;
 905         eps = (max(a, -a) + max(b, -b)) * 0.001;
 906         if(a - b < eps && b - a < eps)
 907                 return TRUE;
 908         return FALSE;
 909 }
 910
 911 float almost_in_bounds(float a, float b, float c)
 912 {
 913         float eps;
 914         eps = (max(a, -a) + max(c, -c)) * 0.001;
 915         if(a > c)
 916                 eps = -eps;
 917         return b == median(a - eps, b, c + eps);
 918 }
 919
 920 float power2of(float e)
 921 {
 922         return pow(2, e);
 923 }
 924 float log2of(float x)
 925 {
 926         // NOTE: generated code
 927         if(x > 2048)
 928                 if(x > 131072)
 929                         if(x > 1048576)
 930                                 if(x > 4194304)
 931                                         return 23;
 932                                 else
 933                                         if(x > 2097152)
 934                                                 return 22;
 935                                         else
 936                                                 return 21;
 937                         else
 938                                 if(x > 524288)
 939                                         return 20;
 940                                 else
 941                                         if(x > 262144)
 942                                                 return 19;
 943                                         else
 944                                                 return 18;
 945                 else
 946                         if(x > 16384)
 947                                 if(x > 65536)
 948                                         return 17;
 949                                 else
 950                                         if(x > 32768)
 951                                                 return 16;
 952                                         else
 953                                                 return 15;
 954                         else
 955                                 if(x > 8192)
 956                                         return 14;
 957                                 else
 958                                         if(x > 4096)
 959                                                 return 13;
 960                                         else
 961                                                 return 12;
 962         else
 963                 if(x > 32)
 964                         if(x > 256)
 965                                 if(x > 1024)
 966                                         return 11;
 967                                 else
 968                                         if(x > 512)
 969                                                 return 10;
 970                                         else
 971                                                 return 9;
 972                         else
 973                                 if(x > 128)
 974                                         return 8;
 975                                 else
 976                                         if(x > 64)
 977                                                 return 7;
 978                                         else
 979                                                 return 6;
 980                 else
 981                         if(x > 4)
 982                                 if(x > 16)
 983                                         return 5;
 984                                 else
 985                                         if(x > 8)
 986                                                 return 4;
 987                                         else
 988                                                 return 3;
 989                         else
 990                                 if(x > 2)
 991                                         return 2;
 992                                 else
 993                                         if(x > 1)
 994                                                 return 1;
 995                                         else
 996                                                 return 0;
 997 }
 998
 999 float rgb_mi_ma_to_hue(vector rgb, float mi, float ma)
1000 {
1001         if(mi == ma)
1002                 return 0;
1003         else if(ma == rgb_x)
1004         {
1005                 if(rgb_y >= rgb_z)
1006                         return (rgb_y - rgb_z) / (ma - mi);
1007                 else
1008                         return (rgb_y - rgb_z) / (ma - mi) + 6;
1009         }
1010         else if(ma == rgb_y)
1011                 return (rgb_z - rgb_x) / (ma - mi) + 2;
1012         else // if(ma == rgb_z)
1013                 return (rgb_x - rgb_y) / (ma - mi) + 4;
1014 }
1015
1016 vector hue_mi_ma_to_rgb(float hue, float mi, float ma)
1017 {
1018         vector rgb;
1019
1020         hue -= 6 * floor(hue / 6);
1021
1022         //else if(ma == rgb_x)
1023         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1024         if(hue <= 1)
1025         {
1026                 rgb_x = ma;
1027                 rgb_y = hue * (ma - mi) + mi;
1028                 rgb_z = mi;
1029         }
1030         //else if(ma == rgb_y)
1031         //      hue = 60 * (rgb_z - rgb_x) / (ma - mi) + 120;
1032         else if(hue <= 2)
1033         {
1034                 rgb_x = (2 - hue) * (ma - mi) + mi;
1035                 rgb_y = ma;
1036                 rgb_z = mi;
1037         }
1038         else if(hue <= 3)
1039         {
1040                 rgb_x = mi;
1041                 rgb_y = ma;
1042                 rgb_z = (hue - 2) * (ma - mi) + mi;
1043         }
1044         //else // if(ma == rgb_z)
1045         //      hue = 60 * (rgb_x - rgb_y) / (ma - mi) + 240;
1046         else if(hue <= 4)
1047         {
1048                 rgb_x = mi;
1049                 rgb_y = (4 - hue) * (ma - mi) + mi;
1050                 rgb_z = ma;
1051         }
1052         else if(hue <= 5)
1053         {
1054                 rgb_x = (hue - 4) * (ma - mi) + mi;
1055                 rgb_y = mi;
1056                 rgb_z = ma;
1057         }
1058         //else if(ma == rgb_x)
1059         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1060         else // if(hue <= 6)
1061         {
1062                 rgb_x = ma;
1063                 rgb_y = mi;
1064                 rgb_z = (6 - hue) * (ma - mi) + mi;
1065         }
1066
1067         return rgb;
1068 }
1069
1070 vector rgb_to_hsv(vector rgb)
1071 {
1072         float mi, ma;
1073         vector hsv;
1074
1075         mi = min(rgb_x, rgb_y, rgb_z);
1076         ma = max(rgb_x, rgb_y, rgb_z);
1077
1078         hsv_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1079         hsv_z = ma;
1080
1081         if(ma == 0)
1082                 hsv_y = 0;
1083         else
1084                 hsv_y = 1 - mi/ma;
1085
1086         return hsv;
1087 }
1088
1089 vector hsv_to_rgb(vector hsv)
1090 {
1091         return hue_mi_ma_to_rgb(hsv_x, hsv_z * (1 - hsv_y), hsv_z);
1092 }
1093
1094 vector rgb_to_hsl(vector rgb)
1095 {
1096         float mi, ma;
1097         vector hsl;
1098
1099         mi = min(rgb_x, rgb_y, rgb_z);
1100         ma = max(rgb_x, rgb_y, rgb_z);
1101
1102         hsl_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1103
1104         hsl_z = 0.5 * (mi + ma);
1105         if(mi == ma)
1106                 hsl_y = 0;
1107         else if(hsl_z <= 0.5)
1108                 hsl_y = (ma - mi) / (2*hsl_z);
1109         else // if(hsl_z > 0.5)
1110                 hsl_y = (ma - mi) / (2 - 2*hsl_z);
1111
1112         return hsl;
1113 }
1114
1115 vector hsl_to_rgb(vector hsl)
1116 {
1117         float mi, ma, maminusmi;
1118
1119         if(hsl_z <= 0.5)
1120                 maminusmi = hsl_y * 2 * hsl_z;
1121         else
1122                 maminusmi = hsl_y * (2 - 2 * hsl_z);
1123
1124         // hsl_z     = 0.5 * mi + 0.5 * ma
1125         // maminusmi =     - mi +       ma
1126         mi = hsl_z - 0.5 * maminusmi;
1127         ma = hsl_z + 0.5 * maminusmi;
1128
1129         return hue_mi_ma_to_rgb(hsl_x, mi, ma);
1130 }
1131
1132 string rgb_to_hexcolor(vector rgb)
1133 {
1134         return
1135                 strcat(
1136                         "^x",
1137                         DEC_TO_HEXDIGIT(floor(rgb_x * 15 + 0.5)),
1138                         DEC_TO_HEXDIGIT(floor(rgb_y * 15 + 0.5)),
1139                         DEC_TO_HEXDIGIT(floor(rgb_z * 15 + 0.5))
1140                 );
1141 }
1142
1143 // requires that m2>m1 in all coordinates, and that m4>m3
1144 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;}
1145
1146 // requires the same, but is a stronger condition
1147 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;}
1148
1149 #ifndef MENUQC
1150 #endif
1151
1152 float textLengthUpToWidth(string theText, float maxWidth, vector theSize, textLengthUpToWidth_widthFunction_t w)
1153 {
1154         // STOP.
1155         // The following function is SLOW.
1156         // For your safety and for the protection of those around you...
1157         // DO NOT CALL THIS AT HOME.
1158         // No really, don't.
1159         if(w(theText, theSize) <= maxWidth)
1160                 return strlen(theText); // yeah!
1161
1162         // binary search for right place to cut string
1163         float ch;
1164         float left, right, middle; // this always works
1165         left = 0;
1166         right = strlen(theText); // this always fails
1167         do
1168         {
1169                 middle = floor((left + right) / 2);
1170                 if(w(substring(theText, 0, middle), theSize) <= maxWidth)
1171                         left = middle;
1172                 else
1173                         right = middle;
1174         }
1175         while(left < right - 1);
1176
1177         if(w("^7", theSize) == 0) // detect color codes support in the width function
1178         {
1179                 // NOTE: when color codes are involved, this binary search is,
1180                 // mathematically, BROKEN. However, it is obviously guaranteed to
1181                 // terminate, as the range still halves each time - but nevertheless, it is
1182                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1183                 // range, and "right" is outside).
1184
1185                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1186                 // and decrease left on the basis of the chars detected of the truncated tag
1187                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1188                 // (sometimes too much but with a correct result)
1189                 // it fixes also ^[0-9]
1190                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1191                         left-=1;
1192
1193                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1194                         left-=2;
1195                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1196                         {
1197                                 ch = str2chr(theText, left-1);
1198                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1199                                         left-=3;
1200                         }
1201                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1202                         {
1203                                 ch = str2chr(theText, left-2);
1204                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1205                                 {
1206                                         ch = str2chr(theText, left-1);
1207                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1208                                                 left-=4;
1209                                 }
1210                         }
1211         }
1212
1213         return left;
1214 }
1215
1216 float textLengthUpToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t w)
1217 {
1218         // STOP.
1219         // The following function is SLOW.
1220         // For your safety and for the protection of those around you...
1221         // DO NOT CALL THIS AT HOME.
1222         // No really, don't.
1223         if(w(theText) <= maxWidth)
1224                 return strlen(theText); // yeah!
1225
1226         // binary search for right place to cut string
1227         float ch;
1228         float left, right, middle; // this always works
1229         left = 0;
1230         right = strlen(theText); // this always fails
1231         do
1232         {
1233                 middle = floor((left + right) / 2);
1234                 if(w(substring(theText, 0, middle)) <= maxWidth)
1235                         left = middle;
1236                 else
1237                         right = middle;
1238         }
1239         while(left < right - 1);
1240
1241         if(w("^7") == 0) // detect color codes support in the width function
1242         {
1243                 // NOTE: when color codes are involved, this binary search is,
1244                 // mathematically, BROKEN. However, it is obviously guaranteed to
1245                 // terminate, as the range still halves each time - but nevertheless, it is
1246                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1247                 // range, and "right" is outside).
1248
1249                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1250                 // and decrease left on the basis of the chars detected of the truncated tag
1251                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1252                 // (sometimes too much but with a correct result)
1253                 // it fixes also ^[0-9]
1254                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1255                         left-=1;
1256
1257                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1258                         left-=2;
1259                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1260                         {
1261                                 ch = str2chr(theText, left-1);
1262                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1263                                         left-=3;
1264                         }
1265                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1266                         {
1267                                 ch = str2chr(theText, left-2);
1268                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1269                                 {
1270                                         ch = str2chr(theText, left-1);
1271                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1272                                                 left-=4;
1273                                 }
1274                         }
1275         }
1276
1277         return left;
1278 }
1279
1280 string find_last_color_code(string s)
1281 {
1282         float start, len, i, carets;
1283         start = strstrofs(s, "^", 0);
1284         if (start == -1) // no caret found
1285                 return "";
1286         len = strlen(s)-1;
1287         for(i = len; i >= start; --i)
1288         {
1289                 if(substring(s, i, 1) != "^")
1290                         continue;
1291
1292                 carets = 1;
1293                 while (i-carets >= start && substring(s, i-carets, 1) == "^")
1294                         ++carets;
1295
1296                 // check if carets aren't all escaped
1297                 if (carets == 1 || mod(carets, 2) == 1) // first check is just an optimization
1298                 {
1299                         if(i+1 <= len)
1300                         if(strstrofs("0123456789", substring(s, i+1, 1), 0) >= 0)
1301                                 return substring(s, i, 2);
1302
1303                         if(i+4 <= len)
1304                         if(substring(s, i+1, 1) == "x")
1305                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+2, 1), 0) >= 0)
1306                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+3, 1), 0) >= 0)
1307                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+4, 1), 0) >= 0)
1308                                 return substring(s, i, 5);
1309                 }
1310                 i -= carets; // this also skips one char before the carets
1311         }
1312
1313         return "";
1314 }
1315
1316 string getWrappedLine(float w, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1317 {
1318         float cantake;
1319         float take;
1320         string s;
1321
1322         s = getWrappedLine_remaining;
1323
1324         if(w <= 0)
1325         {
1326                 getWrappedLine_remaining = string_null;
1327                 return s; // the line has no size ANYWAY, nothing would be displayed.
1328         }
1329
1330         cantake = textLengthUpToWidth(s, w, theFontSize, tw);
1331         if(cantake > 0 && cantake < strlen(s))
1332         {
1333                 take = cantake - 1;
1334                 while(take > 0 && substring(s, take, 1) != " ")
1335                         --take;
1336                 if(take == 0)
1337                 {
1338                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1339                         if(getWrappedLine_remaining == "")
1340                                 getWrappedLine_remaining = string_null;
1341                         else if (tw("^7", theFontSize) == 0)
1342                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
1343                         return substring(s, 0, cantake);
1344                 }
1345                 else
1346                 {
1347                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1348                         if(getWrappedLine_remaining == "")
1349                                 getWrappedLine_remaining = string_null;
1350                         else if (tw("^7", theFontSize) == 0)
1351                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
1352                         return substring(s, 0, take);
1353                 }
1354         }
1355         else
1356         {
1357                 getWrappedLine_remaining = string_null;
1358                 return s;
1359         }
1360 }
1361
1362 string getWrappedLineLen(float w, textLengthUpToLength_lenFunction_t tw)
1363 {
1364         float cantake;
1365         float take;
1366         string s;
1367
1368         s = getWrappedLine_remaining;
1369
1370         if(w <= 0)
1371         {
1372                 getWrappedLine_remaining = string_null;
1373                 return s; // the line has no size ANYWAY, nothing would be displayed.
1374         }
1375
1376         cantake = textLengthUpToLength(s, w, tw);
1377         if(cantake > 0 && cantake < strlen(s))
1378         {
1379                 take = cantake - 1;
1380                 while(take > 0 && substring(s, take, 1) != " ")
1381                         --take;
1382                 if(take == 0)
1383                 {
1384                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1385                         if(getWrappedLine_remaining == "")
1386                                 getWrappedLine_remaining = string_null;
1387                         else if (tw("^7") == 0)
1388                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
1389                         return substring(s, 0, cantake);
1390                 }
1391                 else
1392                 {
1393                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1394                         if(getWrappedLine_remaining == "")
1395                                 getWrappedLine_remaining = string_null;
1396                         else if (tw("^7") == 0)
1397                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
1398                         return substring(s, 0, take);
1399                 }
1400         }
1401         else
1402         {
1403                 getWrappedLine_remaining = string_null;
1404                 return s;
1405         }
1406 }
1407
1408 string textShortenToWidth(string theText, float maxWidth, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1409 {
1410         if(tw(theText, theFontSize) <= maxWidth)
1411                 return theText;
1412         else
1413                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - tw("...", theFontSize), theFontSize, tw)), "...");
1414 }
1415
1416 string textShortenToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t tw)
1417 {
1418         if(tw(theText) <= maxWidth)
1419                 return theText;
1420         else
1421                 return strcat(substring(theText, 0, textLengthUpToLength(theText, maxWidth - tw("..."), tw)), "...");
1422 }
1423
1424 float isGametypeInFilter(float gt, float tp, float ts, string pattern)
1425 {
1426         string subpattern, subpattern2, subpattern3, subpattern4;
1427         subpattern = strcat(",", MapInfo_Type_ToString(gt), ",");
1428         if(tp)
1429                 subpattern2 = ",teams,";
1430         else
1431                 subpattern2 = ",noteams,";
1432         if(ts)
1433                 subpattern3 = ",teamspawns,";
1434         else
1435                 subpattern3 = ",noteamspawns,";
1436         if(gt == MAPINFO_TYPE_RACE || gt == MAPINFO_TYPE_CTS)
1437                 subpattern4 = ",race,";
1438         else
1439                 subpattern4 = string_null;
1440
1441         if(substring(pattern, 0, 1) == "-")
1442         {
1443                 pattern = substring(pattern, 1, strlen(pattern) - 1);
1444                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
1445                         return 0;
1446                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
1447                         return 0;
1448                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) >= 0)
1449                         return 0;
1450                 if(subpattern4 && strstrofs(strcat(",", pattern, ","), subpattern4, 0) >= 0)
1451                         return 0;
1452         }
1453         else
1454         {
1455                 if(substring(pattern, 0, 1) == "+")
1456                         pattern = substring(pattern, 1, strlen(pattern) - 1);
1457                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
1458                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
1459                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) < 0)
1460                 if((!subpattern4) || strstrofs(strcat(",", pattern, ","), subpattern4, 0) < 0)
1461                         return 0;
1462         }
1463         return 1;
1464 }
1465
1466 void shuffle(float n, swapfunc_t swap, entity pass)
1467 {
1468         float i, j;
1469         for(i = 1; i < n; ++i)
1470         {
1471                 // swap i-th item at a random position from 0 to i
1472                 // proof for even distribution:
1473                 //   n = 1: obvious
1474                 //   n -> n+1:
1475                 //     item n+1 gets at any position with chance 1/(n+1)
1476                 //     all others will get their 1/n chance reduced by factor n/(n+1)
1477                 //     to be on place n+1, their chance will be 1/(n+1)
1478                 //     1/n * n/(n+1) = 1/(n+1)
1479                 //     q.e.d.
1480                 j = floor(random() * (i + 1));
1481                 if(j != i)
1482                         swap(j, i, pass);
1483         }
1484 }
1485
1486 string substring_range(string s, float b, float e)
1487 {
1488         return substring(s, b, e - b);
1489 }
1490
1491 string swapwords(string str, float i, float j)
1492 {
1493         float n;
1494         string s1, s2, s3, s4, s5;
1495         float si, ei, sj, ej, s0, en;
1496         n = tokenizebyseparator(str, " "); // must match g_maplist processing in ShuffleMaplist and "shuffle"
1497         si = argv_start_index(i);
1498         sj = argv_start_index(j);
1499         ei = argv_end_index(i);
1500         ej = argv_end_index(j);
1501         s0 = argv_start_index(0);
1502         en = argv_end_index(n-1);
1503         s1 = substring_range(str, s0, si);
1504         s2 = substring_range(str, si, ei);
1505         s3 = substring_range(str, ei, sj);
1506         s4 = substring_range(str, sj, ej);
1507         s5 = substring_range(str, ej, en);
1508         return strcat(s1, s4, s3, s2, s5);
1509 }
1510
1511 string _shufflewords_str;
1512 void _shufflewords_swapfunc(float i, float j, entity pass)
1513 {
1514         _shufflewords_str = swapwords(_shufflewords_str, i, j);
1515 }
1516 string shufflewords(string str)
1517 {
1518         float n;
1519         _shufflewords_str = str;
1520         n = tokenizebyseparator(str, " ");
1521         shuffle(n, _shufflewords_swapfunc, world);
1522         str = _shufflewords_str;
1523         _shufflewords_str = string_null;
1524         return str;
1525 }
1526
1527 vector solve_quadratic(float a, float b, float c) // ax^2 + bx + c = 0
1528 {
1529         vector v;
1530         float D;
1531         v = '0 0 0';
1532         if(a == 0)
1533         {
1534                 if(b != 0)
1535                 {
1536                         v_x = v_y = -c / b;
1537                         v_z = 1;
1538                 }
1539                 else
1540                 {
1541                         if(c == 0)
1542                         {
1543                                 // actually, every number solves the equation!
1544                                 v_z = 1;
1545                         }
1546                 }
1547         }
1548         else
1549         {
1550                 D = b*b - 4*a*c;
1551                 if(D >= 0)
1552                 {
1553                         D = sqrt(D);
1554                         if(a > 0) // put the smaller solution first
1555                         {
1556                                 v_x = ((-b)-D) / (2*a);
1557                                 v_y = ((-b)+D) / (2*a);
1558                         }
1559                         else
1560                         {
1561                                 v_x = (-b+D) / (2*a);
1562                                 v_y = (-b-D) / (2*a);
1563                         }
1564                         v_z = 1;
1565                 }
1566                 else
1567                 {
1568                         // complex solutions!
1569                         D = sqrt(-D);
1570                         v_x = -b / (2*a);
1571                         if(a > 0)
1572                                 v_y =  D / (2*a);
1573                         else
1574                                 v_y = -D / (2*a);
1575                         v_z = 0;
1576                 }
1577         }
1578         return v;
1579 }
1580
1581 void check_unacceptable_compiler_bugs()
1582 {
1583         if(cvar("_allow_unacceptable_compiler_bugs"))
1584                 return;
1585         tokenize_console("foo bar");
1586         if(strcat(argv(0), substring("foo bar", 4, 7 - argv_start_index(1))) == "barbar")
1587                 error("fteqcc bug introduced with revision 3178 detected. Please upgrade fteqcc to a later revision, downgrade fteqcc to revision 3177, or pester Spike until he fixes it. You can set _allow_unacceptable_compiler_bugs 1 to skip this check, but expect stuff to be horribly broken then.");
1588
1589         string s = "";
1590         if not(s)
1591                 error("The empty string counts as false. We do not want that!");
1592 }
1593
1594 float compressShotOrigin(vector v)
1595 {
1596         float x, y, z;
1597         x = rint(v_x * 2);
1598         y = rint(v_y * 4) + 128;
1599         z = rint(v_z * 4) + 128;
1600         if(x > 255 || x < 0)
1601         {
1602                 print("shot origin ", vtos(v), " x out of bounds\n");
1603                 x = bound(0, x, 255);
1604         }
1605         if(y > 255 || y < 0)
1606         {
1607                 print("shot origin ", vtos(v), " y out of bounds\n");
1608                 y = bound(0, y, 255);
1609         }
1610         if(z > 255 || z < 0)
1611         {
1612                 print("shot origin ", vtos(v), " z out of bounds\n");
1613                 z = bound(0, z, 255);
1614         }
1615         return x * 0x10000 + y * 0x100 + z;
1616 }
1617 vector decompressShotOrigin(float f)
1618 {
1619         vector v;
1620         v_x = ((f & 0xFF0000) / 0x10000) / 2;
1621         v_y = ((f & 0xFF00) / 0x100 - 128) / 4;
1622         v_z = ((f & 0xFF) - 128) / 4;
1623         return v;
1624 }
1625
1626 void heapsort(float n, swapfunc_t swap, comparefunc_t cmp, entity pass)
1627 {
1628         float start, end, root, child;
1629
1630         // heapify
1631         start = floor((n - 2) / 2);
1632         while(start >= 0)
1633         {
1634                 // siftdown(start, count-1);
1635                 root = start;
1636                 while(root * 2 + 1 <= n-1)
1637                 {
1638                         child = root * 2 + 1;
1639                         if(child < n-1)
1640                                 if(cmp(child, child+1, pass) < 0)
1641                                         ++child;
1642                         if(cmp(root, child, pass) < 0)
1643                         {
1644                                 swap(root, child, pass);
1645                                 root = child;
1646                         }
1647                         else
1648                                 break;
1649                 }
1650                 // end of siftdown
1651                 --start;
1652         }
1653
1654         // extract
1655         end = n - 1;
1656         while(end > 0)
1657         {
1658                 swap(0, end, pass);
1659                 --end;
1660                 // siftdown(0, end);
1661                 root = 0;
1662                 while(root * 2 + 1 <= end)
1663                 {
1664                         child = root * 2 + 1;
1665                         if(child < end && cmp(child, child+1, pass) < 0)
1666                                 ++child;
1667                         if(cmp(root, child, pass) < 0)
1668                         {
1669                                 swap(root, child, pass);
1670                                 root = child;
1671                         }
1672                         else
1673                                 break;
1674                 }
1675                 // end of siftdown
1676         }
1677 }
1678
1679 void RandomSelection_Init()
1680 {
1681         RandomSelection_totalweight = 0;
1682         RandomSelection_chosen_ent = world;
1683         RandomSelection_chosen_float = 0;
1684         RandomSelection_chosen_string = string_null;
1685         RandomSelection_best_priority = -1;
1686 }
1687 void RandomSelection_Add(entity e, float f, string s, float weight, float priority)
1688 {
1689         if(priority > RandomSelection_best_priority)
1690         {
1691                 RandomSelection_best_priority = priority;
1692                 RandomSelection_chosen_ent = e;
1693                 RandomSelection_chosen_float = f;
1694                 RandomSelection_chosen_string = s;
1695                 RandomSelection_totalweight = weight;
1696         }
1697         else if(priority == RandomSelection_best_priority)
1698         {
1699                 RandomSelection_totalweight += weight;
1700                 if(random() * RandomSelection_totalweight <= weight)
1701                 {
1702                         RandomSelection_chosen_ent = e;
1703                         RandomSelection_chosen_float = f;
1704                         RandomSelection_chosen_string = s;
1705                 }
1706         }
1707 }
1708
1709 vector healtharmor_maxdamage(float h, float a, float armorblock)
1710 {
1711         // NOTE: we'll always choose the SMALLER value...
1712         float healthdamage, armordamage, armorideal;
1713         vector v;
1714         healthdamage = (h - 1) / (1 - armorblock); // damage we can take if we could use more health
1715         armordamage = a + (h - 1); // damage we can take if we could use more armor
1716         armorideal = healthdamage * armorblock;
1717         v_y = armorideal;
1718         if(armordamage < healthdamage)
1719         {
1720                 v_x = armordamage;
1721                 v_z = 1;
1722         }
1723         else
1724         {
1725                 v_x = healthdamage;
1726                 v_z = 0;
1727         }
1728         return v;
1729 }
1730
1731 vector healtharmor_applydamage(float a, float armorblock, float damage)
1732 {
1733         vector v;
1734         v_y = bound(0, damage * armorblock, a); // save
1735         v_x = bound(0, damage - v_y, damage); // take
1736         v_z = 0;
1737         return v;
1738 }
1739
1740 string getcurrentmod()
1741 {
1742         float n;
1743         string m;
1744         m = cvar_string("fs_gamedir");
1745         n = tokenize_console(m);
1746         if(n == 0)
1747                 return "data";
1748         else
1749                 return argv(n - 1);
1750 }
1751
1752 #ifndef MENUQC
1753 #ifdef CSQC
1754 float ReadInt24_t()
1755 {
1756         float v;
1757         v = ReadShort() * 256; // note: this is signed
1758         v += ReadByte(); // note: this is unsigned
1759         return v;
1760 }
1761 #else
1762 void WriteInt24_t(float dst, float val)
1763 {
1764         float v;
1765         WriteShort(dst, (v = floor(val / 256)));
1766         WriteByte(dst, val - v * 256); // 0..255
1767 }
1768 #endif
1769 #endif
1770
1771 float float2range11(float f)
1772 {
1773         // continuous function mapping all reals into -1..1
1774         return f / (fabs(f) + 1);
1775 }
1776
1777 float float2range01(float f)
1778 {
1779         // continuous function mapping all reals into 0..1
1780         return 0.5 + 0.5 * float2range11(f);
1781 }
1782
1783 // from the GNU Scientific Library
1784 float gsl_ran_gaussian_lastvalue;
1785 float gsl_ran_gaussian_lastvalue_set;
1786 float gsl_ran_gaussian(float sigma)
1787 {
1788         float a, b;
1789         if(gsl_ran_gaussian_lastvalue_set)
1790         {
1791                 gsl_ran_gaussian_lastvalue_set = 0;
1792                 return sigma * gsl_ran_gaussian_lastvalue;
1793         }
1794         else
1795         {
1796                 a = random() * 2 * M_PI;
1797                 b = sqrt(-2 * log(random()));
1798                 gsl_ran_gaussian_lastvalue = cos(a) * b;
1799                 gsl_ran_gaussian_lastvalue_set = 1;
1800                 return sigma * sin(a) * b;
1801         }
1802 }
1803
1804 string car(string s)
1805 {
1806         float o;
1807         o = strstrofs(s, " ", 0);
1808         if(o < 0)
1809                 return s;
1810         return substring(s, 0, o);
1811 }
1812 string cdr(string s)
1813 {
1814         float o;
1815         o = strstrofs(s, " ", 0);
1816         if(o < 0)
1817                 return string_null;
1818         return substring(s, o + 1, strlen(s) - (o + 1));
1819 }
1820 float matchacl(string acl, string str)
1821 {
1822         string t, s;
1823         float r, d;
1824         r = 0;
1825         while(acl)
1826         {
1827                 t = car(acl); acl = cdr(acl);
1828                 d = 1;
1829                 if(substring(t, 0, 1) == "-")
1830                 {
1831                         d = -1;
1832                         t = substring(t, 1, strlen(t) - 1);
1833                 }
1834                 else if(substring(t, 0, 1) == "+")
1835                         t = substring(t, 1, strlen(t) - 1);
1836                 if(substring(t, -1, 1) == "*")
1837                 {
1838                         t = substring(t, 0, strlen(t) - 1);
1839                         s = substring(s, 0, strlen(t));
1840                 }
1841                 else
1842                         s = str;
1843
1844                 if(s == t)
1845                 {
1846                         r = d;
1847                 }
1848         }
1849         return r;
1850 }
1851 float startsWith(string haystack, string needle)
1852 {
1853         return substring(haystack, 0, strlen(needle)) == needle;
1854 }
1855 float startsWithNocase(string haystack, string needle)
1856 {
1857         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
1858 }
1859
1860 string get_model_datafilename(string m, float sk, string fil)
1861 {
1862         if(m)
1863                 m = strcat(m, "_");
1864         else
1865                 m = "models/player/*_";
1866         if(sk >= 0)
1867                 m = strcat(m, ftos(sk));
1868         else
1869                 m = strcat(m, "*");
1870         return strcat(m, ".", fil);
1871 }
1872
1873 float get_model_parameters(string m, float sk)
1874 {
1875         string fn, s, c;
1876         float fh;
1877
1878         get_model_parameters_modelname = string_null;
1879         get_model_parameters_modelskin = -1;
1880         get_model_parameters_name = string_null;
1881         get_model_parameters_species = -1;
1882         get_model_parameters_sex = string_null;
1883         get_model_parameters_weight = -1;
1884         get_model_parameters_age = -1;
1885         get_model_parameters_desc = string_null;
1886
1887         if not(m)
1888                 return 1;
1889         if(sk < 0)
1890         {
1891                 if(substring(m, -4, -1) != ".txt")
1892                         return 0;
1893                 if(substring(m, -6, 1) != "_")
1894                         return 0;
1895                 sk = stof(substring(m, -5, 1));
1896                 m = substring(m, 0, -7);
1897         }
1898
1899         fn = get_model_datafilename(m, sk, "txt");
1900         fh = fopen(fn, FILE_READ);
1901         if(fh < 0)
1902         {
1903                 sk = 0;
1904                 fn = get_model_datafilename(m, sk, "txt");
1905                 fh = fopen(fn, FILE_READ);
1906                 if(fh < 0)
1907                         return 0;
1908         }
1909
1910         get_model_parameters_modelname = m;
1911         get_model_parameters_modelskin = sk;
1912         while((s = fgets(fh)))
1913         {
1914                 if(s == "")
1915                         break; // next lines will be description
1916                 c = car(s);
1917                 s = cdr(s);
1918                 if(c == "name")
1919                         get_model_parameters_name = s;
1920                 if(c == "species")
1921                         switch(s)
1922                         {
1923                                 case "human":       get_model_parameters_species = SPECIES_HUMAN;       break;
1924                                 case "alien":       get_model_parameters_species = SPECIES_ALIEN;       break;
1925                                 case "robot_shiny": get_model_parameters_species = SPECIES_ROBOT_SHINY; break;
1926                                 case "robot_rusty": get_model_parameters_species = SPECIES_ROBOT_RUSTY; break;
1927                                 case "robot_solid": get_model_parameters_species = SPECIES_ROBOT_SOLID; break;
1928                                 case "animal":      get_model_parameters_species = SPECIES_ANIMAL;      break;
1929                                 case "reserved":    get_model_parameters_species = SPECIES_RESERVED;    break;
1930                         }
1931                 if(c == "sex")
1932                         get_model_parameters_sex = s;
1933                 if(c == "weight")
1934                         get_model_parameters_weight = stof(s);
1935                 if(c == "age")
1936                         get_model_parameters_age = stof(s);
1937         }
1938
1939         while((s = fgets(fh)))
1940         {
1941                 if(get_model_parameters_desc)
1942                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
1943                 if(s != "")
1944                         get_model_parameters_desc = strcat(get_model_parameters_desc, s);
1945         }
1946
1947         fclose(fh);
1948
1949         return 1;
1950 }
1951
1952 vector vec2(vector v)
1953 {
1954         v_z = 0;
1955         return v;
1956 }
1957
1958 #ifndef MENUQC
1959 vector NearestPointOnBox(entity box, vector org)
1960 {
1961         vector m1, m2, nearest;
1962
1963         m1 = box.mins + box.origin;
1964         m2 = box.maxs + box.origin;
1965
1966         nearest_x = bound(m1_x, org_x, m2_x);
1967         nearest_y = bound(m1_y, org_y, m2_y);
1968         nearest_z = bound(m1_z, org_z, m2_z);
1969
1970         return nearest;
1971 }
1972 #endif
1973
1974 float vercmp_recursive(string v1, string v2)
1975 {
1976         float dot1, dot2;
1977         string s1, s2;
1978         float r;
1979
1980         dot1 = strstrofs(v1, ".", 0);
1981         dot2 = strstrofs(v2, ".", 0);
1982         if(dot1 == -1)
1983                 s1 = v1;
1984         else
1985                 s1 = substring(v1, 0, dot1);
1986         if(dot2 == -1)
1987                 s2 = v2;
1988         else
1989                 s2 = substring(v2, 0, dot2);
1990
1991         r = stof(s1) - stof(s2);
1992         if(r != 0)
1993                 return r;
1994
1995         r = strcasecmp(s1, s2);
1996         if(r != 0)
1997                 return r;
1998
1999         if(dot1 == -1)
2000                 if(dot2 == -1)
2001                         return 0;
2002                 else
2003                         return -1;
2004         else
2005                 if(dot2 == -1)
2006                         return 1;
2007                 else
2008                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2009 }
2010
2011 float vercmp(string v1, string v2)
2012 {
2013         if(strcasecmp(v1, v2) == 0) // early out check
2014                 return 0;
2015
2016         // "git" beats all
2017         if(v1 == "git")
2018                 return 1;
2019         if(v2 == "git")
2020                 return -1;
2021
2022         return vercmp_recursive(v1, v2);
2023 }
2024
2025 float u8_strsize(string s)
2026 {
2027         float l, i, c;
2028         l = 0;
2029         for(i = 0; ; ++i)
2030         {
2031                 c = str2chr(s, i);
2032                 if(c <= 0)
2033                         break;
2034                 ++l;
2035                 if(c >= 0x80)
2036                         ++l;
2037                 if(c >= 0x800)
2038                         ++l;
2039                 if(c >= 0x10000)
2040                         ++l;
2041         }
2042         return l;
2043 }
2044
2045 // translation helpers
2046 string language_filename(string s)
2047 {
2048         string fn;
2049         float fh;
2050         fn = prvm_language;
2051         if(fn == "" || fn == "dump")
2052                 return s;
2053         fn = strcat(s, ".", fn);
2054         if((fh = fopen(fn, FILE_READ)) >= 0)
2055         {
2056                 fclose(fh);
2057                 return fn;
2058         }
2059         return s;
2060 }
2061 string CTX(string s)
2062 {
2063         float p = strstrofs(s, "^", 0);
2064         if(p < 0)
2065                 return s;
2066         return substring(s, p+1, -1);
2067 }
2068
2069 // x-encoding (encoding as zero length invisible string)
2070 const string XENCODE_2  = "xX";
2071 const string XENCODE_22 = "0123456789abcdefABCDEF";
2072 string xencode(float f)
2073 {
2074         float a, b, c, d;
2075         d = mod(f, 22); f = floor(f / 22);
2076         c = mod(f, 22); f = floor(f / 22);
2077         b = mod(f, 22); f = floor(f / 22);
2078         a = mod(f,  2); // f = floor(f /  2);
2079         return strcat(
2080                 "^",
2081                 substring(XENCODE_2,  a, 1),
2082                 substring(XENCODE_22, b, 1),
2083                 substring(XENCODE_22, c, 1),
2084                 substring(XENCODE_22, d, 1)
2085         );
2086 }
2087 float xdecode(string s)
2088 {
2089         float a, b, c, d;
2090         if(substring(s, 0, 1) != "^")
2091                 return -1;
2092         if(strlen(s) < 5)
2093                 return -1;
2094         a = strstrofs(XENCODE_2,  substring(s, 1, 1), 0);
2095         b = strstrofs(XENCODE_22, substring(s, 2, 1), 0);
2096         c = strstrofs(XENCODE_22, substring(s, 3, 1), 0);
2097         d = strstrofs(XENCODE_22, substring(s, 4, 1), 0);
2098         if(a < 0 || b < 0 || c < 0 || d < 0)
2099                 return -1;
2100         return ((a * 22 + b) * 22 + c) * 22 + d;
2101 }
2102
2103 float lowestbit(float f)
2104 {
2105         f &~= f * 2;
2106         f &~= f * 4;
2107         f &~= f * 16;
2108         f &~= f * 256;
2109         f &~= f * 65536;
2110         return f;
2111 }
2112
2113 /*
2114 string strlimitedlen(string input, string truncation, float strip_colors, float limit)
2115 {
2116         if(strlen((strip_colors ? strdecolorize(input) : input)) <= limit)
2117                 return input;
2118         else
2119                 return strcat(substring(input, 0, (strlen(input) - strlen(truncation))), truncation);
2120 }*/
2121
2122 // escape the string to make it safe for consoles
2123 string MakeConsoleSafe(string input)
2124 {
2125         input = strreplace("\n", "", input);
2126         input = strreplace("\\", "\\\\", input);
2127         input = strreplace("$", "$$", input);
2128         input = strreplace("\"", "\\\"", input);
2129         return input;
2130 }
2131
2132 #ifndef MENUQC
2133 // get true/false value of a string with multiple different inputs
2134 float InterpretBoolean(string input)
2135 {
2136         switch(strtolower(input))
2137         {
2138                 case "yes":
2139                 case "true":
2140                 case "on":
2141                         return TRUE;
2142
2143                 case "no":
2144                 case "false":
2145                 case "off":
2146                         return FALSE;
2147
2148                 default: return stof(input);
2149         }
2150 }
2151 #endif
2152
2153 #ifdef CSQC
2154 entity ReadCSQCEntity()
2155 {
2156         float f;
2157         f = ReadShort();
2158         if(f == 0)
2159                 return world;
2160         return findfloat(world, entnum, f);
2161 }
2162 #endif
2163
2164 float shutdown_running;
2165 #ifdef SVQC
2166 void SV_Shutdown()
2167 #endif
2168 #ifdef CSQC
2169 void CSQC_Shutdown()
2170 #endif
2171 #ifdef MENUQC
2172 void m_shutdown()
2173 #endif
2174 {
2175         if(shutdown_running)
2176         {
2177                 print("Recursive shutdown detected! Only restoring cvars...\n");
2178         }
2179         else
2180         {
2181                 shutdown_running = 1;
2182                 Shutdown();
2183         }
2184         cvar_settemp_restore(); // this must be done LAST, but in any case
2185 }
2186
2187 #define APPROXPASTTIME_ACCURACY_REQUIREMENT 0.05
2188 #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
2189 #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
2190 // this will use the value:
2191 //   128
2192 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
2193 // accuracy at x is 1/derivative, i.e.
2194 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
2195 #ifdef SVQC
2196 void WriteApproxPastTime(float dst, float t)
2197 {
2198         float dt = time - t;
2199
2200         // warning: this is approximate; do not resend when you don't have to!
2201         // be careful with sendflags here!
2202         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
2203
2204         // map to range...
2205         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
2206
2207         // round...
2208         dt = rint(bound(0, dt, 255));
2209
2210         WriteByte(dst, dt);
2211 }
2212 #endif
2213 #ifdef CSQC
2214 float ReadApproxPastTime()
2215 {
2216         float dt = ReadByte();
2217
2218         // map from range...PPROXPASTTIME_MAX / 256
2219         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
2220
2221         return servertime - dt;
2222 }
2223 #endif
2224
2225 #ifndef MENUQC
2226 .float skeleton_bones_index;
2227 void Skeleton_SetBones(entity e)
2228 {
2229         // set skeleton_bones to the total number of bones on the model
2230         if(e.skeleton_bones_index == e.modelindex)
2231                 return; // same model, nothing to update
2232
2233         float skelindex;
2234         skelindex = skel_create(e.modelindex);
2235         e.skeleton_bones = skel_get_numbones(skelindex);
2236         skel_delete(skelindex);
2237         e.skeleton_bones_index = e.modelindex;
2238 }
2239 #endif
2240
2241 string to_execute_next_frame;
2242 void execute_next_frame()
2243 {
2244         if(to_execute_next_frame)
2245         {
2246                 localcmd("\n", to_execute_next_frame, "\n");
2247                 strunzone(to_execute_next_frame);
2248                 to_execute_next_frame = string_null;
2249         }
2250 }
2251 void queue_to_execute_next_frame(string s)
2252 {
2253         if(to_execute_next_frame)
2254         {
2255                 s = strcat(s, "\n", to_execute_next_frame);
2256                 strunzone(to_execute_next_frame);
2257         }
2258         to_execute_next_frame = strzone(s);
2259 }