qcsrc/common/vehicles/unit/raptor.qc

   1 #ifdef REGISTER_VEHICLE
   2 REGISTER_VEHICLE(
   3 /* VEH_##id   */ RAPTOR,
   4 /* function   */ v_raptor,
   5 /* spawnflags */ VHF_DMGSHAKE | VHF_DMGROLL,
   6 /* mins,maxs  */ '-80 -80 0', '80 80 70',
   7 /* model          */ "models/vehicles/raptor.dpm",
   8 /* head_model */ "",
   9 /* hud_model  */ "models/vehicles/raptor_cockpit.dpm",
  10 /* tags           */ "", "tag_hud", "tag_camera",
  11 /* netname        */ "raptor",
  12 /* fullname   */ _("Raptor")
  13 );
  14 #else
  15
  16 const float RSM_FIRST = 0;
  17 const float RSM_BOMB = 0;
  18 const float RSM_FLARE = 1;
  19 const float RSM_LAST = 1;
  20
  21 #ifdef SVQC
  22 float autocvar_g_vehicle_raptor;
  23
  24 float autocvar_g_vehicle_raptor_respawntime;
  25 float autocvar_g_vehicle_raptor_takeofftime;
  26
  27 float autocvar_g_vehicle_raptor_movestyle;
  28 float autocvar_g_vehicle_raptor_turnspeed;
  29 float autocvar_g_vehicle_raptor_pitchspeed;
  30 float autocvar_g_vehicle_raptor_pitchlimit;
  31
  32 float autocvar_g_vehicle_raptor_speed_forward;
  33 float autocvar_g_vehicle_raptor_speed_strafe;
  34 float autocvar_g_vehicle_raptor_speed_up;
  35 float autocvar_g_vehicle_raptor_speed_down;
  36 float autocvar_g_vehicle_raptor_friction;
  37
  38 float autocvar_g_vehicle_raptor_bomblets;
  39 float autocvar_g_vehicle_raptor_bomblet_alt;
  40 float autocvar_g_vehicle_raptor_bomblet_time;
  41 float autocvar_g_vehicle_raptor_bomblet_damage;
  42 float autocvar_g_vehicle_raptor_bomblet_spread;
  43 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  44 float autocvar_g_vehicle_raptor_bomblet_radius;
  45 float autocvar_g_vehicle_raptor_bomblet_force;
  46 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  47 float autocvar_g_vehicle_raptor_bombs_refire;
  48
  49 float autocvar_g_vehicle_raptor_flare_refire;
  50 float autocvar_g_vehicle_raptor_flare_lifetime;
  51 float autocvar_g_vehicle_raptor_flare_chase;
  52 float autocvar_g_vehicle_raptor_flare_range;
  53
  54 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  55 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  56 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  57 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  58
  59 float autocvar_g_vehicle_raptor_cannon_locktarget;
  60 float autocvar_g_vehicle_raptor_cannon_locking_time;
  61 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  62 float autocvar_g_vehicle_raptor_cannon_locked_time;
  63 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  64
  65 float autocvar_g_vehicle_raptor_cannon_cost;
  66 float autocvar_g_vehicle_raptor_cannon_damage;
  67 float autocvar_g_vehicle_raptor_cannon_radius;
  68 float autocvar_g_vehicle_raptor_cannon_refire;
  69 float autocvar_g_vehicle_raptor_cannon_speed;
  70 float autocvar_g_vehicle_raptor_cannon_spread;
  71 float autocvar_g_vehicle_raptor_cannon_force;
  72
  73 float autocvar_g_vehicle_raptor_energy;
  74 float autocvar_g_vehicle_raptor_energy_regen;
  75 float autocvar_g_vehicle_raptor_energy_regen_pause;
  76
  77 float autocvar_g_vehicle_raptor_health;
  78 float autocvar_g_vehicle_raptor_health_regen;
  79 float autocvar_g_vehicle_raptor_health_regen_pause;
  80
  81 float autocvar_g_vehicle_raptor_shield;
  82 float autocvar_g_vehicle_raptor_shield_regen;
  83 float autocvar_g_vehicle_raptor_shield_regen_pause;
  84
  85 float autocvar_g_vehicle_raptor_bouncefactor;
  86 float autocvar_g_vehicle_raptor_bouncestop;
  87 vector autocvar_g_vehicle_raptor_bouncepain;
  88
  89 .entity bomb1;
  90 .entity bomb2;
  91
  92 float raptor_altitude(float amax)
  93 {
  94         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), MOVE_WORLDONLY, self);
  95         return vlen(self.origin - trace_endpos);
  96 }
  97
  98 void raptor_bomblet_boom()
  99 {
 100         RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
 101                                                                         autocvar_g_vehicle_raptor_bomblet_edgedamage,
 102                                                                         autocvar_g_vehicle_raptor_bomblet_radius, world,
 103                                                                         autocvar_g_vehicle_raptor_bomblet_force, DEATH_VH_RAPT_BOMB, world);
 104         remove(self);
 105 }
 106
 107 void raptor_bomblet_touch()
 108 {
 109         if(other == self.owner)
 110                 return;
 111
 112         PROJECTILE_TOUCH;
 113         self.think = raptor_bomblet_boom;
 114         self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
 115 }
 116
 117 void raptor_bomb_burst()
 118 {
 119         if(self.cnt > time)
 120         if(autocvar_g_vehicle_raptor_bomblet_alt)
 121         {
 122                 self.nextthink = time;
 123                 traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 124                 if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 125                 {
 126                         UpdateCSQCProjectile(self);
 127                         return;
 128                 }
 129         }
 130
 131         entity bomblet;
 132         float i;
 133
 134         Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_VH_RAPT_FRAGMENT, 0, self);
 135
 136         for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 137         {
 138                 bomblet = spawn();
 139                 setorigin(bomblet, self.origin);
 140
 141                 bomblet.movetype        = MOVETYPE_TOSS;
 142                 bomblet.touch      = raptor_bomblet_touch;
 143                 bomblet.think      = raptor_bomblet_boom;
 144                 bomblet.nextthink   = time + 5;
 145                 bomblet.owner      = self.owner;
 146                 bomblet.realowner   = self.realowner;
 147                 bomblet.velocity        = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 148
 149                 PROJECTILE_MAKETRIGGER(bomblet);
 150                 CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 151         }
 152
 153         remove(self);
 154 }
 155
 156 void raptor_bombdrop()
 157 {
 158         entity bomb_1, bomb_2;
 159
 160         bomb_1 = spawn();
 161         bomb_2 = spawn();
 162
 163         setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 164         setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 165
 166         bomb_1.movetype  = bomb_2.movetype   = MOVETYPE_BOUNCE;
 167         bomb_1.velocity  = bomb_2.velocity   = self.velocity;
 168         bomb_1.touch            = bomb_2.touch    = raptor_bomb_burst;
 169         bomb_1.think            = bomb_2.think    = raptor_bomb_burst;
 170         bomb_1.cnt                = bomb_2.cnt          = time + 10;
 171
 172         if(autocvar_g_vehicle_raptor_bomblet_alt)
 173                 bomb_1.nextthink = bomb_2.nextthink  = time;
 174         else
 175                 bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 176
 177         bomb_1.owner     = bomb_2.owner   = self;
 178         bomb_1.realowner = bomb_2.realowner  = self.owner;
 179         bomb_1.solid     = bomb_2.solid   = SOLID_BBOX;
 180         bomb_1.gravity   = bomb_2.gravity       = 1;
 181
 182         PROJECTILE_MAKETRIGGER(bomb_1);
 183         PROJECTILE_MAKETRIGGER(bomb_2);
 184
 185         CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 186         CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 187 }
 188
 189
 190 void raptor_fire_cannon(entity gun, string tagname)
 191 {
 192         vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 193                                                    gettaginfo(gun, gettagindex(gun, tagname)), normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 194                                                    autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 195                                                    DEATH_VH_RAPT_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE, self.owner);
 196 }
 197
 198 void raptor_land()
 199 {
 200         float hgt;
 201
 202         hgt = raptor_altitude(512);
 203         self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 204         self.angles_x *= 0.95;
 205         self.angles_z *= 0.95;
 206
 207         if(hgt < 128)
 208         if(hgt > 0)
 209                 self.frame = (hgt / 128) * 25;
 210
 211         self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 212         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 213
 214         if(hgt < 16)
 215         {
 216                 self.movetype = MOVETYPE_TOSS;
 217                 self.think      = vehicles_think;
 218                 self.frame      = 0;
 219         }
 220
 221         self.nextthink  = time;
 222 }
 223
 224 void raptor_exit(float eject)
 225 {
 226         vector spot;
 227         self.tur_head.exteriormodeltoclient = world;
 228
 229         if(self.deadflag == DEAD_NO)
 230         {
 231                 self.think        = raptor_land;
 232                 self.nextthink  = time;
 233         }
 234
 235         if not (self.owner)
 236                 return;
 237
 238         makevectors(self.angles);
 239         if(eject)
 240         {
 241                 spot = self.origin + v_forward * 100 + '0 0 64';
 242                 spot = vehicles_findgoodexit(spot);
 243                 setorigin(self.owner , spot);
 244                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 245                 self.owner.oldvelocity = self.owner.velocity;
 246         }
 247         else
 248         {
 249                 if(vlen(self.velocity) > 2 * autocvar_sv_maxairspeed)
 250                 {
 251                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 252                         self.owner.velocity_z += 200;
 253                         spot = self.origin + v_forward * 32 + '0 0 64';
 254                         spot = vehicles_findgoodexit(spot);
 255                 }
 256                 else
 257                 {
 258                         self.owner.velocity = self.velocity * 0.5;
 259                         self.owner.velocity_z += 10;
 260                         spot = self.origin - v_forward * 200 + '0 0 64';
 261                         spot = vehicles_findgoodexit(spot);
 262                 }
 263                 self.owner.oldvelocity = self.owner.velocity;
 264                 setorigin(self.owner , spot);
 265         }
 266
 267         antilag_clear(self.owner);
 268         self.owner = world;
 269 }
 270
 271 void raptor_flare_touch()
 272 {
 273         remove(self);
 274 }
 275
 276 void raptor_flare_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 277 {
 278         self.health -= damage;
 279         if(self.health <= 0)
 280                 remove(self);
 281 }
 282
 283 void raptor_flare_think()
 284 {
 285         self.nextthink = time + 0.1;
 286         entity _missile = findchainentity(enemy, self.owner);
 287         while(_missile)
 288         {
 289                 if(_missile.flags & FL_PROJECTILE)
 290                 if(vlen(self.origin - _missile.origin) < autocvar_g_vehicle_raptor_flare_range)
 291                 if(random() > autocvar_g_vehicle_raptor_flare_chase)
 292                         _missile.enemy = self;
 293                 _missile = _missile.chain;
 294         }
 295
 296         if(self.tur_impacttime < time)
 297                 remove(self);
 298 }
 299
 300 float raptor_frame()
 301 {
 302         entity player, raptor;
 303         float ftmp = 0;
 304         vector df;
 305
 306         if(intermission_running)
 307                 return 1;
 308
 309         player = self;
 310         raptor = self.vehicle;
 311         self   = raptor;
 312         vehicles_painframe();
 313         /*
 314         ftmp = vlen(self.velocity);
 315         if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 316                 ftmp = 1;
 317         else
 318                 ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 319         */
 320
 321         if(self.sound_nexttime < time)
 322         {
 323                 self.sound_nexttime = time + 7.955812;
 324                 //sound (self.tur_head, CH_TRIGGER_SINGLE, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTEN_NORM );
 325                 sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", 1, ATTEN_NORM);
 326                 self.wait = ftmp;
 327         }
 328         /*
 329         else if(fabs(ftmp - self.wait) > 0.2)
 330         {
 331                 sound (self.tur_head, CH_TRIGGER_SINGLE, "", 1 - ftmp,   ATTEN_NORM );
 332                 sound (self, CH_TRIGGER_SINGLE, "", ftmp, ATTEN_NORM);
 333                 self.wait = ftmp;
 334         }
 335         */
 336
 337         if(raptor.deadflag != DEAD_NO)
 338         {
 339                 self = player;
 340                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 341                 return 1;
 342         }
 343         crosshair_trace(player);
 344
 345         vector vang;
 346         vang = raptor.angles;
 347         df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 348         vang_x *= -1;
 349         df_x *= -1;
 350         if(df_x > 180)  df_x -= 360;
 351         if(df_x < -180) df_x += 360;
 352         if(df_y > 180)  df_y -= 360;
 353         if(df_y < -180) df_y += 360;
 354
 355         ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 356         if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 357         raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 358
 359         // Pitch
 360         ftmp = 0;
 361         if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 362         else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 363
 364         df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 365         ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 366         raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 367
 368         raptor.angles_x = anglemods(raptor.angles_x);
 369         raptor.angles_y = anglemods(raptor.angles_y);
 370         raptor.angles_z = anglemods(raptor.angles_z);
 371
 372         if(autocvar_g_vehicle_raptor_movestyle == 1)
 373                 makevectors('0 1 0' * raptor.angles_y);
 374         else
 375                 makevectors(player.v_angle);
 376
 377         df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 378
 379         if(player.movement_x != 0)
 380         {
 381                 if(player.movement_x > 0)
 382                         df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 383                 else if(player.movement_x < 0)
 384                         df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 385         }
 386
 387         if(player.movement_y != 0)
 388         {
 389                 if(player.movement_y < 0)
 390                         df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 391                 else if(player.movement_y > 0)
 392                         df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 393
 394                 raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 395         }
 396         else
 397         {
 398                 raptor.angles_z *= 0.95;
 399                 if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 400                         raptor.angles_z = 0;
 401         }
 402
 403         if(player.BUTTON_CROUCH)
 404                 df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 405         else if (player.BUTTON_JUMP)
 406                 df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 407
 408         raptor.velocity  += df * frametime;
 409         player.velocity = player.movement  = raptor.velocity;
 410         setorigin(player, raptor.origin + '0 0 32');
 411
 412         vector vf, ad;
 413         // Target lock & predict
 414         if(autocvar_g_vehicle_raptor_cannon_locktarget == 2)
 415         {
 416                 if(raptor.gun1.lock_time < time || raptor.gun1.enemy.deadflag)
 417                         raptor.gun1.enemy = world;
 418
 419                 if(trace_ent)
 420                 if(trace_ent.movetype)
 421                 if(trace_ent.takedamage)
 422                 if(!trace_ent.deadflag)
 423                 {
 424                         if(teamplay)
 425                         {
 426                                 if(trace_ent.team != player.team)
 427                                 {
 428                                         raptor.gun1.enemy = trace_ent;
 429                                         raptor.gun1.lock_time = time + 5;
 430                                 }
 431                         }
 432                         else
 433                         {
 434                                 raptor.gun1.enemy = trace_ent;
 435                                 raptor.gun1.lock_time = time + 0.5;
 436                         }
 437                 }
 438
 439                 if(raptor.gun1.enemy)
 440                 {
 441                         float i, distance, impact_time;
 442
 443                         vf = real_origin(raptor.gun1.enemy);
 444                         UpdateAuxiliaryXhair(player, vf, '1 0 0', 1);
 445                         vector _vel = raptor.gun1.enemy.velocity;
 446                         if(raptor.gun1.enemy.movetype == MOVETYPE_WALK)
 447                                 _vel_z *= 0.1;
 448
 449                         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 450                         {
 451                                 ad = vf;
 452                                 for(i = 0; i < 4; ++i)
 453                                 {
 454                                         distance = vlen(ad - player.origin);
 455                                         impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 456                                         ad = vf + _vel * impact_time;
 457                                 }
 458                                 trace_endpos = ad;
 459                         }
 460                         else
 461                                 trace_endpos = vf;
 462                 }
 463         }
 464         else if(autocvar_g_vehicle_raptor_cannon_locktarget == 1)
 465         {
 466
 467                 vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 468                                                          (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 469                                                          autocvar_g_vehicle_raptor_cannon_locked_time);
 470
 471                 if(self.lock_target != world)
 472                 if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 473                 if(self.lock_strength == 1)
 474                 {
 475                         float i, distance, impact_time;
 476
 477                         vf = real_origin(raptor.lock_target);
 478                         ad = vf;
 479                         for(i = 0; i < 4; ++i)
 480                         {
 481                                 distance = vlen(ad - raptor.origin);
 482                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 483                                 ad = vf + raptor.lock_target.velocity * impact_time;
 484                         }
 485                         trace_endpos = ad;
 486                 }
 487
 488                 if(self.lock_target)
 489                 {
 490                         if(raptor.lock_strength == 1)
 491                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 492                         else if(self.lock_strength > 0.5)
 493                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 494                         else if(self.lock_strength < 0.5)
 495                                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 496                 }
 497         }
 498
 499
 500         vehicle_aimturret(raptor, trace_endpos, raptor.gun1, "fire1",
 501                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 502                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 503
 504         vehicle_aimturret(raptor, trace_endpos, raptor.gun2, "fire1",
 505                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 506                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 507
 508         /*
 509         ad = ad * 0.5;
 510         v_forward = vf * 0.5;
 511         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 512         UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 513         */
 514
 515         if(player.BUTTON_ATCK)
 516         if(raptor.attack_finished_single <= time)
 517         if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 518         {
 519                 raptor.misc_bulletcounter += 1;
 520                 raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 521                 if(raptor.misc_bulletcounter <= 2)
 522                         raptor_fire_cannon(self.gun1, "fire1");
 523                 else if(raptor.misc_bulletcounter == 3)
 524                         raptor_fire_cannon(self.gun2, "fire1");
 525                 else
 526                 {
 527                         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 528                         raptor_fire_cannon(self.gun2, "fire1");
 529                         raptor.misc_bulletcounter = 0;
 530                 }
 531                 raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 532                 self.cnt = time;
 533         }
 534
 535         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 536                 vehicles_regen(raptor.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, TRUE);
 537
 538         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 539                 vehicles_regen(raptor.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, FALSE);
 540
 541         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 542                 vehicles_regen(raptor.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, FALSE);
 543
 544         if(raptor.vehicle_weapon2mode == RSM_BOMB)
 545         {
 546                 if(time > raptor.lip + autocvar_g_vehicle_raptor_bombs_refire)
 547                 if(player.BUTTON_ATCK2)
 548                 {
 549                         raptor_bombdrop();
 550                         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 551                         raptor.lip   = time;
 552                 }
 553         }
 554         else
 555         {
 556                 if(time > raptor.lip + autocvar_g_vehicle_raptor_flare_refire)
 557                 if(player.BUTTON_ATCK2)
 558                 {
 559                         float i;
 560                         entity _flare;
 561
 562                         for(i = 0; i < 3; ++i)
 563                         {
 564                         _flare = spawn();
 565                         setmodel(_flare, "models/runematch/rune.mdl");
 566                         _flare.effects = EF_LOWPRECISION | EF_FLAME;
 567                         _flare.scale = 0.5;
 568                         setorigin(_flare, self.origin - '0 0 16');
 569                         _flare.movetype = MOVETYPE_TOSS;
 570                         _flare.gravity = 0.15;
 571                         _flare.velocity = 0.25 * raptor.velocity + (v_forward + randomvec() * 0.25)* -500;
 572                         _flare.think = raptor_flare_think;
 573                         _flare.nextthink = time;
 574                         _flare.owner = raptor;
 575                         _flare.solid = SOLID_CORPSE;
 576                         _flare.takedamage = DAMAGE_YES;
 577                         _flare.event_damage = raptor_flare_damage;
 578                         _flare.health = 20;
 579                         _flare.tur_impacttime = time + autocvar_g_vehicle_raptor_flare_lifetime;
 580                         _flare.touch = raptor_flare_touch;
 581                         }
 582                         raptor.delay = time + autocvar_g_vehicle_raptor_flare_refire;
 583                         raptor.lip   = time;
 584                 }
 585         }
 586
 587         raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 588         player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 589
 590         if(self.bomb1.cnt < time)
 591         {
 592                 entity _missile = findchainentity(enemy, raptor);
 593                 float _incomming = 0;
 594                 while(_missile)
 595                 {
 596                         if(_missile.flags & FL_PROJECTILE)
 597                         if(MISSILE_IS_TRACKING(_missile))
 598                         if(vlen(self.origin - _missile.origin) < 2 * autocvar_g_vehicle_raptor_flare_range)
 599                                 ++_incomming;
 600
 601                         _missile = _missile.chain;
 602                 }
 603
 604                 if(_incomming)
 605                         sound(self, CH_PAIN_SINGLE, "vehicles/missile_alarm.wav", VOL_BASE, ATTEN_NONE);
 606
 607                 self.bomb1.cnt = time + 1;
 608         }
 609
 610
 611         VEHICLE_UPDATE_PLAYER(player, health, raptor);
 612         VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 613         if(self.vehicle_flags & VHF_HASSHIELD)
 614                 VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 615
 616         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 617
 618         self = player;
 619         return 1;
 620 }
 621
 622 float raptor_takeoff()
 623 {
 624         entity player, raptor;
 625
 626         player = self;
 627         raptor = self.vehicle;
 628         self   = raptor;
 629         if(self.sound_nexttime < time)
 630         {
 631                 self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 632                 sound (self, CH_TRIGGER_SINGLE, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 633         }
 634
 635         // Takeoff sequense
 636         if(raptor.frame < 25)
 637         {
 638                 raptor.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / sys_frametime);
 639                 raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 640                 self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 641                 self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 642                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 643
 644                 setorigin(player, raptor.origin + '0 0 32');
 645         }
 646         else
 647                 player.PlayerPhysplug = raptor_frame;
 648
 649         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 650                 vehicles_regen(raptor.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, TRUE);
 651
 652         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 653                 vehicles_regen(raptor.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, FALSE);
 654
 655         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 656                 vehicles_regen(raptor.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, FALSE);
 657
 658
 659         raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 660         player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 661
 662         VEHICLE_UPDATE_PLAYER(player, health, raptor);
 663         VEHICLE_UPDATE_PLAYER(player, energy, raptor);
 664         if(self.vehicle_flags & VHF_HASSHIELD)
 665                 VEHICLE_UPDATE_PLAYER(player, shield, raptor);
 666
 667         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 668         self = player;
 669         return 1;
 670 }
 671
 672 void raptor_blowup()
 673 {
 674         self.deadflag   = DEAD_DEAD;
 675         self.vehicle_exit(VHEF_NORMAL);
 676         RadiusDamage (self, self.enemy, 250, 15, 250, world, 250, DEATH_VH_RAPT_DEATH, world);
 677
 678         self.alpha                = -1;
 679         self.movetype      = MOVETYPE_NONE;
 680         self.effects            = EF_NODRAW;
 681         self.colormod      = '0 0 0';
 682         self.avelocity    = '0 0 0';
 683         self.velocity      = '0 0 0';
 684
 685         setorigin(self, self.pos1);
 686         self.touch = func_null;
 687         self.nextthink = 0;
 688 }
 689
 690 void raptor_diethink()
 691 {
 692         if(time >= self.wait)
 693                 self.think = raptor_blowup;
 694
 695         if(random() < 0.1)
 696         {
 697                 sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 698                 pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 699         }
 700         self.nextthink = time + 0.1;
 701 }
 702
 703 // If we dont do this ever now and then, the raptors rotors
 704 // stop working, presumably due to angle overflow. cute.
 705 void raptor_rotor_anglefix()
 706 {
 707         self.gun1.angles_y = anglemods(self.gun1.angles_y);
 708         self.gun2.angles_y = anglemods(self.gun2.angles_y);
 709         self.nextthink = time + 15;
 710 }
 711
 712 float raptor_impulse(float _imp)
 713 {
 714         switch(_imp)
 715         {
 716                 case 10:
 717                 case 15:
 718                 case 18:
 719                         self.vehicle.vehicle_weapon2mode += 1;
 720                         if(self.vehicle.vehicle_weapon2mode > RSM_LAST)
 721                                 self.vehicle.vehicle_weapon2mode = RSM_FIRST;
 722
 723                         CSQCVehicleSetup(self, 0);
 724                         return TRUE;
 725                 case 12:
 726                 case 16:
 727                 case 19:
 728                         self.vehicle.vehicle_weapon2mode -= 1;
 729                         if(self.vehicle.vehicle_weapon2mode < RSM_FIRST)
 730                                 self.vehicle.vehicle_weapon2mode = RSM_LAST;
 731
 732                         CSQCVehicleSetup(self, 0);
 733                         return TRUE;
 734
 735                 /*
 736                 case 17: // toss gun, could be used to exit?
 737                         break;
 738                 case 20: // Manual minigun reload?
 739                         break;
 740                 */
 741         }
 742         return FALSE;
 743 }
 744
 745 void spawnfunc_vehicle_raptor()
 746 {
 747         if not(autocvar_g_vehicle_raptor) { remove(self); return; }
 748         if not(vehicle_initialize(VEH_RAPTOR, FALSE)) { remove(self); return; }
 749 }
 750
 751 float v_raptor(float req)
 752 {
 753         switch(req)
 754         {
 755                 case VR_IMPACT:
 756                 {
 757                         if(autocvar_g_vehicle_raptor_bouncepain)
 758                                 vehicles_impact(autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 759
 760                         return TRUE;
 761                 }
 762                 case VR_ENTER:
 763                 {
 764                         self.vehicle_weapon2mode = RSM_BOMB;
 765                         self.owner.PlayerPhysplug = raptor_takeoff;
 766                         self.movetype      = MOVETYPE_BOUNCEMISSILE;
 767                         self.solid                = SOLID_SLIDEBOX;
 768                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 769                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 770                         self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 771                         self.tur_head.exteriormodeltoclient = self.owner;
 772
 773                         self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 774                         self.lip   = time;
 775
 776                         if(self.owner.flagcarried)
 777                            setorigin(self.owner.flagcarried, '-20 0 96');
 778
 779                         CSQCVehicleSetup(self.owner, 0);
 780                         return TRUE;
 781                 }
 782                 case VR_THINK:
 783                 {
 784                         return TRUE;
 785                 }
 786                 case VR_DEATH:
 787                 {
 788                         self.health                             = 0;
 789                         self.event_damage               = func_null;
 790                         self.solid                              = SOLID_CORPSE;
 791                         self.takedamage                 = DAMAGE_NO;
 792                         self.deadflag                   = DEAD_DYING;
 793                         self.movetype                   = MOVETYPE_BOUNCE;
 794                         self.think                              = raptor_diethink;
 795                         self.nextthink                  = time;
 796                         self.wait                               = time + 5 + (random() * 5);
 797
 798                         pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 799
 800                         self.velocity_z += 600;
 801
 802                         self.avelocity = '0 0.5 1' * (random() * 400);
 803                         self.avelocity -= '0 0.5 1' * (random() * 400);
 804
 805                         self.colormod = '-0.5 -0.5 -0.5';
 806                         self.touch = raptor_blowup;
 807                         return TRUE;
 808                 }
 809                 case VR_SPAWN:
 810                 {
 811                         if not(self.gun1)
 812                         {
 813                                 entity spinner;
 814                                 vector ofs;
 815
 816                                 //FIXME: Camera is in a bad place in HUD model.
 817                                 //setorigin(self.vehicle_viewport, '25 0 5');
 818
 819                                 self.vehicles_impulse   = raptor_impulse;
 820
 821                                 self.frame = 0;
 822
 823                                 self.bomb1 = spawn();
 824                                 self.bomb2 = spawn();
 825                                 self.gun1  = spawn();
 826                                 self.gun2  = spawn();
 827
 828                                 setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 829                                 setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 830                                 setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 831                                 setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 832                                 setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 833
 834                                 setattachment(self.bomb1, self, "bombmount_left");
 835                                 setattachment(self.bomb2, self, "bombmount_right");
 836                                 setattachment(self.tur_head, self,"root");
 837
 838                                 // FIXMODEL Guns mounts to angled bones
 839                                 self.bomb1.angles = self.angles;
 840                                 self.angles = '0 0 0';
 841                                 // This messes up gun-aim, so work arround it.
 842                                 //setattachment(self.gun1, self, "gunmount_left");
 843                                 ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 844                                 ofs -= self.origin;
 845                                 setattachment(self.gun1, self, "");
 846                                 setorigin(self.gun1, ofs);
 847
 848                                 //setattachment(self.gun2, self, "gunmount_right");
 849                                 ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 850                                 ofs -= self.origin;
 851                                 setattachment(self.gun2, self, "");
 852                                 setorigin(self.gun2, ofs);
 853
 854                                 self.angles = self.bomb1.angles;
 855                                 self.bomb1.angles = '0 0 0';
 856
 857                                 spinner = spawn();
 858                                 spinner.owner = self;
 859                                 setmodel(spinner,"models/vehicles/spinner.dpm");
 860                                 setattachment(spinner, self, "engine_left");
 861                                 spinner.movetype = MOVETYPE_NOCLIP;
 862                                 spinner.avelocity = '0 90 0';
 863                                 self.bomb1.gun1 = spinner;
 864
 865                                 spinner = spawn();
 866                                 spinner.owner = self;
 867                                 setmodel(spinner,"models/vehicles/spinner.dpm");
 868                                 setattachment(spinner, self, "engine_right");
 869                                 spinner.movetype = MOVETYPE_NOCLIP;
 870                                 spinner.avelocity = '0 -90 0';
 871                                 self.bomb1.gun2 = spinner;
 872
 873                                 // Sigh.
 874                                 self.bomb1.think = raptor_rotor_anglefix;
 875                                 self.bomb1.nextthink = time;
 876
 877                                 self.mass                          = 1 ;
 878                         }
 879
 880                         self.frame                = 0;
 881                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 882                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 883                         self.movetype      = MOVETYPE_TOSS;
 884                         self.solid                = SOLID_SLIDEBOX;
 885                         self.vehicle_energy = 1;
 886
 887                         self.PlayerPhysplug = raptor_frame;
 888
 889                         self.bomb1.gun1.avelocity_y = 90;
 890                         self.bomb1.gun2.avelocity_y = -90;
 891
 892                         self.delay = time;
 893
 894                         self.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 895                         self.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 896                         self.damageforcescale = 0.25;
 897                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 898                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 899                         return TRUE;
 900                 }
 901                 case VR_SETUP:
 902                 {
 903                         if(autocvar_g_vehicle_raptor_shield)
 904                                 self.vehicle_flags |= VHF_HASSHIELD;
 905
 906                         if(autocvar_g_vehicle_raptor_shield_regen)
 907                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 908
 909                         if(autocvar_g_vehicle_raptor_health_regen)
 910                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 911
 912                         if(autocvar_g_vehicle_raptor_energy_regen)
 913                                 self.vehicle_flags |= VHF_ENERGYREGEN;
 914
 915                         self.vehicle_exit = raptor_exit;
 916                         self.respawntime = autocvar_g_vehicle_raptor_respawntime;
 917                         self.vehicle_health = autocvar_g_vehicle_raptor_health;
 918                         self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 919                         self.max_health = self.vehicle_health;
 920
 921                         return TRUE;
 922                 }
 923                 case VR_PRECACHE:
 924                 {
 925                         precache_model ("models/vehicles/raptor.dpm");
 926                         precache_model ("models/vehicles/raptor_gun.dpm");
 927                         precache_model ("models/vehicles/spinner.dpm");
 928                         precache_model ("models/vehicles/raptor_cockpit.dpm");
 929                         precache_model ("models/vehicles/clusterbomb_folded.md3");
 930                         precache_model ("models/vehicles/raptor_body.dpm");
 931
 932                         precache_sound ("vehicles/raptor_fly.wav");
 933                         precache_sound ("vehicles/raptor_speed.wav");
 934                         precache_sound ("vehicles/missile_alarm.wav");
 935
 936                         return TRUE;
 937                 }
 938         }
 939
 940         return TRUE;
 941 }
 942
 943 #endif // SVQC
 944 #ifdef CSQC
 945
 946 #define raptor_ico  "gfx/vehicles/raptor.tga"
 947 #define raptor_gun  "gfx/vehicles/raptor_guns.tga"
 948 #define raptor_bomb "gfx/vehicles/raptor_bombs.tga"
 949 #define raptor_drop "gfx/vehicles/axh-dropcross.tga"
 950 string raptor_xhair;
 951
 952 float v_raptor(float req)
 953 {
 954         switch(req)
 955         {
 956                 case VR_HUD:
 957                 {
 958                         if(autocvar_r_letterbox)
 959                                 return TRUE;
 960
 961                         vector picsize, hudloc = '0 0 0', pic2size, picloc;
 962
 963                         // Fetch health & ammo stats
 964                         HUD_GETVEHICLESTATS
 965
 966                         picsize = draw_getimagesize(hud_bg) * autocvar_cl_vehicles_hudscale;
 967                         hudloc_y = vid_conheight - picsize_y;
 968                         hudloc_x = vid_conwidth * 0.5 - picsize_x * 0.5;
 969
 970                         drawpic(hudloc, hud_bg, picsize, '1 1 1', autocvar_cl_vehicles_hudalpha, DRAWFLAG_NORMAL);
 971
 972                         ammo1   *= 0.01;
 973                         ammo2   *= 0.01;
 974                         shield  *= 0.01;
 975                         vh_health  *= 0.01;
 976                         energy  *= 0.01;
 977                         reload1 = reload2 * 0.01;
 978                         //reload2 *= 0.01;
 979
 980                         pic2size = draw_getimagesize(raptor_ico) * (autocvar_cl_vehicles_hudscale * 0.8);
 981                         picloc = picsize * 0.5 - pic2size * 0.5;
 982                         if(vh_health < 0.25)
 983                                 drawpic(hudloc + picloc, raptor_ico, pic2size,  '1 0 0' + '0 1 1' * sin(time * 8),  1, DRAWFLAG_NORMAL);
 984                         else
 985                                 drawpic(hudloc + picloc, raptor_ico, pic2size,  '1 1 1' * vh_health  + '1 0 0' * (1 - vh_health),  1, DRAWFLAG_NORMAL);
 986                         drawpic(hudloc + picloc, raptor_bomb, pic2size,  '1 1 1' * reload1 + '1 0 0' * (1 - reload1), 1, DRAWFLAG_NORMAL);
 987                         drawpic(hudloc + picloc, raptor_gun, pic2size, '1 1 1' * energy   + '1 0 0' * (1 - energy),   1, DRAWFLAG_NORMAL);
 988                         drawpic(hudloc + picloc, hud_sh, pic2size,  '1 1 1', shield, DRAWFLAG_NORMAL);
 989
 990                 // Health bar
 991                         picsize = draw_getimagesize(hud_hp_bar) * autocvar_cl_vehicles_hudscale;
 992                         picloc = '69 69 0' * autocvar_cl_vehicles_hudscale;
 993                         drawsetcliparea(hudloc_x + picloc_x + (picsize_x * (1 - vh_health)), 0, vid_conwidth, vid_conheight);
 994                         drawpic(hudloc + picloc, hud_hp_bar, picsize, '1 1 1', 1 , DRAWFLAG_NORMAL);
 995                         drawresetcliparea();
 996                 // ..  and icon
 997                         picsize = draw_getimagesize(hud_hp_ico) * autocvar_cl_vehicles_hudscale;
 998                         picloc = '37 65 0' * autocvar_cl_vehicles_hudscale;
 999                         if(vh_health < 0.25)
1000                         {
1001                                 if(alarm1time < time)
1002                                 {
1003                                         alarm1time = time + 2;
1004                                         vehicle_alarm(self, CH_PAIN_SINGLE, "vehicles/alarm.wav");
1005                                 }
1006
1007                                 drawpic(hudloc + picloc, hud_hp_ico, picsize, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
1008                         }
1009                         else
1010                         {
1011                                 drawpic(hudloc + picloc, hud_hp_ico, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1012                                 if(alarm1time)
1013                                 {
1014                                         vehicle_alarm(self, CH_PAIN_SINGLE, "misc/null.wav");
1015                                         alarm1time = 0;
1016                                 }
1017                         }
1018
1019                 // Shield bar
1020                         picsize = draw_getimagesize(hud_sh_bar) * autocvar_cl_vehicles_hudscale;
1021                         picloc = '69 140 0' * autocvar_cl_vehicles_hudscale;
1022                         drawsetcliparea(hudloc_x + picloc_x + (picsize_x * (1 - shield)), 0, vid_conwidth, vid_conheight);
1023                         drawpic(hudloc + picloc, hud_sh_bar, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1024                         drawresetcliparea();
1025                 // ..  and icon
1026                         picloc = '40 136 0' * autocvar_cl_vehicles_hudscale;
1027                         picsize = draw_getimagesize(hud_sh_ico) * autocvar_cl_vehicles_hudscale;
1028                         if(shield < 0.25)
1029                         {
1030                                 if(alarm2time < time)
1031                                 {
1032                                         alarm2time = time + 1;
1033                                         vehicle_alarm(self, CH_TRIGGER_SINGLE, "vehicles/alarm_shield.wav");
1034                                 }
1035                                 drawpic(hudloc + picloc, hud_sh_ico, picsize, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
1036                         }
1037                         else
1038                         {
1039                                 drawpic(hudloc + picloc, hud_sh_ico, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1040                                 if(alarm2time)
1041                                 {
1042                                         vehicle_alarm(self, CH_TRIGGER_SINGLE, "misc/null.wav");
1043                                         alarm2time = 0;
1044                                 }
1045                         }
1046
1047                 // Gun bar
1048                         picsize = draw_getimagesize(hud_ammo1_bar) * autocvar_cl_vehicles_hudscale;
1049                         picloc = '450 69 0' * autocvar_cl_vehicles_hudscale;
1050                         drawsetcliparea(hudloc_x + picloc_x, picloc_y, picsize_x * energy, vid_conheight);
1051                         drawpic(hudloc + picloc, hud_ammo1_bar, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1052                         drawresetcliparea();
1053                 // ..  and icon
1054                         picsize = draw_getimagesize(hud_ammo1_ico) * autocvar_cl_vehicles_hudscale;
1055                         picloc = '664 60 0' * autocvar_cl_vehicles_hudscale;
1056                         if(energy < 0.2)
1057                                 drawpic(hudloc + picloc, hud_ammo1_ico, picsize, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
1058                         else
1059                                 drawpic(hudloc + picloc, hud_ammo1_ico, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1060
1061                 // Bomb bar
1062                         picsize = draw_getimagesize(hud_ammo2_bar) * autocvar_cl_vehicles_hudscale;
1063                         picloc = '450 140 0' * autocvar_cl_vehicles_hudscale;
1064                         drawsetcliparea(hudloc_x + picloc_x, hudloc_y + picloc_y, picsize_x * reload1, vid_conheight);
1065                         drawpic(hudloc + picloc, hud_ammo2_bar, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1066                         drawresetcliparea();
1067                 // ..  and icon
1068                         pic2size = draw_getimagesize(hud_ammo2_ico) * autocvar_cl_vehicles_hudscale;
1069                         picloc = '664 130 0' * autocvar_cl_vehicles_hudscale;
1070                         if(reload1 != 1)
1071                                 drawpic(hudloc + picloc, hud_ammo2_ico, pic2size, '1 0 0' + '0 1 1' * sin(time * 8), 1, DRAWFLAG_NORMAL);
1072                         else
1073                                 drawpic(hudloc + picloc, hud_ammo2_ico, pic2size, '1 1 1', 1, DRAWFLAG_NORMAL);
1074
1075                         if(weapon2mode == RSM_FLARE)
1076                         {
1077                                 raptor_xhair =  "gfx/vehicles/axh-bracket.tga";
1078                         }
1079                         else
1080                         {
1081                                 raptor_xhair =  "gfx/vehicles/axh-ring.tga";
1082
1083                                 // Bombing crosshair
1084                                 if(!dropmark)
1085                                 {
1086                                         dropmark = spawn();
1087                                         dropmark.owner = self;
1088                                         dropmark.gravity = 1;
1089                                 }
1090
1091                                 if(reload2 == 100)
1092                                 {
1093                                         vector where;
1094
1095                                         setorigin(dropmark, pmove_org);
1096                                         dropmark.velocity = pmove_vel;
1097                                         tracetoss(dropmark, self);
1098
1099                                         where = project_3d_to_2d(trace_endpos);
1100
1101                                         setorigin(dropmark, trace_endpos);
1102                                         picsize = draw_getimagesize(raptor_drop) * 0.2;
1103
1104                                         if not (where_z < 0 || where_x < 0 || where_y < 0 || where_x > vid_conwidth || where_y > vid_conheight)
1105                                         {
1106                                                 where_x -= picsize_x * 0.5;
1107                                                 where_y -= picsize_y * 0.5;
1108                                                 where_z = 0;
1109                                                 drawpic(where, raptor_drop, picsize, '0 2 0', 1, DRAWFLAG_ADDITIVE);
1110                                         }
1111                                         dropmark.cnt = time + 5;
1112                                 }
1113                                 else
1114                                 {
1115                                         vector where;
1116                                         if(dropmark.cnt > time)
1117                                         {
1118                                                 where = project_3d_to_2d(dropmark.origin);
1119                                                 picsize = draw_getimagesize(raptor_drop) * 0.25;
1120
1121                                                 if not (where_z < 0 || where_x < 0 || where_y < 0 || where_x > vid_conwidth || where_y > vid_conheight)
1122                                                 {
1123                                                         where_x -= picsize_x * 0.5;
1124                                                         where_y -= picsize_y * 0.5;
1125                                                         where_z = 0;
1126                                                         drawpic(where, raptor_drop, picsize, '2 0 0', 1, DRAWFLAG_ADDITIVE);
1127                                                 }
1128                                         }
1129                                 }
1130                         }
1131
1132                         if (scoreboard_showscores)
1133                                 HUD_DrawScoreboard();
1134                         else
1135                         {
1136                                 picsize = draw_getimagesize(raptor_xhair);
1137                                 picsize_x *= 0.5;
1138                                 picsize_y *= 0.5;
1139
1140                                 drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), raptor_xhair, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1141                         }
1142
1143                         return TRUE;
1144                 }
1145                 case VR_SETUP:
1146                 {
1147                         AuxiliaryXhair[0].axh_image   = "gfx/vehicles/axh-special2.tga";
1148                         AuxiliaryXhair[0].axh_scale   = 0.5;
1149
1150                         AuxiliaryXhair[1].axh_image = "gfx/vehicles/axh-bracket.tga";
1151                         AuxiliaryXhair[1].axh_scale = 0.25;
1152                         return TRUE;
1153                 }
1154                 case VR_PRECACHE:
1155                 {
1156                         precache_model ("models/vehicles/raptor.dpm");
1157                         precache_model ("models/vehicles/raptor_gun.dpm");
1158                         precache_model ("models/vehicles/spinner.dpm");
1159                         precache_model ("models/vehicles/raptor_cockpit.dpm");
1160                         precache_model ("models/vehicles/clusterbomb_folded.md3");
1161                         precache_model ("models/vehicles/raptor_body.dpm");
1162
1163                         return TRUE;
1164                 }
1165         }
1166
1167         return TRUE;
1168 }
1169
1170 #endif // CSQC
1171 #endif // REGISTER_VEHICLE