Some optimizations to client side items and spawn points
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / vehicles / sv_vehicles.qc
1 #include "sv_vehicles.qh"
2
3 bool SendAuxiliaryXhair(entity this, entity to, int sf)
4 {
5         WriteHeader(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
6         WriteByte(MSG_ENTITY, sf);
7
8         WriteByte(MSG_ENTITY, this.cnt);
9
10         if(sf & 2)
11         {
12                 WriteCoord(MSG_ENTITY, this.origin_x);
13                 WriteCoord(MSG_ENTITY, this.origin_y);
14                 WriteCoord(MSG_ENTITY, this.origin_z);
15         }
16
17         if(sf & 4)
18         {
19                 WriteByte(MSG_ENTITY, rint(this.colormod_x * 255));
20                 WriteByte(MSG_ENTITY, rint(this.colormod_y * 255));
21                 WriteByte(MSG_ENTITY, rint(this.colormod_z * 255));
22         }
23
24         return true;
25 }
26
27 bool AuxiliaryXhair_customize(entity this, entity client)
28 {
29         //entity e = WaypointSprite_getviewentity(client);
30         entity axh = client.(AuxiliaryXhair[this.cnt]);
31         return axh.owner == this.owner; // cheaply check if the client's axh owner is the same as our real owner
32 }
33
34 .vector axh_prevorigin;
35 .vector axh_prevcolors;
36
37 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, int axh_id)
38 {
39         if(!IS_REAL_CLIENT(own))
40                 return;
41
42         axh_id = bound(0, axh_id, MAX_AXH);
43         entity axh = own.(AuxiliaryXhair[axh_id]);
44
45         if(axh == NULL || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist? Mario: because of sloppy code like this)
46         {
47                 axh = new(auxiliary_xhair);
48                 axh.cnt = axh_id;
49                 //axh.drawonlytoclient = own; // not spectatable
50                 setcefc(axh, AuxiliaryXhair_customize);
51                 axh.owner = own;
52                 Net_LinkEntity(axh, false, 0, SendAuxiliaryXhair);
53         }
54
55         if(loc != axh.axh_prevorigin)
56         {
57                 setorigin(axh, loc);
58                 axh.SendFlags |= 2;
59         }
60
61         if(clr != axh.axh_prevcolors)
62         {
63                 axh.colormod = clr;
64                 axh.SendFlags |= 4;
65         }
66
67         own.(AuxiliaryXhair[axh_id]) = axh; // set it anyway...?
68 }
69
70 void CSQCVehicleSetup(entity own, int vehicle_id)
71 {
72         if(!IS_REAL_CLIENT(own))
73                 return;
74
75         msg_entity = own;
76
77         WriteHeader(MSG_ONE, TE_CSQC_VEHICLESETUP);
78         WriteByte(MSG_ONE, vehicle_id);
79
80         if(vehicle_id == 0 || vehicle_id == HUD_NORMAL)
81         {
82                 for(int i = 0; i < MAX_AXH; ++i)
83                 {
84                         entity axh = own.(AuxiliaryXhair[i]);
85                         own.(AuxiliaryXhair[i]) = NULL;
86
87                         if(axh.owner == own && axh != NULL && !wasfreed(axh))
88                                 delete(axh);
89                 }
90         }
91 }
92
93 void vehicles_locktarget(entity this, float incr, float decr, float _lock_time)
94 {
95         if(this.lock_target && IS_DEAD(this.lock_target))
96         {
97                 this.lock_target        = NULL;
98                 this.lock_strength  = 0;
99                 this.lock_time    = 0;
100         }
101
102         if(this.lock_time > time)
103         {
104                 if(this.lock_target)
105                 if(this.lock_soundtime < time)
106                 {
107                         this.lock_soundtime = time + 0.5;
108                         play2(this.owner, "vehicles/locked.wav");
109                 }
110
111                 return;
112         }
113
114         if(trace_ent != NULL)
115         {
116                 if(SAME_TEAM(trace_ent, this))
117                         trace_ent = NULL;
118
119                 if(IS_DEAD(trace_ent))
120                         trace_ent = NULL;
121
122                 if(!(IS_VEHICLE(trace_ent) || IS_TURRET(trace_ent)))
123                         trace_ent = NULL;
124
125                 if(trace_ent.alpha <= 0.5 && trace_ent.alpha != 0)
126                         trace_ent = NULL; // invisible
127         }
128
129         if(this.lock_target == NULL && trace_ent != NULL)
130                 this.lock_target = trace_ent;
131
132         if(this.lock_target && trace_ent == this.lock_target)
133         {
134                 if(this.lock_strength != 1 && this.lock_strength + incr >= 1)
135                 {
136                         play2(this.owner, "vehicles/lock.wav");
137                         this.lock_soundtime = time + 0.8;
138                 }
139                 else if (this.lock_strength != 1 && this.lock_soundtime < time)
140                 {
141                         play2(this.owner, "vehicles/locking.wav");
142                         this.lock_soundtime = time + 0.3;
143                 }
144         }
145
146         // Have a locking target
147         // Trace hit current target
148         if(trace_ent == this.lock_target && trace_ent != NULL)
149         {
150                 this.lock_strength = min(this.lock_strength + incr, 1);
151                 if(this.lock_strength == 1)
152                         this.lock_time = time + _lock_time;
153         }
154         else
155         {
156                 if(trace_ent)
157                         this.lock_strength = max(this.lock_strength - decr * 2, 0);
158                 else
159                         this.lock_strength = max(this.lock_strength - decr, 0);
160
161                 if(this.lock_strength == 0)
162                         this.lock_target = NULL;
163         }
164 }
165
166 float vehicle_altitude(entity this, float amax)
167 {
168         tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * amax), MOVE_WORLDONLY, this);
169         return vlen(this.origin - trace_endpos);
170 }
171
172 vector vehicles_force_fromtag_hover(entity this, string tag_name, float spring_length, float max_power)
173 {
174         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
175         v_forward  = normalize(v_forward) * -1;
176         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
177
178         force_fromtag_power = (1 - trace_fraction) * max_power;
179         force_fromtag_normpower = force_fromtag_power / max_power;
180
181         return v_forward  * force_fromtag_power;
182 }
183
184 vector vehicles_force_fromtag_maglev(entity this, string tag_name, float spring_length, float max_power)
185 {
186         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
187         v_forward  = normalize(v_forward) * -1;
188         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
189
190         // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
191         if(trace_fraction == 1.0)
192         {
193                 force_fromtag_normpower = -0.25;
194                 return '0 0 -200';
195         }
196
197         force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
198         force_fromtag_normpower = force_fromtag_power / max_power;
199
200         return v_forward  * force_fromtag_power;
201 }
202
203 // projectile handling
204 void vehicles_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
205 {
206         // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
207         if(inflictor.owner == this.owner)
208                 return;
209
210         this.health -= damage;
211         this.velocity += force;
212         if(this.health < 1)
213         {
214                 this.takedamage = DAMAGE_NO;
215                 this.event_damage = func_null;
216                 setthink(this, adaptor_think2use);
217                 this.nextthink = time;
218         }
219 }
220
221 void vehicles_projectile_explode(entity this, entity toucher)
222 {
223         if(this.owner && toucher != NULL)
224         {
225                 if(toucher == this.owner.vehicle)
226                         return;
227
228                 if(toucher == this.owner.vehicle.tur_head)
229                         return;
230         }
231
232         PROJECTILE_TOUCH(this, toucher);
233
234         this.event_damage = func_null;
235         RadiusDamage (this, this.realowner, this.shot_dmg, 0, this.shot_radius, this, NULL, this.shot_force, this.totalfrags, toucher);
236
237         delete(this);
238 }
239
240 void vehicles_projectile_explode_think(entity this)
241 {
242         vehicles_projectile_explode(this, NULL);
243 }
244
245 void vehicles_projectile_explode_use(entity this, entity actor, entity trigger)
246 {
247         vehicles_projectile_explode(this, trigger);
248 }
249
250 entity vehicles_projectile(entity this, string _mzlfx, Sound _mzlsound,
251                                                    vector _org, vector _vel,
252                                                    float _dmg, float _radi, float _force,  float _size,
253                                                    int _deahtype, float _projtype, float _health,
254                                                    bool _cull, bool _clianim, entity _owner)
255 {
256     TC(Sound, _mzlsound);
257         entity proj;
258
259         proj = spawn();
260
261         PROJECTILE_MAKETRIGGER(proj);
262         setorigin(proj, _org);
263
264         proj.shot_dmg            = _dmg;
265         proj.shot_radius          = _radi;
266         proj.shot_force    = _force;
267         proj.totalfrags    = _deahtype;
268         proj.solid                      = SOLID_BBOX;
269         set_movetype(proj, MOVETYPE_FLYMISSILE);
270         proj.flags = FL_PROJECTILE;
271         IL_PUSH(g_projectiles, proj);
272         IL_PUSH(g_bot_dodge, proj);
273         proj.bot_dodge          = true;
274         proj.bot_dodgerating  = _dmg;
275         proj.velocity            = _vel;
276         settouch(proj, vehicles_projectile_explode);
277         proj.use                          = vehicles_projectile_explode_use;
278         proj.owner                      = this;
279         proj.realowner          = _owner;
280         setthink(proj, SUB_Remove);
281         proj.nextthink          = time + 30;
282
283         if(_health)
284         {
285                 proj.takedamage    = DAMAGE_AIM;
286                 proj.event_damage        = vehicles_projectile_damage;
287                 proj.health                = _health;
288         }
289         else
290                 proj.flags |= FL_NOTARGET;
291
292         if(_mzlsound != SND_Null)
293                 sound (this, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTEN_NORM);
294
295         if(_mzlfx)
296                 Send_Effect_(_mzlfx, proj.origin, proj.velocity, 1);
297
298         setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
299
300         CSQCProjectile(proj, _clianim, _projtype, _cull);
301
302         return proj;
303 }
304
305 void vehicles_gib_explode(entity this)
306 {
307         sound (this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
308         Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
309         Send_Effect(EFFECT_EXPLOSION_SMALL, this.wp00.origin + '0 0 64', '0 0 0', 1);
310         delete(this);
311 }
312
313 void vehicles_gib_touch(entity this, entity toucher)
314 {
315         vehicles_gib_explode(this);
316 }
317
318 void vehicles_gib_think(entity this)
319 {
320         this.alpha -= 0.1;
321         if(this.cnt >= time)
322                 delete(this);
323         else
324                 this.nextthink = time + 0.1;
325 }
326
327 entity vehicle_tossgib(entity this, entity _template, vector _vel, string _tag, bool _burn, bool _explode, float _maxtime, vector _rot)
328 {
329         entity _gib = spawn();
330         _setmodel(_gib, _template.model);
331         vector org = gettaginfo(this, gettagindex(this, _tag));
332         setorigin(_gib, org);
333         _gib.velocity = _vel;
334         set_movetype(_gib, MOVETYPE_TOSS);
335         _gib.solid = SOLID_CORPSE;
336         _gib.colormod = '-0.5 -0.5 -0.5';
337         _gib.effects = EF_LOWPRECISION;
338         _gib.avelocity = _rot;
339
340         if(_burn)
341                 _gib.effects |= EF_FLAME;
342
343         if(_explode)
344         {
345                 setthink(_gib, vehicles_gib_explode);
346                 _gib.nextthink = time + random() * _explode;
347                 settouch(_gib, vehicles_gib_touch);
348         }
349         else
350         {
351                 _gib.cnt = time + _maxtime;
352                 setthink(_gib, vehicles_gib_think);
353                 _gib.nextthink = time + _maxtime - 1;
354                 _gib.alpha = 1;
355         }
356         return _gib;
357 }
358
359 bool vehicle_addplayerslot(     entity _owner,
360                                                                 entity _slot,
361                                                                 int _hud,
362                                                                 Model _hud_model,
363                                                                 bool(entity,float) _framefunc,
364                                                                 void(entity,bool) _exitfunc, float(entity, entity) _enterfunc)
365 {
366         if(!(_owner.vehicle_flags & VHF_MULTISLOT))
367                 _owner.vehicle_flags |= VHF_MULTISLOT;
368
369         _slot.PlayerPhysplug = _framefunc;
370         _slot.vehicle_exit = _exitfunc;
371         _slot.vehicle_enter = _enterfunc;
372         _slot.hud = _hud;
373         _slot.vehicle_flags = VHF_PLAYERSLOT;
374         _slot.vehicle_viewport = spawn();
375         _slot.vehicle_hudmodel = spawn();
376         _slot.vehicle_hudmodel.viewmodelforclient = _slot;
377         _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
378
379         setmodel(_slot.vehicle_hudmodel, _hud_model);
380         setmodel(_slot.vehicle_viewport, MDL_Null);
381
382         setattachment(_slot.vehicle_hudmodel, _slot, "");
383         setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
384
385         return true;
386 }
387
388 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
389                                                  float _pichlimit_min, float _pichlimit_max,
390                                                  float _rotlimit_min, float _rotlimit_max, float _aimspeed)
391 {
392         vector vtmp, vtag;
393         float ftmp;
394         vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
395         vtmp = vectoangles(normalize(_target - vtag));
396         vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
397         vtmp = AnglesTransform_Normalize(vtmp, true);
398         ftmp = _aimspeed * frametime;
399         vtmp_y = bound(-ftmp, vtmp_y, ftmp);
400         vtmp_x = bound(-ftmp, vtmp_x, ftmp);
401         _turrret.angles_y = bound(_rotlimit_min, _turrret.angles_y + vtmp_y, _rotlimit_max);
402         _turrret.angles_x = bound(_pichlimit_min, _turrret.angles_x + vtmp_x, _pichlimit_max);
403         return vtag;
404 }
405
406 void vehicles_reset_colors(entity this, entity player)
407 {
408         int eff = 0, cmap;
409         const vector cmod = '0 0 0';
410         if(this.team && teamplay)
411                 cmap = 1024 + (this.team - 1) * 17;
412         else if(player)
413                 cmap = player.colormap;
414         else
415                 cmap = 1024;
416         if(autocvar_g_nodepthtestplayers)
417                 eff |= EF_NODEPTHTEST;
418         if(autocvar_g_fullbrightplayers)
419                 eff |= EF_FULLBRIGHT;
420
421         // Find all ents attacked to main model and setup effects, colormod etc.
422         FOREACH_ENTITY_ENT(tag_entity, this,
423         {
424                 if(it == this.vehicle_shieldent)
425                         continue;
426
427                 it.effects = eff;
428                 it.colormod = cmod;
429                 it.colormap = cmap;
430                 it.alpha = 1;
431         });
432
433         // Also check head tags
434         FOREACH_ENTITY_ENT(tag_entity, this.tur_head,
435         {
436                 if(it == this.vehicle_shieldent)
437                         continue;
438
439                 it.effects = eff;
440                 it.colormod = cmod;
441                 it.colormap = cmap;
442                 it.alpha = 1;
443         });
444
445         this.vehicle_hudmodel.effects  = this.effects  = eff; // | EF_LOWPRECISION;
446         this.vehicle_hudmodel.colormod = this.colormod = cmod;
447         this.vehicle_hudmodel.colormap = this.colormap = cmap;
448         this.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
449
450         this.alpha       = 1;
451         this.avelocity = '0 0 0';
452         this.velocity  = '0 0 0';
453         this.effects   = eff;
454
455         Vehicle info = Vehicles_from(this.vehicleid);
456         info.vr_setcolors(info, this);
457 }
458
459 void vehicles_clearreturn(entity veh)
460 {
461         // Remove "return helper" entities, if any.
462         IL_EACH(g_vehicle_returners, it.wp00 == veh,
463         {
464                 it.classname = "";
465                 setthink(it, SUB_Remove);
466                 it.nextthink = time + 0.1;
467                 IL_REMOVE(g_vehicle_returners, it);
468
469                 if(it.waypointsprite_attached)
470                         WaypointSprite_Kill(it.waypointsprite_attached);
471         });
472 }
473
474 void vehicles_spawn(entity this);
475 void vehicles_return(entity this)
476 {
477         Send_Effect(EFFECT_TELEPORT, this.wp00.origin + '0 0 64', '0 0 0', 1);
478
479         setthink(this.wp00, vehicles_spawn);
480         this.wp00.nextthink = time;
481
482         if(this.waypointsprite_attached)
483                 WaypointSprite_Kill(this.waypointsprite_attached);
484
485         delete(this);
486 }
487
488 void vehicles_showwp_goaway(entity this)
489 {
490         if(this.waypointsprite_attached)
491                 WaypointSprite_Kill(this.waypointsprite_attached);
492
493         delete(this);
494 }
495
496 void vehicles_showwp(entity this)
497 {
498         entity ent = this;
499
500         if(ent.cnt)
501         {
502                 setthink(ent, vehicles_return);
503                 ent.nextthink = ent.cnt;
504         }
505         else
506         {
507                 setthink(ent, vehicles_return);
508                 ent.nextthink  = time + 1;
509
510                 ent = spawn();
511                 ent.team = this.wp00.team;
512                 ent.wp00 = this.wp00;
513                 setorigin(ent, this.wp00.pos1);
514
515                 ent.nextthink = time + 5;
516                 setthink(ent, vehicles_showwp_goaway);
517         }
518
519         vector rgb;
520         if(teamplay && ent.team)
521                 rgb = Team_ColorRGB(ent.team);
522         else
523                 rgb = '1 1 1';
524         entity wp = WaypointSprite_Spawn(WP_Vehicle, 0, 0, ent, '0 0 64', NULL, 0, ent, waypointsprite_attached, true, RADARICON_Vehicle);
525         wp.colormod = rgb;
526         if(ent.waypointsprite_attached)
527         {
528                 WaypointSprite_UpdateRule(ent.waypointsprite_attached, ent.wp00.team, SPRITERULE_DEFAULT);
529                 if(this == NULL)
530                         WaypointSprite_UpdateBuildFinished(ent.waypointsprite_attached, ent.nextthink);
531                 WaypointSprite_Ping(ent.waypointsprite_attached);
532         }
533 }
534
535 void vehicles_setreturn(entity veh)
536 {
537         vehicles_clearreturn(veh);
538
539         entity ret = new(vehicle_return);
540         IL_PUSH(g_vehicle_returners, ret);
541         ret.wp00           = veh;
542         ret.team                = veh.team;
543         setthink(ret, vehicles_showwp);
544
545         if(IS_DEAD(veh))
546         {
547                 ret.cnt          = time + veh.respawntime;
548                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 5);
549         }
550         else
551         {
552                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 1);
553         }
554
555         setorigin(ret, veh.pos1 + '0 0 96');
556 }
557
558 void vehicle_use(entity this, entity actor, entity trigger)
559 {
560         LOG_DEBUG("vehicle ", this.netname, " used by ", actor.classname);
561
562         this.tur_head.team = actor.team;
563
564         if(this.tur_head.team == 0)
565                 this.active = ACTIVE_NOT;
566         else
567                 this.active = ACTIVE_ACTIVE;
568
569         if(this.active == ACTIVE_ACTIVE && !IS_DEAD(this) && !game_stopped)
570         {
571                 LOG_DEBUG("Respawning vehicle: ", this.netname);
572                 if(this.effects & EF_NODRAW)
573                 {
574                         setthink(this, vehicles_spawn);
575                         this.nextthink = time + 3;
576                 }
577                 else
578                 {
579                         vehicles_setreturn(this);
580                         vehicles_reset_colors(this, actor);
581                 }
582         }
583 }
584
585 void vehicles_regen(entity this, float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
586 {
587         if(this.(regen_field) < field_max)
588         if(timer + rpause < time)
589         {
590                 if(_healthscale)
591                         regen = regen * (this.vehicle_health / this.max_health);
592
593                 this.(regen_field) = min(this.(regen_field) + regen * delta_time, field_max);
594
595                 if(this.owner)
596                         this.owner.(regen_field) = (this.(regen_field) / field_max) * 100;
597         }
598 }
599
600 void shieldhit_think(entity this)
601 {
602         this.alpha -= 0.1;
603         if (this.alpha <= 0)
604         {
605                 // setmodel(this, MDL_Null);
606                 this.alpha = -1;
607                 this.effects |= EF_NODRAW;
608         }
609         else
610         {
611                 this.nextthink = time + 0.1;
612         }
613 }
614
615 void vehicles_painframe(entity this)
616 {
617         int myhealth = ((this.owner) ? this.owner.vehicle_health : ((this.vehicle_health / this.max_health) * 100));
618
619         if(myhealth <= 50)
620         if(this.pain_frame < time)
621         {
622                 float _ftmp = myhealth / 50;
623                 this.pain_frame = time + max(0.1, 0.1 + (random() * 0.5 * _ftmp));
624                 Send_Effect(EFFECT_SMOKE_SMALL, (this.origin + (randomvec() * 80)), '0 0 0', 1);
625
626                 if(this.vehicle_flags & VHF_DMGSHAKE)
627                         this.velocity += randomvec() * 30;
628
629                 if(this.vehicle_flags & VHF_DMGROLL)
630                         if(this.vehicle_flags & VHF_DMGHEADROLL)
631                                 this.tur_head.angles += randomvec();
632                         else
633                                 this.angles += randomvec();
634         }
635 }
636
637 void vehicles_frame(entity this, entity actor)
638 {
639         vehicles_painframe(this);
640 }
641
642 void vehicles_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
643 {
644         this.dmg_time = time;
645
646         // WEAPONTODO
647         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX))
648                 damage *= autocvar_g_vehicles_vortex_damagerate;
649         else if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
650                 damage *= autocvar_g_vehicles_machinegun_damagerate;
651         else if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
652                 damage *= autocvar_g_vehicles_rifle_damagerate;
653         else if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
654                 damage *= autocvar_g_vehicles_vaporizer_damagerate;
655         else if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
656                 damage *= autocvar_g_vehicles_tag_damagerate;
657         else if(DEATH_WEAPONOF(deathtype) != WEP_Null)
658                 damage *= autocvar_g_vehicles_weapon_damagerate;
659
660         this.enemy = attacker;
661
662         this.pain_finished = time;
663
664         if((this.vehicle_flags & VHF_HASSHIELD) && (this.vehicle_shield > 0))
665         {
666                 if (wasfreed(this.vehicle_shieldent) || this.vehicle_shieldent == NULL)
667                 {
668                         this.vehicle_shieldent = spawn();
669                         this.vehicle_shieldent.effects = EF_LOWPRECISION;
670
671                         setmodel(this.vehicle_shieldent, MDL_VEH_SHIELD);
672                         setattachment(this.vehicle_shieldent, this, "");
673                         setorigin(this.vehicle_shieldent, real_origin(this) - this.origin);
674                         this.vehicle_shieldent.scale       = 256 / vlen(this.maxs - this.mins);
675                         setthink(this.vehicle_shieldent, shieldhit_think);
676                 }
677
678                 this.vehicle_shieldent.colormod = '1 1 1';
679                 this.vehicle_shieldent.alpha = 0.45;
680                 this.vehicle_shieldent.angles = vectoangles(normalize(hitloc - (this.origin + this.vehicle_shieldent.origin))) - this.angles;
681                 this.vehicle_shieldent.nextthink = time;
682                 this.vehicle_shieldent.effects &= ~EF_NODRAW;
683
684                 this.vehicle_shield -= damage;
685
686                 if(this.vehicle_shield < 0)
687                 {
688                         this.vehicle_health -= fabs(this.vehicle_shield);
689                         this.vehicle_shieldent.colormod = '2 0 0';
690                         this.vehicle_shield = 0;
691                         this.vehicle_shieldent.alpha = 0.75;
692
693                         if(sound_allowed(MSG_BROADCAST, attacker))
694                                 spamsound (this, CH_PAIN, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);   // FIXME: PLACEHOLDER
695                 }
696                 else
697                         if(sound_allowed(MSG_BROADCAST, attacker))
698                                 spamsound (this, CH_PAIN, SND_ONS_ELECTRICITY_EXPLODE, VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
699
700         }
701         else
702         {
703                 this.vehicle_health -= damage;
704
705                 if(sound_allowed(MSG_BROADCAST, attacker))
706                         spamsound (this, CH_PAIN, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
707         }
708
709         if(this.damageforcescale < 1 && this.damageforcescale > 0)
710                 this.velocity += force * this.damageforcescale;
711         else
712                 this.velocity += force;
713
714         if(this.vehicle_health <= 0)
715         {
716                 if(this.owner)
717                         if(this.vehicle_flags & VHF_DEATHEJECT)
718                                 vehicles_exit(this, VHEF_EJECT);
719                         else
720                                 vehicles_exit(this, VHEF_RELEASE);
721
722
723                 antilag_clear(this, this);
724
725                 Vehicle info = Vehicles_from(this.vehicleid);
726                 info.vr_death(info, this);
727                 vehicles_setreturn(this);
728         }
729 }
730
731 bool vehicles_crushable(entity e)
732 {
733         if(IS_PLAYER(e) && time >= e.vehicle_enter_delay)
734                 return true;
735
736         if(IS_MONSTER(e))
737                 return true;
738
739         return false;
740 }
741
742 void vehicles_impact(entity this, float _minspeed, float _speedfac, float _maxpain)
743 {
744         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
745                 return;
746
747         if(this.play_time < time)
748         {
749                 float wc = vlen(this.velocity - this.oldvelocity);
750                 //dprint("oldvel: ", vtos(this.oldvelocity), "\n");
751                 //dprint("vel: ", vtos(this.velocity), "\n");
752                 if(_minspeed < wc)
753                 {
754                         float take = min(_speedfac * wc, _maxpain);
755                         Damage (this, NULL, NULL, take, DEATH_FALL.m_id, this.origin, '0 0 0');
756                         this.play_time = time + 0.25;
757
758                         //dprint("wc: ", ftos(wc), "\n");
759                         //dprint("take: ", ftos(take), "\n");
760                 }
761         }
762 }
763
764 // vehicle enter/exit handling
765 vector vehicles_findgoodexit(entity this, entity player, vector prefer_spot)
766 {
767         // TODO: we actually want the player's size here
768         tracebox(this.origin + '0 0 32', PL_MIN_CONST, PL_MAX_CONST, prefer_spot, MOVE_NORMAL, player);
769         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
770                 return prefer_spot;
771
772         float mysize = 1.5 * vlen(this.maxs - this.mins);
773         vector v;
774         vector v2 = 0.5 * (this.absmin + this.absmax);
775         for(int i = 0; i < autocvar_g_vehicles_exit_attempts; ++i)
776         {
777                 v = randomvec();
778                 v_z = 0;
779                 v = v2 + normalize(v) * mysize;
780                 tracebox(v2, PL_MIN_CONST, PL_MAX_CONST, v, MOVE_NORMAL, player);
781                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
782                         return v;
783         }
784
785         return this.origin;
786 }
787
788 .int old_vehicle_flags;
789 void vehicles_exit(entity vehic, bool eject)
790 {
791         entity player = vehic.owner;
792
793         if(vehicles_exit_running)
794         {
795                 LOG_TRACE("^1vehicles_exit already running! this is not good...");
796                 return;
797         }
798
799         vehicles_exit_running = true;
800
801         // TODO: this was in an IS_CLIENT check, make sure it isn't actually needed!
802         if(vehic.vehicle_flags & VHF_PLAYERSLOT)
803         {
804                 vehic.vehicle_exit(vehic, eject);
805                 vehicles_exit_running = false;
806                 return;
807         }
808
809         if (player)
810         {
811                 if (IS_REAL_CLIENT(player))
812                 {
813                         msg_entity = player;
814                         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
815                         WriteEntity( MSG_ONE, player);
816
817                         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
818                         WriteAngle(MSG_ONE, 0);
819                         WriteAngle(MSG_ONE, vehic.angles_y);
820                         WriteAngle(MSG_ONE, 0);
821                 }
822
823                 setsize(player, STAT(PL_MIN, player), STAT(PL_MAX, player));
824
825                 player.takedamage               = DAMAGE_AIM;
826                 player.solid                    = SOLID_SLIDEBOX;
827                 set_movetype(player, MOVETYPE_WALK);
828                 player.effects             &= ~EF_NODRAW;
829                 player.teleportable     = TELEPORT_NORMAL;
830                 player.alpha                    = 1;
831                 player.PlayerPhysplug   = func_null;
832                 player.vehicle                  = NULL;
833                 player.view_ofs         = STAT(PL_VIEW_OFS, player);
834                 player.event_damage     = PlayerDamage;
835                 player.hud                              = HUD_NORMAL;
836                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++ slot)
837                 {
838                         .entity weaponentity = weaponentities[slot];
839                         player.(weaponentity).m_switchweapon = vehic.(weaponentity).m_switchweapon;
840                         delete(vehic.(weaponentity)); // no longer needed
841                 }
842                 player.last_vehiclecheck = time + 3;
843                 player.vehicle_enter_delay = time + 2;
844
845                 CSQCVehicleSetup(player, HUD_NORMAL);
846
847                 Kill_Notification(NOTIF_ONE, player, MSG_CENTER, CPID_VEHICLES);
848                 Kill_Notification(NOTIF_ONE, player, MSG_CENTER, CPID_VEHICLES_OTHER); // kill all vehicle notifications when exiting a vehicle?
849         }
850
851         vehic.flags |= FL_NOTARGET;
852
853         if(!IS_DEAD(vehic))
854                 vehic.avelocity = '0 0 0';
855
856         vehic.tur_head.nodrawtoclient = NULL;
857
858         if(!teamplay)
859                 vehic.team = 0;
860
861         WaypointSprite_Kill(vehic.wps_intruder);
862
863         MUTATOR_CALLHOOK(VehicleExit, player, vehic);
864
865         vehic.team = vehic.tur_head.team;
866
867         if(vehic.old_vehicle_flags & VHF_SHIELDREGEN)
868                 vehic.vehicle_flags |= VHF_SHIELDREGEN;
869         vehic.old_vehicle_flags = 0;
870
871         sound (vehic, CH_TRIGGER_SINGLE, SND_Null, 1, ATTEN_NORM);
872         vehic.vehicle_hudmodel.viewmodelforclient = vehic;
873         vehic.phase = time + 1;
874
875         vehic.vehicle_exit(vehic, eject);
876
877         vehicles_setreturn(vehic);
878         vehicles_reset_colors(vehic, NULL);
879         vehic.owner = NULL;
880
881         CSQCMODEL_AUTOINIT(vehic);
882
883         if(player)
884                 player.oldorigin = player.origin; // player's location is set by the exit functions, so we need to do this after everything
885
886         vehicles_exit_running = false;
887 }
888
889 void vehicles_touch(entity this, entity toucher)
890 {
891         if(MUTATOR_CALLHOOK(VehicleTouch, this, toucher))
892                 return;
893
894         // Vehicle currently in use
895         if(this.owner)
896         {
897                 if(!forbidWeaponUse(this.owner))
898                 if(toucher != NULL)
899                 if((this.origin_z + this.maxs_z) > (toucher.origin_z))
900                 if(vehicles_crushable(toucher))
901                 {
902                         if(vdist(this.velocity, >=, 30))
903                                 Damage(toucher, this, this.owner, autocvar_g_vehicles_crush_dmg, DEATH_VH_CRUSH.m_id, '0 0 0', normalize(toucher.origin - this.origin) * autocvar_g_vehicles_crush_force);
904
905                         return; // Dont do selfdamage when hitting "soft targets".
906                 }
907
908                 if(this.play_time < time) {
909                         Vehicle info = Vehicles_from(this.vehicleid);
910                         info.vr_impact(info, this);
911                 }
912
913                 return;
914         }
915
916         if(autocvar_g_vehicles_enter)
917                 return;
918
919         vehicles_enter(toucher, this);
920 }
921
922 bool vehicle_impulse(entity this, int imp)
923 {
924         entity v = this.vehicle;
925         if (!v) return false;
926         if (IS_DEAD(v)) return false;
927         bool(entity,int) f = v.vehicles_impulse;
928         if (f && f(this,imp)) return true;
929         switch (imp)
930         {
931                 case IMP_weapon_drop.impulse:
932                 {
933                         stuffcmd(this, "\ntoggle cl_eventchase_vehicle\nset _vehicles_shownchasemessage 1\n");
934                         return true;
935                 }
936         }
937         return false;
938 }
939
940 void vehicles_enter(entity pl, entity veh)
941 {
942    // Remove this when bots know how to use vehicles
943         if((IS_BOT_CLIENT(pl) && !autocvar_g_vehicles_allow_bots))
944                 return;
945
946         if((!IS_PLAYER(pl))
947         || (veh.phase >= time)
948         || (pl.vehicle_enter_delay >= time)
949         || (STAT(FROZEN, pl))
950         || (IS_DEAD(pl))
951         || (pl.vehicle)
952         ) { return; }
953
954         Vehicle info = Vehicles_from(veh.vehicleid);
955
956         if(autocvar_g_vehicles_enter) // vehicle's touch function should handle this if entering via use key is disabled (TODO)
957         if(veh.vehicle_flags & VHF_MULTISLOT)
958         if(veh.owner && SAME_TEAM(pl, veh))
959         {
960                 // we don't need a return value or anything here
961                 // if successful the owner check below will prevent anything weird
962                 info.vr_gunner_enter(info, veh, pl);
963         }
964
965         if(veh.owner)
966                 return; // got here and didn't enter the gunner, return
967
968         if(teamplay)
969         if(veh.team)
970         if(DIFF_TEAM(pl, veh))
971         if(autocvar_g_vehicles_steal)
972         {
973                 FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, veh), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_VEHICLE_STEAL));
974
975                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_STEAL_SELF);
976
977                 veh.vehicle_shield = 0;
978                 veh.old_vehicle_flags = veh.vehicle_flags; // make a backup just so we're not permanently crippling this vehicle
979                 veh.vehicle_flags &= ~VHF_SHIELDREGEN;
980
981                 if (autocvar_g_vehicles_steal_show_waypoint) {
982                         entity wp = WaypointSprite_Spawn(WP_VehicleIntruder, 0, 0, pl, '0 0 68', NULL, veh.team, veh, wps_intruder, true, RADARICON_DANGER);
983                         wp.colormod = Team_ColorRGB(pl.team);
984                 }
985         }
986         else return;
987
988         RemoveGrapplingHooks(pl);
989
990         veh.vehicle_ammo1 = 0;
991         veh.vehicle_ammo2 = 0;
992         veh.vehicle_reload1 = 0;
993         veh.vehicle_reload2 = 0;
994         veh.vehicle_energy = 0;
995
996         veh.owner = pl;
997         pl.vehicle = veh;
998
999         // .viewmodelforclient works better.
1000         //veh.vehicle_hudmodel.drawonlytoclient = veh.owner;
1001
1002         veh.vehicle_hudmodel.viewmodelforclient = pl;
1003
1004         pl.crouch = false;
1005         pl.view_ofs = STAT(PL_VIEW_OFS, pl);
1006         setsize(pl, STAT(PL_MIN, pl), STAT(PL_MAX, pl));
1007
1008         veh.event_damage        = vehicles_damage;
1009         veh.nextthink           = 0;
1010         pl.items &= ~IT_USING_JETPACK;
1011         pl.angles                       = veh.angles;
1012         pl.takedamage           = DAMAGE_NO;
1013         pl.solid                        = SOLID_NOT;
1014         pl.disableclientprediction = 1; // physics is no longer run, so this won't be reset
1015         set_movetype(pl, MOVETYPE_NOCLIP);
1016         pl.teleportable         = false;
1017         pl.alpha                        = -1;
1018         pl.event_damage         = func_null;
1019         pl.view_ofs                     = '0 0 0';
1020         veh.colormap            = pl.colormap;
1021         if(veh.tur_head)
1022                 veh.tur_head.colormap = pl.colormap;
1023         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1024         {
1025                 .entity weaponentity = weaponentities[slot];
1026                 veh.(weaponentity) = new(temp_wepent);
1027                 veh.(weaponentity).m_switchweapon = pl.(weaponentity).m_switchweapon;
1028         }
1029         pl.hud = veh.vehicleid;
1030         pl.PlayerPhysplug = veh.PlayerPhysplug;
1031
1032         pl.vehicle_ammo1 = veh.vehicle_ammo1;
1033         pl.vehicle_ammo2 = veh.vehicle_ammo2;
1034         pl.vehicle_reload1 = veh.vehicle_reload1;
1035         pl.vehicle_reload2 = veh.vehicle_reload2;
1036         pl.vehicle_energy = veh.vehicle_energy;
1037
1038         // Cant do this, hides attached objects too.
1039         //veh.exteriormodeltoclient = veh.owner;
1040         //veh.tur_head.exteriormodeltoclient = veh.owner;
1041
1042         UNSET_ONGROUND(pl);
1043         UNSET_ONGROUND(veh);
1044
1045         veh.team = pl.team;
1046         veh.flags -= FL_NOTARGET;
1047
1048         vehicles_reset_colors(veh, pl);
1049
1050         if (IS_REAL_CLIENT(pl))
1051         {
1052                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_ENTER);
1053
1054                 msg_entity = pl;
1055                 WriteByte (MSG_ONE, SVC_SETVIEWPORT);
1056                 WriteEntity(MSG_ONE, veh.vehicle_viewport);
1057
1058                 WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1059                 if(veh.tur_head)
1060                 {
1061                         WriteAngle(MSG_ONE, veh.tur_head.angles_x + veh.angles_x); // tilt
1062                         WriteAngle(MSG_ONE, veh.tur_head.angles_y + veh.angles_y); // yaw
1063                         WriteAngle(MSG_ONE, 0);                                                                   // roll
1064                 }
1065                 else
1066                 {
1067                         WriteAngle(MSG_ONE, veh.angles_x * -1); // tilt
1068                         WriteAngle(MSG_ONE, veh.angles_y);        // yaw
1069                         WriteAngle(MSG_ONE, 0);                           // roll
1070                 }
1071         }
1072
1073         vehicles_clearreturn(veh);
1074
1075         CSQCVehicleSetup(pl, veh.vehicleid);
1076
1077         MUTATOR_CALLHOOK(VehicleEnter, pl, veh);
1078
1079         CSQCModel_UnlinkEntity(veh);
1080         info.vr_enter(info, veh);
1081
1082         antilag_clear(pl, CS(pl));
1083 }
1084
1085 void vehicles_think(entity this)
1086 {
1087         this.nextthink = time + autocvar_g_vehicles_thinkrate;
1088
1089         if(this.owner)
1090                 this.owner.vehicle_weapon2mode = this.vehicle_weapon2mode;
1091
1092         Vehicle info = Vehicles_from(this.vehicleid);
1093         info.vr_think(info, this);
1094
1095         vehicles_painframe(this);
1096
1097         CSQCMODEL_AUTOUPDATE(this);
1098 }
1099
1100 void vehicles_reset(entity this)
1101 {
1102         if(this.owner)
1103                 vehicles_exit(this, VHEF_RELEASE);
1104
1105         vehicles_clearreturn(this);
1106
1107         if(this.active != ACTIVE_NOT)
1108                 vehicles_spawn(this);
1109 }
1110
1111 // initialization
1112 void vehicles_spawn(entity this)
1113 {
1114         LOG_DEBUG("Spawning vehicle: ", this.classname);
1115
1116         // disown & reset
1117         this.vehicle_hudmodel.viewmodelforclient = this;
1118
1119         this.owner                              = NULL;
1120         settouch(this, vehicles_touch);
1121         this.event_damage               = vehicles_damage;
1122         this.reset                              = vehicles_reset;
1123         this.iscreature                 = true;
1124         this.teleportable               = false; // no teleporting for vehicles, too buggy
1125         this.damagedbycontents  = true;
1126         set_movetype(this, MOVETYPE_WALK);
1127         this.solid                              = SOLID_SLIDEBOX;
1128         this.takedamage                 = DAMAGE_AIM;
1129         this.deadflag                   = DEAD_NO;
1130         if(!this.bot_attack)
1131                 IL_PUSH(g_bot_targets, this);
1132         this.bot_attack                 = true;
1133         this.flags                              = FL_NOTARGET;
1134         this.avelocity                  = '0 0 0';
1135         this.velocity                   = '0 0 0';
1136         setthink(this, vehicles_think);
1137         this.nextthink                  = time;
1138
1139         // Reset locking
1140         this.lock_strength = 0;
1141         this.lock_target = NULL;
1142         this.misc_bulletcounter = 0;
1143
1144         // Return to spawn
1145         this.angles = this.pos2;
1146         setorigin(this, this.pos1);
1147         // Show it
1148         Send_Effect(EFFECT_TELEPORT, this.origin + '0 0 64', '0 0 0', 1);
1149
1150         if(this.vehicle_controller)
1151                 this.team = this.vehicle_controller.team;
1152
1153         FOREACH_CLIENT(IS_PLAYER(it),
1154         {
1155                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1156             {
1157                 .entity weaponentity = weaponentities[slot];
1158                 if(it.(weaponentity).hook.aiment == this)
1159                         RemoveHook(it.(weaponentity).hook);
1160             }
1161         });
1162
1163
1164         Vehicle info = Vehicles_from(this.vehicleid);
1165         info.vr_spawn(info, this);
1166
1167         vehicles_reset_colors(this, NULL);
1168
1169         CSQCMODEL_AUTOINIT(this);
1170 }
1171
1172 bool vehicle_initialize(entity this, Vehicle info, bool nodrop)
1173 {
1174         if(!autocvar_g_vehicles)
1175                 return false;
1176
1177         if(!info.vehicleid)
1178                 return false;
1179
1180         if(!this.tur_head)
1181         {
1182                 info.vr_precache(info);
1183                 IL_PUSH(g_vehicles, this);
1184         }
1185
1186         if(this.targetname && this.targetname != "")
1187         {
1188                 this.vehicle_controller = find(NULL, target, this.targetname);
1189                 if(!this.vehicle_controller)
1190                 {
1191                         LOG_DEBUG("^1WARNING: ^7Vehicle with invalid .targetname");
1192                         this.active = ACTIVE_ACTIVE;
1193                 }
1194                 else
1195                 {
1196                         this.team = this.vehicle_controller.team;
1197                         this.use = vehicle_use;
1198
1199                         if(teamplay)
1200                         {
1201                                 if(this.vehicle_controller.team == 0)
1202                                         this.active = ACTIVE_NOT;
1203                                 else
1204                                         this.active = ACTIVE_ACTIVE;
1205                         }
1206                 }
1207         }
1208         else { this.active = ACTIVE_ACTIVE; }
1209
1210         if(this.team && (!teamplay || !autocvar_g_vehicles_teams))
1211                 this.team = 0;
1212
1213         if(this.mdl == "" || !this.mdl)
1214                 _setmodel(this, info.model);
1215         else
1216                 _setmodel(this, this.mdl);
1217
1218         this.vehicle_flags |= VHF_ISVEHICLE;
1219
1220         this.vehicle_viewport           = new(vehicle_viewport);
1221         this.vehicle_hudmodel           = new(vehicle_hudmodel);
1222         this.tur_head                           = new(tur_head);
1223         this.tur_head.owner                     = this;
1224         this.takedamage                         = DAMAGE_NO;
1225         this.bot_attack                         = true;
1226         IL_PUSH(g_bot_targets, this);
1227         this.iscreature                         = true;
1228         this.teleportable                       = false; // no teleporting for vehicles, too buggy
1229         this.damagedbycontents          = true;
1230         IL_PUSH(g_damagedbycontents, this);
1231         this.vehicleid                          = info.vehicleid;
1232         this.PlayerPhysplug                     = info.PlayerPhysplug;
1233         this.event_damage                       = func_null;
1234         settouch(this, vehicles_touch);
1235         setthink(this, vehicles_spawn);
1236         this.nextthink                          = time;
1237         this.effects                            = EF_NODRAW;
1238         this.dphitcontentsmask          = DPCONTENTS_BODY | DPCONTENTS_SOLID;
1239
1240         if(autocvar_g_playerclip_collisions)
1241                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1242
1243         if(autocvar_g_nodepthtestplayers)
1244                 this.effects |= EF_NODEPTHTEST;
1245
1246         if(autocvar_g_fullbrightplayers)
1247                 this.effects |= EF_FULLBRIGHT;
1248
1249         _setmodel(this.vehicle_hudmodel, info.hud_model);
1250         setmodel(this.vehicle_viewport, MDL_Null);
1251
1252         if(info.head_model != "")
1253         {
1254                 _setmodel(this.tur_head, info.head_model);
1255                 setattachment(this.tur_head, this, info.tag_head);
1256                 setattachment(this.vehicle_hudmodel, this.tur_head, info.tag_hud);
1257                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1258         }
1259         else
1260         {
1261                 setattachment(this.tur_head, this, "");
1262                 setattachment(this.vehicle_hudmodel, this, info.tag_hud);
1263                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1264         }
1265
1266         setsize(this, info.m_mins, info.m_maxs);
1267
1268         info.vr_setup(info, this);
1269
1270         if(!nodrop)
1271         {
1272                 setorigin(this, this.origin);
1273                 tracebox(this.origin + '0 0 100', info.m_mins, info.m_maxs, this.origin - '0 0 10000', MOVE_WORLDONLY, this);
1274                 setorigin(this, trace_endpos);
1275         }
1276
1277         this.pos1 = this.origin;
1278         this.pos2 = this.angles;
1279         this.tur_head.team = this.team;
1280
1281         if(this.active == ACTIVE_NOT)
1282                 this.nextthink = 0; // wait until activated
1283         else if(autocvar_g_vehicles_delayspawn)
1284                 this.nextthink = time + this.respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter);
1285         else
1286                 this.nextthink = time + game_starttime;
1287
1288         if(MUTATOR_CALLHOOK(VehicleInit, this))
1289                 return false;
1290
1291         return true;
1292 }