qcsrc/common/vehicles/vehicle/racer.qc

   1 #include "racer.qh"
   2
   3 #ifdef IMPLEMENTATION
   4
   5 #ifdef SVQC
   6 #include <common/triggers/trigger/impulse.qh>
   7
   8 bool autocvar_g_vehicle_racer = true;
   9
  10 float autocvar_g_vehicle_racer_thinkrate = 0.05; // TODO: any higher causes it to sink in liquids
  11
  12 float autocvar_g_vehicle_racer_speed_afterburn = 3000;
  13 // energy consumed per second
  14 float autocvar_g_vehicle_racer_afterburn_cost = 130;
  15
  16 float autocvar_g_vehicle_racer_waterburn_cost = 5;
  17 float autocvar_g_vehicle_racer_waterburn_speed = 750;
  18
  19 float autocvar_g_vehicle_racer_water_speed_forward = 600;
  20 float autocvar_g_vehicle_racer_water_speed_strafe = 600;
  21
  22 float autocvar_g_vehicle_racer_pitchlimit = 30;
  23
  24 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  25 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  26
  27 float autocvar_g_vehicle_racer_anglestabilizer = 1.75;
  28 float autocvar_g_vehicle_racer_downforce = 0.01;
  29
  30 float autocvar_g_vehicle_racer_speed_forward = 650;
  31 float autocvar_g_vehicle_racer_speed_strafe = 650;
  32 float autocvar_g_vehicle_racer_springlength = 90;
  33 float autocvar_g_vehicle_racer_upforcedamper = 2;
  34 float autocvar_g_vehicle_racer_friction = 0.45;
  35
  36 float autocvar_g_vehicle_racer_water_time = 5;
  37
  38 //float autocvar_g_vehicle_racer_collision_multiplier = 0.05;
  39
  40 // 0 = hover, != 0 = maglev
  41 int autocvar_g_vehicle_racer_hovertype = 0;
  42 // NOTE!! x 4 (4 engines)
  43 float autocvar_g_vehicle_racer_hoverpower = 8000;
  44
  45 float autocvar_g_vehicle_racer_turnroll = 30;
  46 float autocvar_g_vehicle_racer_turnspeed = 220;
  47 float autocvar_g_vehicle_racer_pitchspeed = 125;
  48
  49 float autocvar_g_vehicle_racer_energy = 100;
  50 float autocvar_g_vehicle_racer_energy_regen = 90;
  51 float autocvar_g_vehicle_racer_energy_regen_pause = 0.35;
  52
  53 float autocvar_g_vehicle_racer_health = 200;
  54 float autocvar_g_vehicle_racer_health_regen = 0;
  55 float autocvar_g_vehicle_racer_health_regen_pause = 0;
  56
  57 float autocvar_g_vehicle_racer_shield = 100;
  58 float autocvar_g_vehicle_racer_shield_regen = 30;
  59 float autocvar_g_vehicle_racer_shield_regen_pause = 1;
  60
  61 bool autocvar_g_vehicle_racer_rocket_locktarget = true;
  62 float autocvar_g_vehicle_racer_rocket_locking_time = 0.35;
  63 float autocvar_g_vehicle_racer_rocket_locking_releasetime = 0.5;
  64 float autocvar_g_vehicle_racer_rocket_locked_time = 4;
  65
  66 float autocvar_g_vehicle_racer_respawntime = 35;
  67
  68 float autocvar_g_vehicle_racer_blowup_radius = 250;
  69 float autocvar_g_vehicle_racer_blowup_coredamage = 250;
  70 float autocvar_g_vehicle_racer_blowup_edgedamage = 15;
  71 float autocvar_g_vehicle_racer_blowup_forceintensity = 250;
  72
  73 // Factor of old velocity to keep after collision
  74 float autocvar_g_vehicle_racer_bouncefactor = 0.25;
  75 // if != 0, New veloctiy after bounce = 0 if new velocity < this
  76 float autocvar_g_vehicle_racer_bouncestop = 0;
  77 // "minspeed_for_pain speedchange_to_pain_factor max_damage"
  78 vector autocvar_g_vehicle_racer_bouncepain = '200 0.15 150';
  79
  80 .float racer_watertime;
  81
  82 var vector racer_force_from_tag(entity this, string tag_name, float spring_length, float max_power);
  83
  84 void racer_align4point(entity this, float _delta)
  85 {
  86         vector push_vector;
  87         float fl_push, fr_push, bl_push, br_push;
  88
  89         push_vector  = racer_force_from_tag(this, "tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  90         fr_push   = force_fromtag_normpower;
  91         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  92
  93         push_vector += racer_force_from_tag(this, "tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  94         fl_push   = force_fromtag_normpower;
  95         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  96
  97         push_vector += racer_force_from_tag(this, "tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  98         br_push   = force_fromtag_normpower;
  99         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 100
 101         push_vector += racer_force_from_tag(this, "tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 102         bl_push   = force_fromtag_normpower;
 103         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 104
 105         this.velocity += push_vector * _delta;
 106
 107         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 108
 109         int cont = pointcontents(this.origin - '0 0 64');
 110         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 111         {
 112                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 113
 114                 if(PHYS_INPUT_BUTTON_CROUCH(this.owner) && time < this.air_finished)
 115                         this.velocity_z += 30;
 116                 else
 117                         this.velocity_z += 200;
 118         }
 119
 120
 121         // Anti ocilation
 122         if(this.velocity_z > 0)
 123                 this.velocity_z *= 1 - uforce * _delta;
 124
 125         push_vector_x =  (fl_push - bl_push);
 126         push_vector_x += (fr_push - br_push);
 127         push_vector_x *= 360;
 128
 129         push_vector_z = (fr_push - fl_push);
 130         push_vector_z += (br_push - bl_push);
 131         push_vector_z *= 360;
 132
 133         // Apply angle diffrance
 134         this.angles_z += push_vector_z * _delta;
 135         this.angles_x += push_vector_x * _delta;
 136
 137         // Apply stabilizer
 138         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 139         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 140 }
 141
 142 void racer_fire_rocket_aim(entity player, string tagname, entity trg)
 143 {
 144         entity racer = player.vehicle;
 145         vector v = gettaginfo(racer, gettagindex(racer, tagname));
 146         racer_fire_rocket(player, v, v_forward, trg);
 147 }
 148
 149 bool racer_frame(entity this, float dt)
 150 {
 151         entity vehic = this.vehicle;
 152         return = true;
 153
 154         if(game_stopped)
 155         {
 156                 vehic.solid = SOLID_NOT;
 157                 vehic.takedamage = DAMAGE_NO;
 158                 set_movetype(vehic, MOVETYPE_NONE);
 159                 return;
 160         }
 161
 162         vehicles_frame(vehic, this);
 163
 164         traceline(vehic.origin, vehic.origin + '0 0 1', MOVE_NOMONSTERS, this);
 165         int cont = trace_dpstartcontents;
 166         if(!(cont & DPCONTENTS_WATER))
 167                 vehic.air_finished = time + autocvar_g_vehicle_racer_water_time;
 168
 169         if(IS_DEAD(vehic))
 170         {
 171                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 172                 return;
 173         }
 174
 175         racer_align4point(vehic, dt);
 176
 177         PHYS_INPUT_BUTTON_ZOOM(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 178
 179         vehic.angles_x *= -1;
 180
 181         // Yaw
 182         float ftmp = autocvar_g_vehicle_racer_turnspeed * dt;
 183         ftmp = bound(-ftmp, shortangle_f(this.v_angle_y - vehic.angles_y, vehic.angles_y), ftmp);
 184         vehic.angles_y = anglemods(vehic.angles_y + ftmp);
 185
 186         // Roll
 187         vehic.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * dt;
 188
 189         // Pitch
 190         ftmp = autocvar_g_vehicle_racer_pitchspeed  * dt;
 191         ftmp = bound(-ftmp, shortangle_f(this.v_angle_x - vehic.angles_x, vehic.angles_x), ftmp);
 192         vehic.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(vehic.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 193
 194         makevectors(vehic.angles);
 195         vehic.angles_x *= -1;
 196
 197         //ftmp = vehic.velocity_z;
 198         vector df = vehic.velocity * -autocvar_g_vehicle_racer_friction;
 199         //vehic.velocity_z = ftmp;
 200
 201         if(CS(this).movement)
 202         {
 203                 if(cont & DPCONTENTS_LIQUIDSMASK)
 204                 {
 205                         if(CS(this).movement_x) { df += v_forward * ((CS(this).movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 206                         if(CS(this).movement_y) { df += v_right * ((CS(this).movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 207                 }
 208                 else
 209                 {
 210                         if(CS(this).movement_x) { df += v_forward * ((CS(this).movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 211                         if(CS(this).movement_y) { df += v_right * ((CS(this).movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 212                 }
 213
 214 #ifdef SVQC
 215                 if(vehic.sound_nexttime < time || vehic.sounds != 1)
 216                 {
 217                         vehic.sounds = 1;
 218                         vehic.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 219                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
 220                 }
 221 #endif
 222         }
 223 #ifdef SVQC
 224         else
 225         {
 226                 if(vehic.sound_nexttime < time || vehic.sounds != 0)
 227                 {
 228                         vehic.sounds = 0;
 229                         vehic.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 230                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
 231                 }
 232         }
 233 #endif
 234
 235         // Afterburn
 236         if (PHYS_INPUT_BUTTON_JUMP(this) && vehic.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * dt))
 237         {
 238 #ifdef SVQC
 239                 if(time - vehic.wait > 0.2)
 240                         pointparticles(EFFECT_RACER_BOOSTER, vehic.origin - v_forward * 32, v_forward  * vlen(vehic.velocity), 1);
 241 #endif
 242
 243                 vehic.wait = time;
 244
 245                 if(cont & DPCONTENTS_LIQUIDSMASK)
 246                 {
 247                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * dt;
 248                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 249                 }
 250                 else
 251                 {
 252                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * dt;
 253                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 254                 }
 255
 256 #ifdef SVQC
 257                 if(vehic.invincible_finished < time)
 258                 {
 259                         traceline(vehic.origin, vehic.origin - '0 0 256', MOVE_NORMAL, vehic);
 260                         if(trace_fraction != 1.0)
 261                                 pointparticles(EFFECT_SMOKE_SMALL, trace_endpos, '0 0 0', 1);
 262
 263                         vehic.invincible_finished = time + 0.1 + (random() * 0.1);
 264                 }
 265
 266                 if(vehic.strength_finished < time)
 267                 {
 268                         vehic.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 269                         sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
 270                 }
 271 #endif
 272         }
 273         else
 274         {
 275                 vehic.strength_finished = 0;
 276                 sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 277         }
 278
 279         if(cont & DPCONTENTS_LIQUIDSMASK)
 280                 vehic.racer_watertime = time;
 281
 282         float dforce = autocvar_g_vehicle_racer_downforce;
 283         if(time - vehic.racer_watertime <= 3)
 284                 dforce = autocvar_g_vehicle_racer_water_downforce;
 285
 286         df -= v_up * (vlen(vehic.velocity) * dforce);
 287         CS(this).movement = vehic.velocity += df * dt;
 288
 289 #ifdef SVQC
 290
 291         Weapon wep1 = WEP_RACER;
 292         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 293         if (!forbidWeaponUse(this))
 294         if (PHYS_INPUT_BUTTON_ATCK(this))
 295         if (wep1.wr_checkammo1(wep1, vehic, weaponentity))
 296         {
 297                 string tagname = (vehic.cnt)
 298                     ? (vehic.cnt = 0, "tag_fire1")
 299                     : (vehic.cnt = 1, "tag_fire2");
 300                 vector org = gettaginfo(vehic, gettagindex(vehic, tagname));
 301                 w_shotorg = org;
 302                 w_shotdir = v_forward;
 303                 // Fix z-aim (for chase mode)
 304                 crosshair_trace(this);
 305                 w_shotdir.z = normalize(trace_endpos - org).z * 0.5;
 306                 wep1.wr_think(wep1, vehic, weaponentity, 1);
 307         }
 308
 309         if(autocvar_g_vehicle_racer_rocket_locktarget)
 310         {
 311                 if(time >= vehic.vehicle_last_trace)
 312                 {
 313                         crosshair_trace(this);
 314
 315                         vehicles_locktarget(vehic, (1 / autocvar_g_vehicle_racer_rocket_locking_time) * dt,
 316                                                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * dt,
 317                                                          autocvar_g_vehicle_racer_rocket_locked_time);
 318
 319                         vehic.vehicle_last_trace = time + autocvar_g_vehicle_racer_thinkrate;
 320                 }
 321
 322                 if(vehic.lock_target)
 323                 {
 324                         if(vehic.lock_strength == 1)
 325                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '1 0 0', 0);
 326                         else if(vehic.lock_strength > 0.5)
 327                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 1 0', 0);
 328                         else if(vehic.lock_strength < 0.5)
 329                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 0 1', 0);
 330                 }
 331         }
 332
 333         if(!forbidWeaponUse(this))
 334         if(time > vehic.delay)
 335         if(PHYS_INPUT_BUTTON_ATCK2(this))
 336         {
 337                 vehic.misc_bulletcounter += 1;
 338                 vehic.delay = time + 0.3;
 339
 340                 if(vehic.misc_bulletcounter == 1)
 341                 {
 342                         racer_fire_rocket_aim(this, "tag_rocket_r", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 343                         this.vehicle_ammo2 = 50;
 344                 }
 345                 else if(vehic.misc_bulletcounter == 2)
 346                 {
 347                         racer_fire_rocket_aim(this, "tag_rocket_l", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 348                         vehic.lock_strength  = 0;
 349                         vehic.lock_target       = NULL;
 350                         vehic.misc_bulletcounter = 0;
 351                         vehic.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 352                         vehic.lip = time;
 353                         this.vehicle_ammo2 = 0;
 354                 }
 355         }
 356         else if(vehic.misc_bulletcounter == 0)
 357                 this.vehicle_ammo2 = 100;
 358
 359         this.vehicle_reload2 = bound(0, 100 * ((time - vehic.lip) / (vehic.delay - vehic.lip)), 100);
 360
 361         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 362                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, dt, true);
 363
 364         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 365                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, dt, false);
 366
 367         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 368                 vehicles_regen(vehic, vehic.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, dt, false);
 369
 370         VEHICLE_UPDATE_PLAYER(this, vehic, health, racer);
 371         VEHICLE_UPDATE_PLAYER(this, vehic, energy, racer);
 372
 373         if(vehic.vehicle_flags & VHF_HASSHIELD)
 374                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, racer);
 375
 376         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 377 #endif
 378
 379         setorigin(this, vehic.origin + '0 0 32');
 380         this.oldorigin = this.origin; // negate fall damage
 381         this.velocity = vehic.velocity;
 382 }
 383
 384 void racer_think(entity this)
 385 {
 386         this.nextthink = time + autocvar_g_vehicle_racer_thinkrate;
 387
 388         tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, this);
 389
 390         vector df = this.velocity * -autocvar_g_vehicle_racer_friction;
 391         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 392
 393         float forced = autocvar_g_vehicle_racer_upforcedamper;
 394
 395         //int cont = pointcontents(this.origin - '0 0 64');
 396         traceline(this.origin - '0 0 64', this.origin - '0 0 64', MOVE_NOMONSTERS, this);
 397         //if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 398         if(trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
 399         {
 400                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 401                 this.velocity_z += 200;
 402         }
 403
 404         this.velocity += df * autocvar_g_vehicle_racer_thinkrate;
 405         if(this.velocity_z > 0)
 406                 this.velocity_z *= 1 - forced * autocvar_g_vehicle_racer_thinkrate;
 407
 408         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * autocvar_g_vehicle_racer_thinkrate);
 409         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * autocvar_g_vehicle_racer_thinkrate);
 410
 411         CSQCMODEL_AUTOUPDATE(this);
 412 }
 413
 414 void racer_exit(entity this, int eject)
 415 {
 416         vector spot;
 417
 418         setthink(this, racer_think);
 419         this.nextthink  = time;
 420         set_movetype(this, MOVETYPE_BOUNCE);
 421         sound (this.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 422
 423         if(!this.owner)
 424                 return;
 425
 426         makevectors(this.angles);
 427         if(eject)
 428         {
 429                 spot = this.origin + v_forward * 100 + '0 0 64';
 430                 spot = vehicles_findgoodexit(this, this.owner, spot);
 431                 setorigin(this.owner, spot);
 432                 this.owner.velocity = (v_up + v_forward * 0.25) * 750;
 433                 this.owner.oldvelocity = this.owner.velocity;
 434         }
 435         else
 436         {
 437                 if(vdist(this.velocity, >, 2 * autocvar_sv_maxairspeed))
 438                 {
 439                         this.owner.velocity = normalize(this.velocity) * autocvar_sv_maxairspeed * 2;
 440                         this.owner.velocity_z += 200;
 441                         spot = this.origin + v_forward * 32 + '0 0 32';
 442                         spot = vehicles_findgoodexit(this, this.owner, spot);
 443                 }
 444                 else
 445                 {
 446                         this.owner.velocity = this.velocity * 0.5;
 447                         this.owner.velocity_z += 10;
 448                         spot = this.origin - v_forward * 200 + '0 0 32';
 449                         spot = vehicles_findgoodexit(this, this.owner, spot);
 450                 }
 451                 this.owner.oldvelocity = this.owner.velocity;
 452                 setorigin(this.owner , spot);
 453         }
 454         antilag_clear(this.owner, CS(this.owner));
 455         this.owner = NULL;
 456 }
 457
 458 void racer_blowup(entity this)
 459 {
 460         this.deadflag = DEAD_DEAD;
 461         this.vehicle_exit(this, VHEF_NORMAL);
 462
 463         RadiusDamage (this, this.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 464                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 465                                         autocvar_g_vehicle_racer_blowup_radius, NULL, NULL,
 466                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 467                                         DEATH_VH_WAKI_DEATH.m_id, NULL);
 468
 469         this.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 470         setthink(this, vehicles_spawn);
 471         set_movetype(this, MOVETYPE_NONE);
 472         this.effects    = EF_NODRAW;
 473         this.solid = SOLID_NOT;
 474
 475         this.colormod  = '0 0 0';
 476         this.avelocity = '0 0 0';
 477         this.velocity  = '0 0 0';
 478
 479         setorigin(this, this.pos1);
 480 }
 481
 482 void racer_blowup_think(entity this)
 483 {
 484         this.nextthink = time;
 485
 486         if(time >= this.delay)
 487                 racer_blowup(this);
 488
 489         CSQCMODEL_AUTOUPDATE(this);
 490 }
 491
 492 void racer_deadtouch(entity this, entity toucher)
 493 {
 494         this.avelocity_x *= 0.7;
 495         this.cnt -= 1;
 496         if(this.cnt <= 0)
 497                 racer_blowup(this);
 498 }
 499
 500 spawnfunc(vehicle_racer)
 501 {
 502         if(!autocvar_g_vehicle_racer) { delete(this); return; }
 503         if(!vehicle_initialize(this, VEH_RACER, false)) { delete(this); return; }
 504 }
 505
 506 #endif // SVQC
 507
 508 METHOD(Racer, vr_impact, void(Racer thisveh, entity instance))
 509 {
 510 #ifdef SVQC
 511     if(autocvar_g_vehicle_racer_bouncepain)
 512         vehicles_impact(instance, autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 513 #endif
 514 }
 515
 516 METHOD(Racer, vr_enter, void(Racer thisveh, entity instance))
 517 {
 518 #ifdef SVQC
 519     set_movetype(instance, MOVETYPE_BOUNCE);
 520     instance.owner.vehicle_health = (instance.vehicle_health / autocvar_g_vehicle_racer_health)  * 100;
 521     instance.owner.vehicle_shield = (instance.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 522
 523     if(instance.owner.flagcarried)
 524        setorigin(instance.owner.flagcarried, '-190 0 96');
 525 #elif defined(CSQC)
 526     set_movetype(instance, MOVETYPE_BOUNCE);
 527 #endif
 528 }
 529
 530 METHOD(Racer, vr_spawn, void(Racer thisveh, entity instance))
 531 {
 532 #ifdef SVQC
 533     if(instance.scale != 0.5)
 534     {
 535         if(autocvar_g_vehicle_racer_hovertype != 0)
 536             racer_force_from_tag = vehicles_force_fromtag_maglev;
 537         else
 538             racer_force_from_tag = vehicles_force_fromtag_hover;
 539
 540         // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 541         instance.scale = 0.5;
 542         setattachment(instance.vehicle_hudmodel, instance, "");
 543         setattachment(instance.vehicle_viewport, instance, "tag_viewport");
 544
 545         instance.mass                      = 900;
 546     }
 547
 548     setthink(instance, racer_think);
 549     instance.nextthink    = time;
 550     instance.vehicle_health = autocvar_g_vehicle_racer_health;
 551     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 552
 553     set_movetype(instance, MOVETYPE_TOSS);
 554     instance.solid                = SOLID_SLIDEBOX;
 555     instance.delay                = time;
 556     instance.scale                = 0.5;
 557
 558     instance.PlayerPhysplug = racer_frame;
 559
 560     instance.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 561     instance.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 562     instance.damageforcescale = 0.5;
 563     instance.vehicle_health = autocvar_g_vehicle_racer_health;
 564     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 565 #endif
 566 }
 567
 568 METHOD(Racer, vr_death, void(Racer thisveh, entity instance))
 569 {
 570 #ifdef SVQC
 571     setSendEntity(instance, func_null); // stop networking this racer (for now)
 572     instance.health                     = 0;
 573     instance.event_damage       = func_null;
 574     instance.solid                      = SOLID_CORPSE;
 575     instance.takedamage         = DAMAGE_NO;
 576     instance.deadflag           = DEAD_DYING;
 577     set_movetype(instance, MOVETYPE_BOUNCE);
 578     instance.wait                       = time;
 579     instance.delay                      = 2 + time + random() * 3;
 580     instance.cnt                        = 1 + random() * 2;
 581     settouch(instance, racer_deadtouch);
 582
 583     Send_Effect(EFFECT_EXPLOSION_MEDIUM, instance.origin, '0 0 0', 1);
 584
 585     if(random() < 0.5)
 586         instance.avelocity_z = 32;
 587     else
 588         instance.avelocity_z = -32;
 589
 590     instance.avelocity_x = -vlen(instance.velocity) * 0.2;
 591     instance.velocity += '0 0 700';
 592     instance.colormod = '-0.5 -0.5 -0.5';
 593
 594     setthink(instance, racer_blowup_think);
 595     instance.nextthink = time;
 596 #endif
 597 }
 598
 599 #ifdef CSQC
 600 METHOD(Racer, vr_hud, void(Racer thisveh))
 601 {
 602     Vehicles_drawHUD(VEH_RACER.m_icon, "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 603                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 604                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 605 }
 606 METHOD(Racer, vr_crosshair, void(Racer thisveh, entity player))
 607 {
 608     Vehicles_drawCrosshair(vCROSS_GUIDE);
 609 }
 610 #endif
 611 METHOD(Racer, vr_setup, void(Racer thisveh, entity instance))
 612 {
 613 #ifdef SVQC
 614     instance.vehicle_exit = racer_exit;
 615
 616     // we have no need to network energy
 617     if(autocvar_g_vehicle_racer_energy)
 618     if(autocvar_g_vehicle_racer_energy_regen)
 619         instance.vehicle_flags |= VHF_ENERGYREGEN;
 620
 621     if(autocvar_g_vehicle_racer_shield)
 622         instance.vehicle_flags |= VHF_HASSHIELD;
 623
 624     if(autocvar_g_vehicle_racer_shield_regen)
 625         instance.vehicle_flags |= VHF_SHIELDREGEN;
 626
 627     if(autocvar_g_vehicle_racer_health_regen)
 628         instance.vehicle_flags |= VHF_HEALTHREGEN;
 629
 630     instance.respawntime = autocvar_g_vehicle_racer_respawntime;
 631     instance.vehicle_health = autocvar_g_vehicle_racer_health;
 632     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 633     instance.max_health = instance.vehicle_health;
 634 #endif
 635
 636 #ifdef CSQC
 637     AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 638 #endif
 639 }
 640
 641 #endif