qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/defs.qh>
   7         #include "../constants.qh"
   8         #include "../stats.qh"
   9         #include <lib/warpzone/anglestransform.qh>
  10         #include <lib/warpzone/common.qh>
  11         #include <lib/warpzone/client.qh>
  12         #include "../util.qh"
  13         #include <client/autocvars.qh>
  14         #include "../deathtypes/all.qh"
  15         #include <lib/csqcmodel/interpolate.qh>
  16         #include "../physics/movetypes/movetypes.qh"
  17         #include <client/main.qh>
  18         #include <lib/csqcmodel/cl_model.qh>
  19 #elif defined(MENUQC)
  20 #elif defined(SVQC)
  21         #include <common/items/_mod.qh>
  22     #include <lib/warpzone/anglestransform.qh>
  23     #include <lib/warpzone/common.qh>
  24     #include <lib/warpzone/util_server.qh>
  25     #include <lib/warpzone/server.qh>
  26     #include "../constants.qh"
  27     #include "../stats.qh"
  28     #include "../teams.qh"
  29     #include "../util.qh"
  30     #include "../monsters/_mod.qh"
  31     #include "config.qh"
  32     #include <server/weapons/csqcprojectile.qh>
  33     #include <server/weapons/tracing.qh>
  34     #include "../t_items.qh"
  35     #include <server/autocvars.qh>
  36     #include <server/constants.qh>
  37     #include <server/defs.qh>
  38     #include "../notifications/all.qh"
  39     #include "../deathtypes/all.qh"
  40     #include <server/mutators/_mod.qh>
  41     #include "../mapinfo.qh"
  42     #include <server/command/_mod.qh>
  43     #include <lib/csqcmodel/sv_model.qh>
  44     #include <server/portals.qh>
  45     #include <server/g_hook.qh>
  46 #endif
  47 #ifdef GAMEQC
  48         #include "calculations.qc"
  49 #endif
  50 #ifdef SVQC
  51         #include "config.qc"
  52 #endif
  53 #define IMPLEMENTATION
  54 #include "all.inc"
  55 #undef IMPLEMENTATION
  56
  57 // WEAPON PLUGIN SYSTEM
  58
  59 WepSet _WepSet_FromWeapon(int a)
  60 {
  61         a -= WEP_FIRST;
  62         if (Weapons_MAX > 24)
  63                 if (a >= 24)
  64                 {
  65                         a -= 24;
  66                         if (Weapons_MAX > 48)
  67                                 if (a >= 24)
  68                                 {
  69                                         a -= 24;
  70                                         return '0 0 1' * (2 ** a);
  71                                 }
  72                         return '0 1 0' * (2 ** a);
  73                 }
  74         return '1 0 0' * (2 ** a);
  75 }
  76 #ifdef SVQC
  77         void WriteWepSet(float dst, WepSet w)
  78         {
  79                 if (Weapons_MAX > 48) WriteInt72_t(dst, w);
  80                 else if (Weapons_MAX > 24) WriteInt48_t(dst, w);
  81                 else WriteInt24_t(dst, w.x);
  82         }
  83 #endif
  84 #ifdef CSQC
  85         WepSet WepSet_GetFromStat()
  86         {
  87                 return STAT(WEAPONS);
  88         }
  89         WepSet WepSet_GetFromStat_InMap()
  90         {
  91                 return STAT(WEAPONSINMAP);
  92         }
  93         WepSet ReadWepSet()
  94         {
  95                 if (Weapons_MAX > 48) return ReadInt72_t();
  96                 if (Weapons_MAX > 24) return ReadInt48_t();
  97                 return ReadInt24_t() * '1 0 0';
  98         }
  99 #endif
 100
 101 string W_FixWeaponOrder(string order, float complete)
 102 {
 103         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 104 }
 105 string W_NameWeaponOrder_MapFunc(string s)
 106 {
 107         int i = stof(s);
 108         if (s == "0" || i)
 109         {
 110                 entity wi = Weapons_from(i);
 111                 if (wi != WEP_Null) return wi.netname;
 112         }
 113         return s;
 114 }
 115
 116 string W_UndeprecateName(string s)
 117 {
 118         switch (s)
 119         {
 120                 case "nex": return "vortex";
 121                 case "rocketlauncher": return "devastator";
 122                 case "laser": return "blaster";
 123                 case "minstanex": return "vaporizer";
 124                 case "grenadelauncher": return "mortar";
 125                 case "uzi": return "machinegun";
 126                 default: return s;
 127         }
 128 }
 129 string W_NameWeaponOrder(string order)
 130 {
 131         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 132 }
 133 string W_NumberWeaponOrder_MapFunc(string s)
 134 {
 135         if (s == "0" || stof(s)) return s;
 136         s = W_UndeprecateName(s);
 137         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 138         return s;
 139 }
 140 string W_NumberWeaponOrder(string order)
 141 {
 142         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 143 }
 144
 145 float W_FixWeaponOrder_BuildImpulseList_buf[Weapons_MAX];
 146 string W_FixWeaponOrder_BuildImpulseList_order;
 147 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 148 {
 149         float h;
 150         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 151         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 152         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 153 }
 154 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 155 {
 156         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 157         Weapon e1 = Weapons_from(si);
 158         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 159         Weapon e2 = Weapons_from(sj);
 160         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 161         if (d != 0) return -d;  // high impulse first!
 162         return strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 163                 sprintf(" %d ", si), 0)
 164                -
 165                strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 166                 sprintf(" %d ", sj), 0)
 167         ;  // low char index first!
 168 }
 169 string W_FixWeaponOrder_BuildImpulseList(string o)
 170 {
 171         int i;
 172         W_FixWeaponOrder_BuildImpulseList_order = o;
 173         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 174                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 175         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 176                 NULL);
 177         o = "";
 178         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 179                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 180         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 181         return substring(o, 1, -1);
 182 }
 183
 184 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 185 {
 186         return W_FixWeaponOrder(order, 0);
 187 }
 188
 189 string W_FixWeaponOrder_ForceComplete(string order)
 190 {
 191         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 192         return W_FixWeaponOrder(order, 1);
 193 }
 194
 195 void W_RandomWeapons(entity e, float n)
 196 {
 197         int i;
 198         WepSet remaining;
 199         WepSet result;
 200         remaining = e.weapons;
 201         result = '0 0 0';
 202         for (i = 0; i < n; ++i)
 203         {
 204                 RandomSelection_Init();
 205                 FOREACH(Weapons, it != WEP_Null, {
 206                         if (remaining & (it.m_wepset))
 207                                 RandomSelection_AddEnt(it, 1, 1);
 208                 });
 209                 Weapon w = RandomSelection_chosen_ent;
 210                 result |= WepSet_FromWeapon(w);
 211                 remaining &= ~WepSet_FromWeapon(w);
 212         }
 213         e.weapons = result;
 214 }
 215
 216 string GetAmmoPicture(.int ammotype)
 217 {
 218         switch (ammotype)
 219         {
 220                 case ammo_shells:  return ITEM_Shells.m_icon;
 221                 case ammo_nails:   return ITEM_Bullets.m_icon;
 222                 case ammo_rockets: return ITEM_Rockets.m_icon;
 223                 case ammo_cells:   return ITEM_Cells.m_icon;
 224                 case ammo_plasma:  return ITEM_Plasma.m_icon;
 225                 case ammo_fuel:    return ITEM_JetpackFuel.m_icon;
 226                 default: return "";  // wtf, no ammo type?
 227         }
 228 }
 229
 230 #ifdef CSQC
 231         .int GetAmmoFieldFromNum(int i)
 232         {
 233                 switch (i)
 234                 {
 235                         case 0: return ammo_shells;
 236                         case 1: return ammo_nails;
 237                         case 2: return ammo_rockets;
 238                         case 3: return ammo_cells;
 239                         case 4: return ammo_plasma;
 240                         case 5: return ammo_fuel;
 241                         default: return ammo_none;
 242                 }
 243         }
 244
 245         int GetAmmoStat(.int ammotype)
 246         {
 247                 switch (ammotype)
 248                 {
 249                         case ammo_shells: return STAT_SHELLS;
 250                         case ammo_nails: return STAT_NAILS;
 251                         case ammo_rockets: return STAT_ROCKETS;
 252                         case ammo_cells: return STAT_CELLS;
 253                         case ammo_plasma: return STAT_PLASMA.m_id;
 254                         case ammo_fuel: return STAT_FUEL.m_id;
 255                         default: return -1;
 256                 }
 257         }
 258 #endif
 259
 260 string W_Sound(string w_snd)
 261 {
 262         string output = strcat("weapons/", w_snd);
 263         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 264         return M_ARGV(1, string);
 265 }
 266
 267 string W_Model(string w_mdl)
 268 {
 269         string output = strcat("models/weapons/", w_mdl);
 270         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 271         return M_ARGV(1, string);
 272 }
 273
 274 #ifdef GAMEQC
 275 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 276 {
 277         switch (algn)
 278         {
 279                 default:
 280                 case 3:
 281                         // right alignment
 282                         break;
 283                 case 4:
 284                         // left
 285                         vecs.y = -vecs.y;
 286                         break;
 287                 case 1:
 288                 case 2:
 289                         // center
 290                         vecs.y = 0;
 291                         vecs.z -= 2;
 292                         break;
 293         }
 294         return vecs;
 295 }
 296
 297 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 298 {
 299 #ifdef SVQC
 300         string s;
 301 #endif
 302         if (visual)
 303         {
 304                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 305         }
 306 #ifdef SVQC
 307         else if (autocvar_g_shootfromeye)
 308         {
 309                 vecs.y = vecs.z = 0;
 310         }
 311         else if (autocvar_g_shootfromcenter)
 312         {
 313                 vecs.y = 0;
 314                 vecs.z -= 2;
 315         }
 316         else if ((s = autocvar_g_shootfromfixedorigin) != "")
 317         {
 318                 vector v = stov(s);
 319                 if (y_is_right) v.y = -v.y;
 320                 if (v.x != 0) vecs.x = v.x;
 321                 vecs.y = v.y;
 322                 vecs.z = v.z;
 323         }
 324 #endif
 325         else  // just do the same as top
 326         {
 327                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 328         }
 329
 330         return vecs;
 331 }
 332
 333 #define shotorg_adjust shotorg_adjust_values
 334
 335 /**
 336  * supported formats:
 337  *
 338  * 1. simple animated model, muzzle flash handling on h_ model:
 339  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 340  *      tags:
 341  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 342  *        shell = casings ejection point (must be on the right hand side of the gun)
 343  *        weapon = attachment for v_tuba.md3
 344  *    v_tuba.md3 - first and third person model
 345  *    g_tuba.md3 - pickup model
 346  *
 347  * 2. simple animated model, muzzle flash handling on v_ model:
 348  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 349  *      tags:
 350  *        weapon = attachment for v_tuba.md3
 351  *    v_tuba.md3 - first and third person model
 352  *      tags:
 353  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 354  *        shell = casings ejection point (must be on the right hand side of the gun)
 355  *    g_tuba.md3 - pickup model
 356  *
 357  * 3. fully animated model, muzzle flash handling on h_ model:
 358  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 359  *      tags:
 360  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 361  *        shell = casings ejection point (must be on the right hand side of the gun)
 362  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 363  *    v_tuba.md3 - third person model
 364  *    g_tuba.md3 - pickup model
 365  *
 366  * 4. fully animated model, muzzle flash handling on v_ model:
 367  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 368  *      tags:
 369  *        shot = muzzle end (shot origin)
 370  *        shell = casings ejection point (must be on the right hand side of the gun)
 371  *    v_tuba.md3 - third person model
 372  *      tags:
 373  *        shot = muzzle end (for muzzle flashes)
 374  *    g_tuba.md3 - pickup model
 375  *
 376  * writes:
 377  *   this.origin, this.angles
 378  *   this.weaponchild
 379  *   this.movedir, this.view_ofs
 380  *   attachment stuff
 381  *   anim stuff
 382  * to free:
 383  *   call again with ""
 384  *   remove the ent
 385  */
 386 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 387 {
 388         if (name == "")
 389         {
 390                 vector oldmin = this.mins, oldmax = this.maxs;
 391                 setmodel(this, MDL_Null);
 392                 setsize(this, oldmin, oldmax);
 393                 if (this.weaponchild) delete(this.weaponchild);
 394                 this.weaponchild = NULL;
 395                 this.movedir = '0 0 0';
 396                 this.spawnorigin = '0 0 0';
 397                 this.oldorigin = '0 0 0';
 398                 this.anim_fire1  = '0 1 0.01';
 399                 this.anim_fire2  = '0 1 0.01';
 400                 this.anim_idle   = '0 1 0.01';
 401                 this.anim_reload = '0 1 0.01';
 402         }
 403         else
 404         {
 405                 // if there is a child entity, hide it until we're sure we use it
 406                 if (this.weaponchild) this.weaponchild.model = "";
 407                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 408                 int v_shot_idx;  // used later
 409                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 410
 411                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 412                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 413                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 414                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 415                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 416                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 417
 418                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 419                 // if we don't, this is a "real" animated model
 420                 string t;
 421                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 422                 {
 423                         if (!this.weaponchild)
 424                         {
 425                                 this.weaponchild = new(weaponchild);
 426 #ifdef CSQC
 427                                 this.weaponchild.drawmask = MASK_NORMAL;
 428                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 429 #endif
 430                         }
 431                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 432                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 433                         setattachment(this.weaponchild, this, t);
 434                 }
 435                 else
 436                 {
 437                         if (this.weaponchild) delete(this.weaponchild);
 438                         this.weaponchild = NULL;
 439                 }
 440
 441                 setsize(this, '0 0 0', '0 0 0');
 442                 setorigin(this, '0 0 0');
 443                 this.angles = '0 0 0';
 444                 this.frame = 0;
 445 #ifdef SVQC
 446                 this.viewmodelforclient = NULL;
 447 #else
 448                 this.renderflags &= ~RF_VIEWMODEL;
 449 #endif
 450                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 451                 {
 452                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 453                 }
 454                 else
 455                 {
 456                         int idx;
 457                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 458                         {
 459                                 this.movedir = gettaginfo(this, idx);
 460                         }
 461                         else
 462                         {
 463                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 464                                         this.model);
 465                                 this.movedir = '0 0 0';
 466                         }
 467                 }
 468                 {
 469                         int idx = 0;
 470                         // v_ model attached to invisible h_ model
 471                         if (this.weaponchild
 472                             && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 473                         {
 474                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 475                         }
 476                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 477                         {
 478                                 this.spawnorigin = gettaginfo(this, idx);
 479                         }
 480                         else
 481                         {
 482                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 483                                         this.model);
 484                                 this.spawnorigin = this.movedir;
 485                         }
 486                 }
 487                 if (v_shot_idx)
 488                 {
 489                         this.oldorigin = '0 0 0';  // use regular attachment
 490                 }
 491                 else
 492                 {
 493                         int idx;
 494                         if (this.weaponchild)
 495                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 496                         else
 497                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 498                         if (idx)
 499                         {
 500                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 501                         }
 502                         else
 503                         {
 504                                 LOG_WARNF(
 505                                         "weapon model %s does not support the 'handle' tag "
 506                                         "and neither does the v_ model support the 'shot' tag, "
 507                                         "will display muzzle flashes TOTALLY wrong\n",
 508                                         this.model);
 509                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 510                         }
 511                 }
 512
 513 #ifdef SVQC
 514                 this.viewmodelforclient = this.owner;
 515 #else
 516                 this.renderflags |= RF_VIEWMODEL;
 517 #endif
 518         }
 519
 520         this.view_ofs = '0 0 0';
 521
 522         if (this.movedir.x >= 0)
 523         {
 524                 //int algn = STAT(GUNALIGN, this.owner);
 525                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 526         #ifdef SVQC
 527                 this.m_gunalign = algn;
 528         #endif
 529                 vector v = this.movedir;
 530                 this.movedir = shotorg_adjust(v, false, false, algn);
 531                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 532         }
 533         int compressed_shotorg = compressShotOrigin(this.movedir);
 534         // make them match perfectly
 535 #ifdef SVQC
 536         this.movedir = decompressShotOrigin(this.owner.stat_shotorg = compressed_shotorg);
 537 #else
 538         this.movedir = decompressShotOrigin(compressed_shotorg);
 539 #endif
 540
 541         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 542
 543         // check if an instant weapon switch occurred
 544         setorigin(this, this.view_ofs);
 545         if (!_anim) return;
 546         // reset animstate now
 547         this.wframe = WFRAME_IDLE;
 548         setanim(this, this.anim_idle, true, false, true);
 549 }
 550 #endif
 551
 552 #ifdef GAMEQC
 553
 554 REGISTER_NET_TEMP(wframe)
 555 #ifdef CSQC
 556 NET_HANDLE(wframe, bool isNew)
 557 {
 558         vector a;
 559         a.x = ReadCoord();
 560     a.y = ReadCoord();
 561     a.z = ReadCoord();
 562     int slot = ReadByte();
 563         bool restartanim = ReadByte();
 564         entity wepent = viewmodels[slot];
 565         if(a.x == wepent.anim_idle_x) // we don't need to enforce idle animation
 566                 wepent.animstate_looping = false;
 567         else
 568                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 569         wepent.state = ReadByte();
 570         wepent.weapon_nextthink = ReadFloat();
 571         switch (wepent.state)
 572         {
 573                 case WS_RAISE:
 574                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 575                         break;
 576                 case WS_DROP:
 577                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 578                         break;
 579         default:
 580             wepent.weapon_switchdelay = 0;
 581             break;
 582         }
 583         return true;
 584 }
 585 #endif
 586
 587 #ifdef SVQC
 588 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim)
 589 {
 590         if (!IS_REAL_CLIENT(actor)) return;
 591         int channel = MSG_ONE;
 592         msg_entity = actor;
 593         WriteHeader(channel, wframe);
 594         WriteCoord(channel, a.x);
 595         WriteCoord(channel, a.y);
 596         WriteCoord(channel, a.z);
 597         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 598         WriteByte(channel, restartanim);
 599         WriteByte(channel, weaponentity.state);
 600         WriteFloat(channel, weaponentity.weapon_nextthink);
 601 }
 602 #endif
 603
 604 REGISTER_NET_C2S(w_whereis)
 605 #ifdef SVQC
 606 void Weapon_whereis(Weapon this, entity cl);
 607 NET_HANDLE(w_whereis, bool)
 608 {
 609         Weapon wpn = ReadRegistered(Weapons);
 610         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 611         return true;
 612 }
 613 #else
 614 void w_whereis(Weapon this)
 615 {
 616         int channel = MSG_C2S;
 617         WriteHeader(channel, w_whereis);
 618         WriteRegistered(Weapons, channel, this);
 619 }
 620 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 621 {
 622         switch (request)
 623         {
 624                 case CMD_REQUEST_COMMAND:
 625                 {
 626                         string s = argv(1);
 627                         if (s == "all")
 628                         {
 629                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 630                                 return;
 631                         }
 632                         if (s == "unowned")
 633                         {
 634                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 635                                 return;
 636                         }
 637                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 638                         {
 639                                 w_whereis(it);
 640                                 return;
 641                         });
 642                 }
 643                 default:
 644                 {
 645                         LOG_INFOF("Incorrect parameters for ^2%s^7\n", "weapon_find");
 646                 }
 647                 case CMD_REQUEST_USAGE:
 648                 {
 649                         LOG_INFO("\nUsage:^3 cl_cmd weapon_find weapon\n");
 650                         LOG_INFO("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.\n");
 651                         return;
 652                 }
 653         }
 654 }
 655 #endif
 656
 657
 658 #endif
 659
 660 #endif