qcsrc/common/viewloc.qc

   1 #include "viewloc.qh"
   2 #include "util.qh"
   3
   4 #if defined(CSQC)
   5     #include "../client/defs.qh"
   6     #include "constants.qh"
   7 #elif defined(MENUQC)
   8 #elif defined(SVQC)
   9         #include "../server/defs.qh"
  10 #endif
  11
  12 // client movement
  13 void viewloc_PlayerPhysics(entity this)
  14 {
  15         if(this.viewloc)
  16         {
  17                 if(this.viewloc.goalentity == this.viewloc.enemy)
  18                         return; // we can't side-scroll in this case
  19
  20                 vector old_movement = PHYS_CS(this).movement;
  21                 PHYS_CS(this).movement_x = old_movement_y;
  22                 if((this.viewloc.spawnflags & VIEWLOC_FREEMOVE) && !(time < this.ladder_time))
  23                         PHYS_CS(this).movement_y = old_movement_x;
  24                 else
  25                         PHYS_CS(this).movement_y = 0;
  26
  27                 vector level_start, level_end;
  28                 level_start = this.viewloc.enemy.origin;
  29                 level_end = this.viewloc.goalentity.origin;
  30                 vector forward = vectoangles(normalize(level_end - level_start));
  31                 vector backward = vectoangles(normalize(level_start - level_end));
  32
  33                 if((this.viewloc.spawnflags & VIEWLOC_FREEMOVE) && this.angles_y < 0 && !(time < this.ladder_time))
  34                         PHYS_CS(this).movement_y = -PHYS_CS(this).movement_y;
  35
  36                 if(this.viewloc.spawnflags & VIEWLOC_FREEAIM)
  37                 {
  38                         if(this.angles_y > 0)
  39                                 PHYS_CS(this).movement_x = -PHYS_CS(this).movement_x;
  40                 }
  41                 else
  42                 {
  43                         if(PHYS_CS(this).movement_x < 0)
  44                                 PHYS_CS(this).movement_x = -PHYS_CS(this).movement_x;
  45
  46                         if(PHYS_CS(this).movement_x < 0) // left
  47                                 this.angles_y = backward.y;
  48                         if(PHYS_CS(this).movement_x > 0) // right
  49                                 this.angles_y = forward.y;
  50                 }
  51         #if 0
  52                 //if(!PHYS_INPUT_BUTTON_CROUCH(this) && !IS_DUCKED(this))
  53                 if(!(this.viewloc.spawnflags & VIEWLOC_FREEMOVE))
  54                 {
  55 #ifdef SVQC
  56                         //PHYS_INPUT_BUTTON_CROUCH(this) = (old_movement_x < 0);
  57                         if (old_movement.x < 0)
  58                                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
  59 #elif defined(CSQC)
  60                         if (old_movement.x < 0)
  61                         {
  62                                 input_buttons |= BIT(4);
  63                                 this.flags |= FL_DUCKED;
  64                         }
  65                         //else { input_buttons &= ~16; this.flags &= ~FL_DUCKED; }
  66 #endif
  67                 }
  68         #endif
  69         }
  70 }
  71
  72 #ifdef CSQC
  73
  74 void viewloc_SetTags(entity this)
  75 {
  76         if(this.viewloc && wasfreed(this.viewloc))
  77                 this.viewloc = NULL;
  78
  79         if(this.viewloc.entnum != this.tag_networkviewloc)
  80         if(this.tag_networkviewloc == 0)
  81                 this.viewloc = NULL;
  82         else
  83                 this.viewloc = findfloat(NULL, entnum, this.tag_networkviewloc);
  84 }
  85
  86 vector CursorToWorldCoord(vector mpos)
  87 {
  88         vector wnear = cs_unproject(vec2(mpos)); // determine the world coordinate for the mouse cursor upon the near clip plane
  89         vector wfar = cs_unproject(vec3(mpos.x, mpos.y, max_shot_distance)); // determine the world coordinate for the mouse cursor upon the far clip plane, with an outrageously large value as a workaround for dp.
  90         traceline(wnear, wfar, MOVE_NOMONSTERS, NULL);
  91         return trace_endpos;
  92 }
  93
  94 vector old_camera_angle = '0 0 0';
  95 bool autocvar_cam_snap_close;
  96 bool autocvar_cam_track;
  97 bool autocvar_cam_snap_hard;
  98 bool autocvar_cam_snap_unlock;
  99 bool autocvar_cam_useangle = true;
 100 void viewloc_SetViewLocation()
 101 {
 102         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 103         if (!view) return;
 104         //NOTE: the "cam_" cvars sould probably be changed out with a spawnflag or an entity key. I have it like this for my testing -- Player_2
 105         if(view.viewloc && !wasfreed(view.viewloc) && view.viewloc.enemy && view.viewloc.goalentity)
 106         {
 107                 bool have_sidescroll = (view.viewloc.enemy != view.viewloc.goalentity);
 108                 vector position_a = view.viewloc.enemy.origin;
 109                 vector position_b = view.viewloc.goalentity.origin;
 110                 vector camera_angle = '0 0 0';
 111                 vector camera_position;
 112
 113                 /*TODO: have the camera only move when a player moves too much from the center of the camera
 114                  * basically the player would move around in a small "box" in the center of the screen with out changing the camera position or angles */
 115                 camera_position = vec_bounds_in(view.origin, position_a, position_b);
 116
 117                 // use camera's angle when possible
 118                 if (autocvar_cam_useangle) {
 119                         camera_angle = view.viewloc.enemy.movedir;
 120                 }
 121
 122                 // a tracking camera follows the player when it leaves the world box
 123                 if (autocvar_cam_track || !have_sidescroll) {
 124                         camera_angle = aim_vec (camera_position, view.origin);
 125                 }
 126
 127                 // hard snap changes the angle as soon as it crosses over the nearest 90 degree mark
 128                 if (autocvar_cam_snap_hard) {
 129                         camera_angle = angle_snap_vec(aim_vec(camera_position, view.origin), 90);
 130                 }
 131
 132                 // tries to avoid snapping unless it *really* needs to
 133                 if (autocvar_cam_snap_close) {
 134                         // like hard snap, but don't snap angles yet.
 135                         camera_angle = aim_vec(camera_position, view.origin);
 136
 137                         /* if the difference between the old and new angle is 60 degrees or more, switch angles.
 138                          * NOTE: bug/feature: this will use non-snaped angles for one frame.
 139                          * doing this results in less code, faster code, and a smoother transisition between angles.
 140                          */
 141                         float camera_angle_diff = max(camera_angle.y, old_camera_angle.y) - min(camera_angle.y, old_camera_angle.y);
 142
 143                         if (60 <= camera_angle_diff) { // use new angles
 144                                 old_camera_angle.y = angle_snap_f(camera_angle.y, 90);
 145                         } else { // use old angles
 146                                 camera_angle.y = old_camera_angle.y;
 147                         }
 148                 }
 149
 150                 //unlocking this allows the camera to look up and down. this also allows a top-down view.
 151                 if (!autocvar_cam_snap_unlock) {
 152                         camera_angle.x = 0;
 153                         camera_angle.z = 0;
 154                 }
 155
 156 #if 0
 157                 LOG_TRACE(vtos(camera_position));
 158                 LOG_TRACE(vtos(old_camera_angle));
 159                 LOG_TRACE(vtos(camera_angle));
 160 #endif
 161
 162                 freeze_org = getpropertyvec(VF_ORIGIN);
 163                 freeze_ang = getpropertyvec(VF_ANGLES);
 164                 setproperty(VF_ORIGIN, camera_position);
 165                 setproperty(VF_ANGLES, camera_angle);
 166
 167                 if(spectatee_status)
 168                         return; // if spectating, don't replace angles or inputs!
 169
 170                 if (have_sidescroll) {
 171                         vector view_angle = view.angles;
 172                         if (!(view.viewloc.spawnflags & VIEWLOC_FREEAIM)) {
 173                                 vector avatar_facing_dir;
 174                                 // get the player's forward-facing direction, based on positions a and b
 175                                 if (0 == input_movevalues.y) {
 176                                         avatar_facing_dir = view_angle; // default to the previous values
 177                                 } else if (0 > input_movevalues.y) { // left is forward
 178                                         avatar_facing_dir = vectoangles(normalize(vec_to_max(position_b, position_a) - vec_to_min(position_b, position_a)));
 179                                 } else { // right is forward
 180                                         avatar_facing_dir = vectoangles(normalize(vec_to_min(position_b, position_a) - vec_to_max(position_b, position_a)));
 181                                 }
 182                                 view_angle.y = avatar_facing_dir.y; // snap avatar to look on along the correct axis
 183
 184                                 // if (0 == input_movevalues.x) look straight ahead
 185                                 if (!(view.viewloc.spawnflags & VIEWLOC_FREEMOVE)) {
 186                                         if (0 > input_movevalues.x) { // look up
 187                                                 view_angle.x = 50;
 188                                         } else if (0 < input_movevalues.x) { // look down
 189                                                 view_angle.x = -50;
 190                                         }
 191                                 }
 192                         } else {
 193                                 vector mpos = CursorToWorldCoord(viewloc_mousepos);
 194                                 mpos.x = view.origin.x; // replace the cursor's x position with the player's
 195                                 view_angle = aim_vec(view.origin + view.view_ofs, mpos); // get new angles
 196                         }
 197                         view.angles_y = view_angle.y;
 198                         setproperty(VF_CL_VIEWANGLES, view_angle);
 199                 }
 200         }
 201 }
 202
 203 STATIC_INIT_LATE(viewloc_cursor)
 204 {
 205         // fix the mouse position on init so it isn't in the corner
 206         viewloc_mousepos = '0.5 0 0' * autocvar_vid_conwidth + '0 0.5 0' * autocvar_vid_conheight;
 207 }
 208
 209 #endif