qcsrc/common/vehicles/sv_vehicles.qc

   1 #include "sv_vehicles.qh"
   2
   3 bool SendAuxiliaryXhair(entity this, entity to, int sf)
   4 {
   5         WriteHeader(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
   6         WriteByte(MSG_ENTITY, sf);
   7
   8         WriteByte(MSG_ENTITY, this.cnt);
   9
  10         if(sf & 2)
  11         {
  12                 WriteCoord(MSG_ENTITY, this.origin_x);
  13                 WriteCoord(MSG_ENTITY, this.origin_y);
  14                 WriteCoord(MSG_ENTITY, this.origin_z);
  15         }
  16
  17         if(sf & 4)
  18         {
  19                 WriteByte(MSG_ENTITY, rint(this.colormod_x * 255));
  20                 WriteByte(MSG_ENTITY, rint(this.colormod_y * 255));
  21                 WriteByte(MSG_ENTITY, rint(this.colormod_z * 255));
  22         }
  23
  24         return true;
  25 }
  26
  27 bool AuxiliaryXhair_customize(entity this, entity client)
  28 {
  29         //entity e = WaypointSprite_getviewentity(client);
  30         entity axh = client.(AuxiliaryXhair[this.cnt]);
  31         return axh.owner == this.owner; // cheaply check if the client's axh owner is the same as our real owner
  32 }
  33
  34 .vector axh_prevorigin;
  35 .vector axh_prevcolors;
  36
  37 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, int axh_id)
  38 {
  39         if(!IS_REAL_CLIENT(own))
  40                 return;
  41
  42         axh_id = bound(0, axh_id, MAX_AXH);
  43         entity axh = own.(AuxiliaryXhair[axh_id]);
  44
  45         if(axh == NULL || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist? Mario: because of sloppy code like this)
  46         {
  47                 axh = new(auxiliary_xhair);
  48                 axh.cnt = axh_id;
  49                 //axh.drawonlytoclient = own; // not spectatable
  50                 setcefc(axh, AuxiliaryXhair_customize);
  51                 axh.owner = own;
  52                 Net_LinkEntity(axh, false, 0, SendAuxiliaryXhair);
  53         }
  54
  55         if(loc != axh.axh_prevorigin)
  56         {
  57                 setorigin(axh, loc);
  58                 axh.SendFlags |= 2;
  59         }
  60
  61         if(clr != axh.axh_prevcolors)
  62         {
  63                 axh.colormod = clr;
  64                 axh.SendFlags |= 4;
  65         }
  66
  67         own.(AuxiliaryXhair[axh_id]) = axh; // set it anyway...?
  68 }
  69
  70 void CSQCVehicleSetup(entity own, int vehicle_id)
  71 {
  72         if(!IS_REAL_CLIENT(own))
  73                 return;
  74
  75         msg_entity = own;
  76
  77         WriteHeader(MSG_ONE, TE_CSQC_VEHICLESETUP);
  78         WriteByte(MSG_ONE, vehicle_id);
  79
  80         if(vehicle_id == 0 || vehicle_id == HUD_NORMAL)
  81         {
  82                 for(int i = 0; i < MAX_AXH; ++i)
  83                 {
  84                         entity axh = own.(AuxiliaryXhair[i]);
  85                         own.(AuxiliaryXhair[i]) = NULL;
  86
  87                         if(axh.owner == own && axh != NULL && !wasfreed(axh))
  88                                 delete(axh);
  89                 }
  90         }
  91 }
  92
  93 void vehicles_locktarget(entity this, float incr, float decr, float _lock_time)
  94 {
  95         if(this.lock_target && IS_DEAD(this.lock_target))
  96         {
  97                 this.lock_target        = NULL;
  98                 this.lock_strength  = 0;
  99                 this.lock_time    = 0;
 100         }
 101
 102         if(this.lock_time > time)
 103         {
 104                 if(this.lock_target)
 105                 if(this.lock_soundtime < time)
 106                 {
 107                         this.lock_soundtime = time + 0.5;
 108                         play2(this.owner, "vehicles/locked.wav");
 109                 }
 110
 111                 return;
 112         }
 113
 114         if(trace_ent != NULL)
 115         {
 116                 if(SAME_TEAM(trace_ent, this))
 117                         trace_ent = NULL;
 118
 119                 if(IS_DEAD(trace_ent))
 120                         trace_ent = NULL;
 121
 122                 if(!(IS_VEHICLE(trace_ent) || IS_TURRET(trace_ent)))
 123                         trace_ent = NULL;
 124
 125                 if(trace_ent.alpha <= 0.5 && trace_ent.alpha != 0)
 126                         trace_ent = NULL; // invisible
 127         }
 128
 129         if(this.lock_target == NULL && trace_ent != NULL)
 130                 this.lock_target = trace_ent;
 131
 132         if(this.lock_target && trace_ent == this.lock_target)
 133         {
 134                 if(this.lock_strength != 1 && this.lock_strength + incr >= 1)
 135                 {
 136                         play2(this.owner, "vehicles/lock.wav");
 137                         this.lock_soundtime = time + 0.8;
 138                 }
 139                 else if (this.lock_strength != 1 && this.lock_soundtime < time)
 140                 {
 141                         play2(this.owner, "vehicles/locking.wav");
 142                         this.lock_soundtime = time + 0.3;
 143                 }
 144         }
 145
 146         // Have a locking target
 147         // Trace hit current target
 148         if(trace_ent == this.lock_target && trace_ent != NULL)
 149         {
 150                 this.lock_strength = min(this.lock_strength + incr, 1);
 151                 if(this.lock_strength == 1)
 152                         this.lock_time = time + _lock_time;
 153         }
 154         else
 155         {
 156                 if(trace_ent)
 157                         this.lock_strength = max(this.lock_strength - decr * 2, 0);
 158                 else
 159                         this.lock_strength = max(this.lock_strength - decr, 0);
 160
 161                 if(this.lock_strength == 0)
 162                         this.lock_target = NULL;
 163         }
 164 }
 165
 166 float vehicle_altitude(entity this, float amax)
 167 {
 168         tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * amax), MOVE_WORLDONLY, this);
 169         return vlen(this.origin - trace_endpos);
 170 }
 171
 172 vector vehicles_force_fromtag_hover(entity this, string tag_name, float spring_length, float max_power)
 173 {
 174         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
 175         v_forward  = normalize(v_forward) * -1;
 176         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
 177
 178         force_fromtag_power = (1 - trace_fraction) * max_power;
 179         force_fromtag_normpower = force_fromtag_power / max_power;
 180
 181         return v_forward  * force_fromtag_power;
 182 }
 183
 184 vector vehicles_force_fromtag_maglev(entity this, string tag_name, float spring_length, float max_power)
 185 {
 186         force_fromtag_origin = gettaginfo(this, gettagindex(this, tag_name));
 187         v_forward  = normalize(v_forward) * -1;
 188         traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, this);
 189
 190         // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 191         if(trace_fraction == 1.0)
 192         {
 193                 force_fromtag_normpower = -0.25;
 194                 return '0 0 -200';
 195         }
 196
 197         force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 198         force_fromtag_normpower = force_fromtag_power / max_power;
 199
 200         return v_forward  * force_fromtag_power;
 201 }
 202
 203 // projectile handling
 204 void vehicles_projectile_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 205 {
 206         // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 207         if(inflictor.owner == this.owner)
 208                 return;
 209
 210         this.health -= damage;
 211         this.velocity += force;
 212         if(this.health < 1)
 213         {
 214                 this.takedamage = DAMAGE_NO;
 215                 this.event_damage = func_null;
 216                 setthink(this, adaptor_think2use);
 217                 this.nextthink = time;
 218         }
 219 }
 220
 221 void vehicles_projectile_explode(entity this, entity toucher)
 222 {
 223         if(this.owner && toucher != NULL)
 224         {
 225                 if(toucher == this.owner.vehicle)
 226                         return;
 227
 228                 if(toucher == this.owner.vehicle.tur_head)
 229                         return;
 230         }
 231
 232         PROJECTILE_TOUCH(this, toucher);
 233
 234         this.event_damage = func_null;
 235         RadiusDamage (this, this.realowner, this.shot_dmg, 0, this.shot_radius, this, NULL, this.shot_force, this.totalfrags, toucher);
 236
 237         delete(this);
 238 }
 239
 240 void vehicles_projectile_explode_think(entity this)
 241 {
 242         vehicles_projectile_explode(this, NULL);
 243 }
 244
 245 void vehicles_projectile_explode_use(entity this, entity actor, entity trigger)
 246 {
 247         vehicles_projectile_explode(this, trigger);
 248 }
 249
 250 entity vehicles_projectile(entity this, string _mzlfx, Sound _mzlsound,
 251                                                    vector _org, vector _vel,
 252                                                    float _dmg, float _radi, float _force,  float _size,
 253                                                    int _deahtype, float _projtype, float _health,
 254                                                    bool _cull, bool _clianim, entity _owner)
 255 {
 256     TC(Sound, _mzlsound);
 257         entity proj;
 258
 259         proj = spawn();
 260
 261         PROJECTILE_MAKETRIGGER(proj);
 262         setorigin(proj, _org);
 263
 264         proj.shot_dmg            = _dmg;
 265         proj.shot_radius          = _radi;
 266         proj.shot_force    = _force;
 267         proj.totalfrags    = _deahtype;
 268         proj.solid                      = SOLID_BBOX;
 269         set_movetype(proj, MOVETYPE_FLYMISSILE);
 270         proj.flags = FL_PROJECTILE;
 271         IL_PUSH(g_projectiles, proj);
 272         IL_PUSH(g_bot_dodge, proj);
 273         proj.bot_dodge          = true;
 274         proj.bot_dodgerating  = _dmg;
 275         proj.velocity            = _vel;
 276         settouch(proj, vehicles_projectile_explode);
 277         proj.use                          = vehicles_projectile_explode_use;
 278         proj.owner                      = this;
 279         proj.realowner          = _owner;
 280         setthink(proj, SUB_Remove);
 281         proj.nextthink          = time + 30;
 282
 283         if(_health)
 284         {
 285                 proj.takedamage    = DAMAGE_AIM;
 286                 proj.event_damage        = vehicles_projectile_damage;
 287                 proj.health                = _health;
 288         }
 289         else
 290                 proj.flags |= FL_NOTARGET;
 291
 292         if(_mzlsound != SND_Null)
 293                 sound (this, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTEN_NORM);
 294
 295         if(_mzlfx)
 296                 Send_Effect_(_mzlfx, proj.origin, proj.velocity, 1);
 297
 298         setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 299
 300         CSQCProjectile(proj, _clianim, _projtype, _cull);
 301
 302         return proj;
 303 }
 304
 305 void vehicles_gib_explode(entity this)
 306 {
 307         sound (this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 308         Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 309         Send_Effect(EFFECT_EXPLOSION_SMALL, this.wp00.origin + '0 0 64', '0 0 0', 1);
 310         delete(this);
 311 }
 312
 313 void vehicles_gib_touch(entity this, entity toucher)
 314 {
 315         vehicles_gib_explode(this);
 316 }
 317
 318 void vehicles_gib_think(entity this)
 319 {
 320         this.alpha -= 0.1;
 321         if(this.cnt >= time)
 322                 delete(this);
 323         else
 324                 this.nextthink = time + 0.1;
 325 }
 326
 327 entity vehicle_tossgib(entity this, entity _template, vector _vel, string _tag, bool _burn, bool _explode, float _maxtime, vector _rot)
 328 {
 329         entity _gib = spawn();
 330         _setmodel(_gib, _template.model);
 331         vector org = gettaginfo(this, gettagindex(this, _tag));
 332         setorigin(_gib, org);
 333         _gib.velocity = _vel;
 334         set_movetype(_gib, MOVETYPE_TOSS);
 335         _gib.solid = SOLID_CORPSE;
 336         _gib.colormod = '-0.5 -0.5 -0.5';
 337         _gib.effects = EF_LOWPRECISION;
 338         _gib.avelocity = _rot;
 339
 340         if(_burn)
 341                 _gib.effects |= EF_FLAME;
 342
 343         if(_explode)
 344         {
 345                 setthink(_gib, vehicles_gib_explode);
 346                 _gib.nextthink = time + random() * _explode;
 347                 settouch(_gib, vehicles_gib_touch);
 348         }
 349         else
 350         {
 351                 _gib.cnt = time + _maxtime;
 352                 setthink(_gib, vehicles_gib_think);
 353                 _gib.nextthink = time + _maxtime - 1;
 354                 _gib.alpha = 1;
 355         }
 356         return _gib;
 357 }
 358
 359 bool vehicle_addplayerslot(     entity _owner,
 360                                                                 entity _slot,
 361                                                                 int _hud,
 362                                                                 Model _hud_model,
 363                                                                 bool(entity,float) _framefunc,
 364                                                                 void(entity,bool) _exitfunc, float(entity, entity) _enterfunc)
 365 {
 366         if(!(_owner.vehicle_flags & VHF_MULTISLOT))
 367                 _owner.vehicle_flags |= VHF_MULTISLOT;
 368
 369         _slot.PlayerPhysplug = _framefunc;
 370         _slot.vehicle_exit = _exitfunc;
 371         _slot.vehicle_enter = _enterfunc;
 372         _slot.hud = _hud;
 373         _slot.vehicle_flags = VHF_PLAYERSLOT;
 374         _slot.vehicle_viewport = spawn();
 375         _slot.vehicle_hudmodel = spawn();
 376         _slot.vehicle_hudmodel.viewmodelforclient = _slot;
 377         _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 378
 379         setmodel(_slot.vehicle_hudmodel, _hud_model);
 380         setmodel(_slot.vehicle_viewport, MDL_Null);
 381
 382         setattachment(_slot.vehicle_hudmodel, _slot, "");
 383         setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
 384
 385         return true;
 386 }
 387
 388 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
 389                                                  float _pichlimit_min, float _pichlimit_max,
 390                                                  float _rotlimit_min, float _rotlimit_max, float _aimspeed)
 391 {
 392         vector vtmp, vtag;
 393         float ftmp;
 394         vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
 395         vtmp = vectoangles(normalize(_target - vtag));
 396         vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
 397         vtmp = AnglesTransform_Normalize(vtmp, true);
 398         ftmp = _aimspeed * frametime;
 399         vtmp_y = bound(-ftmp, vtmp_y, ftmp);
 400         vtmp_x = bound(-ftmp, vtmp_x, ftmp);
 401         _turrret.angles_y = bound(_rotlimit_min, _turrret.angles_y + vtmp_y, _rotlimit_max);
 402         _turrret.angles_x = bound(_pichlimit_min, _turrret.angles_x + vtmp_x, _pichlimit_max);
 403         return vtag;
 404 }
 405
 406 void vehicles_reset_colors(entity this, entity player)
 407 {
 408         int eff = 0, cmap;
 409         const vector cmod = '0 0 0';
 410         if(this.team && teamplay)
 411                 cmap = 1024 + (this.team - 1) * 17;
 412         else if(player)
 413                 cmap = player.colormap;
 414         else
 415                 cmap = 1024;
 416         if(autocvar_g_nodepthtestplayers)
 417                 eff |= EF_NODEPTHTEST;
 418         if(autocvar_g_fullbrightplayers)
 419                 eff |= EF_FULLBRIGHT;
 420
 421         // Find all ents attacked to main model and setup effects, colormod etc.
 422         FOREACH_ENTITY_ENT(tag_entity, this,
 423         {
 424                 if(it == this.vehicle_shieldent)
 425                         continue;
 426
 427                 it.effects = eff;
 428                 it.colormod = cmod;
 429                 it.colormap = cmap;
 430                 it.alpha = 1;
 431         });
 432
 433         // Also check head tags
 434         FOREACH_ENTITY_ENT(tag_entity, this.tur_head,
 435         {
 436                 if(it == this.vehicle_shieldent)
 437                         continue;
 438
 439                 it.effects = eff;
 440                 it.colormod = cmod;
 441                 it.colormap = cmap;
 442                 it.alpha = 1;
 443         });
 444
 445         this.vehicle_hudmodel.effects  = this.effects  = eff; // | EF_LOWPRECISION;
 446         this.vehicle_hudmodel.colormod = this.colormod = cmod;
 447         this.vehicle_hudmodel.colormap = this.colormap = cmap;
 448         this.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 449
 450         this.alpha       = 1;
 451         this.avelocity = '0 0 0';
 452         this.velocity  = '0 0 0';
 453         this.effects   = eff;
 454
 455         Vehicle info = Vehicles_from(this.vehicleid);
 456         info.vr_setcolors(info, this);
 457 }
 458
 459 void vehicles_clearreturn(entity veh)
 460 {
 461         // Remove "return helper" entities, if any.
 462         IL_EACH(g_vehicle_returners, it.wp00 == veh,
 463         {
 464                 it.classname = "";
 465                 setthink(it, SUB_Remove);
 466                 it.nextthink = time + 0.1;
 467                 IL_REMOVE(g_vehicle_returners, it);
 468
 469                 if(it.waypointsprite_attached)
 470                         WaypointSprite_Kill(it.waypointsprite_attached);
 471         });
 472 }
 473
 474 void vehicles_spawn(entity this);
 475 void vehicles_return(entity this)
 476 {
 477         Send_Effect(EFFECT_TELEPORT, this.wp00.origin + '0 0 64', '0 0 0', 1);
 478
 479         setthink(this.wp00, vehicles_spawn);
 480         this.wp00.nextthink = time;
 481
 482         if(this.waypointsprite_attached)
 483                 WaypointSprite_Kill(this.waypointsprite_attached);
 484
 485         delete(this);
 486 }
 487
 488 void vehicles_showwp_goaway(entity this)
 489 {
 490         if(this.waypointsprite_attached)
 491                 WaypointSprite_Kill(this.waypointsprite_attached);
 492
 493         delete(this);
 494 }
 495
 496 void vehicles_showwp(entity this)
 497 {
 498         entity ent = this;
 499
 500         if(ent.cnt)
 501         {
 502                 setthink(ent, vehicles_return);
 503                 ent.nextthink = ent.cnt;
 504         }
 505         else
 506         {
 507                 setthink(ent, vehicles_return);
 508                 ent.nextthink  = time + 1;
 509
 510                 ent = spawn();
 511                 ent.team = this.wp00.team;
 512                 ent.wp00 = this.wp00;
 513                 setorigin(ent, this.wp00.pos1);
 514
 515                 ent.nextthink = time + 5;
 516                 setthink(ent, vehicles_showwp_goaway);
 517         }
 518
 519         vector rgb;
 520         if(teamplay && ent.team)
 521                 rgb = Team_ColorRGB(ent.team);
 522         else
 523                 rgb = '1 1 1';
 524         entity wp = WaypointSprite_Spawn(WP_Vehicle, 0, 0, ent, '0 0 64', NULL, 0, ent, waypointsprite_attached, true, RADARICON_Vehicle);
 525         wp.wp_extra = ent.wp00.vehicleid;
 526         wp.colormod = rgb;
 527         if(ent.waypointsprite_attached)
 528         {
 529                 WaypointSprite_UpdateRule(ent.waypointsprite_attached, ent.wp00.team, SPRITERULE_DEFAULT);
 530                 if(this == NULL)
 531                         WaypointSprite_UpdateBuildFinished(ent.waypointsprite_attached, ent.nextthink);
 532                 WaypointSprite_Ping(ent.waypointsprite_attached);
 533         }
 534 }
 535
 536 void vehicles_setreturn(entity veh)
 537 {
 538         vehicles_clearreturn(veh);
 539
 540         entity ret = new(vehicle_return);
 541         IL_PUSH(g_vehicle_returners, ret);
 542         ret.wp00           = veh;
 543         ret.team                = veh.team;
 544         setthink(ret, vehicles_showwp);
 545
 546         if(IS_DEAD(veh))
 547         {
 548                 ret.cnt          = time + veh.respawntime;
 549                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 5);
 550         }
 551         else
 552         {
 553                 ret.nextthink   = min(time + veh.respawntime, time + veh.respawntime - 1);
 554         }
 555
 556         setorigin(ret, veh.pos1 + '0 0 96');
 557 }
 558
 559 void vehicle_use(entity this, entity actor, entity trigger)
 560 {
 561         LOG_DEBUG("vehicle ", this.netname, " used by ", actor.classname);
 562
 563         this.tur_head.team = actor.team;
 564
 565         if(this.tur_head.team == 0)
 566                 this.active = ACTIVE_NOT;
 567         else
 568                 this.active = ACTIVE_ACTIVE;
 569
 570         if(this.active == ACTIVE_ACTIVE && !IS_DEAD(this) && !game_stopped)
 571         {
 572                 LOG_DEBUG("Respawning vehicle: ", this.netname);
 573                 if(this.effects & EF_NODRAW)
 574                 {
 575                         setthink(this, vehicles_spawn);
 576                         this.nextthink = time + 3;
 577                 }
 578                 else
 579                 {
 580                         vehicles_setreturn(this);
 581                         vehicles_reset_colors(this, actor);
 582                 }
 583         }
 584 }
 585
 586 void vehicles_regen(entity this, float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 587 {
 588         if(this.(regen_field) < field_max)
 589         if(timer + rpause < time)
 590         {
 591                 if(_healthscale)
 592                         regen = regen * (this.vehicle_health / this.max_health);
 593
 594                 this.(regen_field) = min(this.(regen_field) + regen * delta_time, field_max);
 595
 596                 if(this.owner)
 597                         this.owner.(regen_field) = (this.(regen_field) / field_max) * 100;
 598         }
 599 }
 600
 601 void shieldhit_think(entity this)
 602 {
 603         this.alpha -= 0.1;
 604         if (this.alpha <= 0)
 605         {
 606                 // setmodel(this, MDL_Null);
 607                 this.alpha = -1;
 608                 this.effects |= EF_NODRAW;
 609         }
 610         else
 611         {
 612                 this.nextthink = time + 0.1;
 613         }
 614 }
 615
 616 void vehicles_painframe(entity this)
 617 {
 618         int myhealth = ((this.owner) ? this.owner.vehicle_health : ((this.vehicle_health / this.max_health) * 100));
 619
 620         if(myhealth <= 50)
 621         if(this.pain_frame < time)
 622         {
 623                 float _ftmp = myhealth / 50;
 624                 this.pain_frame = time + max(0.1, 0.1 + (random() * 0.5 * _ftmp));
 625                 Send_Effect(EFFECT_SMOKE_SMALL, (this.origin + (randomvec() * 80)), '0 0 0', 1);
 626
 627                 if(this.vehicle_flags & VHF_DMGSHAKE)
 628                         this.velocity += randomvec() * 30;
 629
 630                 if(this.vehicle_flags & VHF_DMGROLL)
 631                         if(this.vehicle_flags & VHF_DMGHEADROLL)
 632                                 this.tur_head.angles += randomvec();
 633                         else
 634                                 this.angles += randomvec();
 635         }
 636 }
 637
 638 void vehicles_frame(entity this, entity actor)
 639 {
 640         vehicles_painframe(this);
 641 }
 642
 643 void vehicles_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 644 {
 645         this.dmg_time = time;
 646
 647         // WEAPONTODO
 648         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX))
 649                 damage *= autocvar_g_vehicles_vortex_damagerate;
 650         else if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 651                 damage *= autocvar_g_vehicles_machinegun_damagerate;
 652         else if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 653                 damage *= autocvar_g_vehicles_rifle_damagerate;
 654         else if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 655                 damage *= autocvar_g_vehicles_vaporizer_damagerate;
 656         else if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 657                 damage *= autocvar_g_vehicles_tag_damagerate;
 658         else if(DEATH_WEAPONOF(deathtype) != WEP_Null)
 659                 damage *= autocvar_g_vehicles_weapon_damagerate;
 660
 661         this.enemy = attacker;
 662
 663         this.pain_finished = time;
 664
 665         if((this.vehicle_flags & VHF_HASSHIELD) && (this.vehicle_shield > 0))
 666         {
 667                 if (wasfreed(this.vehicle_shieldent) || this.vehicle_shieldent == NULL)
 668                 {
 669                         this.vehicle_shieldent = spawn();
 670                         this.vehicle_shieldent.effects = EF_LOWPRECISION;
 671
 672                         setmodel(this.vehicle_shieldent, MDL_VEH_SHIELD);
 673                         setattachment(this.vehicle_shieldent, this, "");
 674                         setorigin(this.vehicle_shieldent, real_origin(this) - this.origin);
 675                         this.vehicle_shieldent.scale       = 256 / vlen(this.maxs - this.mins);
 676                         setthink(this.vehicle_shieldent, shieldhit_think);
 677                 }
 678
 679                 this.vehicle_shieldent.colormod = '1 1 1';
 680                 this.vehicle_shieldent.alpha = 0.45;
 681                 this.vehicle_shieldent.angles = vectoangles(normalize(hitloc - (this.origin + this.vehicle_shieldent.origin))) - this.angles;
 682                 this.vehicle_shieldent.nextthink = time;
 683                 this.vehicle_shieldent.effects &= ~EF_NODRAW;
 684
 685                 this.vehicle_shield -= damage;
 686
 687                 if(this.vehicle_shield < 0)
 688                 {
 689                         this.vehicle_health -= fabs(this.vehicle_shield);
 690                         this.vehicle_shieldent.colormod = '2 0 0';
 691                         this.vehicle_shield = 0;
 692                         this.vehicle_shieldent.alpha = 0.75;
 693
 694                         if(sound_allowed(MSG_BROADCAST, attacker))
 695                                 spamsound (this, CH_PAIN, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);   // FIXME: PLACEHOLDER
 696                 }
 697                 else
 698                         if(sound_allowed(MSG_BROADCAST, attacker))
 699                                 spamsound (this, CH_PAIN, SND_ONS_ELECTRICITY_EXPLODE, VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 700
 701         }
 702         else
 703         {
 704                 this.vehicle_health -= damage;
 705
 706                 if(sound_allowed(MSG_BROADCAST, attacker))
 707                         spamsound (this, CH_PAIN, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 708         }
 709
 710         if(this.damageforcescale < 1 && this.damageforcescale > 0)
 711                 this.velocity += force * this.damageforcescale;
 712         else
 713                 this.velocity += force;
 714
 715         if(this.vehicle_health <= 0)
 716         {
 717                 if(this.owner)
 718                         if(this.vehicle_flags & VHF_DEATHEJECT)
 719                                 vehicles_exit(this, VHEF_EJECT);
 720                         else
 721                                 vehicles_exit(this, VHEF_RELEASE);
 722
 723
 724                 antilag_clear(this, this);
 725
 726                 Vehicle info = Vehicles_from(this.vehicleid);
 727                 info.vr_death(info, this);
 728                 vehicles_setreturn(this);
 729         }
 730 }
 731
 732 bool vehicles_crushable(entity e)
 733 {
 734         if(IS_PLAYER(e) && time >= e.vehicle_enter_delay)
 735                 return true;
 736
 737         if(IS_MONSTER(e))
 738                 return true;
 739
 740         return false;
 741 }
 742
 743 void vehicles_impact(entity this, float _minspeed, float _speedfac, float _maxpain)
 744 {
 745         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 746                 return;
 747
 748         if(this.play_time < time)
 749         {
 750                 float wc = vlen(this.velocity - this.oldvelocity);
 751                 //dprint("oldvel: ", vtos(this.oldvelocity), "\n");
 752                 //dprint("vel: ", vtos(this.velocity), "\n");
 753                 if(_minspeed < wc)
 754                 {
 755                         float take = min(_speedfac * wc, _maxpain);
 756                         Damage (this, NULL, NULL, take, DEATH_FALL.m_id, this.origin, '0 0 0');
 757                         this.play_time = time + 0.25;
 758
 759                         //dprint("wc: ", ftos(wc), "\n");
 760                         //dprint("take: ", ftos(take), "\n");
 761                 }
 762         }
 763 }
 764
 765 // vehicle enter/exit handling
 766 vector vehicles_findgoodexit(entity this, entity player, vector prefer_spot)
 767 {
 768         // TODO: we actually want the player's size here
 769         tracebox(this.origin + '0 0 32', PL_MIN_CONST, PL_MAX_CONST, prefer_spot, MOVE_NORMAL, player);
 770         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 771                 return prefer_spot;
 772
 773         float mysize = 1.5 * vlen(this.maxs - this.mins);
 774         vector v;
 775         vector v2 = 0.5 * (this.absmin + this.absmax);
 776         for(int i = 0; i < autocvar_g_vehicles_exit_attempts; ++i)
 777         {
 778                 v = randomvec();
 779                 v_z = 0;
 780                 v = v2 + normalize(v) * mysize;
 781                 tracebox(v2, PL_MIN_CONST, PL_MAX_CONST, v, MOVE_NORMAL, player);
 782                 if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 783                         return v;
 784         }
 785
 786         return this.origin;
 787 }
 788
 789 .int old_vehicle_flags;
 790 void vehicles_exit(entity vehic, bool eject)
 791 {
 792         entity player = vehic.owner;
 793
 794         if(vehicles_exit_running)
 795         {
 796                 LOG_TRACE("^1vehicles_exit already running! this is not good...");
 797                 return;
 798         }
 799
 800         vehicles_exit_running = true;
 801
 802         // TODO: this was in an IS_CLIENT check, make sure it isn't actually needed!
 803         if(vehic.vehicle_flags & VHF_PLAYERSLOT)
 804         {
 805                 vehic.vehicle_exit(vehic, eject);
 806                 vehicles_exit_running = false;
 807                 return;
 808         }
 809
 810         if (player)
 811         {
 812                 if (IS_REAL_CLIENT(player))
 813                 {
 814                         msg_entity = player;
 815                         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 816                         WriteEntity( MSG_ONE, player);
 817
 818                         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 819                         WriteAngle(MSG_ONE, 0);
 820                         WriteAngle(MSG_ONE, vehic.angles_y);
 821                         WriteAngle(MSG_ONE, 0);
 822                 }
 823
 824                 setsize(player, STAT(PL_MIN, player), STAT(PL_MAX, player));
 825
 826                 player.takedamage               = DAMAGE_AIM;
 827                 player.solid                    = SOLID_SLIDEBOX;
 828                 set_movetype(player, MOVETYPE_WALK);
 829                 player.effects             &= ~EF_NODRAW;
 830                 player.teleportable     = TELEPORT_NORMAL;
 831                 player.alpha                    = 1;
 832                 player.PlayerPhysplug   = func_null;
 833                 player.vehicle                  = NULL;
 834                 player.view_ofs         = STAT(PL_VIEW_OFS, player);
 835                 player.event_damage     = PlayerDamage;
 836                 player.hud                              = HUD_NORMAL;
 837                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++ slot)
 838                 {
 839                         .entity weaponentity = weaponentities[slot];
 840                         player.(weaponentity).m_switchweapon = vehic.(weaponentity).m_switchweapon;
 841                         delete(vehic.(weaponentity)); // no longer needed
 842                 }
 843                 player.last_vehiclecheck = time + 3;
 844                 player.vehicle_enter_delay = time + 2;
 845
 846                 CSQCVehicleSetup(player, HUD_NORMAL);
 847
 848                 Kill_Notification(NOTIF_ONE, player, MSG_CENTER, CPID_VEHICLES);
 849                 Kill_Notification(NOTIF_ONE, player, MSG_CENTER, CPID_VEHICLES_OTHER); // kill all vehicle notifications when exiting a vehicle?
 850         }
 851
 852         vehic.flags |= FL_NOTARGET;
 853
 854         if(!IS_DEAD(vehic))
 855                 vehic.avelocity = '0 0 0';
 856
 857         vehic.tur_head.nodrawtoclient = NULL;
 858
 859         if(!teamplay)
 860                 vehic.team = 0;
 861
 862         WaypointSprite_Kill(vehic.wps_intruder);
 863
 864         MUTATOR_CALLHOOK(VehicleExit, player, vehic);
 865
 866         vehic.team = vehic.tur_head.team;
 867
 868         if(vehic.old_vehicle_flags & VHF_SHIELDREGEN)
 869                 vehic.vehicle_flags |= VHF_SHIELDREGEN;
 870         vehic.old_vehicle_flags = 0;
 871
 872         sound (vehic, CH_TRIGGER_SINGLE, SND_Null, 1, ATTEN_NORM);
 873         vehic.vehicle_hudmodel.viewmodelforclient = vehic;
 874         vehic.phase = time + 1;
 875
 876         vehic.vehicle_exit(vehic, eject);
 877
 878         vehicles_setreturn(vehic);
 879         vehicles_reset_colors(vehic, NULL);
 880         vehic.owner = NULL;
 881
 882         CSQCMODEL_AUTOINIT(vehic);
 883
 884         if(player)
 885                 player.oldorigin = player.origin; // player's location is set by the exit functions, so we need to do this after everything
 886
 887         vehicles_exit_running = false;
 888 }
 889
 890 void vehicles_touch(entity this, entity toucher)
 891 {
 892         if(MUTATOR_CALLHOOK(VehicleTouch, this, toucher))
 893                 return;
 894
 895         // Vehicle currently in use
 896         if(this.owner)
 897         {
 898                 if(!forbidWeaponUse(this.owner))
 899                 if(toucher != NULL)
 900                 if((this.origin_z + this.maxs_z) > (toucher.origin_z))
 901                 if(vehicles_crushable(toucher))
 902                 {
 903                         if(vdist(this.velocity, >=, 30))
 904                                 Damage(toucher, this, this.owner, autocvar_g_vehicles_crush_dmg, DEATH_VH_CRUSH.m_id, '0 0 0', normalize(toucher.origin - this.origin) * autocvar_g_vehicles_crush_force);
 905
 906                         return; // Dont do selfdamage when hitting "soft targets".
 907                 }
 908
 909                 if(this.play_time < time) {
 910                         Vehicle info = Vehicles_from(this.vehicleid);
 911                         info.vr_impact(info, this);
 912                 }
 913
 914                 return;
 915         }
 916
 917         if(autocvar_g_vehicles_enter)
 918                 return;
 919
 920         vehicles_enter(toucher, this);
 921 }
 922
 923 bool vehicle_impulse(entity this, int imp)
 924 {
 925         entity v = this.vehicle;
 926         if (!v) return false;
 927         if (IS_DEAD(v)) return false;
 928         bool(entity,int) f = v.vehicles_impulse;
 929         if (f && f(this,imp)) return true;
 930         switch (imp)
 931         {
 932                 case IMP_weapon_drop.impulse:
 933                 {
 934                         stuffcmd(this, "\ntoggle cl_eventchase_vehicle\nset _vehicles_shownchasemessage 1\n");
 935                         return true;
 936                 }
 937         }
 938         return false;
 939 }
 940
 941 void vehicles_enter(entity pl, entity veh)
 942 {
 943    // Remove this when bots know how to use vehicles
 944         if((IS_BOT_CLIENT(pl) && !autocvar_g_vehicles_allow_bots))
 945                 return;
 946
 947         if((!IS_PLAYER(pl))
 948         || (veh.phase >= time)
 949         || (pl.vehicle_enter_delay >= time)
 950         || (STAT(FROZEN, pl))
 951         || (IS_DEAD(pl))
 952         || (pl.vehicle)
 953         ) { return; }
 954
 955         Vehicle info = Vehicles_from(veh.vehicleid);
 956
 957         if(autocvar_g_vehicles_enter) // vehicle's touch function should handle this if entering via use key is disabled (TODO)
 958         if(veh.vehicle_flags & VHF_MULTISLOT)
 959         if(veh.owner && SAME_TEAM(pl, veh))
 960         {
 961                 // we don't need a return value or anything here
 962                 // if successful the owner check below will prevent anything weird
 963                 info.vr_gunner_enter(info, veh, pl);
 964         }
 965
 966         if(veh.owner)
 967                 return; // got here and didn't enter the gunner, return
 968
 969         if(teamplay)
 970         if(veh.team)
 971         if(DIFF_TEAM(pl, veh))
 972         if(autocvar_g_vehicles_steal)
 973         {
 974                 FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, veh), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_VEHICLE_STEAL));
 975
 976                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_STEAL_SELF);
 977
 978                 veh.vehicle_shield = 0;
 979                 veh.old_vehicle_flags = veh.vehicle_flags; // make a backup just so we're not permanently crippling this vehicle
 980                 veh.vehicle_flags &= ~VHF_SHIELDREGEN;
 981
 982                 if (autocvar_g_vehicles_steal_show_waypoint) {
 983                         entity wp = WaypointSprite_Spawn(WP_VehicleIntruder, 0, 0, pl, '0 0 68', NULL, veh.team, veh, wps_intruder, true, RADARICON_DANGER);
 984                         wp.colormod = Team_ColorRGB(pl.team);
 985                 }
 986         }
 987         else return;
 988
 989         RemoveGrapplingHooks(pl);
 990
 991         veh.vehicle_ammo1 = 0;
 992         veh.vehicle_ammo2 = 0;
 993         veh.vehicle_reload1 = 0;
 994         veh.vehicle_reload2 = 0;
 995         veh.vehicle_energy = 0;
 996
 997         veh.owner = pl;
 998         pl.vehicle = veh;
 999
1000         // .viewmodelforclient works better.
1001         //veh.vehicle_hudmodel.drawonlytoclient = veh.owner;
1002
1003         veh.vehicle_hudmodel.viewmodelforclient = pl;
1004
1005         pl.crouch = false;
1006         pl.view_ofs = STAT(PL_VIEW_OFS, pl);
1007         setsize(pl, STAT(PL_MIN, pl), STAT(PL_MAX, pl));
1008
1009         veh.event_damage        = vehicles_damage;
1010         veh.nextthink           = 0;
1011         pl.items &= ~IT_USING_JETPACK;
1012         pl.angles                       = veh.angles;
1013         pl.takedamage           = DAMAGE_NO;
1014         pl.solid                        = SOLID_NOT;
1015         pl.disableclientprediction = 1; // physics is no longer run, so this won't be reset
1016         set_movetype(pl, MOVETYPE_NOCLIP);
1017         pl.teleportable         = false;
1018         pl.alpha                        = -1;
1019         pl.event_damage         = func_null;
1020         pl.view_ofs                     = '0 0 0';
1021         veh.colormap            = pl.colormap;
1022         if(veh.tur_head)
1023                 veh.tur_head.colormap = pl.colormap;
1024         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1025         {
1026                 .entity weaponentity = weaponentities[slot];
1027                 veh.(weaponentity) = new(temp_wepent);
1028                 veh.(weaponentity).m_switchweapon = pl.(weaponentity).m_switchweapon;
1029         }
1030         pl.hud = veh.vehicleid;
1031         pl.PlayerPhysplug = veh.PlayerPhysplug;
1032
1033         pl.vehicle_ammo1 = veh.vehicle_ammo1;
1034         pl.vehicle_ammo2 = veh.vehicle_ammo2;
1035         pl.vehicle_reload1 = veh.vehicle_reload1;
1036         pl.vehicle_reload2 = veh.vehicle_reload2;
1037         pl.vehicle_energy = veh.vehicle_energy;
1038
1039         // Cant do this, hides attached objects too.
1040         //veh.exteriormodeltoclient = veh.owner;
1041         //veh.tur_head.exteriormodeltoclient = veh.owner;
1042
1043         UNSET_ONGROUND(pl);
1044         UNSET_ONGROUND(veh);
1045
1046         veh.team = pl.team;
1047         veh.flags -= FL_NOTARGET;
1048
1049         vehicles_reset_colors(veh, pl);
1050
1051         if (IS_REAL_CLIENT(pl))
1052         {
1053                 Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_VEHICLE_ENTER);
1054
1055                 msg_entity = pl;
1056                 WriteByte (MSG_ONE, SVC_SETVIEWPORT);
1057                 WriteEntity(MSG_ONE, veh.vehicle_viewport);
1058
1059                 WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1060                 if(veh.tur_head)
1061                 {
1062                         WriteAngle(MSG_ONE, veh.tur_head.angles_x + veh.angles_x); // tilt
1063                         WriteAngle(MSG_ONE, veh.tur_head.angles_y + veh.angles_y); // yaw
1064                         WriteAngle(MSG_ONE, 0);                                                                   // roll
1065                 }
1066                 else
1067                 {
1068                         WriteAngle(MSG_ONE, veh.angles_x * -1); // tilt
1069                         WriteAngle(MSG_ONE, veh.angles_y);        // yaw
1070                         WriteAngle(MSG_ONE, 0);                           // roll
1071                 }
1072         }
1073
1074         vehicles_clearreturn(veh);
1075
1076         CSQCVehicleSetup(pl, veh.vehicleid);
1077
1078         MUTATOR_CALLHOOK(VehicleEnter, pl, veh);
1079
1080         CSQCModel_UnlinkEntity(veh);
1081         info.vr_enter(info, veh);
1082
1083         antilag_clear(pl, CS(pl));
1084 }
1085
1086 void vehicles_think(entity this)
1087 {
1088         this.nextthink = time + autocvar_g_vehicles_thinkrate;
1089
1090         if(this.owner)
1091                 this.owner.vehicle_weapon2mode = this.vehicle_weapon2mode;
1092
1093         Vehicle info = Vehicles_from(this.vehicleid);
1094         info.vr_think(info, this);
1095
1096         vehicles_painframe(this);
1097
1098         CSQCMODEL_AUTOUPDATE(this);
1099 }
1100
1101 void vehicles_reset(entity this)
1102 {
1103         if(this.owner)
1104                 vehicles_exit(this, VHEF_RELEASE);
1105
1106         vehicles_clearreturn(this);
1107
1108         if(this.active != ACTIVE_NOT)
1109                 vehicles_spawn(this);
1110 }
1111
1112 // initialization
1113 void vehicles_spawn(entity this)
1114 {
1115         LOG_DEBUG("Spawning vehicle: ", this.classname);
1116
1117         // disown & reset
1118         this.vehicle_hudmodel.viewmodelforclient = this;
1119
1120         this.owner                              = NULL;
1121         settouch(this, vehicles_touch);
1122         this.event_damage               = vehicles_damage;
1123         this.reset                              = vehicles_reset;
1124         this.iscreature                 = true;
1125         this.teleportable               = false; // no teleporting for vehicles, too buggy
1126         this.damagedbycontents  = true;
1127         set_movetype(this, MOVETYPE_WALK);
1128         this.solid                              = SOLID_SLIDEBOX;
1129         this.takedamage                 = DAMAGE_AIM;
1130         this.deadflag                   = DEAD_NO;
1131         if(!this.bot_attack)
1132                 IL_PUSH(g_bot_targets, this);
1133         this.bot_attack                 = true;
1134         this.flags                              = FL_NOTARGET;
1135         this.avelocity                  = '0 0 0';
1136         this.velocity                   = '0 0 0';
1137         setthink(this, vehicles_think);
1138         this.nextthink                  = time;
1139
1140         // Reset locking
1141         this.lock_strength = 0;
1142         this.lock_target = NULL;
1143         this.misc_bulletcounter = 0;
1144
1145         // Return to spawn
1146         this.angles = this.pos2;
1147         setorigin(this, this.pos1);
1148         // Show it
1149         Send_Effect(EFFECT_TELEPORT, this.origin + '0 0 64', '0 0 0', 1);
1150
1151         if(this.vehicle_controller)
1152                 this.team = this.vehicle_controller.team;
1153
1154         FOREACH_CLIENT(IS_PLAYER(it),
1155         {
1156                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1157             {
1158                 .entity weaponentity = weaponentities[slot];
1159                 if(it.(weaponentity).hook.aiment == this)
1160                         RemoveHook(it.(weaponentity).hook);
1161             }
1162         });
1163
1164
1165         Vehicle info = Vehicles_from(this.vehicleid);
1166         info.vr_spawn(info, this);
1167
1168         vehicles_reset_colors(this, NULL);
1169
1170         CSQCMODEL_AUTOINIT(this);
1171 }
1172
1173 bool vehicle_initialize(entity this, Vehicle info, bool nodrop)
1174 {
1175         if(!autocvar_g_vehicles)
1176                 return false;
1177
1178         if(!info.vehicleid)
1179                 return false;
1180
1181         if(!this.tur_head)
1182         {
1183                 info.vr_precache(info);
1184                 IL_PUSH(g_vehicles, this);
1185         }
1186
1187         if(this.targetname && this.targetname != "")
1188         {
1189                 this.vehicle_controller = find(NULL, target, this.targetname);
1190                 if(!this.vehicle_controller)
1191                 {
1192                         LOG_DEBUG("^1WARNING: ^7Vehicle with invalid .targetname");
1193                         this.active = ACTIVE_ACTIVE;
1194                 }
1195                 else
1196                 {
1197                         this.team = this.vehicle_controller.team;
1198                         this.use = vehicle_use;
1199
1200                         if(teamplay)
1201                         {
1202                                 if(this.vehicle_controller.team == 0)
1203                                         this.active = ACTIVE_NOT;
1204                                 else
1205                                         this.active = ACTIVE_ACTIVE;
1206                         }
1207                 }
1208         }
1209         else { this.active = ACTIVE_ACTIVE; }
1210
1211         if(this.team && (!teamplay || !autocvar_g_vehicles_teams))
1212                 this.team = 0;
1213
1214         if(this.mdl == "" || !this.mdl)
1215                 _setmodel(this, info.model);
1216         else
1217                 _setmodel(this, this.mdl);
1218
1219         this.vehicle_flags |= VHF_ISVEHICLE;
1220
1221         this.vehicle_viewport           = new(vehicle_viewport);
1222         this.vehicle_hudmodel           = new(vehicle_hudmodel);
1223         this.tur_head                           = new(tur_head);
1224         this.tur_head.owner                     = this;
1225         this.takedamage                         = DAMAGE_NO;
1226         this.bot_attack                         = true;
1227         IL_PUSH(g_bot_targets, this);
1228         this.iscreature                         = true;
1229         this.teleportable                       = false; // no teleporting for vehicles, too buggy
1230         this.damagedbycontents          = true;
1231         IL_PUSH(g_damagedbycontents, this);
1232         this.vehicleid                          = info.vehicleid;
1233         this.PlayerPhysplug                     = info.PlayerPhysplug;
1234         this.event_damage                       = func_null;
1235         settouch(this, vehicles_touch);
1236         setthink(this, vehicles_spawn);
1237         this.nextthink                          = time;
1238         this.effects                            = EF_NODRAW;
1239         this.dphitcontentsmask          = DPCONTENTS_BODY | DPCONTENTS_SOLID;
1240
1241         if(autocvar_g_playerclip_collisions)
1242                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1243
1244         if(autocvar_g_nodepthtestplayers)
1245                 this.effects |= EF_NODEPTHTEST;
1246
1247         if(autocvar_g_fullbrightplayers)
1248                 this.effects |= EF_FULLBRIGHT;
1249
1250         _setmodel(this.vehicle_hudmodel, info.hud_model);
1251         setmodel(this.vehicle_viewport, MDL_Null);
1252
1253         if(info.head_model != "")
1254         {
1255                 _setmodel(this.tur_head, info.head_model);
1256                 setattachment(this.tur_head, this, info.tag_head);
1257                 setattachment(this.vehicle_hudmodel, this.tur_head, info.tag_hud);
1258                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1259         }
1260         else
1261         {
1262                 setattachment(this.tur_head, this, "");
1263                 setattachment(this.vehicle_hudmodel, this, info.tag_hud);
1264                 setattachment(this.vehicle_viewport, this.vehicle_hudmodel, info.tag_view);
1265         }
1266
1267         setsize(this, info.m_mins, info.m_maxs);
1268
1269         info.vr_setup(info, this);
1270
1271         if(!nodrop)
1272         {
1273                 setorigin(this, this.origin);
1274                 tracebox(this.origin + '0 0 100', info.m_mins, info.m_maxs, this.origin - '0 0 10000', MOVE_WORLDONLY, this);
1275                 setorigin(this, trace_endpos);
1276         }
1277
1278         this.pos1 = this.origin;
1279         this.pos2 = this.angles;
1280         this.tur_head.team = this.team;
1281
1282         if(this.active == ACTIVE_NOT)
1283                 this.nextthink = 0; // wait until activated
1284         else if(autocvar_g_vehicles_delayspawn)
1285                 this.nextthink = time + this.respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter);
1286         else
1287                 this.nextthink = time + game_starttime;
1288
1289         if(MUTATOR_CALLHOOK(VehicleInit, this))
1290                 return false;
1291
1292         return true;
1293 }